Ticket #1728: 0001-Convert-build-script-to-Scheme-for-Windows-support.patch

postgresql/4.1.3/build-postgresql

@@ -1 +1 @@
 #!/bin/sh
-
-# Determine if pkg-config exists and knows about libpq, otherwise
-# fall back on pg_config to determine compiler and linker flags.
-if pkg-config --exists libpq >/dev/null 2>/dev/null; then
-   CFLAGS="`pkg-config --cflags libpq`"
-   LDFLAGS="`pkg-config --libs libpq`"
-else
-   CFLAGS="-I`pg_config --includedir`"
-   LDFLAGS="-L`pg_config --libdir` -Wl,-rpath `pg_config --libdir` -lpq"
-fi
-
-known_features="escape-identifier connectdb-params diag-query-position diag-schema-info"
-
-feature_flags=""
-for feature in $known_features; do
-    if "$CHICKEN_CSC" -C "$CFLAGS" -L "$LDFLAGS" "feature-tests/$feature.c" >/dev/null 2>/dev/null; then
-        feature_flags="$feature_flags -Dhas-$feature"
-    fi
-    rm -f feature-tests/$feature.o feature-tests/$feature
-done
-
-"$CHICKEN_CSC" $feature_flags -C "$CFLAGS" -L "$LDFLAGS" "$@"
+"$CHICKEN_CSI" -s build-postgresql.scm "$@"

new file postgresql/4.1.3/build-postgresql.bat

@@ +1 @@
+@echo off
+"%CHICKEN_CSI%" -s build-postgresql.scm %*

new file postgresql/4.1.3/build-postgresql.scm

@@ +1 @@
+(import scheme)
+(import (chicken base))
+(import (chicken file))
+(import (chicken io))
+(import (chicken format))
+(import (chicken pathname))
+(import (chicken platform))
+(import (chicken process))
+(import (chicken process-context))
+(import (chicken string))
+
+(define blackhole-device
+  (cond-expand
+   ((or unix cygwin) ">/dev/null 2>/dev/null")
+   (windows ">NUL 2>NUL")))
+
+(define object-extension
+  (cond-expand
+   (unix "o")
+   (windows "obj")))
+
+(define executable-extension
+  (cond-expand
+   (unix "")
+   (windows "exe")))
+
+;; adapted from egg-compile.scm
+(define (system+ str)
+  (system (if (and (eq? (software-type) 'windows)
+                   (not (eq? (software-version) 'cygwin))
+                   (positive? (string-length str))
+                   (char=? #\" (string-ref str 0)))
+              (string-append "\"" str "\"")
+              str)))
+
+(define cflags #f)
+(define ldflags #f)
+
+(define (capture command)
+  (string-chomp
+   (with-input-from-pipe command (cut read-string #f))))
+
+;; Determine if pkg-config exists and knows about libpq
+(cond
+ ((and (get-environment-variable "PG_CFLAGS")
+       (get-environment-variable "PG_LDFLAGS"))
+  (set! cflags (get-environment-variable "PG_CFLAGS"))
+  (set! ldflags (get-environment-variable "PG_LDFLAGS")))
+ ((zero? (system+ (format "pkg-config --exists libpq ~a" blackhole-device)))
+  (set! cflags (capture "pkg-config --cflags libpq"))
+  (set! ldflags (capture "pkg-config --libs libpq")))
+ ((zero? (system+ (format "pg_config --version ~a" blackhole-device)))
+  (set! cflags (format "-I~a" (capture "pg_config --includedir")))
+  (set! ldflags (format "-L~a -Wl,-rpath ~a -lpq"
+                        (capture "pg_config --libdir")
+                        (capture "pg_config --libdir"))))
+ (else
+  (print "Please ensure that libpq and its headers are installed. "
+         "Either install `pkg-config` or `pg_config` to auto-detect "
+         "flags or set them manually in PG_CFLAGS and PG_LDFLAGS.")
+  (exit 1)))
+
+(define csc (get-environment-variable "CHICKEN_CSC"))
+(define known-features '("escape-identifier" "connectdb-params"
+                         "diag-query-position" "diag-schema-info"))
+(define feature-flags "")
+
+(for-each
+ (lambda (feature)
+   (when (zero? (system+ (format "~a -C ~a -L ~a ~a ~a"
+                                 (qs csc) (qs cflags) (qs ldflags)
+                                 (qs (make-pathname "feature-tests" feature "c"))
+                                 blackhole-device)))
+     (set! feature-flags (string-append feature-flags " -Dhas-" feature)))
+   (delete-file*
+    (make-pathname "feature-tests" feature object-extension))
+   (delete-file*
+    (make-pathname "feature-tests" feature executable-extension)))
+ known-features)
+
+(define cmdline
+  (format "~a ~a -C ~a -L ~a ~a"
+          (qs csc) feature-flags (qs cflags) (qs ldflags)
+          (string-intersperse (map qs (command-line-arguments)) " ")))
+
+(let ((status (system+ cmdline)))
+  (when (not (zero? status))
+    (error "shell invocation failed with non-zero return status" cmdline status)))