source: project/release/3/uri-generic/trunk/uri-generic.scm @ 12924

Last change on this file since 12924 was 12924, checked in by sjamaan, 13 years ago

Merge latest release 4 changes

File size: 34.6 KB
Line 
1
2;;
3;; Definitions and parsing routines for Uniform Resource Identifiers (RFC 3986).
4;;
5;; Based on the Haskell URI library by  Graham Klyne <gk@ninebynine.org>.
6;;
7;; Copyright 2008 Ivan Raikov, Peter Bex.
8;;
9;;
10;;  Redistribution and use in source and binary forms, with or without
11;;  modification, are permitted provided that the following conditions
12;;  are met:
13;;
14;;  - Redistributions of source code must retain the above copyright
15;;  notice, this list of conditions and the following disclaimer.
16;;
17;;  - Redistributions in binary form must reproduce the above
18;;  copyright notice, this list of conditions and the following
19;;  disclaimer in the documentation and/or other materials provided
20;;  with the distribution.
21;;
22;;  - Neither name of the copyright holders nor the names of its
23;;  contributors may be used to endorse or promote products derived
24;;  from this software without specific prior written permission.
25;;
26;;  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND THE
27;;  CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES,
28;;  INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
29;;  MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
30;;  DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR THE
31;;  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
32;;  SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
33;;  LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
34;;  USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
35;;  AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
36;;  LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
37;;  ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
38;;  POSSIBILITY OF SUCH DAMAGE.
39;;
40
41(require-extension syntax-case)
42(require-extension matchable)
43(require-extension defstruct)
44(require-extension srfi-1)
45(require-extension srfi-4)
46
47(define-extension uri-generic)
48
49(declare
50 (not usual-integrations)
51 (fixnum)
52 (inline)
53 (lambda-lift)
54 (export uri-reference update-uri update-authority
55         uri? uri-auth uri-authority uri-scheme uri-path uri-query
56         uri-fragment uri-host uri-port uri-username uri-password
57         authority? authority-host authority-port
58         authority-username authority-password
59         
60         absolute-uri uri->string uri->list 
61         uri-relative-to uri-relative-from 
62         uri-decode-string uri-encode-string 
63         uri-normalize-case uri-normalize-path-segments
64         char-set:gen-delims char-set:sub-delims
65         char-set:uri-reserved char-set:uri-unreserved))
66
67(cond-expand
68   (utf8-strings (use utf8-srfi-13 utf8-srfi-14))
69   (else (use srfi-13 srfi-14)))
70
71(defstruct URI      scheme authority path query fragment)
72(defstruct URIAuth  username password host port)
73
74(define-record-printer (URI x out)
75  (fprintf out "#(URI scheme=~S authority=~A path=~S query=~S fragment=~S)"
76           (URI-scheme x)
77           (URI-authority x)
78           (URI-path x)
79           (URI-query x)
80           (URI-fragment x)))
81
82(define-record-printer (URIAuth x out)
83  (fprintf out "#(URIAuth host=~S port=~A)"
84           (URIAuth-host x)
85           (URIAuth-port x)))
86
87(define uri? URI?)
88
89(define uri-auth       URI-authority )
90(define uri-authority  URI-authority )
91(define uri-scheme     URI-scheme )
92(define uri-path       URI-path )
93(define uri-query      URI-query )
94(define uri-fragment   URI-fragment )
95
96(define (uri-host x)
97  (let ((auth (URI-authority x)))
98    (and auth (URIAuth-host auth))))
99
100(define (uri-port x)
101  (let ((auth (URI-authority x)))
102    (and auth (URIAuth-port auth))))
103
104(define (uri-username x)
105  (let ((auth (URI-authority x)))
106    (and auth (URIAuth-username auth))))
107
108(define (uri-password x)
109  (let ((auth (URI-authority x)))
110    (and auth (URIAuth-password auth))))
111
112(define authority? URIAuth?)
113(define authority-host URIAuth-host)
114(define authority-port URIAuth-port)
115(define authority-username URIAuth-username)
116(define authority-password URIAuth-password)
117
118(define update-authority
119  (let ((unset (list 'unset)))
120    (lambda (auth #!key (host unset) (port unset) (username unset) (password unset))
121      (make-URIAuth host: (if (eq? host unset) (URIAuth-host auth) host)
122                    port: (if (eq? port unset) (URIAuth-port auth) port)
123                    username: (if (eq? username unset) (URIAuth-username auth) username)
124                    password: (if (eq? password unset) (URIAuth-password auth) password)))))
125
126(define update-uri
127  (let ((unset (list 'unset)))
128   (lambda (uri . key/values)
129     (apply
130      (lambda (#!key
131               (scheme (URI-scheme uri)) (path (URI-path uri))
132               (query (URI-query uri)) (fragment (URI-fragment uri))
133               (auth unset) (authority unset))
134        (let* ((base-auth (or
135                           (cond
136                            ((not (eq? unset auth)) auth)
137                            ((not (eq? unset authority)) authority)
138                            (else (URI-authority uri)))
139                           (make-URIAuth)))
140               (updated-auth (apply update-authority base-auth key/values))
141               (final-auth (if (equal? (make-URIAuth) updated-auth)
142                               #f
143                               updated-auth)))
144          (make-URI scheme: scheme path: path query: query fragment: fragment
145                    authority: final-auth))) key/values))))
146
147;; Character classes
148 
149(define (hexdigit-char? c)    (and (char? c) (char-set-contains? char-set:hex-digit c)))
150
151(define (reserved-char? c)    (and (char? c) (char-set-contains? char-set:uri-reserved c)))
152
153(define (unreserved-char? c)  (and (char? c) (char-set-contains? char-set:uri-unreserved c)))
154
155(define (scheme-char? c)      (and (char? c) (char-set-contains? char-set:scheme c)))
156
157(define (ipv-future-char? c)  (and (char? c) (char-set-contains? char-set:ipv-future c)))
158
159(define (pct-encoded? c)      (match c ((#\% h1 h2) #t) (else #f)))
160
161
162;; Helper functions for character parsing
163 
164(define (uchar extras)
165  (let ((extras-set (or (and (char-set? extras) extras) (string->char-set extras))))
166    (lambda (c) (or (pct-encoded? c) (unreserved-char? c) 
167                    (char-set-contains? char-set:sub-delims c) 
168                    (char-set-contains? extras-set c) ))))
169 
170;; same as uchar, but without sub-delims
171(define (schar extras)
172  (let ((extras-set (or (and (char-set? extras) extras) (string->char-set extras))))
173    (lambda (c) (or (pct-encoded? c)  (unreserved-char? c) 
174                    (char-set-contains? extras-set c) ))))
175                 
176(define (many pred?)
177  (lambda (s)
178    (let loop ((lst (list)) (rst s))
179      (cond ((null? rst)        (list (reverse lst) rst))
180            ((pred? (car rst))  (loop (cons (car rst) lst) (cdr rst)))
181            (else               (list (reverse lst) rst))))))
182
183(define (many1 pred?)
184  (lambda (s)
185    (let ((a1 (and (not (null? s)) (pred? (car s)) (car s))))
186      (and a1 (match ((many pred?) (cdr s))
187                     ((as rst)  (list (cons a1 as) rst))
188                     (else #f))))))
189
190
191(define (count-min-max m n pred?)
192  (lambda (s) 
193    (let loop ((m m) (n n) (lst (list)) (rst s))
194      (cond ((and (pair? rst) (positive? m))
195             (if (pred? (car rst))
196                 (loop (- m 1) (- n 1) (cons (car rst) lst) (cdr rst)) #f))
197            ((or (<= n 0) (null? rst))   (list (reverse lst) rst))
198            (else
199             (if (pred? (car rst))
200                 (loop 0 (- n 1) (cons (car rst) lst) (cdr rst))
201                 (list (reverse lst) rst)))))))
202
203;; Parser combinators
204
205(define (consume f) 
206  (lambda (s)
207    (let loop ((lst (list)) (rst s))
208      (match (f rst)
209             ((a rst)  (loop (cons a lst) rst))
210             (else  (list (reverse lst) rst))))))
211
212
213(define (consume-count n f)
214  (lambda (s)
215    (let loop ((n n) (lst (list)) (rst s))
216      (if (positive? n)
217          (match (or (f rst) (list #f s))
218                 ((x rst)  (and x (loop (- n 1) (cons x lst) rst))))
219          (list (reverse lst) rst)))))
220
221
222(define (consume-min-max m n f)
223  (lambda (s) 
224    (let loop ((m m) (n n) (lst (list)) (rst s))
225      (cond ((positive? m)
226             (match (f rst)
227                    ((a1 rst) (loop (- m 1) (- n 1) (cons a1 lst) rst))
228                    (else #f)))
229            ((<= n 0)   (list (reverse lst) rst))
230            (else
231             (match (f rst)
232                    ((a1 rst) (loop 0 (- n 1) (cons a1 lst) rst))
233                    (else #f)))))))
234
235;; Helper function for malformed ip address error messages
236
237(define (try-ip-literal->string s)
238  (let loop ((lst (list))  (rst s))
239    (match rst ((#\] . rst)  (uri-char-list->string (reverse lst)))
240           (()  (uri-char-list->string (reverse lst)))
241           (else (loop (cons (car rst) lst) (cdr rst))))))
242
243;; RFC 3986, section 2.1
244;;
245;; Returns a 'pct-encoded' sequence of octets.
246;;
247(define (pct-encode char-list char-set)
248  (define (hex-digit i)
249    (and (>= i 0) (< i 16)
250         (car (string->list (string-upcase (number->string i 16))))))
251  (reverse (fold (lambda (c cl)
252                   (if (char-set-contains? char-set c)
253                       (let* ((x (char->integer c))
254                              (h1 (hex-digit (quotient x 16)))
255                              (h2 (hex-digit (remainder x 16))))
256                         (cons `(#\% ,h1 ,h2) cl))
257                       (cons c cl)))
258                 (list) char-list)))
259
260;; Inverse operation: 'pct-decode' a sequence of octets.
261
262(define (pct-decode char-list char-set)
263  (define (octet-decode h1 h2)
264    (string->number (list->string (list h1 h2)) 16))
265  (map (lambda (c)
266        (match c
267               ((#\% h1 h2) (let ((dc (integer->char (octet-decode h1 h2))))
268                              (if (char-set-contains? char-set dc) dc c)))
269               (else c)))
270       char-list))
271
272
273;; RFC3986, section 2.2
274;;
275;; Reserved characters.
276;;
277
278(define char-set:gen-delims (string->char-set ":/?#[]@"))
279(define char-set:sub-delims (string->char-set "!$&'()*+,;="))
280
281(define char-set:uri-reserved (char-set-union char-set:gen-delims char-set:sub-delims))
282
283;;  RFC3986, section 2.3
284;;
285;;  "Unreserved" characters.
286;;
287
288(define char-set:uri-unreserved 
289  (char-set-union char-set:letter+digit (string->char-set "-_.~")))
290
291
292
293;;  RFC3986, section 3
294;;
295;;   URI         = scheme ":" hier-part [ "?" query ] [ "#" fragment ]
296;;
297;;   hier-part   = "//" authority path-abempty
298;;               / path-abs
299;;               / path-rootless
300;;               / path-empty
301
302(define (uri s)
303  (let ((s (if (string? s) (uri-string->normalized-char-list s) s)))
304    (match (scheme s)
305           ((us rst)
306            (match-let* (((ua up rst)   (hier-part rst))
307                         ((uq rst)      (match rst ((#\? . rst) (query rst))
308                                               (else (list #f rst))))
309                         ((uf rst)      (match rst ((#\# . rst) (fragment rst))
310                                               (else (list #f rst)))))
311                        (make-URI scheme: (string->symbol (list->string us)) authority: ua 
312                                  path: (uri-path-list->path up) query: (and uq (uri-char-list->string uq))
313                                  fragment: (and uf (uri-char-list->string uf)))))
314         (else #f))))
315
316(define (uri-path-list->path pcl)
317  (let ((cs (char-set-union char-set:uri-unreserved (char-set #\/))))
318    (match pcl
319           (('/ . rst) (cons '/ (map (compose uri-char-list->string (cute pct-decode <> cs)) rst)))
320           (else (map (compose uri-char-list->string (cute pct-decode <> cs)) pcl)))))
321
322(define (hier-part s)
323  (match s ((#\/ #\/ . rst) 
324            (match-let* (((ua rst)  (authority rst))
325                         ((up rst)  (path-abempty rst)))
326                        (list ua up rst)))
327         (else (match-let (((up rst) (or (path-abs s) (path-rootless s) (list '() s))))
328                          (list #f up rst)))))
329
330;;  RFC3986, section 3.1
331
332(define scheme0 (many scheme-char?))
333(define (scheme s)
334  (match (scheme0 s)
335         ((ss (#\: . rst))  (list ss rst))
336         (else #f)))
337
338(define char-set:scheme
339  (char-set-union char-set:letter+digit (string->char-set "+-.")))
340
341
342;;  RFC3986, section 3.2
343;;
344;;     authority     = [ userinfo "@" ] host [ ":" port ]
345
346(define (authority s)
347  (match-let* (((uu uw rst)   (or (userinfo s) (list #f #f s)))
348               ((uh rst)      (host rst))
349               ((up rst)      (or (port rst) (list #f rst))))
350              (list (make-URIAuth username: (and uu (uri-char-list->string uu)) 
351                                  password: (and uw (uri-char-list->string uw))
352                                  host: (uri-char-list->string uh) 
353                                  port: (and (pair? up) (string->number (list->string up))))
354                    rst)))
355
356;;  RFC3986, section 3.2.1
357;;
358;;     userinfo      = *( unreserved / pct-encoded / sub-delims / ":" )
359;;
360;; We split this up in the leading part without colons ("username") and
361;; everything after that ("password"), including extra colons.
362;;
363;; The RFC is not very clear, but it does mention this:
364;;   "The userinfo subcomponent may consist of a user name and,
365;;    optionally, scheme-specific information about how to gain
366;;    authorization to access the resource."
367;;
368;; The grammar allows multiple colons, and the RFC then continues:
369;;   "Applications should not render as clear text any data after
370;;    the first colon (":") character found within a userinfo
371;;    subcomponent unless the data after the colon is the empty
372;;    string (indicating no password)."
373
374(define userinfo0  (many (uchar ";&=+$,")))
375(define userinfo1  (many (uchar ";&=+$,:")))
376
377(define (userinfo s)
378  (match (userinfo0 s)
379         ((uu ( #\: . rst))   (match (userinfo1 rst)
380                                     ((up ( #\@ . rst) ) (list uu up rst))
381                                     (else #f)))
382         ((uu ( #\@ . rst)) (list uu #f rst))
383         (else #f)))
384
385
386;;  RFC3986, section 3.2.2
387;;
388;;     host          = IP-literal / IPv4address / reg-name
389;;     IP-literal    = "[" ( IPv6address / IPvFuture  ) "]"
390;;     IPvFuture     = "v" 1*HEXDIG "." 1*( unreserved / sub-delims / ":" )
391
392(define (host s)  (or (ip-literal s) (ipv4-address s) (reg-name s)))
393
394(define (ip-literal s)
395  (match s ((#\[ . rst) 
396            (match (or (ipv6-address rst) (ipv-future rst))
397                   ((ua (#\] . rst))  (list ua rst))
398                   (else (error 'ip-literal "malformed ip literal" (try-ip-literal->string rst)))))
399         (else #f)))
400
401(define ipv-future0  (many ipv-future-char?))
402
403(define (ipv-future s)
404  (match s ((#\v (? hexdigit-char?) #\. . rst)  (ipv-future0 rst))
405         (else #f)))
406
407(define char-set:ipv-future 
408  (char-set-union char-set:uri-unreserved char-set:sub-delims (char-set #\;)))
409
410
411
412;; IPv6address =                                  6( h16 ":" ) ls32
413;;                   /                       "::" 5( h16 ":" ) ls32
414;;                   / [               h16 ] "::" 4( h16 ":" ) ls32
415;;                   / [ *1( h16 ":" ) h16 ] "::" 3( h16 ":" ) ls32
416;;                   / [ *2( h16 ":" ) h16 ] "::" 2( h16 ":" ) ls32
417;;                   / [ *3( h16 ":" ) h16 ] "::"    h16 ":"   ls32
418;;                   / [ *4( h16 ":" ) h16 ] "::"              ls32
419;;                   / [ *5( h16 ":" ) h16 ] "::"              h16
420;;                   / [ *6( h16 ":" ) h16 ] "::"
421
422;;       ls32        = ( h16 ":" h16 ) / IPv4address
423;;                   ; least-significant 32 bits of address
424
425;;       h16         = 1*4HEXDIG
426;;                   ; 16 bits of address represented in hexadecimal
427
428
429(define (ipv6-address s)
430  (or (match (u6-h4c s) ;; 6( h16 ":" ) ls32
431
432             ((a2 rst)  (match (ls32 rst)
433                               ((a3 rst)  (list (append (concatenate a2) a3) rst))
434                               (else #f)))
435             (else #f))
436      (match s          ;; "::" 5( h16 ":" ) ls32
437             ((#\: #\: . rst) 
438              (match (u5-h4c rst)
439                     ((a2 rst)  (match (ls32 rst)
440                                       ((a3 rst)  (list (append (list #\: #\:) (concatenate a2) a3) rst))
441                                       (else #f)))))
442             (else #f))
443      (match (u_opt_n_h4c_h4 0 s)
444             ((a1 rst) (match rst
445                              ((#\: #\: . rst) 
446                               (match (u4-h4c rst)
447                                      ((a2 rst)  (match (ls32 rst)
448                                                        ((a3 rst) 
449                                                         (list (append (concatenate a1) (list #\: #\:) 
450                                                                       (concatenate a2) a3) rst))
451                                                        (else #f)))
452                                      (else #f)
453                                      ))
454                              (else #f)))
455              (else #f))
456      (match (u_opt_n_h4c_h4 1 s)
457             ((a1 rst) 
458                      (match rst       
459                              ((#\: #\: . rst) 
460                               (match (u3-h4c rst)
461                                      ((a2 rst)  (match (ls32 rst)
462                                                        ((a3 rst) 
463                                                         (list (append (concatenate a1) (list #\: #\:) 
464                                                                       (concatenate a2) a3) rst))
465                                                        (else #f)))
466                                      (else #f)
467                                      ))
468                              (else #f)))
469              (else #f))
470      (match (u_opt_n_h4c_h4 2 s)
471             ((a1 rst) (match rst       
472                              ((#\: #\: . rst) 
473                               (match (u2-h4c rst)
474                                      ((a2 rst)  (match (ls32 rst)
475                                                        ((a3 rst)  (list (append (concatenate a1) (list #\: #\:) 
476                                                                                 (concatenate a2) a3) rst))
477                                                        (else #f)))
478                                      (else #f)
479                                      ))
480                              (else #f)))
481              (else #f))
482      (match (u_opt_n_h4c_h4 3 s)
483             ((a1 rst) (match rst       
484                              ((#\: #\: . rst) 
485                               (match (h4c rst)
486                                      ((a2 rst)  (match (ls32 rst)
487                                                        ((a3 rst)  (list (append (concatenate a1) (list #\: #\:) 
488                                                                                 (concatenate a2) a3) rst))
489                                                        (else #f)))
490                                      (else #f)
491                                      ))
492                              (else #f)))
493              (else #f))
494      (match (u_opt_n_h4c_h4 4 s)
495             ((a1 rst) (match rst       
496                              ((#\: #\: . rst) 
497                               (match (ls32 rst)
498                                      ((a3 rst)  (list (append (concatenate a1) (list #\: #\:) a3) rst))
499                                      (else #f)))
500                              (else #f)))
501              (else #f))
502      (match (u_opt_n_h4c_h4 5 s)
503             ((a1 rst) (match rst       
504                              ((#\: #\: . rst) 
505                               (match (h4 rst)
506                                      ((a3 rst)  (list (append (concatenate a1) (list #\: #\:) a3) rst))
507                                      (else #f)))
508                              (else #f)))
509              (else #f))
510      (match (u_opt_n_h4c_h4 6 s)
511             ((a1 rst) (match rst       
512                              ((#\: #\: . rst) 
513                               (list (append (concatenate a1) (list #\: #\:)) rst))
514                              (else #f)))
515              (else #f))
516      (error 'ipv6-address "malformed ipv6 address" (try-ip-literal->string s))))
517
518
519
520(define (u_opt_n_h4c_h4 n s)
521  (match ((consume-min-max 0 n h4c) s)
522         ((a1 rst)  (match (h4 rst)
523                           ((a2 rst) (list (append a1 (list a2)) rst))
524                           (else #f)))
525         (else #f)))
526
527(define (ls32 s)
528  (match (h4c s)
529         ((a1 rst) (match (h4 rst)
530                          ((a2 rst)  (list (append a1 a2) rst))
531                          (else (ipv4-address s))))
532         (else (ipv4-address s))))
533
534(define (h4c s)
535  (match (h4 s)
536         ((a1 (#\: (and r1 (not #\:)) . rst))
537          (list (append a1 (list #\:)) (cons r1 rst)))
538         (else #f)))
539
540(define u6-h4c (consume-count 6 h4c))
541(define u5-h4c (consume-count 5 h4c))
542(define u4-h4c (consume-count 4 h4c))
543(define u3-h4c (consume-count 3 h4c))
544(define u2-h4c (consume-count 2 h4c))
545
546(define h4 (count-min-max 1 4 hexdigit-char?))
547
548(define (ipv4-address s)
549  (match (dec-octet s)
550         ((a1 (#\. rst)) 
551          (match (dec-octet rst)
552                 ((a2 (#\. rst)) 
553                  (match (dec-octet rst)
554                         ((a3 (#\. rst)) 
555                          (match (dec-octet rst)
556                                 ((a4 rst)  (list (append a1 #\. a2 #\. a3 #\. a4) rst))
557                                 (else #f)))
558                         (else #f)))
559                 (else #f)))
560         (else #f)))
561
562(define (ipv4-octet? lst)
563  (and (every (lambda (x) (char-set-contains? char-set:digit x)) lst)
564       (let ((num (string->number (list->string lst))))
565         (and num (>= num 0) (<= num 255)))))
566
567(define (dec-octet s)
568  (match ((count-min-max 1 3 char-numeric?) s)
569         (((and a1 (? ipv4-octet?)) rst)  (list a1 rst))
570         (else #f)))
571
572(define reg-name
573  (count-min-max 0 255 (lambda (c) (or (pct-encoded? c) 
574                                       (unreserved-char? c) 
575                                       (char-set-contains? char-set:sub-delims c) ))))
576
577;;  RFC3986, section 3.2.3
578;;
579;;     port          = *DIGIT
580
581(define port0 (many char-numeric?))
582
583(define (port s)
584  (match s ((#\: . rst)  (port0 rst))
585         (else #f)))
586
587
588;;
589;;  RFC3986, section 3.3
590;;
591;;   path          = path-abempty    ; begins with "/" or is empty
592;;                 / path-abs        ; begins with "/" but not "//"
593;;                 / path-noscheme   ; begins with a non-colon segment
594;;                 / path-rootless   ; begins with a segment
595;;                 / path-empty      ; zero characters
596;;
597;;   path-abempty  = *( "/" segment )
598;;   path-abs      = "/" [ segment-nz *( "/" segment ) ]
599;;   path-noscheme = segment-nzc *( "/" segment )
600;;   path-rootless = segment-nz *( "/" segment )
601;;   path-empty    = 0<pchar>
602;;
603;;   segment       = *pchar
604;;   segment-nz    = 1*pchar
605;;   segment-nzc   = 1*( unreserved / pct-encoded / sub-delims / "@" )
606;;
607;;   pchar         = unreserved / pct-encoded / sub-delims / ":" / "@"
608
609(define (path s)
610  (or (path-abempty s)  (path-abs s) (path-noscheme s) 
611      (path-rootless s) (list (list) s)))
612
613 
614(define (slash-segment s)
615  (match s
616         ((#\/ . rst)
617          (or (slash-segment rst)
618              (match (segment rst)
619                     ((ss rst)  (list ss rst))
620                     (else #f))))
621         (else  #f)))
622
623(define pchar (uchar ":@"))
624
625(define segment (many pchar))
626
627(define segment-nz (many1 pchar))
628
629(define segment-nzc (many1 (uchar "@")))
630
631(define (path-abempty s)
632  (match ((consume slash-segment) s)
633         ((() rst) (list (list) rst))
634         ((path rst) (list (cons '/ path) rst))))
635
636(define (path-abs s)
637  (match s
638         ((#\/)          (list (list '/ (list))  (list)))
639         ((#\/ . rst)    (match (path-rootless rst)
640                                ((lst rst) (list (cons '/ lst) rst))
641                                (else #f)))
642         (else #f)))
643
644(define (path-noscheme s)
645  (match (segment-nzc s)
646         ((s1 rst)  (match ((consume slash-segment) rst)
647                           ((ss rst) (list (cons s1 ss) rst))))
648         (else #f)))
649
650(define (path-rootless s)
651  (match (segment-nz s)
652         ((s1 rst)  (match ((consume slash-segment) rst)
653                           ((ss rst) (list (cons s1 ss) rst))))
654         (else #f)))
655
656;;  RFC3986, section 3.4
657;;
658;;   query         = *( pchar / "/" / "?" )
659
660(define query0  (many (uchar ":@/?")))
661(define (query s)
662  (match (query0 s)
663         ((ss rst)  (list ss rst))
664         (else #f)))
665
666;;  RFC3986, section 3.5
667;;   fragment         = *( pchar / "/" / "?" )
668
669(define fragment0  (many (uchar ":@/?")))
670(define (fragment s)
671  (match (fragment0 s)
672         ((ss rst)  (list ss rst))
673         (else #f)))
674
675;;  Reference, Relative and Absolute URI forms
676;;
677;;  RFC3986, section 4.1
678
679(define (uri-reference s)
680  (let ((s (if (string? s) (uri-string->normalized-char-list s) s)))
681    (or (uri s) (relative-ref s))))
682
683;;  RFC3986, section 4.2
684;;
685;;   relative-URI  = relative-part [ "?" query ] [ "#" fragment ]
686;;
687;;   relative-part = "//" authority path-abempty
688;;                 / path-abs
689;;                 / path-noscheme
690;;                 / path-empty
691
692(define (relative-ref s)
693  (and (not (scheme s))
694       (match-let* (((ua up rst)  (relative-part s))
695                    ((uq rst)     (match rst ((#\? . rst) (query rst))
696                                         (else (list #f rst))))
697                    ((uf rst)     (match rst ((#\# . rst) (fragment rst))
698                                         (else (list #f rst)))))
699                   (make-URI scheme: #f authority: ua path: (uri-path-list->path up) 
700                             query: (and uq (uri-char-list->string uq))
701                             fragment: (and uf (uri-char-list->string uf))))))
702
703(define (relative-part s)
704  (match s
705         ((#\/ #\/ . rst)
706          (match-let* (((ua rst)  (authority rst))
707                       ((up rst)  (path-abempty rst)))
708                      (list ua up rst)))
709         (else (match-let* (((up rst)  (or (path-abs s) (path-noscheme s) (list (list) s))))
710                           (list #f up rst))))) 
711
712
713
714;;  RFC3986, section 4.3
715
716(define (absolute-uri s)
717  (let ((s (if (string? s) (uri-string->normalized-char-list s) s)))
718    (match (scheme s)
719           ((us rst) 
720            (match-let* (((ua up rst)  (hier-part rst))
721                         ((uq rst)     (match rst ((#\? . rst)  (query rst))
722                                              (else (list #f rst)))))
723                        (make-URI scheme: (string->symbol (list->string us)) authority: ua 
724                                  path: (uri-path-list->path up) query: (and uq (uri-char-list->string uq))
725                                  fragment: #f)))
726           (error 'absolute-uri "no scheme found in URI string"))))
727                     
728
729;; Turns a URI into a string.
730;;
731;; Uses a supplied function to map the userinfo part of the URI.
732;;
733
734(define (uri->string uri . rest)
735   (let-optionals rest ((userinfomap (lambda (u pw) (string-append u ":******" ))))
736    (match uri
737           (($ URI scheme authority path query fragment)
738            (string-append
739             ((lambda (x) (or (and x (string-append (->string x) ":")) ""))  scheme)
740             (if authority
741                 (string-append (uri-auth->string authority userinfomap))
742                 "")
743             (path->string path)
744             (if query (string-append "?" query) "")
745             (if fragment (string-append  "#" fragment) "")))
746           (else #f))))
747
748(define (uri-auth->string uri-auth userinfomap)
749  (match uri-auth
750         (($ URIAuth username password host port)
751          (string-append "//" (if username
752                                  ((lambda (x) (or (and x (string-append x "@")) ""))
753                                   (userinfomap username password)) "")
754                         host ((lambda (x) (or (and x (string-append ":" (->string x))) ""))
755                               port)))
756         (else #f)))
757                         
758(define (path->string path)
759  (match path
760         (('/ . segments)     (string-append "/" (join-segments segments)))
761         (((? protect?) . _)  (join-segments (cons "." path)))
762         (else                (join-segments path))))
763
764(define (join-segments segments)
765  (string-intersperse
766   (map (lambda (segment)
767          (uri-encode-string segment (char-set #\/)))
768        segments) "/"))
769
770;; Section 4.2; if the first segment contains a colon, it must be prefixed "./"
771(define (protect? sa) (string-index sa #\:))
772
773; specific: ((uri-authority uri) (uri-path uri) (uri-query uri)).
774
775(define (uri->list uri . rest)
776  (let-optionals rest ((userinfomap (lambda (u pw) (string-append u ":******" ))))
777    (match uri
778           (($ URI scheme authority path query fragment)
779            `(,scheme (,(uri-auth->list authority userinfomap) ,path ,query) ,fragment))
780           (else #f))))
781
782(define (uri-auth->list uri-auth userinfomap)
783  (match uri-auth
784         (($ URIAuth username password regname port)
785          `(,(if (and username password) (userinfomap username password) #f) ,regname ,port ))
786         (else #f)))
787                         
788
789;;  Percent encoding and decoding
790
791(define (uri-encode-string str #!optional (char-set (char-set-complement
792                                                     char-set:uri-unreserved)))
793  (let ((clst (string->list str)))
794    (uri-char-list->string
795     (pct-encode clst char-set))))
796
797(define (uri-decode-string str #!optional (char-set char-set:full))
798  (uri-char-list->string (pct-decode (uri-string->char-list str) char-set)))
799   
800(define (uri-string->normalized-char-list str)
801  (pct-decode (uri-string->char-list str) char-set:uri-unreserved))
802
803
804;; Convert a URI character list to a string
805
806(define (uri-char-list->string s)
807  (reverse-list->string 
808   (fold (lambda (x ax)
809           (cond ((char? x) (cons x ax))
810                 ((list? x) (append-reverse x ax)))) (list) s)))
811   
812;; Convert a string to a URI character list
813
814(define (uri-string->char-list s)
815  (let loop ((cs (list)) (lst (string->list s)))
816    (if (null? lst) (reverse cs)
817        (match lst
818               ((#\% h1 h2 . rst)  (loop (cons (list #\% h1 h2) cs) rst))
819               (((and c (? char?)) . rst)  (loop (cons c cs) rst))))))
820   
821;;
822;;  Resolving a relative URI relative to a base URI
823;;
824;;  Returns a new URI which represents the value of the first URI
825;;  interpreted as relative to the second URI.
826;;
827;;  For example:
828;;
829;;  (uri->string (relative-to (uri-reference "foo") (uri "http://bar.org/")) )
830;;         => "http://bar.org/foo"
831;;
832;;  (uri->string (non-strict-relative-to (uri "http:foo") (uri "http://bar.org/")) )
833;;         => "http://bar.org/foo"
834;;
835;;  Algorithm from RFC3986, section 5.2.2
836;;
837
838(define (uri-relative-to ref base)
839  (and (uri? ref) (uri? base)
840       (cond ((uri-scheme ref)      (just-segments ref))
841             ((uri-authority ref)   (let ((x (just-segments ref)))
842                                      (URI-scheme-set! x (uri-scheme base))
843                                      x))
844
845             (((lambda (p) (and (not (null? p)) p))  (uri-path ref)) =>
846              (lambda (ref-path)
847                (if (and (pair? ref-path) (eq? '/ (car ref-path)))
848                    (let ((x (just-segments ref)))
849                      (URI-scheme-set! x (uri-scheme base))
850                      (URI-authority-set! x (uri-auth base))
851                      x)
852                    (let ((x (udup ref)))
853                      (URI-scheme-set! x (uri-scheme base))
854                      (URI-authority-set! x (uri-auth base))
855                      (URI-path-set! x (merge-paths base x))
856                      (just-segments x)))))
857             ((uri-query ref)       (let ((x (udup ref)))
858                                      (URI-scheme-set! x (uri-scheme base))
859                                      (URI-authority-set! x (uri-auth base))
860                                      (URI-path-set! x (list ""))
861                                      (URI-path-set! x (merge-paths base x))
862                                      (just-segments x)))
863
864             (else                  (let ((x (just-segments ref)))
865                                      (URI-scheme-set! x (uri-scheme base))
866                                      (URI-authority-set! x (uri-auth base))
867                                      (URI-path-set! x (uri-path base))
868                                      (URI-query-set! x (uri-query base))
869                                      x)))))
870
871(define (just-segments u)
872  (let ((p (remove-dot-segments (uri-path u))))
873    (make-URI scheme: (uri-scheme u) authority: (uri-auth u) path: p
874              query: (uri-query u) fragment: (uri-fragment u))))
875
876(define (merge0 pb pr)
877  (let* ((rpb  (reverse pb))
878         (pb1  (reverse (if (pair? rpb) (cdr rpb) rpb))))
879    (append pb1 pr)))
880
881(define (merge-paths b r)
882  (let ((ba (uri-authority b))
883        (pb (uri-path b))
884        (pr (uri-path r)))
885    (let ((mp  (if (and ba (null? pb)) pr (merge0 pb pr))))
886      mp)))
887
888(define (uri-non-strict-relative-to ref base)
889  (let ((rs (uri-scheme ref))
890        (rb (uri-scheme base)))
891    (let ((ref1 (make-URI scheme: (if (eq? rs rb) #f (uri-scheme ref))
892                          authority: (uri-auth ref) path: (uri-path ref)
893                          query: (uri-query ref) fragment: (uri-fragment ref))))
894      (uri-relative-to ref1 base))))
895
896
897;;  Remove dot segments, but protect leading '/' character
898
899(define (remove-dot-segments ps)
900  (match ps
901         (('/ . rst)   (cons '/ (elim-dots rst)))
902         (else         (elim-dots ps))))
903
904(define (elim-dots ps)
905  (let loop ((ps ps) (lst (list)))
906    (if (null? ps) (reverse lst)
907        (match ps
908               (("." . rst)
909                (loop rst (match lst
910                                 (("" dir . rest) lst)
911                                 ((file . rest) (cons "" lst))
912                                 (else (list "")))))
913               ((".." . rst)
914                (loop rst (match lst
915                                 (("" dir . rest) (cons "" rest))
916                                 ((file . rest) (cons "" rest))
917                                 (else (list "")))))
918               (("")
919                (loop (list) (match lst
920                                    (("" . rst2) lst)
921                                    (else (cons "" lst)))))
922               ((x . rst)
923                (loop rst (match lst
924                                 (("" . rst2) (cons x rst2))
925                                 (else (cons x lst)))))))))
926
927;;
928;; Finding a URI relative to a base URI
929;;
930;; Returns a new URI which represents the relative location of the
931;; first URI with respect to the second URI.  Thus, the values
932;; supplied are expected to be absolute URIs, and the result returned
933;; may be a relative URI.
934;;
935;; Example:
936;;
937;; (uri->string
938;;  (uri-relative-from (uri "http://example.com/Root/sub1/name2#frag")
939;;                     (uri "http://example.com/Root/sub2/name2#frag")))
940;;    ==> "../sub1/name2#frag"
941;;
942
943
944(define (uri-relative-from uabs base)
945  (cond ((ucdiff? uri-scheme uabs base)      (udup uabs))
946        ((ucdiff? uri-authority uabs base)   (let ((x (udup uabs)))
947                                               (URI-scheme-set! x #f)
948                                               x))
949        ;; Special case: no relative representation for http://a/ -> http://a
950        ;; ....unless that should be a path of ("..")
951        ((null? (uri-path uabs))             (let ((x (udup uabs)))
952                                               (URI-scheme-set! x #f)
953                                               x))
954        ((ucdiff? uri-path uabs base)       
955         (let ((x    (udup uabs))
956               (path (rel-path-from (remove-body-dot-segments (uri-path uabs))
957                                    (remove-body-dot-segments (uri-path base)))))
958           (URI-scheme-set! x #f)
959           (URI-authority-set! x #f)
960           (URI-path-set! x path)
961           x))
962        ((ucdiff? uri-query uabs base) 
963         (let ((x (udup uabs)))
964           (URI-scheme-set! x #f)
965           (URI-authority-set! x #f)
966           (URI-path-set! x (list))
967           x))
968        (else                            
969         (let ((x (udup uabs)))
970           (URI-scheme-set! x #f)
971           (URI-authority-set! x #f)
972           (URI-query-set! x #f)
973           (URI-path-set! x (list))
974           x))))
975
976
977(define (udup u)
978  (make-URI scheme: (uri-scheme u) authority: (uri-auth u) path: (uri-path u)
979            query: (uri-query u) fragment: (uri-fragment u)))
980
981(define (ucdiff? sel u1 u2)
982  (let ((s1 (sel u1))
983        (s2 (sel u2)))
984    (not (cond ((and (URIAuth? s1) (URIAuth? s2))
985                (not (or (ucdiff? uri-username u1 u2) (ucdiff? uri-host u1 u2) (ucdiff? uri-port u1 u2))))
986               ((and (list? s1) (list? s2))       (every equal? s1 s2))
987               ((and (string? s1) (string? s2))   (string=? s1 s2))
988               (else                              (eq? s1 s2))))))
989
990(define (remove-body-dot-segments p)
991  (or (and (pair? p)
992           (let ((r (reverse p)))
993             (reverse (cons (car r) (remove-dot-segments (cdr r))))))
994      p))
995
996(define (rel-path-from pabs base)
997  (match (list pabs base)
998         ((pabs ()) pabs)
999         ((() base) (list))
1000         ;; Construct a relative path segment if the paths share a
1001         ;; leading segment other than a leading '/'
1002         ((('/ . (and sa1 (ra1 . ra2))) ('/ . (and sb1 (rb1 . rb2))))
1003          (make-rel-path
1004           (if (string=? ra1 rb1)
1005               (rel-path-from1 sa1 sb1)
1006               pabs)))
1007         (else (error 'rel-path-from "Both URI paths must be absolute" pabs base))))
1008
1009(define (make-rel-path x)
1010  (match x
1011         ((or ('/ . rst) ("." . rst) (".." rst)) x)
1012         (else (cons "." x))))
1013
1014;;  rel-path-from1 strips off trailing names from the supplied paths,
1015
1016(define (rel-path-from1 pabs base)
1017  (match-let* (((na . sa)  (reverse pabs)) 
1018               ((nb . sb)  (reverse base)))
1019     (let ((rp (rel-segs-from (reverse sa) (reverse sb))))
1020       (if (null? rp)  (cond ((string=? na nb)  (list))
1021                             (else              (list na)))
1022           (append rp (list na))))))
1023
1024                         
1025;;  rel-segs-from discards any common leading segments from both paths,
1026;;  then invokes dif-segs-from to calculate a relative path from the end
1027;;  of the base path to the end of the target path.  The final name is
1028;;  handled separately, so this deals only with "directory" segments.
1029
1030(define (rel-segs-from sabs base)
1031  (cond ((and (null? sabs) (null? base))  (list))
1032        ((or (null? sabs) (null? base))   (dif-segs-from sabs base))
1033        (else (match-let (((sa1 . ra1) sabs)
1034                          ((sb1 . rb1) base))
1035                         (if (string=? sa1 sb1)
1036                             (rel-segs-from ra1 rb1)
1037                             (dif-segs-from sabs base))))))
1038
1039;;  dif-segs-from calculates a path difference from base to target,
1040;;  not including the final name at the end of the path (i.e. results
1041;;  always ends with '/')
1042;;
1043;;  This function operates under the invariant that the supplied value
1044;;  of sabs is the desired path relative to the beginning of base.
1045;;  Thus, when base is empty, the desired path has been found.
1046
1047(define (dif-segs-from sabs base)
1048  (if (null? base) sabs (dif-segs-from (cons ".." sabs)  (cdr base))))
1049
1050
1051
1052;; Other normalization functions
1053;;
1054;; Case normalization; cf. RFC3986 section 6.2.2.1
1055
1056(define (uri-normalize-case uri)
1057  (let* ((normalized-uri (uri-reference (normalize-pct-encoding (uri->string uri (lambda (user pass) (conc user ":" pass))))))
1058         (scheme         (string->symbol (string-downcase (->string (uri-scheme uri)))))
1059         (host           (normalize-pct-encoding (string-downcase (uri-host uri)))))
1060    (update-uri normalized-uri scheme: scheme host: host)))
1061
1062(define (normalize-pct-encoding str)
1063  (uri-char-list->string
1064   (map (lambda (c) (match c
1065                           ((#\% h1 h2)  `(#\% ,(char-upcase h1) ,(char-upcase h2)))
1066                           (else c)))
1067        (uri-string->normalized-char-list str))))
1068
1069;;  Path segment normalization; cf. RFC3986 section 6.2.2.4
1070
1071(define (uri-normalize-path-segments uri)
1072  (let ((u1      (udup uri))
1073        (path    (remove-dot-segments (uri-path uri))))
1074    (URI-path-set! u1 path)
1075    u1))
Note: See TracBrowser for help on using the repository browser.