source: project/chicken/trunk/chicken-install.scm @ 12595

Last change on this file since 12595 was 12595, checked in by felix winkelmann, 13 years ago
  • removed custom declarations
  • added "-update-db" option to chicken-install
  • chicken: "-quiet" is useless and DEPRECATED
  • added support for db file in repository (not used yet)
  • compiler warns if first form in module body is not an `import' form
File size: 15.6 KB
Line 
1;;;; chicken-install.scm
2;
3; Copyright (c) 2008, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library setup-utils setup-download)
28(require-library srfi-1 posix data-structures utils ports regex ports extras
29                 srfi-13 files)
30
31
32(foreign-declare #<<EOF
33#ifndef C_INSTALL_BIN_HOME
34# define C_INSTALL_BIN_HOME   NULL
35#endif
36EOF
37)
38
39
40(module main ()
41 
42  (import scheme chicken srfi-1 posix data-structures utils ports regex ports extras
43          srfi-13 files)
44  (import setup-utils setup-download)
45 
46  (import foreign)
47
48  (define +default-repository-files+
49    '("setup-api.so" "setup-api.import.so"
50      "setup-utils.so" "setup-utils.import.so"
51      "setup-download.so" "setup-download.import.so"
52      "chicken.import.so"
53      "lolevel.import.so"
54      "srfi-1.import.so"
55      "srfi-4.import.so"
56      "data-structures.import.so"
57      "ports.import.so"
58      "files.import.so"
59      "posix.import.so"
60      "srfi-13.import.so"
61      "srfi-69.import.so"
62      "extras.import.so"
63      "regex.import.so"
64      "srfi-14.import.so"
65      "tcp.import.so"
66      "foreign.import.so"
67      "scheme.import.so"
68      "srfi-18.import.so"
69      "utils.import.so"
70      "csi.import.so"))
71
72  (define *program-path*
73    (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
74          (make-pathname p "bin") )
75        (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )
76
77  (define *keep* #f)
78  (define *force* #f)
79  (define *sudo* #f)
80  (define *prefix* #f)
81  (define *host-extension* #f)
82  (define *run-tests* #f)
83  (define *retrieve-only* #f)
84  (define *no-install* #f)
85  (define *username* #f)
86  (define *password* #f)
87  (define *default-sources* '())
88  (define *default-location* #f)
89  (define *default-transport* 'http)
90
91  (define (load-defaults)
92    (let ((deff (make-pathname (chicken-home) "setup.defaults")))
93      (cond ((not (file-exists? deff)) '())
94            (else
95             (set! *default-sources* (read-file deff))
96             (pair? *default-sources*)))))
97
98  (define (deps key meta)
99    (or (and-let* ((d (assq key meta)))
100          (cdr d))
101        '()))
102
103  (define (init-repository dir)
104    (let ((src (repository-path))
105          (copy (if (or (feature? 'mingw32) (feature? 'msvc))
106                    "copy" 
107                    "cp -r")))
108      (print "copying required files to " dir " ...")
109      (for-each
110       (lambda (f)
111         (system* "~a ~a ~a" copy (make-pathname src f) dir))
112       +default-repository-files+)))
113
114  (define (ext-version x)
115    (cond ((or (eq? x 'chicken)
116               (equal? x "chicken")
117               (member (->string x) ##sys#core-library-modules))
118           (chicken-version) )
119          ((extension-information x) =>
120           (lambda (info)
121             (and-let* ((a (assq 'version info)))
122               (->string (cadr a)))))
123          (else #f)))
124
125  (define (outdated-dependencies meta)
126    (let ((ds (append
127               (deps 'depends meta) 
128               (deps 'needs meta)
129               (if *run-tests* (deps 'test-depends meta) '()))))
130      (let loop ((deps ds) (missing '()) (upgrade '()))
131        (if (null? deps)
132            (values (reverse missing) (reverse upgrade))
133            (let ((dep (car deps))
134                  (rest (cdr deps)))
135              (cond ((or (symbol? dep) (string? dep))
136                     (loop rest
137                           (if (ext-version dep)
138                               missing
139                               (cons (->string dep) missing))
140                           upgrade))
141                    ((and (list? dep) (= 2 (length dep))
142                          (or (string? (car dep)) (symbol? (car dep))))
143                     (let ((v (ext-version (car dep))))
144                       (cond ((not v) 
145                              (warning
146                               "installed extension has unknown version - assuming it is outdated" 
147                               (car dep))
148                              (loop rest missing 
149                                    (alist-cons 
150                                     (->string (car dep))
151                                     (->string (cadr dep))
152                                     upgrade)))
153                             ((version>=? (->string (cadr dep)) v)
154                              (loop rest missing
155                                    (alist-cons
156                                     (->string (car dep)) (->string (cadr dep))
157                                     upgrade)))
158                             (else (loop rest missing upgrade)))))
159                    (else
160                     (warning
161                      "invalid dependency syntax in extension meta information" 
162                      dep)
163                     (loop rest missing upgrade))))))))
164
165    (define *eggs+dirs* '())
166    (define *checked* '())
167
168    (define (try name version)
169      (let loop ((defs (if (and *default-location* *default-transport*)
170                           `(((location ,*default-location*)
171                              (transport ,*default-transport*)))
172                           *default-sources*)))
173        (and (pair? defs)
174             (let* ((def (car defs))
175                    (loc (cadr (or (assq 'location def)
176                                   (error "missing location entry" def))))
177                    (trans (cadr (or (assq 'transport def)
178                                     (error "missing transport entry" def)))))
179               (or (condition-case
180                       (retrieve-extension 
181                        name trans loc
182                        version: version
183                        destination: (and *retrieve-only* (current-directory))
184                        tests: *run-tests*
185                        username: *username* 
186                        password: *password*)
187                     ((exn net) 
188                      (print "TCP connect timeout")
189                      #f)
190                     ((exn http-fetch)
191                      (print "HTTP protocol error")
192                      #f)
193                     (e () (abort e)))
194                   (begin
195                     (set! *default-sources* (delete def *default-sources* eq?))
196                     (loop (cdr defs))))))))
197
198    (define (retrieve eggs)
199      (print "retrieving ...")
200      (for-each
201       (lambda (egg)
202         (cond ((assoc egg *eggs+dirs*) =>
203                (lambda (a)
204                  ;; push to front
205                  (set! *eggs+dirs* (cons a (delete a *eggs+dirs* eq?))) ) )
206               (else
207                (let* ((name (if (pair? egg) (car egg) egg))
208                       (version (and (pair? egg) (cdr egg)))
209                       (dir (try name version)))
210                  (unless dir
211                    (error "extension or version not found"))
212                  (print " " name " located at " dir)
213                  (set! *eggs+dirs* (alist-cons name dir *eggs+dirs*))))) )
214       eggs)
215      (unless *retrieve-only*
216        (for-each
217         (lambda (e+d)
218           (unless (member (car e+d) *checked*)
219             (set! *checked* (cons (car e+d) *checked*))
220             (let ((mfile (make-pathname (cdr e+d) (car e+d) "meta")))
221               (cond ((file-exists? mfile)
222                      (let ((meta (with-input-from-file mfile read)))
223                        (print "checking dependencies for `" (car e+d) "' ...")
224                        (let-values (((missing upgrade) (outdated-dependencies meta)))
225                          (when (pair? missing)
226                            (print " missing: " (string-intersperse missing ", "))
227                            (retrieve missing))
228                          (when (and (pair? upgrade)
229                                     (or *force*
230                                         (yes-or-no? 
231                                          (string-concatenate
232                                           (append
233                                            (list "The following installed extensions are outdated, because `"
234                                                  (car e+d) "' requires later versions:\n")
235                                            (map (lambda (e)
236                                                   (sprintf 
237                                                    "  ~a (~a -> ~a)~%"
238                                                    (car e) 
239                                                    (let ((v (assq 'version (extension-information (car e)))))
240                                                      (if v (cadr v) "???"))
241                                                    (cdr e)))
242                                                 upgrade)
243                                            '("\nDo you want to replace the existing extensions?")))
244                                          "no") ) )
245                            (let ((ueggs (unzip1 upgrade)))
246                              (print " upgrade: " (string-intersperse ueggs ", "))
247                              (for-each
248                               (lambda (e)
249                                 (print "removing previously installed extension `" e "' ...")
250                                 (remove-extension e *sudo*) )
251                               ueggs)
252                              (retrieve ueggs))))))
253                     (else
254                      (warning 
255                       (string-append
256                        "extension `" (car e+d) "' has no .meta file "
257                        "- assuming it has no dependencies")))))))
258         *eggs+dirs*)))
259
260    (define (install eggs)
261      (retrieve eggs)
262      (unless *retrieve-only*
263        (for-each ; we assume the order reflects the dependency tree...
264         (lambda (e+d)
265           (print "installing " (car e+d) " ...")
266           (print "changing current directory to " (cdr e+d))
267           (parameterize ((current-directory (cdr e+d)))
268             (let ((cmd (sprintf
269                         "~a/csi -bnq -e \"(require-library setup-api)\" -e \"(import setup-api)\" ~a ~a ~a ~a ~a ~a"
270                         *program-path*
271                         (if *sudo* "-e \"(sudo-install #t)\"" "")
272                         (if *keep* "-e \"(keep-intermediates #t)\"" "")
273                         (if *no-install* "-e \"(setup-install-flag #f)\"" "")
274                         (if *host-extension* "-e \"(host-extension #t)\"" "")
275                         (if *prefix* 
276                             (sprintf "-e \"(installation-prefix \\\"~a\\\")\"" *prefix*)
277                             "")
278                         (make-pathname (cdr e+d) (car e+d) "setup"))))
279               (system* cmd))
280             (when (and *run-tests*
281                        (file-exists? "tests")
282                        (directory? "tests")
283                        (file-exists? "tests/run.scm") )
284               (current-directory "tests")
285               (let ((cmd (sprintf "~a/csi -s run.scm ~a" *program-path* (car e+d))))
286                 (print cmd)
287                 (system* cmd)))))
288         *eggs+dirs*)))
289
290  (define (cleanup)
291    (unless *keep*
292      (and-let* ((tmpdir (temporary-directory)))
293        (remove-directory tmpdir))))
294
295  (define (update-db files)
296    (let* ((files (if (null? files)
297                      (glob (make-pathname (repository-path) "*.import.*"))
298                      files) ) 
299           (dbfile (make-pathname (repository-path) "db")))
300      (for-each
301       (lambda (f)
302         (let ((m (string-match ".*/([^/]+)\\.import\\.(scm|so)" f)))
303           (eval `(import ,(string->symbol (cadr m))))))
304       files)
305      (print "generating database " dbfile)
306      (let ((db
307             (sort
308              (append-map
309               (lambda (m)
310                 (let* ((mod (cdr m))
311                        (mname (##sys#module-name mod)))
312                   (print "  " mname)
313                   (let-values (((_ ve se) (##sys#module-exports mod)))
314                     (append
315                      (map (lambda (se) (list (car se) 'syntax mname)) se)
316                      (map (lambda (ve) (list (car ve) 'value mname)) ve)))))
317               ##sys#module-table) 
318              (lambda (e1 e2)
319                (string<? (symbol->string (car e1)) (symbol->string (car e2)))))))
320        (with-output-to-file (make-pathname (repository-path) "db")
321          (lambda ()
322            (for-each (lambda (x) (write x) (newline)) db))))))
323
324  (define (usage code)
325    (print #<<EOF
326usage: chicken-install [OPTION | EXTENSION[:VERSION]] ...
327
328  -h   -help                    show this message and exit
329  -v   -version                 show version and exit
330       -force                   don't ask, install even if versions don't match
331  -k   -keep                    keep temporary files
332  -l   -location LOCATION       install from given location instead of default
333  -t   -transport TRANSPORT     use given transport instead of default
334  -s   -sudo                    use sudo(1) for installing or removing files
335  -r   -retrieve                only retrieve egg into current directory, don't install
336  -n   -no-install              do not install, just build (implies `-keep')
337  -p   -prefix PREFIX           change installation prefix to PREFIX
338       -host-extension          when cross-compiling, compile extension for host
339       -test                    run included test-cases, if available
340       -username USER           set username for transports that require this
341       -password PASS           set password for transports that require this
342  -i   -init DIRECTORY          initialize empty alternative repository
343  -u   -update-db [FILENAME ...]  update export database
344EOF
345);|
346    (exit code))
347
348  (define *short-options* '(#\h #\k #\l #\t #\s #\p #\r #\n #\v #\i #\u))
349
350  (define (main args)
351    (let ((defaults (load-defaults)))
352      (let loop ((args args) (eggs '()))
353        (cond ((null? args)
354               (when (null? eggs)
355                 (let ((setups (glob "*.setup")))
356                   (cond ((pair? setups)
357                          (set! *eggs+dirs*
358                            (append
359                             (map (lambda (s) (cons (pathname-file s) ".")) setups)
360                             *eggs+dirs*)))
361                         (else
362                          (print "no setup-scripts to process")
363                          (exit 1))) ) )
364               (unless defaults
365                 (unless *default-transport* 
366                   (error "no default transport defined - please use `-transport' option"))
367                 (unless *default-location* 
368                   (error "no default location defined - please use `-location' option")))
369               (install (reverse eggs)))
370              (else
371               (let ((arg (car args)))
372                 (cond ((or (string=? arg "-help") 
373                            (string=? arg "-h")
374                            (string=? arg "--help"))
375                        (usage 0))
376                       ((string=? arg "-force")
377                        (set! *force* #t)
378                        (loop (cdr args) eggs))
379                       ((or (string=? arg "-k") (string=? arg "-keep"))
380                        (set! *keep* #t)
381                        (loop (cdr args) eggs))
382                       ((or (string=? arg "-s") (string=? arg "-sudo"))
383                        (set! *sudo* #t)
384                        (loop (cdr args) eggs))
385                       ((or (string=? arg "-r") (string=? arg "-retrieve"))
386                        (set! *retrieve-only* #t)
387                        (loop (cdr args) eggs))
388                       ((or (string=? arg "-l") (string=? arg "-location"))
389                        (unless (pair? (cdr args)) (usage 1))
390                        (set! *default-location* (cadr args))
391                        (loop (cddr args) eggs))
392                       ((or (string=? arg "-t") (string=? arg "-transport"))
393                        (unless (pair? (cdr args)) (usage 1))
394                        (set! *default-transport* (string->symbol (cadr args)))
395                        (loop (cddr args) eggs))
396                       ((or (string=? arg "-p") (string=? arg "-prefix"))
397                        (unless (pair? (cdr args)) (usage 1))
398                        (set! *prefix* (cadr args))
399                        (loop (cddr args) eggs))
400                       ((or (string=? arg "-n") (string=? arg "-no-install"))
401                        (set! *keep* #t)
402                        (set! *no-install* #t)
403                        (loop (cdr args) eggs))
404                       ((or (string=? arg "-v") (string=? arg "-version"))
405                        (print (chicken-version))
406                        (exit 0))
407                       ((or (string=? arg "-u") (string=? arg "-update-db"))
408                        (update-db (cdr args))
409                        (exit 0))
410                       ((or (string=? arg "-i") (string=? arg "-init"))
411                        (unless (pair? (cdr args)) (usage 1))
412                        (init-repository (cadr args))
413                        (exit 0))
414                       ((string=? "-test" arg)
415                        (set! *run-tests* #t)
416                        (loop (cdr args) eggs))
417                       ((string=? "-host-extension" arg)
418                        (set! *host-extension* #t)
419                        (loop (cdr args) eggs))
420                       ((string=? "-username" arg)
421                        (unless (pair? (cdr args)) (usage 1))
422                        (set! *username* (cadr args))
423                        (loop (cddr args) eggs))
424                       ((string=? "-password" arg)
425                        (unless (pair? (cdr args)) (usage 1))
426                        (set! *password* (cadr args))
427                        (loop (cddr args) eggs))
428                       ((and (positive? (string-length arg))
429                             (char=? #\- (string-ref arg 0)))
430                        (if (> (string-length arg) 2)
431                            (let ((sos (string->list (substring arg 1))))
432                              (if (null? (lset-intersection eq? *short-options* sos))
433                                  (loop (append (map (cut string #\- <>) sos) (cdr args)) eggs)
434                                  (usage 1)))
435                            (usage 1)))
436                       ((equal? "setup" (pathname-extension arg))
437                        (let ((egg (pathname-file arg)))
438                          (set! *eggs+dirs*
439                            (alist-cons
440                             egg
441                             (let ((dir (pathname-directory arg)))
442                               (if dir
443                                   (if (absolute-pathname? dir)
444                                       dir
445                                       (make-pathname (current-directory) dir) )
446                                   (current-directory)))
447                             *eggs+dirs*))
448                          (loop (cdr args) (cons egg eggs))))
449                       ((string-match "([^:]+):(.+)" arg) =>
450                        (lambda (m)
451                          (loop (cdr args) (alist-cons (cadr m) (caddr m) eggs))))
452                       (else (loop (cdr args) (cons arg eggs))))))))))
453
454  (handle-exceptions ex
455      (begin
456        (print-error-message ex (current-error-port))
457        (cleanup)
458        (exit 1))
459    (main (command-line-arguments))
460    (cleanup))
461 
462)
Note: See TracBrowser for help on using the repository browser.