source: project/release/4/intarweb/trunk/tests/run.scm @ 11914

Last change on this file since 11914 was 11914, checked in by sjamaan, 13 years ago

Implement improvement for entity-tag parser which makes it distinguish between quoted strong headers starting with 'W/' as value and regular weak headers

File size: 25.3 KB
Line 
1(require-extension test extras regex uri-generic intarweb)
2
3(define-syntax test-error*
4  (syntax-rules ()
5    ((_ ?msg (?error-type ...) ?expr)
6     (let-syntax ((expression:
7                   (syntax-rules ()
8                     ((_ ?expr)
9                      (condition-case (begin ?expr "<no error thrown>")
10                                      ((?error-type ...) '(?error-type ...))
11                                      (exn () (##sys#slot exn 1)))))))
12       (test ?msg '(?error-type ...) (expression: ?expr))))
13    ((_ ?msg ?error-type ?expr)
14     (test-error* ?msg (?error-type) ?expr))
15    ((_ ?error-type ?expr)
16     (test-error* (sprintf "~S" '?expr) ?error-type ?expr))))
17
18(define (test-read-headers str)
19  (call-with-input-string str
20    (lambda (in)
21      (read-headers in))))
22
23(test-group "Headers"
24  (test-group "Single headers"
25   (parameterize ((single-headers '(foo qux))
26                  (header-parsers `((foo . ,(single identity))
27                                    (qux . ,(single identity)))))
28     (let ((headers (test-read-headers "foo: bar\r\nqux:\t   \tmooh\t   \r\n\r\n")))
29       (test "Basic test"
30             '("bar") (header-values 'foo headers))
31       ;; RFC 2616 4.2
32       (test "Extra spaces are ignored"
33             '("mooh") (header-values 'qux headers)))
34     (let ((headers (test-read-headers "foo: bar\r\n qux: mooh\r\nquux: mumble\r\n\r\n")))
35       ;; RFC 2616 2.2
36       (test "Continuation chars"
37             '("bar qux: mooh") (header-values 'foo headers)))
38     ;; Not in RFC but common behaviour - also, robustness principle
39     (let ((headers (test-read-headers "foo: bar\r\nfoo: qux\r\n")))
40       (test "Multiple headers for singular header types discarded"
41             '("qux") (header-values 'foo headers)))))
42  ;; All this RFC 2616 4.2
43  (test-group "Multi-headers"
44   (parameterize ((header-parsers `((foo . ,(multiple identity)))))
45     (let ((headers (test-read-headers "foo: bar\r\nfoo: qux\r\nquux: mumble\r\n\r\n")))
46       (test "Multiple headers"
47             '("bar" "qux") (header-values 'foo headers)))
48     (let ((headers (test-read-headers "Foo: bar\r\nFoO: qux\r\nquux: mumble\r\n\r\n")))
49       (test "Multiple headers: case insensitivity"
50             '("bar" "qux") (header-values 'foo headers)))
51     (let ((headers (test-read-headers "foo: bar, qux\r\nquux: mumble\r\n\r\n")))
52       (test "Comma-separated headers"
53             '("bar" "qux") (header-values 'foo headers)))
54     (let ((headers (test-read-headers "foo: \"ba\\\"r, qux\"\r\nfoo: mooh\r\n\r\n")))
55       (test "Quoted headers"
56             '("ba\"r, qux" "mooh") (header-values 'foo headers))))
57   ;; RFC 2616 4.5
58   ;; "Unrecognized header fields are treated as entity-header fields."
59   ;;
60   ;; RFC 2616 7.1
61   ;; "Unrecognized header fields SHOULD be ignored by the recipient and MUST be
62   ;;  forwarded by transparent proxies."
63   (let ((headers (test-read-headers "unknown: foo, bar\r\nunknown: blah\r\n\r\n")))
64     (test "Unknown headers are not parsed and put into lists"
65           '("foo, bar" "blah") (header-values 'unknown headers))))
66  (test-group "Miscellaneous"
67    (parameterize ((header-parsers `((foo . ,(multiple identity)))))
68      (test-error "Missing header contents" (test-read-headers "foo\r\n\r\n"))
69      ;; RFC 2616 2.2
70      ;; "The backslash character ("\") MAY be used as a single-character
71      ;; quoting mechanism only within quoted-string and comment constructs."
72      ;;     quoted-pair = "\" CHAR
73      ;; CHAR implies any char, *including* CR/LF. This is clarified by RFC 822,
74      ;; on which RFC 2616 is based.
75      ;; Apparently, even \CRLF is allowed (as opposed to \CR\LF)
76      (test "Embedded newlines"
77            '("bar\r\nqux")
78            ;; XXX Should we interpret "\\\r\n" as "\r\n", too?
79            (header-values 'foo (test-read-headers "Foo: \"bar\\\r\\\nqux\""))))))
80
81(test-group "Specialized header parsers"
82  (test-group "Quality parameter"
83   (let* ((headers (test-read-headers "Accept: text/plain; Q=0.5, text/html, text/plain; q=0.123456, application/pdf; q=1.2345, text/xml; q=-0.234, text/whatever; q="))
84          (accept  (header-contents 'accept headers)))
85     ;; RFC 2616 3.6: "All transfer-coding values are case insensitive".
86     ;; This includes the parameter name (attribute) and value.
87     (test "Explicit quality value (case-insensitive)"
88           0.5 (get-quality (first accept)))
89     (test "Explicit quality encoding value"
90           'text/plain (get-value (first accept)))
91     ;; RFC 2616 3.9
92     (test "Implicit quality value"
93           1.0 (get-quality (second accept)))
94     (test "Implicit quality encoding value"
95           'text/html (get-value (second accept)))
96     (test "Quality values have only three digits"
97           0.123 (get-quality (third accept)))
98     (test "Quality values maximum is 1.0"
99           1.0 (get-quality (fourth accept)))
100     (test "Quality values minimum is 0.0"
101           0.0 (get-quality (fifth accept)))
102     (test "Missing quality value ok"
103           1.0 (get-quality (sixth accept)))))
104
105  (test-group "Symbol-parser-ci"
106    (let* ((headers (test-read-headers "Accept-Ranges: FoO")))
107      (test "Case-insensitive"
108            '(foo) (header-values 'accept-ranges headers))))
109 
110  (test-group "Symbol-parser"
111    (let* ((headers (test-read-headers "Allow: FoO, foo")))
112      (test "Case-sensitive"
113            '(FoO foo) (header-values 'allow headers))))
114
115  (test-group "Natnum-parser"
116    (parameterize ((single-headers '(foo bar qux mooh))
117                   (header-parsers `((foo . ,(single natnum-parser))
118                                     (bar . ,(single natnum-parser))
119                                     (qux . ,(single natnum-parser))
120                                     (mooh . ,(single natnum-parser)))))
121     (let ((headers (test-read-headers "Foo: 10\r\nBar: abc\r\nQux: -10\r\nMooh: 1.6")))
122       (test "Simple test"
123             10 (get-value (car (header-contents 'foo headers))))
124       (test "No number defaults to 0"
125             0 (get-value (car (header-contents 'bar headers))))
126       (test "No negative numbers"
127             0 (get-value (car (header-contents 'qux headers))))
128       ;; This is a "feature" in the interest of the robustness principle
129       (test "Rounding of real numbers"
130             2 (get-value (car (header-contents 'mooh headers)))))))
131
132  (test-group "Cache-control-parser"
133    (let ((headers (test-read-headers "Cache-control: max-age=10, private")))
134      (test "max-age is a number"
135            '(max-age . 10) (get-value (header-list-ref 'max-age (header-contents 'cache-control headers))))
136      (test "private without value"
137            '(private . #t) (get-value (header-list-ref 'private (header-contents 'cache-control headers)))))
138    (let ((headers (test-read-headers "Cache-control: private=\"accept-encoding, accept-ranges\"\r\nCache-control: must-revalidate")))
139      (test "private with values"
140            '(private . (accept-encoding accept-ranges))
141            (get-value (header-list-ref 'private (header-contents 'cache-control headers))))
142      (test "Acts like a multi-header"
143            '(must-revalidate . #t) (get-value (header-list-ref 'must-revalidate (header-contents 'cache-control headers))))))
144
145  ;; RFC 2616, 14.15
146  ;; Also: RFC 1864 (Base64) and RF1321 (MD5)
147  ;; XXX TODO: See if binary strings are useful with the MD5 egg, otherwise
148  ;; we need an additional decoding step
149  (test-group "md5-parser"
150    (let ((headers (test-read-headers "Content-md5: Q2hlY2sgSW50ZWdyaXR5IQ==")))
151      (test "md5 is base64-decoded"
152            "Check Integrity!"
153            (get-value (car (header-contents 'content-md5 headers))))))
154
155  (test-group "Range-parser"
156    (let ((headers (test-read-headers "content-range: bytes 500-999/1234")))
157      (test "Simple range"
158            '(500 999 1234)
159            (get-value (car (header-contents 'content-range headers))))))
160
161  ;; XXX SRFI-19!
162  (test-group "http-time-parser"
163    (let ((headers (test-read-headers "Date: Sun, 06 Nov 1994 08:49:37 GMT")))
164      (test "RFC822/RFC1123 time"
165            0
166            (get-value (car (header-contents 'date headers)))))
167    (let ((headers (test-read-headers "Date: Sunday, 06-Nov-94 08:49:37 GMT")))
168      (test "RFC850 time"
169            0
170            (get-value (car (header-contents 'date headers)))))
171    (let ((headers (test-read-headers "Date: Sun Nov  6 08:49:37 1994")))
172      (test "asctime time"
173            0
174            (get-value (car (header-contents 'date headers))))))
175
176  (test-group "entity-tag-parser"
177    (let ((headers (test-read-headers "Etag: \"foo\"")))
178      (test "Strong tag"
179            '(strong . "foo")
180            (get-value (car (header-contents 'etag headers)))))
181    (let ((headers (test-read-headers "Etag: W/\"bar\"")))
182      (test "Weak tag"
183            '(weak . "bar")
184            (get-value (car (header-contents 'etag headers)))))
185    (let ((headers (test-read-headers "Etag: \"\"")))
186      (test "Empty tag"
187            '(strong . "")
188            (get-value (car (header-contents 'etag headers)))))
189    (let ((headers (test-read-headers "Etag: \"W/bar\"")))
190        (test "Strong tag, containing W/ prefix"
191              '(strong . "W/bar")
192              (get-value (car (header-contents 'etag headers))))))
193
194  (test-group "Set-Cookie-parser"
195    (let* ((headers (test-read-headers "Set-Cookie: foo=\"bar\"")))
196      (test "Simple name/value pair"
197            '("foo" . "bar")
198            (get-value (first (header-contents 'set-cookie headers)))))
199    (let ((headers (test-read-headers "Set-Cookie: foo=bar=qux; max-age=10")))
200      (test "Cookie with = signs"
201            '("foo" . "bar=qux")
202            (get-value (first (header-contents 'set-cookie headers)))))
203    (let* ((headers (test-read-headers "Set-Cookie: foo=bar; Comment=\"Hi, there!\", qux=mooh\r\nSet-Cookie: mumble=mutter")))
204      (test "Comment"
205            "Hi, there!"
206            (get-param 'comment
207                       (first (header-contents 'set-cookie headers))))
208      (test "Multiple cookies in one header"
209            '("qux" . "mooh")
210            (get-value (second (header-contents 'set-cookie headers))))
211      (test "Multiple cookies in multiple headers"
212            '("mumble" . "mutter")
213            (get-value (third (header-contents 'set-cookie headers))))
214      (test "Missing \"secure\" value"
215            #f
216            (get-param 'secure
217                       (third (header-contents 'set-cookie headers)))))
218    (let* ((headers (test-read-headers "Set-Cookie: foo=; expires=Sunday, 20-Jul-08 15:23:42 GMT; secure; path = / ")))
219      (test "Missing value"
220            '("foo" . "")
221            (get-value (first (header-contents 'set-cookie headers))))
222      (test "Old-style cookie expires value"
223            ;; Should use something like
224            ;; (string->date foo "~A, ~d-~b-~y ~H:~M:~S ~z") in an "en" locale
225            0
226            (get-param 'expires
227                       (first (header-contents 'set-cookie headers))))
228      (test "Secure value"
229            #t
230            (get-param 'secure
231                       (first (header-contents 'set-cookie headers))))
232      (test "Path"
233            "/"
234            (get-param 'path
235                       (first (header-contents 'set-cookie headers))))))
236 
237  (test-group "Cookie-parser"
238    (let* ((headers (test-read-headers "Cookie: foo=bar; $Path=/; qux=mooh; $unknown=something")))
239      (test "Multiple cookies in the same header"
240            '(("foo" . "bar") . ("qux" . "mooh"))
241            (cons
242             (get-value (first  (header-contents 'cookie headers)))
243             (get-value (second (header-contents 'cookie headers)))))
244      (test "Parameters of cookies (spaces stripped)"
245            "/"
246            (get-param '$path (first (header-contents 'cookie headers))))
247      (test "Parameters of cookies"
248            "something"
249            (get-param '$unknown (second (header-contents 'cookie headers)))))
250    (let* ((headers (test-read-headers "Cookie: $Version=\"1\"; foo=bar; $Path=/; qux=mooh; $unknown=something")))
251      (test "Version string is used for all cookies"
252            (cons 1 1)
253            (cons
254             (get-param '$version (first (header-contents 'cookie headers)))
255             (get-param '$version (second (header-contents 'cookie headers))))))))
256
257(test-group "Headers"
258  (test "Simple test"
259        `(bar qux)
260        (header-values 'foo (headers `((foo bar qux)))))
261  (test "Multi headers are folded"
262        `(bar qux)
263        (header-values 'foo (headers `((foo bar)
264                                       (foo qux)))))
265  (test "Single headers are unique"
266        `(qux)
267        (header-values 'foo (parameterize ((single-headers '(foo)))
268                                    (headers `((foo bar)
269                                               (foo qux))))))
270  (test "Extra single headers are ignored"
271        `(qux)
272        (header-values 'foo (parameterize ((single-headers '(foo)))
273                                    (headers `((foo bar qux))))))
274  (test "Parameters"
275        `((bar . qux))
276        (get-params
277         (car (header-contents 'foo (headers `((foo #(mooh ((bar . qux))))))))))
278  (test "Multi headers are folded into old headers"
279        `(bar qux)
280        (header-values 'foo (headers `((foo qux))
281                                     (headers `((foo bar)))))))
282
283(define (test-unparse-headers h)
284  (call-with-output-string
285   (lambda (o)
286     (unparse-headers (headers h) o))))
287
288(test-group "Unparsers"
289  (test-group "Default unparser"
290    (test "String"
291          "Foo: bar\r\n"
292          (test-unparse-headers `((foo "bar"))))
293    (test "Multiple strings"
294          "Foo: bar, qux\r\n"
295          (test-unparse-headers `((foo "bar" "qux"))))
296    (test "Auto-quoting on commas and whitespace"
297          "Foo: \"bar, qux\", \"mooh blah\"\r\n"
298          (test-unparse-headers `((foo "bar, qux" "mooh blah"))))
299    ;; RFC 2616 2.2
300    (test "Escaping quotes"
301          "Foo: \"bar \\\" qux\", mooh\r\n"
302          (test-unparse-headers `((foo "bar \" qux" "mooh"))))
303    (test "Escaping control characters"
304          "Foo: \"bar\\\r\\\x01qux\"\r\n"
305          (test-unparse-headers `((foo "bar\r\x01qux"))))
306    ;; Unfortunately, there are no or very few HTTP implementations
307    ;; which understand that newlines can be escaped with a backslash
308    ;; in a quoted string. That's why we don't allow it.
309    ;; The user is expected to escape the newlines according to the type
310    ;; of header (URLencoding, removing the newlines from cookies, etc)
311    (test-error* "Embedded newlines throw an error"
312                 (http unencoded-header)
313                 (test-unparse-headers `((foo "bar\n\x01qux"))))
314    (test "Alist"
315          "Foo: bar=qux, mooh=mumble\r\n"
316          (test-unparse-headers `((foo (bar . qux) (mooh . mumble)))))
317    (test "Alist with escapes"
318          "Foo: bar=qux, mooh=\"mum, ble\"\r\n"
319          (test-unparse-headers `((foo (bar . "qux") (mooh . "mum, ble")))))
320    (test "URI"
321          "Foo: http://foo.com/bar\r\n"
322          (test-unparse-headers `((foo ,(uri-reference "http://foo.com/bar")))))
323    (test "Parameters"
324          "Foo: bar; qux=mooh; mumble=mutter; blah\r\n"
325          (test-unparse-headers `((foo #(bar ((qux . mooh)
326                                              (mumble . mutter)
327                                              (blah . #t)
328                                              (feh . #f)))))))))
329
330(define (test-read-request str)
331  (call-with-input-string str
332    (lambda (in)
333      (read-request in))))
334
335(test-group "Read-request"
336  (parameterize ((request-parsers `(,(lambda (line in)
337                                       (and (string=? line "foo") 'foo))
338                                    ,(lambda (line in)
339                                       (and (string=? line "bar") 'bar)))))
340    (test-error* (http unknown-protocol-line) (test-read-request "qux"))
341    (test-error* (http unknown-protocol-line) (test-read-request ""))
342    (test 'foo (test-read-request "foo"))
343    (test 'bar (test-read-request "bar")))
344  (test-group "HTTP/0.9"
345    (let ((req (test-read-request "GET /path/to/stuff?arg1=val1&arg2=val2\r\n")))
346      (test 0 (request-major req))
347      (test 9 (request-minor req))
348      (test 'GET (request-method req))
349      (test (uri-reference "/path/to/stuff?arg1=val1&arg2=val2") (request-uri req))
350      (test (headers '()) (request-headers req)))
351    ; RFC 1945 5.0 does not mention case-sensitivity for the method in HTTP/0.9.
352    ; It only mentions it in the context of HTTP/1.x (section 5.1.1).
353    ; We obey the BNF syntax rule in 2.1:
354    ;     "literal" - Quotation marks surround literal text.
355    ;                 Unless stated otherwise, the text is case-insensitive.
356    ; Section 4.1 defines:
357    ;     Simple-Request  = "GET" SP Request-URI CRLF
358    (test "Method is case-insensitive" 'GET (request-method (test-read-request "geT /path\r\n")))
359    (test-error "0.9 only knows GET" (test-read-request "PUT /path")))
360  (test-group "HTTP/1.0"
361    (let ((req (test-read-request "GET /path/to/stuff?arg1=val1&arg2=val2 HTTP/1.0\r\n\r\n")))
362      (test 1 (request-major req))
363      (test 0 (request-minor req))
364      (test 'GET (request-method req))
365      (test (uri-reference "/path/to/stuff?arg1=val1&arg2=val2") (request-uri req))
366      (test (headers '()) (request-headers req)))
367    (test 'PUT (request-method (test-read-request "PUT /path HTTP/1.0\r\n"))))
368  (test-group "HTTP/1.1" ; No need to test all things we test for 1.0
369   (let ((req (test-read-request "GET /path/to/stuff?arg1=val1&arg2=val2 HTTP/1.1\r\n\r\n")))
370     (test 1 (request-major req))
371     (test 1 (request-minor req)))
372   (test 'PUT (request-method (test-read-request "PUT /path HTTP/1.1\r\n\r\n")))
373   ; RFC 2616 5.1.1
374   (test "Method is case-sensitive" 'geT (request-method (test-read-request "geT /path HTTP/1.1\r\n\r\n")))
375   ; RFC 2616 3.1 + case-insensitivity BNF rule
376   (test "Protocol is case-insensitive" '1 (request-minor (test-read-request "GET /path htTP/1.1\r\n\r\n"))))) ;; TODO: Chunking
377
378(define (test-write-request req . outputs)
379  (call-with-output-string
380    (lambda (out)
381      (request-port-set! req out)
382      (let ((r (write-request req)))
383       (for-each (lambda (output)
384                   (display output (request-port r)))
385                 outputs)))))
386
387(test-group "Write request"
388  ;; This can also be called Simple-Request as per RFC 1945 4.1
389  ;; RFC 2616 19.6 also states we should recognise 0.9 requests, but if
390  ;; we understand those we should also be able to generate them because
391  ;; a 0.9 server does not understand 1.x requests.
392  (test-group "HTTP/0.9"
393    (let ((req (make-request major: 0 minor: 9
394                             method: 'GET
395                             uri: (uri-reference "/foo/bar.html"))))
396      (test "Always empty headers"
397            "GET /foo/bar.html\r\n"
398            (test-write-request (update-request req
399                                                headers:
400                                                (headers `((foo bar))))
401                                ""))
402      (test "Always GET"
403            "GET /foo/bar.html\r\n"
404            (test-write-request (update-request req method: 'POST)))))
405  (test-group "HTTP/1.0"
406    (let ((req (make-request major: 1 minor: 0
407                             method: 'GET
408                             uri: (uri-reference "/foo/bar.html"))))
409      (test "Headers"
410            "GET /foo/bar.html HTTP/1.0\r\nFoo: bar\r\n\r\ntest"
411            (test-write-request
412             (update-request req
413                             headers: (headers `((foo bar))))
414             "test"))
415      (test "Chunking ignored"
416            "GET /foo/bar.html HTTP/1.0\r\nTransfer-Encoding: chunked\r\n\r\nfoobar"
417            (test-write-request
418             (update-request req
419                             headers: (headers `((transfer-encoding chunked))))
420             "foo" "bar"))))
421  (test-group "HTTP/1.1"
422    (let ((req (make-request major: 1 minor: 1
423                             method: 'GET
424                             uri: (uri-reference "/foo/bar.html"))))
425      (test "Headers"
426            "GET /foo/bar.html HTTP/1.1\r\nFoo: bar\r\n\r\ntest"
427            (test-write-request
428             (update-request req
429                             headers: (headers `((foo bar))))
430             "test"))
431      (test "Chunking"
432            "GET /foo/bar.html HTTP/1.1\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n"
433            (test-write-request
434             (update-request req
435                             headers: (headers `((transfer-encoding chunked))))
436             "foo" "1234567890")))))
437
438(define (test-read-response input-string)
439  (call-with-input-string input-string
440    (lambda (in)
441      (read-response in))))
442
443(test-group "Read response"
444  (test-group "HTTP/1.1"
445    (let ((res (test-read-response "HTTP/1.1 303 See other\r\nFoo: bar\r\n\r\nContents")))
446      (test "Version detection"
447            '(1 . 1)
448            (cons (response-major res) (response-minor res)))
449      (test "Status"
450            '(303 . "See other")
451            (cons (response-code res) (response-reason res)))
452      (test "Headers"
453            '("bar")
454            (header-values 'foo (response-headers res)))
455      (test "Contents"
456            "Contents"
457            (read-string #f (response-port res))))
458    (let ((res (test-read-response "HTTP/1.1 200 OK\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n")))
459      (test "Chunking"
460            "foo1234567890"
461            (read-string #f (response-port res)))))
462  (test-group "HTTP/1.0"
463    (let ((res (test-read-response "HTTP/1.0 303 See other\r\nFoo: bar\r\n\r\nContents")))
464      (test "Version detection"
465            '(1 . 0)
466            (cons (response-major res) (response-minor res)))
467      (test "Status"
468            '(303 . "See other")
469            (cons (response-code res) (response-reason res)))
470      (test "Headers"
471            '("bar")
472            (header-values 'foo (response-headers res)))
473      (test "Contents"
474            "Contents"
475            (read-string #f (response-port res))))
476    (let ((res (test-read-response "HTTP/1.0 200 OK\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n")))
477      (test "Chunking ignored"
478            "3\r\nfoo\r\na\r\n1234567890\r\n"
479            (read-string #f (response-port res)))))
480  (test-group "HTTP/0.9"
481    (let ((res (test-read-response "Doesn't matter what's here\r\nLine 2")))
482      (test "Always OK status"
483            '(200 . "OK")
484            (cons (response-code res) (response-reason res)))
485      (test "Version detection; fallback to 0.9"
486            '(0 . 9)
487            (cons (response-major res) (response-minor res)))
488      (test "No headers"
489            (headers '()) (response-headers res))
490      (test "Contents"
491            "Doesn't matter what's here\r\nLine 2"
492            (read-string #f (response-port res))))))
493
494(define (test-write-response res . outputs)
495  (call-with-output-string
496    (lambda (out)
497      (response-port-set! res out)
498      (let ((r (write-response res)))
499       (for-each (lambda (output)
500                   (display output (response-port r)))
501                 outputs)))))
502
503(test-group "Write response"
504  (test-group "HTTP/0.9"
505    (let ((res (make-response major: 0 minor: 9
506                              code: 200 reason: "OK")))
507      (test "Headers ignored"
508            "These are the contents\r\n"
509            (test-write-response
510             (update-response res headers: (headers `((foo bar))))
511             "These are the contents\r\n"))))
512  (test-group "HTTP/1.0"
513    (let ((res (make-response major: 1 minor: 0
514                              code: 200 reason: "OK")))
515      (test "Headers used"
516            "HTTP/1.0 200 OK\r\nFoo: bar\r\n\r\nThese are the contents\r\n"
517            (test-write-response
518             (update-response res headers: (headers `((foo bar))))
519             "These are the contents\r\n"))
520      (test "Status code"
521            "HTTP/1.0 303 See other\r\n\r\nThese are the contents\r\n"
522            (test-write-response
523             (update-response res code: 303 reason: "See other")
524             "These are the contents\r\n"))
525      (test "Chunking ignored"
526            "HTTP/1.0 200 OK\r\nTransfer-Encoding: chunked\r\n\r\nfoo1234567890"
527            (test-write-response
528             (update-response
529              res
530              headers: (headers `((transfer-encoding chunked))))
531             "foo" "1234567890"))))
532  (test-group "HTTP/1.1"
533   (let ((res (make-response major: 1 minor: 1
534                             code: 200 reason: "OK")))
535     (test "Headers used"
536           "HTTP/1.1 200 OK\r\nFoo: bar\r\n\r\nThese are the contents\r\n"
537            (test-write-response
538             (update-response res headers: (headers `((foo bar))))
539             "These are the contents\r\n"))
540     (test "Status code"
541           "HTTP/1.1 303 See other\r\n\r\nThese are the contents\r\n"
542           (test-write-response
543            (update-response res code: 303 reason: "See other")
544            "These are the contents\r\n"))
545     (test "Chunking"
546           "HTTP/1.1 200 OK\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n"
547           (test-write-response
548            (update-response
549             res
550             headers: (headers `((transfer-encoding chunked))))
551            "foo" "1234567890")))))
552
553;; TODO:
554;; - Implement comments parsing (better: a sane parsing system!)
555;; - Test malformed headers
556;; - When headers are malformed, what to do? Return #f for value and let
557;;    single/multiple discard them? Throw an exception?
558;; - Use SRFI-19
559;; - Rethink the auto-chunking stuff. Maybe this should be done at a higher level
560;; - Think about a good naming convention to distinguish parsers that accept
561;;    one argument (an already-tokenized string) or multiple (raw header data)
Note: See TracBrowser for help on using the repository browser.