source: project/release/5/srfi-4-comprehensions/tags/1.5/srfi-4-comprehensions.scm @ 37270

#|

Derived (almost verbatim) from the code for vector comprehensions in
the SRFI-42 reference implementation.  The copyright on that code is:

Copyright (C) Sebastian Egner (2003). All Rights Reserved.

Permission is hereby granted, free of charge, to any person obtaining
a copy of this software and associated documentation
files (the "Software"), to deal in the Software without restriction,
including without limitation the rights to use, copy, modify, merge,
publish, distribute, sublicense, and/or sell copies of the Software,
and to permit persons to whom the Software is furnished to do so,
subject to the following conditions:

The above copyright notice and this permission notice shall be
included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

Modifications are copyright (C) Will M. Farr (2006), goverened by the
same conditions.  Feel free to email comments to <farr@mit.edu>.  

|#


(module srfi-4-comprehensions 
  (:s8vector :u8vector :s16vector :u16vector :s32vector 
   :u32vector :f64vector :f32vector :s64vector :u64vector 
           
   s8vector-ec u8vector-ec s16vector-ec u16vector-ec s32vector-ec 
   u32vector-ec s64vector-ec u64vector-ec f64vector-ec f32vector-ec
           
   s8vector-of-length-ec u8vector-of-length-ec s16vector-of-length-ec 
   u16vector-of-length-ec s32vector-of-length-ec u32vector-of-length-ec
   s64vector-of-length-ec u64vector-of-length-ec
   f64vector-of-length-ec f32vector-of-length-ec)

  (import scheme (chicken base) (chicken fixnum) srfi-4 srfi-42)
  (import-for-syntax (chicken string))
  
  (define-syntax make/prefix
    (er-macro-transformer
    (lambda (x r c)
      (let* ((pre-sym  (cadr x))
             (vlength  (string->symbol (conc pre-sym "vector-length")))
             (vref     (string->symbol (conc pre-sym "vector-ref")))
             (vgen     (string->symbol (conc ":" pre-sym "vector")))
             (vfilter  (string->symbol (conc "ec-:" pre-sym "vector-filter")))
             (vmake    (string->symbol (conc "make-" pre-sym "vector")))
             (vset!    (string->symbol (conc pre-sym "vector-set!")))
             (list->v  (string->symbol (conc "list->" pre-sym "vector")))
             (v-ec     (string->symbol (conc pre-sym "vector-ec")))
             (v-of-length-ec (string->symbol (conc pre-sym "vector-of-length-ec")))
             (___ (r '___)))
        `(begin
           (define-syntax ,vgen
             (syntax-rules ,___ (index)
               ((,vgen cc var arg)
                (,vgen cc var (index i) arg) )
               ((,vgen cc var (index i) arg)
                (:do cc
                     (let ((vec arg) (len 0)) 
                       (set! len (,vlength vec)))
                     ((i 0))
                     (fx< i len)
                     (let ((var (,vref vec i))))
                     #t
                     ((fx+ i 1)) ))
               ((,vgen cc var (index i) arg1 arg2 arg ,___)
                (:parallel cc (,vgen cc var arg1 arg2 arg ,___) (:integers i)) )
               ((,vgen cc var arg1 arg2 arg ,___)
                (:do cc
                     (let ((vec #f)
                           (len 0)
                           (vecs (,vfilter (list arg1 arg2 arg ,___))) ))
                     ((k 0))
                     (if (fx< k len)
                         #t
                         (if (null? vecs)
                             #f
                             (begin (set! vec (car vecs))
                                    (set! vecs (cdr vecs))
                                    (set! len (,vlength vec))
                                    (set! k 0)
                                    #t )))
                     (let ((var (,vref vec k))))
                     #t
                     ((fx+ k 1)) ))
               ))

           (define (,vfilter vecs)
             (if (null? vecs)
                 '()
                 (if (zero? (,vlength (car vecs)))
                     (,vfilter (cdr vecs))
                     (cons (car vecs) (,vfilter (cdr vecs))) )))

           (define-syntax ,v-ec
             (syntax-rules ,___ ()
               ((v-ec etc1 etc ,___)
                (,list->v (list-ec etc1 etc ,___)) )))

           (define-syntax ,v-of-length-ec
             (syntax-rules ,___ (nested)
               ((v-of-length-ec k (nested q1 ,___) q etc1 etc ,___)
                (v-of-length-ec k (nested q1 ,___ q) etc1 etc ,___) )
               ((v-of-length-ec k q1 q2             etc1 etc ,___)
                (v-of-length-ec k (nested q1 q2)    etc1 etc ,___) )
               ((v-of-length-ec k expression)
                (v-of-length-ec k (nested) expression) )
               ((v-of-length-ec k qualifier expression)
                (let ((len k))
                  (let ((vec (,vmake len))
                        (i 0) )
                    (do-ec qualifier
                           (if (fx< i len)
                               (begin (,vset! vec i expression)
                                      (set! i (fx+ i 1)) )
                               (error "vector is too short for the comprehension") ))
                    (if (eq? i len)
                        vec
                        (error "vector is too long for the comprehension") ))))))
           )
        ))
    ))

   (make/prefix s8)
   (make/prefix u8)
   (make/prefix s16)
   (make/prefix u16)
   (make/prefix s32)
   (make/prefix u32)
   (make/prefix f32)
   (make/prefix f64)
   (make/prefix s64)
   (make/prefix u64)
)