source: project/release/4/http-client/trunk/http-client.scm @ 27129

Last change on this file since 27129 was 27129, checked in by sjamaan, 9 years ago

http-client: forgot to export determine-proxy-username/password. Thanks to David Krentzlin for pointing this out

File size: 34.1 KB
Line 
1;;
2;; Convenient HTTP client library
3;;
4; Copyright (c) 2008-2012, Peter Bex
5; Parts copyright (c) 2000-2004, Felix L. Winkelmann
6; All rights reserved.
7;
8; Redistribution and use in source and binary forms, with or without
9; modification, are permitted provided that the following conditions
10; are met:
11;
12; 1. Redistributions of source code must retain the above copyright
13;    notice, this list of conditions and the following disclaimer.
14; 2. Redistributions in binary form must reproduce the above copyright
15;    notice, this list of conditions and the following disclaimer in the
16;    documentation and/or other materials provided with the distribution.
17; 3. Neither the name of the author nor the names of its
18;    contributors may be used to endorse or promote products derived
19;    from this software without specific prior written permission.
20;
21; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
24; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
25; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
26; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
27; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
28; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
30; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
31; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
32; OF THE POSSIBILITY OF SUCH DAMAGE.
33
34(module http-client
35  (max-retry-attempts max-redirect-depth retry-request? client-software
36   close-connection! close-all-connections!
37   call-with-input-request with-input-from-request call-with-response
38   store-cookie! delete-cookie! get-cookies-for-uri
39   http-authenticators get-username/password
40   basic-authenticator digest-authenticator
41   determine-username/password determine-proxy
42   determine-proxy-from-environment determine-proxy-username/password)
43
44(import chicken scheme lolevel)
45(use srfi-1 srfi-13 srfi-18 srfi-69
46     ports files extras tcp data-structures posix
47     openssl intarweb uri-common message-digest md5 string-utils sendfile)
48
49;; Major TODOs:
50;; * Find a better approach for storing cookies and server connections,
51;;    which will scale to applications with hundreds of connections
52;; * Implement md5-sess handling for digest auth
53;; * Use nonce count in digest auth (is this even needed? I think it's only
54;;    needed if there are webservers out there that send the same nonce
55;;    repeatedly. This client doesn't do request pipelining so we don't
56;;    generate requests with the same nonce if the server doesn't)
57;; * Find a way to do automated testing to increase robustness & reliability
58;; * Test and document SSL support
59;; * The authenticators stuff is really really ugly.  It's intentionally
60;;    undocumented so nobody is going to rely on it too much yet, and
61;;    we have the freedom to change it later.
62
63(define-record http-connection base-uri inport outport proxy)
64
65(define max-retry-attempts (make-parameter 1))
66(define max-redirect-depth (make-parameter 5))
67
68(define retry-request? (make-parameter idempotent?))
69
70(define (determine-proxy-from-environment uri)
71  (let* ((proxy-variable (conc (uri-scheme uri) "_proxy"))
72         (no-proxy (or (get-environment-variable "no_proxy")
73                       (get-environment-variable "NO_PROXY")))
74         (no-proxy (and no-proxy (map (lambda (s)
75                                        (string-split s ":"))
76                                      (string-split no-proxy ","))))
77         (host-excluded? (lambda (entry)
78                           (let ((host (car entry))
79                                 (port (and (pair? (cdr entry))
80                                            (string->number (cadr entry)))))
81                             (and (or (string=? host "*")
82                                      (string-ci=? host (uri-host uri)))
83                                  (or (not port)
84                                      (= (uri-port uri) port)))))))
85    (cond
86     ((and no-proxy (any host-excluded? no-proxy)) #f)
87     ((or (get-environment-variable proxy-variable)
88          (get-environment-variable (string-upcase proxy-variable))
89          (get-environment-variable "all_proxy")
90          (get-environment-variable "ALL_PROXY")) =>
91          (lambda (proxy)               ; TODO: make this just absolute-uri
92            (and-let* ((proxy-uri (uri-reference proxy))
93                       ((absolute-uri? proxy-uri)))
94              proxy-uri)))
95     (else #f))))
96
97(define determine-proxy (make-parameter determine-proxy-from-environment))
98
99(define determine-proxy-username/password
100  (make-parameter (lambda (uri realm)
101                    (values (uri-username uri) (uri-password uri)))))
102
103;; Maybe only pass uri and realm to this?
104(define determine-username/password
105  (make-parameter (lambda (uri realm)
106                    (values (uri-username uri) (uri-password uri)))))
107
108(define client-software
109  (make-parameter (list (list "Chicken Scheme HTTP-client" "0.5" #f))))
110
111;; TODO: find a smarter storage mechanism
112(define cookie-jar (list))
113
114(define connections
115  (make-parameter (make-hash-table
116                   (lambda (a b)
117                     (and (equal? (uri-port a) (uri-port b))
118                          (equal? (uri-host a) (uri-host b))))
119                   (lambda (uri . maybe-bound)
120                     (apply string-hash
121                            (sprintf "~S ~S" (uri-host uri) (uri-port uri))
122                            maybe-bound)))))
123
124(define connections-owner
125  (make-parameter (current-thread)))
126
127(define (ensure-local-connections)
128  (unless (eq? (connections-owner) (current-thread))
129    (connections (make-hash-table equal?))
130    (connections-owner (current-thread))))
131
132(cond-expand
133  ((not has-port-closed)
134   (define (port-closed? p)
135     (##sys#check-port p 'port-closed?)
136     (##sys#slot p 8)))
137  (else))
138
139(define (connection-dropped? con)
140  (or (port-closed? (http-connection-inport con))
141      (port-closed? (http-connection-outport con))
142      (condition-case
143          (and (char-ready? (http-connection-inport con))
144               (eof-object? (peek-char (http-connection-inport con))))
145        ;; Assume connection got reset when we get this exception
146        ((exn i/o net) #t))))
147
148(define (get-connection uri)
149  (ensure-local-connections)
150  (and-let* ((con (hash-table-ref/default (connections) uri #f)))
151    (if (connection-dropped? con)
152        (begin (close-connection! uri) #f)
153        con)))
154
155(define (add-connection! uri con)
156  (ensure-local-connections)
157  (hash-table-set! (connections) uri con))
158
159(define (close-connection! uri-or-con)
160  (ensure-local-connections)
161  (and-let* ((con (if (http-connection? uri-or-con)
162                      uri-or-con
163                      (hash-table-ref/default (connections) uri-or-con #f))))
164    (close-input-port (http-connection-inport con))
165    (close-output-port (http-connection-outport con))
166    (hash-table-delete! (connections) (http-connection-base-uri con))))
167
168(define (close-all-connections!)
169  (ensure-local-connections)
170  (hash-table-walk
171   (connections)
172   (lambda (uri con)
173     (hash-table-delete! (connections) uri)
174     (close-input-port (http-connection-inport con))
175     (close-output-port (http-connection-outport con)))))
176
177(define (ensure-connection! uri)
178  (or (get-connection uri)
179      (let* ((proxy ((determine-proxy) uri))
180             (remote-end (or proxy uri)))
181       (receive (in out)
182         (case (uri-scheme remote-end)
183           ((#f http) (tcp-connect (uri-host remote-end) (uri-port remote-end)))
184           ((https) (ssl-connect (uri-host remote-end) (uri-port remote-end)))
185           (else (http-client-error 'ensure-connection!
186                                    "Unknown URI scheme"
187                                    (list (uri-scheme remote-end))
188                                    'unsupported-uri-scheme
189                                    'uri-scheme (uri-scheme remote-end)
190                                    'request-uri uri 'proxy proxy)))
191         (let ((con (make-http-connection uri in out proxy)))
192           (add-connection! uri con)
193           con)))))
194
195(define (make-delimited-input-port port len)
196  (if (not len)
197      port ;; no need to delimit anything
198      (let ((pos 0))
199        (make-input-port (lambda () ; read
200                           (if (= pos len)
201                               #!eof
202                               (let ((char (read-char port)))
203                                 (set! pos (add1 pos))
204                                 char)))
205                         (lambda () ; char-ready?
206                           (if (= pos len)
207                               #f
208                               (char-ready? port)))
209                         (lambda () ; close
210                           (close-input-port port))))))
211
212(define discard-remaining-data!
213  (let ((buf (make-string 1024)))       ; Doesn't matter, discarded anyway
214    (lambda (response port)
215      ;; If header not available or no response object passed, this reads until EOF
216      (let loop ((len (and response
217                           (header-value
218                            'content-length (response-headers response)))))
219        (if len
220            (when (> len 0)
221              (loop (- len (read-string! len buf port))))
222            (when (> (read-string! len buf port) 0)
223              (loop #f)))))))
224
225(define (add-headers req)
226  (let* ((uri (request-uri req))
227         (cookies (get-cookies-for-uri (request-uri req)))
228         (h `(,@(if (not (null? cookies)) `((cookie . ,cookies)) '())
229              (host ,(cons (uri-host uri) (and (not (uri-default-port? uri))
230                                               (uri-port uri))))
231              ,@(if (and (client-software) (not (null? (client-software))))
232                    `((user-agent ,(client-software)))
233                    '()))))
234    (update-request req
235                    headers: (headers h (request-headers req)))))
236
237(define (http-client-error loc msg args specific . rest)
238  (raise (make-composite-condition
239          (make-property-condition 'exn 'location loc 'message msg 'arguments args)
240          (make-property-condition 'http)
241          (apply make-property-condition specific rest))))
242
243;; RFC 2965, section 3.3.3
244(define (cookie-eq? a-name a-info b-name b-info)
245  (and (string-ci=? a-name b-name)
246       (string-ci=? (alist-ref 'domain a-info) (alist-ref 'domain b-info))
247       (equal?      (alist-ref 'path a-info)   (alist-ref 'path b-info))))
248
249(define (store-cookie! cookie-info set-cookie)
250  (let loop ((cookie (set-cookie->cookie set-cookie))
251             (jar cookie-jar))
252    (cond
253     ((null? jar)
254      (set! cookie-jar (cons (cons cookie-info cookie) cookie-jar))
255      cookie-jar)
256     ((cookie-eq? (car (get-value set-cookie)) cookie-info
257                  (car (get-value (cdar jar))) (caar jar))
258      (set-car! jar (cons cookie-info cookie))
259      cookie-jar)
260     (else (loop cookie (cdr jar))))))
261
262(define (delete-cookie! cookie-name cookie-info)
263  (set! cookie-jar (remove! (lambda (c)
264                              (cookie-eq? (car (get-value (cdr c))) (car c)
265                                          cookie-name cookie-info))
266                            cookie-jar)))
267
268(define (domain-match? uri pattern)
269  (let ((target (uri-host uri)))
270    (or (string-ci=? target pattern)
271        (and (string-prefix? "." pattern)
272             (string-suffix-ci? pattern target)))))
273
274(define (path-match? uri path)
275  (and (uri-path-absolute? uri)
276       (let loop ((path (cdr (uri-path path)))
277                  (uri-path (cdr (uri-path uri))))
278         (or (null? path)               ; done
279             (and (not (null? uri-path))
280                  (or (and (string-null? (car path)) (null? (cdr path)))
281
282                      (and (string=? (car path) (car uri-path))
283                           (loop (cdr path) (cdr uri-path)))))))))
284
285;; Set-cookie provides some info we don't need to store; strip the
286;; nonessential info
287(define (set-cookie->cookie info)
288  (vector (get-value info)
289          (filter (lambda (p)
290                    (member (car p) '(domain path version)))
291                  (get-params info))))
292
293(define (get-cookies-for-uri uri)
294  (let ((uri (if (string? uri) (uri-reference uri) uri)))
295    (map cdr
296         (sort!
297          (filter (lambda (c)
298                    (let ((info (car c)))
299                     (and (domain-match? uri (alist-ref 'domain info))
300                          (member (uri-port uri)
301                                  (alist-ref 'port info eq?
302                                             (list (uri-port uri))))
303                          (path-match? uri (alist-ref 'path info))
304                          (if (alist-ref 'secure info)
305                              (member (uri-scheme uri) '(https shttp))
306                              #t))))
307                  cookie-jar)
308          (lambda (a b)
309            (< (length (uri-path (alist-ref 'path (car a))))
310               (length (uri-path (alist-ref 'path (car b))))))))))
311
312(define (process-set-cookie! con uri r)
313  (let ((prefix-contains-dots?
314         (lambda (host pattern)
315           (string-index host #\. 0 (string-contains-ci host pattern)))))
316    (for-each (lambda (c)
317                (and-let* ((path (or (get-param 'path c) uri))
318                           ((path-match? uri path))
319                           ;; domain must start with dot. Add to intarweb!
320                           (dn (get-param 'domain c (uri-host uri)))
321                           (idx (string-index dn #\.))
322                           ((domain-match? uri dn))
323                           ((not (prefix-contains-dots? (uri-host uri) dn))))
324                  (store-cookie! `((path . ,path)
325                                   (domain . ,dn)
326                                   (secure . ,(get-param 'secure c))) c)))
327              (header-contents 'set-cookie (response-headers r) '()))
328    (for-each (lambda (c)
329                (and-let* (((get-param 'version c)) ; required for set-cookie2
330                           (path (or (get-param 'path c) uri))
331                           ((path-match? uri path))
332                           (dn (get-param 'domain c (uri-host uri)))
333                           ((or (string-ci=? dn ".local")
334                                (and (not (string-null? dn))
335                                     (string-index dn #\. 1))))
336                           ((domain-match? uri dn))
337                           ((not (prefix-contains-dots? (uri-host uri) dn)))
338                           ;; This is a little bit too messy for my tastes...
339                           ;; Can't use #f because that would shortcut and-let*
340                           (ports-value (get-param 'port c 'any))
341                           (ports (if (eq? ports-value #t)
342                                      (list (uri-port uri))
343                                      ports-value))
344                           ((or (eq? ports 'any)
345                                (member (uri-port uri) ports))))
346                  (store-cookie! `((path . ,path)
347                                   (domain . ,dn)
348                                   (port . ,(if (eq? ports 'any) #f ports))
349                                   (secure . ,(get-param 'secure c))) c)))
350              (header-contents 'set-cookie2 (response-headers r) '()))))
351
352(define (call-with-output-digest primitive proc)
353  (let* ((ctx-info (message-digest-primitive-context-info primitive))
354         (ctx (if (procedure? ctx-info) (ctx-info) (allocate ctx-info)))
355         (update-digest (message-digest-primitive-update primitive))
356         (update (lambda (str) (update-digest ctx str (string-length str))))
357         (outport (make-output-port update void)))
358    (handle-exceptions exn
359      (unless (procedure? ctx-info) (free ctx))
360      (let ((result (make-string
361                     (message-digest-primitive-digest-length primitive))))
362        ((message-digest-primitive-init primitive) ctx)
363        (proc outport)
364        ((message-digest-primitive-final primitive) ctx result)
365        (unless (procedure? ctx-info) (free ctx))
366        (string->hex result)))))
367
368(define (get-username/password for-request-header for-uri for-realm)
369  (if (eq? for-request-header 'authorization)
370      ((determine-username/password) for-uri for-realm)
371      ((determine-proxy-username/password) for-uri for-realm)))
372
373;;; TODO: We really, really should get rid of "writer" here.  Some kind of
374;;; generalized way to get the digest is required.  Jeez, HTTP sucks :(
375(define (basic-authenticator response response-header
376                             new-request request-header uri realm writer)
377  (receive (username password)
378    (get-username/password request-header uri realm)
379    (and username
380         (update-request
381          new-request
382          headers: (headers `((,request-header
383                               #(basic ((username . ,username)
384                                        (password . ,(or password ""))))))
385                            (request-headers new-request))))))
386
387(define (digest-authenticator response response-header
388                              new-request request-header uri realm writer)
389  (receive (username password)
390    (get-username/password request-header uri realm)
391    (and username
392         (let* ((hashconc
393                 (lambda args
394                   (message-digest-string
395                    (md5-primitive) (string-join (map ->string args) ":"))))
396                (authless-uri (update-uri (request-uri new-request)
397                                          username: #f password: #f))
398                ;; TODO: domain handling
399                (h (response-headers response))
400                (nonce (header-param 'nonce response-header h))
401                (opaque (header-param 'opaque response-header h))
402                (stale (header-param 'stale response-header h))
403                ;; TODO: "md5-sess" algorithm handling
404                (algorithm (header-param 'algorithm response-header h))
405                (qops (header-param 'qop response-header h '()))
406                (qop (cond ; Pick the strongest of the offered options
407                      ((member 'auth-int qops) 'auth-int)
408                      ((member 'auth qops) 'auth)
409                      (else #f)))
410                (cnonce (and qop (hashconc (current-seconds) realm)))
411                (nc (and qop 1)) ;; TODO
412                (ha1 (hashconc username realm (or password "")))
413                (ha2 (if (eq? qop 'auth-int)
414                         (hashconc (request-method new-request)
415                                   (uri->string authless-uri)
416                                   ;; Generate digest from writer's output
417                                   (call-with-output-digest
418                                    (md5-primitive)
419                                    (lambda (p)
420                                      (writer
421                                       (update-request new-request port: p)))))
422                         (hashconc (request-method new-request)
423                                   (uri->string authless-uri))))
424                (digest
425                 (case qop
426                   ((auth-int auth)
427                    (let ((hex-nc (string-pad (number->string nc 16) 8 #\0)))
428                      (hashconc ha1 nonce hex-nc cnonce qop ha2)))
429                   (else
430                    (hashconc ha1 nonce ha2)))))
431           (update-request new-request
432                           headers: (headers
433                                     `((,request-header
434                                        #(digest ((username . ,username)
435                                                  (uri . ,authless-uri)
436                                                  (realm . ,realm)
437                                                  (nonce . ,nonce)
438                                                  (cnonce . ,cnonce)
439                                                  (qop . ,qop)
440                                                  (nc . ,nc)
441                                                  (response . ,digest)
442                                                  (opaque . ,opaque)))))
443                                     (request-headers new-request)))))))
444
445(define http-authenticators
446  (make-parameter `((basic . ,basic-authenticator)
447                    (digest . ,digest-authenticator))))
448
449(define (authenticate-request request response writer proxy-uri)
450  (and-let* ((type (if (= (response-code response) 401) 'auth 'proxy))
451             (resp-header (if (eq? type 'auth)
452                              'www-authenticate
453                              'proxy-authenticate))
454             (req-header (if (eq? type 'auth)
455                             'authorization
456                             'proxy-authorization))
457             (authtype (header-value resp-header (response-headers response)))
458             (realm (header-param 'realm resp-header (response-headers response)))
459             (auth-uri (if (eq? type 'auth) (request-uri request) proxy-uri))
460             (authenticator (or (alist-ref authtype (http-authenticators))
461                                ;; Should we really raise an error?
462                                (http-client-error 'authenticate-request
463                                                   "Unknown authentication type"
464                                                   (list request)
465                                                   'unknown-authtype
466                                                   'authtype authtype))))
467    (authenticator response resp-header request req-header
468                   auth-uri realm writer)))
469
470(define (call-with-response req writer reader)
471  (let loop ((attempts 0)
472             (redirects 0)
473             (req req))
474    (condition-case
475      (let* ((con (ensure-connection! (request-uri req)))
476             (req (add-headers (update-request
477                                req port: (http-connection-outport con))))
478             ;; No outgoing URIs should ever contain credentials or fragments
479             (req-uri (update-uri (request-uri req)
480                                  fragment: #f username: #f password: #f))
481             ;; RFC1945, 5.1.2: "The absoluteURI form is only allowed
482             ;; when the request is being made to a proxy."
483             ;; RFC2616 is a little more regular (hosts MUST accept
484             ;; absoluteURI), but it says "HTTP/1.1 clients will only
485             ;; generate them in requests to proxies." (also 5.1.2)
486             (req-uri (if (http-connection-proxy con)
487                          req-uri
488                          (update-uri req-uri host: #f port: #f scheme: #f
489                                      path: (or (uri-path req-uri) '(/ "")))))
490             (request (write-request (update-request req uri: req-uri)))
491             ;; Writer should be prepared to be called several times
492             ;; Maybe try and figure out a good way to use the
493             ;; "Expect: 100-continue" header to prevent too much writing?
494             ;; Unfortunately RFC2616 says it's unreliable (8.2.3)...
495             (_ (begin (writer request) (flush-output (request-port req))))
496             (response (read-response (http-connection-inport con)))
497             (cleanup! (lambda (clear-response-data?)
498                         (when clear-response-data?
499                           (discard-remaining-data! response
500                                                    (response-port response)))
501                         (unless (and (keep-alive? request)
502                                      (keep-alive? response))
503                           (close-connection! con)))))
504        (process-set-cookie! con (request-uri req) response)
505        (case (response-code response)
506          ;; TODO: According to spec, we should provide the user with a choice
507          ;; when it's not a GET or HEAD request...
508          ((301 302 303 307)
509           (cleanup! #t)
510           ;; Maybe we should switch to GET on 302 too?  It's not compliant,
511           ;; but very widespread and there's enough software that depends
512           ;; on that behaviour, which might break horribly otherwise...
513           (when (= (response-code response) 303)
514             (request-method-set! req 'GET)) ; Switch to GET
515           (let ((new-uri (header-value 'location (response-headers response))))
516             (if (or (not (max-redirect-depth)) ; unlimited?
517                     (< redirects (max-redirect-depth)))
518                 (loop attempts
519                       (add1 redirects)
520                       (update-request req uri: (uri-relative-to
521                                                 new-uri (request-uri req))))
522                 (http-client-error 'send-request
523                                    "Maximum number of redirects exceeded"
524                                    (list req)
525                                    'redirect-depth-exceeded
526                                    'uri new-uri))))
527          ;; TODO: Test this
528          ((305)                        ; Use proxy (for this request only)
529           (cleanup! #t)
530           (let ((old-determine-proxy (determine-proxy))
531                 (proxy-uri (header-value 'location (response-headers response))))
532             (parameterize ((determine-proxy
533                             (lambda _
534                               ;; Reset determine-proxy so the proxy is really
535                               ;; used for only this one request.
536                               ;; Yes, this is a bit of a hack :)
537                               (determine-proxy old-determine-proxy)
538                               proxy-uri)))
539               (loop attempts redirects req))))
540          ((401 407)          ; Unauthorized, Proxy Authentication Required
541           (cond ((and (or (not (max-retry-attempts)) ; unlimited?
542                           (<= attempts (max-retry-attempts)))
543                       (authenticate-request req response writer
544                                             (http-connection-proxy con)))
545                  => (lambda (new-req)
546                       (cleanup! #t)
547                       (loop (add1 attempts) redirects new-req)))
548                 (else ;; pass it on, we can't throw an error here
549                  (let ((data (reader response)))
550                    (values data (request-uri request) response)))))
551          (else (let ((data (reader response)))
552                  (cleanup! #f)
553                  (values data (request-uri req) response)))))
554        (exn (exn i/o net)
555             (close-connection! (request-uri req))
556             (if (and (or (not (max-retry-attempts)) ; unlimited?
557                          (<= attempts (max-retry-attempts)))
558                      ((retry-request?) req))
559                 (loop (add1 attempts) redirects req)
560                 (raise exn)))
561        (exn ()
562             ;; Never leave the port in an unknown/inconsistent state
563             ;; (the error could have occurred while reading, so there
564             ;;  might be data left in the buffer)
565             (close-connection! (request-uri req))
566             (raise exn)))))
567
568(define (kv-ref l k #!optional default)
569  (let ((rest (memq k l)))
570    (if (and rest (pair? (cdr rest))) (cadr rest) default)))
571
572;; This really, really sucks
573;; TODO: This crap probably belongs in its own egg?  Perhaps later when
574;; we have server-side handling for this too.
575(define (prepare-multipart-chunks boundary entries)
576  (append
577   (map (lambda (entry)
578          (if (not (cdr entry))         ; discard #f values
579              '()
580              (let* ((keys (cdr entry))
581                     (file (kv-ref keys file:))
582                     (filename (or (kv-ref keys filename:)
583                                   (and (port? file) (port-name file))
584                                   (and (string? file) file)))
585                     (filename (and filename
586                                    (pathname-strip-directory filename)))
587                     (h (headers `((content-disposition
588                                    #(form-data ((name . ,(car entry))
589                                                 (filename . ,filename))))
590                                   ,@(if filename
591                                         '((content-type application/octet-stream))
592                                         '()))))
593                     (hs (call-with-output-string
594                           (lambda (s)
595                             (unparse-headers
596                              ;; Allow user headers to override ours
597                              (headers (kv-ref keys headers: '()) h) s)))))
598                (list "--" boundary "\r\n" hs "\r\n"
599                      (cond ((string? file) (cons 'file file))
600                            ((port? file) (cons 'port file))
601                            ((eq? keys #t) "")
602                            (else (->string keys)))
603                  ;; The next boundary must always start on a new line
604                  "\r\n"))))
605        entries)
606   (list (list "--" boundary "--\r\n"))))
607
608(define (write-chunks output-port entries)
609  (for-each (lambda (entry)
610              (for-each (lambda (chunk)
611                          (if (pair? chunk)
612                              (let ((p (if (eq? 'file (car chunk))
613                                           (open-input-file (cdr chunk))
614                                           ;; Should be a port otherwise
615                                           (cdr chunk))))
616                                (handle-exceptions exn
617                                  (begin (close-input-port p) (raise exn))
618                                  (sendfile p output-port))
619                                (close-input-port p))
620                              (display chunk output-port)))
621                        entry))
622            entries))
623
624(define (calculate-chunk-size entries)
625  (call/cc
626   (lambda (return)
627     (fold (lambda (chunks total-size)
628             (fold (lambda (chunk total-size)
629                     (if (pair? chunk)
630                         (if (eq? 'port (car chunk))
631                             ;; Should be a file otherwise.
632                             ;; We can't calculate port lengths.
633                             ;; Let's just punt and hope the server
634                             ;; won't return "411 Length Required"...
635                             ;; (TODO: maybe try seeking it?)
636                             (return #f)
637                             (+ total-size (file-size (cdr chunk))))
638                         (+ total-size (string-length chunk))))
639                   total-size
640                   chunks))
641           0 entries))))
642
643(define (call-with-input-request uri-or-request writer reader)
644  (let* ((type #f)
645         (chunks (cond
646                  ((string? writer) (list (list writer)))
647                  ((and (list? writer)
648                        (any (lambda (x)
649                               (and (pair? x) (pair? (cdr x))
650                                    (eq? (cadr x) file:)))
651                             writer))
652                   (let ((bd (conc "----------------Multipart-=_"
653                                   (gensym 'boundary) "=_=" (current-process-id)
654                                   "=-=" (current-seconds))))
655                     (set! type `#(multipart/form-data ((boundary . ,bd))))
656                     (prepare-multipart-chunks bd writer)))
657                  ;; Default to "&" because some servers choke on ";"
658                  ((list? writer)
659                   (set! type 'application/x-www-form-urlencoded)
660                   (list (list (or (form-urlencode writer separator: "&")
661                                   (http-client-error
662                                    'call-with-input-request
663                                    "Invalid form data!"
664                                    (list uri-or-request writer reader)
665                                    'formdata-error)))))
666                   (else #f)))
667         (write-data! (cond (chunks (lambda (p) (write-chunks p chunks)))
668                            ((procedure? writer) writer)
669                            (else (lambda x (void)))))
670         (uri (cond ((uri? uri-or-request) uri-or-request)
671                    ((string? uri-or-request) (uri-reference uri-or-request))
672                    (else (request-uri uri-or-request))))
673         (req (if (request? uri-or-request)
674                  uri-or-request
675                  (make-request uri: uri method: (if writer 'POST 'GET))))
676         (req (update-request
677               req
678               headers: (headers
679                         `(,@(if chunks
680                                 `((content-length
681                                    ,(calculate-chunk-size chunks)))
682                                 '())
683                           ,@(if type `((content-type ,type)) '()))
684                         (request-headers req)))))
685    (call-with-response
686     req
687     (lambda (request)
688       (let ((port (request-port request)))
689         (write-data! port)))
690     (lambda (response)
691       (let ((port (make-delimited-input-port
692                    (response-port response)
693                    (header-value 'content-length (response-headers response)))))
694         (if (= 200 (response-class response)) ; Everything cool?
695             (let* ((b? ((response-has-message-body-for-request?) response req))
696                    (result (and b? reader (reader port))))
697               (when b? (discard-remaining-data! #f port))
698               result)
699             (http-client-error
700              'call-with-input-request
701              ;; Message
702              (sprintf (case (response-class response)
703                         ((400) "Client error: ~A ~A")
704                         ((500) "Server error: ~A ~A")
705                         (else "Unexpected server response: ~A ~A"))
706                       (response-code response) (response-reason response))
707              ;; arguments
708              (list uri)
709              ;; Specific type
710              (case (response-class response)
711                ((400) 'client-error)
712                ((500) 'server-error)
713                (else 'unexpected-server-response))
714              'response response
715              'body (read-string #f port))))))))
716
717(define (with-input-from-request uri-or-request writer reader)
718  (call-with-input-request uri-or-request
719                           (if (procedure? writer)
720                               (lambda (p) (with-output-to-port p writer))
721                               writer) ;; Assume it's an alist or #f
722                           (lambda (p) (with-input-from-port p reader))))
723
724)
Note: See TracBrowser for help on using the repository browser.