source: project/release/4/intarweb/trunk/tests/run.scm @ 11910

Last change on this file since 11910 was 11910, checked in by sjamaan, 13 years ago

Add error message in case of token with embedded newline

File size: 25.2 KB
Line 
1(require-extension test extras regex uri-generic intarweb)
2
3(define-syntax test-error*
4  (syntax-rules ()
5    ((_ ?msg (?error-type ...) ?expr)
6     (let-syntax ((expression:
7                   (syntax-rules ()
8                     ((_ ?expr)
9                      (condition-case (begin ?expr "<no error thrown>")
10                                      ((?error-type ...) '(?error-type ...))
11                                      (exn () (##sys#slot exn 1)))))))
12       (test ?msg '(?error-type ...) (expression: ?expr))))
13    ((_ ?msg ?error-type ?expr)
14     (test-error* ?msg (?error-type) ?expr))
15    ((_ ?error-type ?expr)
16     (test-error* (sprintf "~S" '?expr) ?error-type ?expr))))
17
18(define (test-read-headers str)
19  (call-with-input-string str
20    (lambda (in)
21      (read-headers in))))
22
23(test-group "Headers"
24  (test-group "Single headers"
25   (parameterize ((single-headers '(foo qux))
26                  (header-parsers `((foo . ,(single identity))
27                                    (qux . ,(single identity)))))
28     (let ((headers (test-read-headers "foo: bar\r\nqux:\t   \tmooh\t   \r\n\r\n")))
29       (test "Basic test"
30             '("bar") (header-values 'foo headers))
31       ;; RFC 2616 4.2
32       (test "Extra spaces are ignored"
33             '("mooh") (header-values 'qux headers)))
34     (let ((headers (test-read-headers "foo: bar\r\n qux: mooh\r\nquux: mumble\r\n\r\n")))
35       ;; RFC 2616 2.2
36       (test "Continuation chars"
37             '("bar qux: mooh") (header-values 'foo headers)))
38     ;; Not in RFC but common behaviour - also, robustness principle
39     (let ((headers (test-read-headers "foo: bar\r\nfoo: qux\r\n")))
40       (test "Multiple headers for singular header types discarded"
41             '("qux") (header-values 'foo headers)))))
42  ;; All this RFC 2616 4.2
43  (test-group "Multi-headers"
44   (parameterize ((header-parsers `((foo . ,(multiple identity)))))
45     (let ((headers (test-read-headers "foo: bar\r\nfoo: qux\r\nquux: mumble\r\n\r\n")))
46       (test "Multiple headers"
47             '("bar" "qux") (header-values 'foo headers)))
48     (let ((headers (test-read-headers "Foo: bar\r\nFoO: qux\r\nquux: mumble\r\n\r\n")))
49       (test "Multiple headers: case insensitivity"
50             '("bar" "qux") (header-values 'foo headers)))
51     (let ((headers (test-read-headers "foo: bar, qux\r\nquux: mumble\r\n\r\n")))
52       (test "Comma-separated headers"
53             '("bar" "qux") (header-values 'foo headers)))
54     (let ((headers (test-read-headers "foo: \"ba\\\"r, qux\"\r\nfoo: mooh\r\n\r\n")))
55       (test "Quoted headers"
56             '("ba\"r, qux" "mooh") (header-values 'foo headers))))
57   ;; RFC 2616 4.5
58   ;; "Unrecognized header fields are treated as entity-header fields."
59   ;;
60   ;; RFC 2616 7.1
61   ;; "Unrecognized header fields SHOULD be ignored by the recipient and MUST be
62   ;;  forwarded by transparent proxies."
63   (let ((headers (test-read-headers "unknown: foo, bar\r\nunknown: blah\r\n\r\n")))
64     (test "Unknown headers are not parsed and put into lists"
65           '("foo, bar" "blah") (header-values 'unknown headers))))
66  (test-group "Miscellaneous"
67    (parameterize ((header-parsers `((foo . ,(multiple identity)))))
68      (test-error "Missing header contents" (test-read-headers "foo\r\n\r\n"))
69      ;; RFC 2616 2.2
70      ;; "The backslash character ("\") MAY be used as a single-character
71      ;; quoting mechanism only within quoted-string and comment constructs."
72      ;;     quoted-pair = "\" CHAR
73      ;; CHAR implies any char, *including* CR/LF. This is clarified by RFC 822,
74      ;; on which RFC 2616 is based.
75      ;; Apparently, even \CRLF is allowed (as opposed to \CR\LF)
76      (test "Embedded newlines"
77            '("bar\r\nqux")
78            ;; XXX Should we interpret "\\\r\n" as "\r\n", too?
79            (header-values 'foo (test-read-headers "Foo: \"bar\\\r\\\nqux\""))))))
80
81(test-group "Specialized header parsers"
82  (test-group "Quality parameter"
83   (let* ((headers (test-read-headers "Accept: text/plain; Q=0.5, text/html, text/plain; q=0.123456, application/pdf; q=1.2345, text/xml; q=-0.234, text/whatever; q="))
84          (accept  (header-contents 'accept headers)))
85     ;; RFC 2616 3.6: "All transfer-coding values are case insensitive".
86     ;; This includes the parameter name (attribute) and value.
87     (test "Explicit quality value (case-insensitive)"
88           0.5 (get-quality (first accept)))
89     (test "Explicit quality encoding value"
90           'text/plain (get-value (first accept)))
91     ;; RFC 2616 3.9
92     (test "Implicit quality value"
93           1.0 (get-quality (second accept)))
94     (test "Implicit quality encoding value"
95           'text/html (get-value (second accept)))
96     (test "Quality values have only three digits"
97           0.123 (get-quality (third accept)))
98     (test "Quality values maximum is 1.0"
99           1.0 (get-quality (fourth accept)))
100     (test "Quality values minimum is 0.0"
101           0.0 (get-quality (fifth accept)))
102     (test "Missing quality value ok"
103           1.0 (get-quality (sixth accept)))))
104
105  (test-group "Symbol-parser-ci"
106    (let* ((headers (test-read-headers "Accept-Ranges: FoO")))
107      (test "Case-insensitive"
108            '(foo) (header-values 'accept-ranges headers))))
109 
110  (test-group "Symbol-parser"
111    (let* ((headers (test-read-headers "Allow: FoO, foo")))
112      (test "Case-sensitive"
113            '(FoO foo) (header-values 'allow headers))))
114
115  (test-group "Natnum-parser"
116    (parameterize ((single-headers '(foo bar qux mooh))
117                   (header-parsers `((foo . ,(single natnum-parser))
118                                     (bar . ,(single natnum-parser))
119                                     (qux . ,(single natnum-parser))
120                                     (mooh . ,(single natnum-parser)))))
121     (let ((headers (test-read-headers "Foo: 10\r\nBar: abc\r\nQux: -10\r\nMooh: 1.6")))
122       (test "Simple test"
123             10 (get-value (car (header-contents 'foo headers))))
124       (test "No number defaults to 0"
125             0 (get-value (car (header-contents 'bar headers))))
126       (test "No negative numbers"
127             0 (get-value (car (header-contents 'qux headers))))
128       ;; This is a "feature" in the interest of the robustness principle
129       (test "Rounding of real numbers"
130             2 (get-value (car (header-contents 'mooh headers)))))))
131
132  (test-group "Cache-control-parser"
133    (let ((headers (test-read-headers "Cache-control: max-age=10, private")))
134      (test "max-age is a number"
135            '(max-age . 10) (get-value (header-list-ref 'max-age (header-contents 'cache-control headers))))
136      (test "private without value"
137            '(private . #t) (get-value (header-list-ref 'private (header-contents 'cache-control headers)))))
138    (let ((headers (test-read-headers "Cache-control: private=\"accept-encoding, accept-ranges\"\r\nCache-control: must-revalidate")))
139      (test "private with values"
140            '(private . (accept-encoding accept-ranges))
141            (get-value (header-list-ref 'private (header-contents 'cache-control headers))))
142      (test "Acts like a multi-header"
143            '(must-revalidate . #t) (get-value (header-list-ref 'must-revalidate (header-contents 'cache-control headers))))))
144
145  ;; RFC 2616, 14.15
146  ;; Also: RFC 1864 (Base64) and RF1321 (MD5)
147  ;; XXX TODO: See if binary strings are useful with the MD5 egg, otherwise
148  ;; we need an additional decoding step
149  (test-group "md5-parser"
150    (let ((headers (test-read-headers "Content-md5: Q2hlY2sgSW50ZWdyaXR5IQ==")))
151      (test "md5 is base64-decoded"
152            "Check Integrity!"
153            (get-value (car (header-contents 'content-md5 headers))))))
154
155  (test-group "Range-parser"
156    (let ((headers (test-read-headers "content-range: bytes 500-999/1234")))
157      (test "Simple range"
158            '(500 999 1234)
159            (get-value (car (header-contents 'content-range headers))))))
160
161  ;; XXX SRFI-19!
162  (test-group "http-time-parser"
163    (let ((headers (test-read-headers "Date: Sun, 06 Nov 1994 08:49:37 GMT")))
164      (test "RFC822/RFC1123 time"
165            0
166            (get-value (car (header-contents 'date headers)))))
167    (let ((headers (test-read-headers "Date: Sunday, 06-Nov-94 08:49:37 GMT")))
168      (test "RFC850 time"
169            0
170            (get-value (car (header-contents 'date headers)))))
171    (let ((headers (test-read-headers "Date: Sun Nov  6 08:49:37 1994")))
172      (test "asctime time"
173            0
174            (get-value (car (header-contents 'date headers))))))
175
176  (test-group "entity-tag-parser"
177    (let ((headers (test-read-headers "Etag: \"foo\"")))
178      (test "Strong tag"
179            '(strong . "foo")
180            (get-value (car (header-contents 'etag headers)))))
181    (let ((headers (test-read-headers "Etag: W/\"bar\"")))
182      (test "Weak tag"
183            '(weak . "bar")
184            (get-value (car (header-contents 'etag headers)))))
185    (let ((headers (test-read-headers "Etag: \"\"")))
186      (test "Empty tag"
187            '(strong . "")
188            (get-value (car (header-contents 'etag headers)))))
189    ;; XXX, is this test important to pass?
190    #;(let ((headers (test-read-headers "Etag: \"W/bar\"")))
191        (test "Strong tag, containing W/ prefix"
192              '(strong . "W/foo")
193              (get-value (car (header-contents 'etag headers))))))
194
195  (test-group "Set-Cookie-parser"
196    (let* ((headers (test-read-headers "Set-Cookie: foo=\"bar\"")))
197      (test "Simple name/value pair"
198            '("foo" . "bar")
199            (get-value (first (header-contents 'set-cookie headers)))))
200    (let ((headers (test-read-headers "Set-Cookie: foo=bar=qux; max-age=10")))
201      (test "Cookie with = signs"
202            '("foo" . "bar=qux")
203            (get-value (first (header-contents 'set-cookie headers)))))
204    (let* ((headers (test-read-headers "Set-Cookie: foo=bar; Comment=\"Hi, there!\", qux=mooh\r\nSet-Cookie: mumble=mutter")))
205      (test "Comment"
206            "Hi, there!"
207            (get-param 'comment
208                       (first (header-contents 'set-cookie headers))))
209      (test "Multiple cookies in one header"
210            '("qux" . "mooh")
211            (get-value (second (header-contents 'set-cookie headers))))
212      (test "Multiple cookies in multiple headers"
213            '("mumble" . "mutter")
214            (get-value (third (header-contents 'set-cookie headers))))
215      (test "Missing \"secure\" value"
216            #f
217            (get-param 'secure
218                       (third (header-contents 'set-cookie headers)))))
219    (let* ((headers (test-read-headers "Set-Cookie: foo=; expires=Sunday, 20-Jul-08 15:23:42 GMT; secure; path = / ")))
220      (test "Missing value"
221            '("foo" . "")
222            (get-value (first (header-contents 'set-cookie headers))))
223      (test "Old-style cookie expires value"
224            ;; Should use something like
225            ;; (string->date foo "~A, ~d-~b-~y ~H:~M:~S ~z") in an "en" locale
226            0
227            (get-param 'expires
228                       (first (header-contents 'set-cookie headers))))
229      (test "Secure value"
230            #t
231            (get-param 'secure
232                       (first (header-contents 'set-cookie headers))))
233      (test "Path"
234            "/"
235            (get-param 'path
236                       (first (header-contents 'set-cookie headers))))))
237 
238  (test-group "Cookie-parser"
239    (let* ((headers (test-read-headers "Cookie: foo=bar; $Path=/; qux=mooh; $unknown=something")))
240      (test "Multiple cookies in the same header"
241            '(("foo" . "bar") . ("qux" . "mooh"))
242            (cons
243             (get-value (first  (header-contents 'cookie headers)))
244             (get-value (second (header-contents 'cookie headers)))))
245      (test "Parameters of cookies (spaces stripped)"
246            "/"
247            (get-param '$path (first (header-contents 'cookie headers))))
248      (test "Parameters of cookies"
249            "something"
250            (get-param '$unknown (second (header-contents 'cookie headers)))))
251    (let* ((headers (test-read-headers "Cookie: $Version=\"1\"; foo=bar; $Path=/; qux=mooh; $unknown=something")))
252      (test "Version string is used for all cookies"
253            (cons 1 1)
254            (cons
255             (get-param '$version (first (header-contents 'cookie headers)))
256             (get-param '$version (second (header-contents 'cookie headers))))))))
257
258(test-group "Headers"
259  (test "Simple test"
260        `(bar qux)
261        (header-values 'foo (headers `((foo bar qux)))))
262  (test "Multi headers are folded"
263        `(bar qux)
264        (header-values 'foo (headers `((foo bar)
265                                       (foo qux)))))
266  (test "Single headers are unique"
267        `(qux)
268        (header-values 'foo (parameterize ((single-headers '(foo)))
269                                    (headers `((foo bar)
270                                               (foo qux))))))
271  (test "Extra single headers are ignored"
272        `(qux)
273        (header-values 'foo (parameterize ((single-headers '(foo)))
274                                    (headers `((foo bar qux))))))
275  (test "Parameters"
276        `((bar . qux))
277        (get-params
278         (car (header-contents 'foo (headers `((foo #(mooh ((bar . qux))))))))))
279  (test "Multi headers are folded into old headers"
280        `(bar qux)
281        (header-values 'foo (headers `((foo qux))
282                                     (headers `((foo bar)))))))
283
284(define (test-unparse-headers h)
285  (call-with-output-string
286   (lambda (o)
287     (unparse-headers (headers h) o))))
288
289(test-group "Unparsers"
290  (test-group "Default unparser"
291    (test "String"
292          "Foo: bar\r\n"
293          (test-unparse-headers `((foo "bar"))))
294    (test "Multiple strings"
295          "Foo: bar, qux\r\n"
296          (test-unparse-headers `((foo "bar" "qux"))))
297    (test "Auto-quoting on commas and whitespace"
298          "Foo: \"bar, qux\", \"mooh blah\"\r\n"
299          (test-unparse-headers `((foo "bar, qux" "mooh blah"))))
300    ;; RFC 2616 2.2
301    (test "Escaping quotes"
302          "Foo: \"bar \\\" qux\", mooh\r\n"
303          (test-unparse-headers `((foo "bar \" qux" "mooh"))))
304    (test "Escaping control characters"
305          "Foo: \"bar\\\r\\\x01qux\"\r\n"
306          (test-unparse-headers `((foo "bar\r\x01qux"))))
307    ;; Unfortunately, there are no or very few HTTP implementations
308    ;; which understand that newlines can be escaped with a backslash
309    ;; in a quoted string. That's why we don't allow it.
310    ;; The user is expected to escape the newlines according to the type
311    ;; of header (URLencoding, removing the newlines from cookies, etc)
312    (test-error* "Embedded newlines throw an error"
313                 (http unencoded-header)
314                 (test-unparse-headers `((foo "bar\n\x01qux"))))
315    (test "Alist"
316          "Foo: bar=qux, mooh=mumble\r\n"
317          (test-unparse-headers `((foo (bar . qux) (mooh . mumble)))))
318    (test "Alist with escapes"
319          "Foo: bar=qux, mooh=\"mum, ble\"\r\n"
320          (test-unparse-headers `((foo (bar . "qux") (mooh . "mum, ble")))))
321    (test "URI"
322          "Foo: http://foo.com/bar\r\n"
323          (test-unparse-headers `((foo ,(uri-reference "http://foo.com/bar")))))
324    (test "Parameters"
325          "Foo: bar; qux=mooh; mumble=mutter; blah\r\n"
326          (test-unparse-headers `((foo #(bar ((qux . mooh)
327                                              (mumble . mutter)
328                                              (blah . #t)
329                                              (feh . #f)))))))))
330
331(define (test-read-request str)
332  (call-with-input-string str
333    (lambda (in)
334      (read-request in))))
335
336(test-group "Read-request"
337  (parameterize ((request-parsers `(,(lambda (line in)
338                                       (and (string=? line "foo") 'foo))
339                                    ,(lambda (line in)
340                                       (and (string=? line "bar") 'bar)))))
341    (test-error* (http unknown-protocol-line) (test-read-request "qux"))
342    (test-error* (http unknown-protocol-line) (test-read-request ""))
343    (test 'foo (test-read-request "foo"))
344    (test 'bar (test-read-request "bar")))
345  (test-group "HTTP/0.9"
346    (let ((req (test-read-request "GET /path/to/stuff?arg1=val1&arg2=val2\r\n")))
347      (test 0 (request-major req))
348      (test 9 (request-minor req))
349      (test 'GET (request-method req))
350      (test (uri-reference "/path/to/stuff?arg1=val1&arg2=val2") (request-uri req))
351      (test (headers '()) (request-headers req)))
352    ; RFC 1945 5.0 does not mention case-sensitivity for the method in HTTP/0.9.
353    ; It only mentions it in the context of HTTP/1.x (section 5.1.1).
354    ; We obey the BNF syntax rule in 2.1:
355    ;     "literal" - Quotation marks surround literal text.
356    ;                 Unless stated otherwise, the text is case-insensitive.
357    ; Section 4.1 defines:
358    ;     Simple-Request  = "GET" SP Request-URI CRLF
359    (test "Method is case-insensitive" 'GET (request-method (test-read-request "geT /path\r\n")))
360    (test-error "0.9 only knows GET" (test-read-request "PUT /path")))
361  (test-group "HTTP/1.0"
362    (let ((req (test-read-request "GET /path/to/stuff?arg1=val1&arg2=val2 HTTP/1.0\r\n\r\n")))
363      (test 1 (request-major req))
364      (test 0 (request-minor req))
365      (test 'GET (request-method req))
366      (test (uri-reference "/path/to/stuff?arg1=val1&arg2=val2") (request-uri req))
367      (test (headers '()) (request-headers req)))
368    (test 'PUT (request-method (test-read-request "PUT /path HTTP/1.0\r\n"))))
369  (test-group "HTTP/1.1" ; No need to test all things we test for 1.0
370   (let ((req (test-read-request "GET /path/to/stuff?arg1=val1&arg2=val2 HTTP/1.1\r\n\r\n")))
371     (test 1 (request-major req))
372     (test 1 (request-minor req)))
373   (test 'PUT (request-method (test-read-request "PUT /path HTTP/1.1\r\n\r\n")))
374   ; RFC 2616 5.1.1
375   (test "Method is case-sensitive" 'geT (request-method (test-read-request "geT /path HTTP/1.1\r\n\r\n")))
376   ; RFC 2616 3.1 + case-insensitivity BNF rule
377   (test "Protocol is case-insensitive" '1 (request-minor (test-read-request "GET /path htTP/1.1\r\n\r\n"))))) ;; TODO: Chunking
378
379(define (test-write-request req . outputs)
380  (call-with-output-string
381    (lambda (out)
382      (request-port-set! req out)
383      (let ((r (write-request req)))
384       (for-each (lambda (output)
385                   (display output (request-port r)))
386                 outputs)))))
387
388(test-group "Write request"
389  ;; This can also be called Simple-Request as per RFC 1945 4.1
390  ;; RFC 2616 19.6 also states we should recognise 0.9 requests, but if
391  ;; we understand those we should also be able to generate them because
392  ;; a 0.9 server does not understand 1.x requests.
393  (test-group "HTTP/0.9"
394    (let ((req (make-request major: 0 minor: 9
395                             method: 'GET
396                             uri: (uri-reference "/foo/bar.html"))))
397      (test "Always empty headers"
398            "GET /foo/bar.html\r\n"
399            (test-write-request (update-request req
400                                                headers:
401                                                (headers `((foo bar))))
402                                ""))
403      (test "Always GET"
404            "GET /foo/bar.html\r\n"
405            (test-write-request (update-request req method: 'POST)))))
406  (test-group "HTTP/1.0"
407    (let ((req (make-request major: 1 minor: 0
408                             method: 'GET
409                             uri: (uri-reference "/foo/bar.html"))))
410      (test "Headers"
411            "GET /foo/bar.html HTTP/1.0\r\nFoo: bar\r\n\r\ntest"
412            (test-write-request
413             (update-request req
414                             headers: (headers `((foo bar))))
415             "test"))
416      (test "Chunking ignored"
417            "GET /foo/bar.html HTTP/1.0\r\nTransfer-Encoding: chunked\r\n\r\nfoobar"
418            (test-write-request
419             (update-request req
420                             headers: (headers `((transfer-encoding chunked))))
421             "foo" "bar"))))
422  (test-group "HTTP/1.1"
423    (let ((req (make-request major: 1 minor: 1
424                             method: 'GET
425                             uri: (uri-reference "/foo/bar.html"))))
426      (test "Headers"
427            "GET /foo/bar.html HTTP/1.1\r\nFoo: bar\r\n\r\ntest"
428            (test-write-request
429             (update-request req
430                             headers: (headers `((foo bar))))
431             "test"))
432      (test "Chunking"
433            "GET /foo/bar.html HTTP/1.1\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n"
434            (test-write-request
435             (update-request req
436                             headers: (headers `((transfer-encoding chunked))))
437             "foo" "1234567890")))))
438
439(define (test-read-response input-string)
440  (call-with-input-string input-string
441    (lambda (in)
442      (read-response in))))
443
444(test-group "Read response"
445  (test-group "HTTP/1.1"
446    (let ((res (test-read-response "HTTP/1.1 303 See other\r\nFoo: bar\r\n\r\nContents")))
447      (test "Version detection"
448            '(1 . 1)
449            (cons (response-major res) (response-minor res)))
450      (test "Status"
451            '(303 . "See other")
452            (cons (response-code res) (response-reason res)))
453      (test "Headers"
454            '("bar")
455            (header-values 'foo (response-headers res)))
456      (test "Contents"
457            "Contents"
458            (read-string #f (response-port res))))
459    (let ((res (test-read-response "HTTP/1.1 200 OK\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n")))
460      (test "Chunking"
461            "foo1234567890"
462            (read-string #f (response-port res)))))
463  (test-group "HTTP/1.0"
464    (let ((res (test-read-response "HTTP/1.0 303 See other\r\nFoo: bar\r\n\r\nContents")))
465      (test "Version detection"
466            '(1 . 0)
467            (cons (response-major res) (response-minor res)))
468      (test "Status"
469            '(303 . "See other")
470            (cons (response-code res) (response-reason res)))
471      (test "Headers"
472            '("bar")
473            (header-values 'foo (response-headers res)))
474      (test "Contents"
475            "Contents"
476            (read-string #f (response-port res))))
477    (let ((res (test-read-response "HTTP/1.0 200 OK\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n")))
478      (test "Chunking ignored"
479            "3\r\nfoo\r\na\r\n1234567890\r\n"
480            (read-string #f (response-port res)))))
481  (test-group "HTTP/0.9"
482    (let ((res (test-read-response "Doesn't matter what's here\r\nLine 2")))
483      (test "Always OK status"
484            '(200 . "OK")
485            (cons (response-code res) (response-reason res)))
486      (test "Version detection; fallback to 0.9"
487            '(0 . 9)
488            (cons (response-major res) (response-minor res)))
489      (test "No headers"
490            (headers '()) (response-headers res))
491      (test "Contents"
492            "Doesn't matter what's here\r\nLine 2"
493            (read-string #f (response-port res))))))
494
495(define (test-write-response res . outputs)
496  (call-with-output-string
497    (lambda (out)
498      (response-port-set! res out)
499      (let ((r (write-response res)))
500       (for-each (lambda (output)
501                   (display output (response-port r)))
502                 outputs)))))
503
504(test-group "Write response"
505  (test-group "HTTP/0.9"
506    (let ((res (make-response major: 0 minor: 9
507                              code: 200 reason: "OK")))
508      (test "Headers ignored"
509            "These are the contents\r\n"
510            (test-write-response
511             (update-response res headers: (headers `((foo bar))))
512             "These are the contents\r\n"))))
513  (test-group "HTTP/1.0"
514    (let ((res (make-response major: 1 minor: 0
515                              code: 200 reason: "OK")))
516      (test "Headers used"
517            "HTTP/1.0 200 OK\r\nFoo: bar\r\n\r\nThese are the contents\r\n"
518            (test-write-response
519             (update-response res headers: (headers `((foo bar))))
520             "These are the contents\r\n"))
521      (test "Status code"
522            "HTTP/1.0 303 See other\r\n\r\nThese are the contents\r\n"
523            (test-write-response
524             (update-response res code: 303 reason: "See other")
525             "These are the contents\r\n"))
526      (test "Chunking ignored"
527            "HTTP/1.0 200 OK\r\nTransfer-Encoding: chunked\r\n\r\nfoo1234567890"
528            (test-write-response
529             (update-response
530              res
531              headers: (headers `((transfer-encoding chunked))))
532             "foo" "1234567890"))))
533  (test-group "HTTP/1.1"
534   (let ((res (make-response major: 1 minor: 1
535                             code: 200 reason: "OK")))
536     (test "Headers used"
537           "HTTP/1.1 200 OK\r\nFoo: bar\r\n\r\nThese are the contents\r\n"
538            (test-write-response
539             (update-response res headers: (headers `((foo bar))))
540             "These are the contents\r\n"))
541     (test "Status code"
542           "HTTP/1.1 303 See other\r\n\r\nThese are the contents\r\n"
543           (test-write-response
544            (update-response res code: 303 reason: "See other")
545            "These are the contents\r\n"))
546     (test "Chunking"
547           "HTTP/1.1 200 OK\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n"
548           (test-write-response
549            (update-response
550             res
551             headers: (headers `((transfer-encoding chunked))))
552            "foo" "1234567890")))))
553
554;; TODO:
555;; - Implement comments parsing (better: a sane parsing system!)
556;; - Test malformed headers
557;; - When headers are malformed, what to do? Return #f for value and let
558;;    single/multiple discard them? Throw an exception?
559;; - Use SRFI-19
560;; - Rethink the auto-chunking stuff. Maybe this should be done at a higher level
Note: See TracBrowser for help on using the repository browser.