source: project/release/5/mailbox/trunk/inline-queue.scm @ 39700

Last change on this file since 39700 was 39700, checked in by Kon Lovett, 2 months ago

new test runner, remove "primitives", stop variant `check-' proc gen, fix record printers

File size: 2.6 KB
Line 
1;;;; inline-queue.scm  -*- Scheme -*-
2;;;; Kon Lovett, Jun '10
3
4;; Issues
5;;
6;; - Requires (only record-variants define-record-type-variant)
7;; & (include "chicken-primitive-object-inlines")
8
9;; Support
10
11;;
12
13;the identifier needs to be defined by somebody
14(define queue 'queue)
15(define-record-type-variant queue (unsafe unchecked inline)
16  (%make-queue hd tl)
17  (%queue?)
18  (hd %queue-first-pair %queue-first-pair-set!)
19  (tl %queue-last-pair %queue-last-pair-set!) )
20
21(define-inline (%make-empty-queue) (%make-queue '() '()))
22
23(define-inline (%queue-empty? q) (null? (%queue-first-pair q)))
24(define-inline (%queue-count q) (length (%queue-first-pair q)))
25
26;; Operations
27
28(define-inline (%queue-last-pair-empty! q) (%queue-last-pair-set! q '()))
29
30(define-inline (%queue-add! q datum)
31  (let ((new-pair (cons datum '())))
32    (if (null? (%queue-first-pair q))
33      (%queue-first-pair-set! q new-pair)
34      (set-cdr! (%queue-last-pair q) new-pair) )
35    (%queue-last-pair-set! q new-pair) ) )
36
37(define-inline (%queue-remove! q)
38  (let* ((first-pair (%queue-first-pair q))
39         (next-pair (cdr first-pair)))
40    (%queue-first-pair-set! q next-pair)
41    (when (null? next-pair) (%queue-last-pair-empty! q) )
42    (car first-pair) ) )
43
44(define-inline (%queue-push-back! q item)
45  (let ((newlist (cons item (%queue-first-pair q))))
46    (%queue-first-pair-set! q newlist)
47    (when (null? (%queue-last-pair q)) (%queue-last-pair-set! q newlist) ) ) )
48
49(define-inline (%queue-push-back-list! q itemlist)
50  (let ((newlist (append! (list-copy itemlist) (%queue-first-pair q))))
51    (%queue-first-pair-set! q newlist)
52    (if (null? newlist)
53      (%queue-last-pair-empty! q)
54      (%queue-last-pair-set! q (last-pair newlist) ) ) ) )
55
56(define-inline (%queue-extract-pair! q targ-pair)
57  ;scan queue list until we find the item to remove
58  (let scanning ((this-pair (%queue-first-pair q)) (prev-pair '()))
59    ;keep scanning until found
60    (cond
61      ;should not happen but no infinite loops
62      ((null? this-pair)
63        ;note that the pair to extract is in fact gone so ...
64        (warning "cannot find queue pair to extract; simultaneous operations?"))
65      ;found?
66      ((eq? this-pair targ-pair)
67        ;so cut out the pair
68        (let ((next-pair (cdr this-pair)))
69          ;at the head of the list, or in the body?
70          (if (null? prev-pair)
71            (%queue-first-pair-set! q next-pair)
72            (set-cdr! prev-pair next-pair) )
73          ;when the cut pair is the last item update the last pair ref.
74          (when (eq? this-pair (%queue-last-pair q))
75            (%queue-last-pair-set! q prev-pair)) ) )
76      ;not found
77      (else
78        (scanning (cdr this-pair) this-pair) ) ) ) )
Note: See TracBrowser for help on using the repository browser.