source: project/release/5/slib-charplot/tags/1.1.0/charplot.scm

Last change on this file was 38404, checked in by Kon Lovett, 8 months ago

use original name

File size: 13.1 KB
Line 
1;;;; "charplot.scm", plotting on character devices for Scheme
2;;; Copyright (C) 1992, 1993, 2001, 2003 Aubrey Jaffer
3;
4;Permission to copy this software, to modify it, to redistribute it,
5;to distribute modified versions, and to use it for any purpose is
6;granted, subject to the following restrictions and understandings.
7;
8;1.  Any copy made of this software must include this copyright notice
9;in full.
10;
11;2.  I have made no warranty or representation that the operation of
12;this software will be error-free, and I am under no obligation to
13;provide any services, by way of maintenance, update, or otherwise.
14;
15;3.  In conjunction with products arising from the use of this
16;material, there shall be no use of my name in any advertising,
17;promotional, or sales literature without prior written consent in
18;each case.
19
20;(require 'printf)
21;(require 'array)
22;(require 'array-for-each)
23;(require 'multiarg/and-)
24;(require 'multiarg-apply)
25
26;;;@ These determine final graph size.
27(define charplot:dimensions #f)
28
29;;; The left margin and legends
30(define charplot:left-margin 12)
31
32(define char:xborder #\_)
33(define char:yborder #\|)
34(define char:xaxis   #\-)
35(define char:yaxis   #\:)
36(define char:xtick   #\.)
37(define char:bar     #\I)
38
39(define char:curves  "*+x@#$%&='")
40
41;;;Converts X to a string whose length is at most MWID.
42(define (charplot:number->string x mwid)
43  (define str (number->string x))
44  (if (> (string-length str) mwid)
45      (substring str 0 mwid)
46      str))
47
48;;;SCALE is a list of numerator and denominator.
49(define charplot:scale-it
50  (if (provided? 'inexact)
51      (lambda (z scale)
52        (inexact->exact (round (/ (* z (car scale)) (cadr scale)))))
53      (lambda (z scale)
54        (quotient (+ (* z (car scale)) (quotient (cadr scale) 2))
55                  (cadr scale)))))
56
57;;; Given the width or height (in characters) and the data-span,
58;;; returns a list of numerator and denominator (NUM DEN) suitable for
59;;; passing as a second argument to CHARPLOT:SCALE-IT.
60;;;
61;;; NUM will be 1, 2, 3, 4, 5, 6, or 8 times a power of ten.
62;;; DEN will be a power of ten.
63;;;
64;;; num   isize
65;;; === < =====
66;;; den   delta
67(define (charplot:find-scale isize delta)
68  (cond ((zero? delta) (set! delta 1))
69        ((inexact? delta) (set! isize (exact->inexact isize))))
70  (do ((d 1 (* d 10))
71       (isize isize (* isize 10)))
72      ((<= delta isize)
73       (do ((n 1 (* n 10))
74            (delta delta (* delta 10)))
75           ((>= (* delta 10) isize)
76            (list (* n (cond ((<= (* delta 8) isize) 8)
77                             ((<= (* delta 6) isize) 6)
78                             ((<= (* delta 5) isize) 5)
79                             ((<= (* delta 4) isize) 4)
80                             ((<= (* delta 3) isize) 3)
81                             ((<= (* delta 2) isize) 2)
82                             (else 1)))
83                  d))))))
84
85(define (charplot:make-array)
86  (define charplot:dimensions (plot-dimensions))
87  (let ((height (or (and charplot:dimensions (car charplot:dimensions))
88                    (output-port-height (current-output-port))))
89        (width (or  (and charplot:dimensions (cadr charplot:dimensions))
90                    (output-port-width (current-output-port)))))
91    (define pra (make-array " "  height width))
92    ;;Put newlines on right edge
93    (do ((idx (+ -1 height) (+ -1 idx)))
94        ((negative? idx))
95      (array-set! pra #\newline idx (+ -1 width)))
96    pra))
97
98;;;Creates and initializes character array with axes, scales, and
99;;;labels.
100(define (charplot:init-array pra xlabel ylabel xmin xscale ymin yscale)
101  (define charplot:left-margin (plot-left-margin))
102  (define char:xborder (xborder-char))
103  (define char:yborder (yborder-char))
104  (define char:xaxis (xaxis-char))
105  (define char:yaxis (yaxis-char))
106  (define char:xtick (xtick-char))
107  (define plot-height (- (car (array-dimensions pra)) 3))
108  (define plot-width (- (cadr (array-dimensions pra)) charplot:left-margin 4))
109  (define xaxis (- (charplot:scale-it ymin yscale)))
110  (define yaxis (- (charplot:scale-it xmin xscale)))
111  (define xstep (if (zero? (modulo (car xscale) 3)) 12 10))
112  ;;CL is the left edge of WIDTH field
113  (define (center-field str width ln cl)
114    (define len (string-length str))
115    (if (< width len)
116        (center-field (substring str 0 width) width ln cl)
117        (do ((cnt (+ -1 len) (+ -1 cnt))
118             (adx (+ (quotient (- width len) 2) cl) (+ 1 adx))
119             (idx 0 (+ 1 idx)))
120            ((negative? cnt))
121          (array-set! pra (string-ref str idx) ln adx))))
122
123  ;;x and y labels
124  (center-field ylabel (+ charplot:left-margin -1) 0 0)
125  (center-field xlabel (+ -1 charplot:left-margin) (+ 2 plot-height) 0)
126
127  ;;horizontal borders, x-axis, and ticking
128  (let ((xstep/2 (quotient (- xstep 2) 2)))
129    (define faxis (modulo (+ charplot:left-margin yaxis) xstep))
130    (define faxis/2 (modulo (+ charplot:left-margin yaxis xstep/2 1) xstep))
131    (define xfudge (modulo yaxis xstep))
132    (do ((cl (+ charplot:left-margin -1) (+ 1 cl)))
133        ((>= cl (+ plot-width charplot:left-margin)))
134      (array-set! pra char:xborder 0 cl)
135      (array-set! pra
136                  (cond ((eqv? faxis (modulo cl xstep)) char:yaxis)
137                        ((eqv? faxis/2 (modulo cl xstep)) char:xtick)
138                        (else char:xborder))
139                  (+ 1 plot-height) cl)
140      (if (<= 0 xaxis plot-height)
141          (array-set! pra char:xaxis (- plot-height xaxis) cl)))
142
143    ;;horizontal coordinates
144    (do ((i xfudge (+ i xstep))
145         (cl (+ charplot:left-margin xfudge (- xstep/2)) (+ xstep cl)))
146        ((> i plot-width))
147      (center-field (charplot:number->string
148                     (/ (* (- i yaxis) (cadr xscale))
149                        (car xscale))
150                     xstep)
151                    xstep (+ 2 plot-height) cl)))
152
153  ;;vertical borders and y-axis
154  (do ((ht plot-height (- ht 1)))
155      ((negative? ht))
156    (array-set! pra char:yborder (+ 1 ht) (+ charplot:left-margin -2))
157    (array-set! pra char:yborder (+ 1 ht) (+ charplot:left-margin plot-width))
158    (if (< -1 yaxis plot-width)
159        (array-set! pra char:yaxis (+ 1 ht) (+ charplot:left-margin yaxis))))
160
161  ;;vertical ticking and coordinates
162  (do ((ht (- plot-height 1) (- ht 1))
163       (ln 1 (+ 1 ln)))
164      ((negative? ht))
165    (let ((ystep (if (zero? (modulo (car yscale) 3)) 3 2)))
166      (if (zero? (modulo (- ht xaxis) ystep))
167          (let* ((v (charplot:number->string (/ (* (- ht xaxis) (cadr yscale))
168                                                (car yscale))
169                                             (+ charplot:left-margin -2)))
170                 (len (string-length v)))
171            (center-field v len ln (- charplot:left-margin 2 len)) ;Actually flush right
172            (array-set! pra char:xaxis ln (+ charplot:left-margin -1))))))
173  ;;return initialized array
174  pra)
175
176(define (charplot:array->list ra)
177  (define dims (array-dimensions ra))
178  (if (= 2 (length dims))
179      (do ((idx (+ -1 (car dims)) (+ -1 idx))
180           (cols '() (cons (do ((jdx (+ -1 (cadr dims)) (+ -1 jdx))
181                                (row '() (cons (array-ref ra idx jdx) row)))
182                               ((negative? jdx) row))
183                           cols)))
184          ((negative? idx) cols))
185      (do ((idx (+ -1 (car dims)) (+ -1 idx))
186           (cols '() (cons (array-ref ra idx) cols)))
187          ((negative? idx) cols))))
188
189;;;Converts data to list of coordinates (list).
190(define (charplot:data->lists data)
191  (cond ((array? data)
192         (case (array-rank data)
193           ((1) (set! data (map list
194                                (let ((ra (apply make-array '#()
195                                                 (array-dimensions data))))
196                                  (array-index-map! ra identity)
197                                  (charplot:array->list ra))
198                                (charplot:array->list data))))
199           ((2) (set! data (charplot:array->list data)))))
200        ((and (pair? (car data)) (not (list? (car data))))
201         (set! data (map (lambda (lst) (list (car lst) (cdr lst))) data))))
202  (cond ((list? (cadar data))
203         (set! data (map (lambda (lst) (cons (car lst) (cadr lst))) data))))
204  data)
205
206;;;An extremum is a list of the maximum and minimum values.
207;;;COORDINATE-EXTREMA returns a rank-length list of these.
208(define (coordinate-extrema data)
209  (define extrema (map (lambda (x) (list x x)) (car data)))
210  (for-each (lambda (lst)
211              (set! extrema (map (lambda (x max-min)
212                                   (list (max x (car max-min))
213                                         (min x (cadr max-min))))
214                                 lst extrema)))
215            data)
216  extrema)
217
218;;;Count occurrences of numbers within evenly spaced ranges; and return
219;;;lists of coordinates for graph.
220(define (histobins data plot-width)
221  (define datcnt (length data))
222  (define xmax (apply max data))
223  (define xmin (apply min data))
224  (if (null? data)
225      '()
226      (let* ((xscale (charplot:find-scale plot-width (- xmax xmin)))
227             (actual-width (- (charplot:scale-it xmax xscale)
228                              (charplot:scale-it xmin xscale)
229                              -1)))
230        (define ix-min (charplot:scale-it xmin xscale))
231        (define xinc (/ (- xmax xmin) actual-width))
232        (define bins (make-vector actual-width 0))
233        (for-each (lambda (x)
234                    (define idx (- (charplot:scale-it x xscale) ix-min))
235                    (if (< -1 idx actual-width)
236                        (vector-set! bins idx (+ 1 (vector-ref bins idx)))
237                        (slib:error x (/ (* x (car xscale)) (cadr xscale))
238                                    (+ ix-min idx))))
239                  data)
240        (map list
241             (do ((idx (+ -1 (vector-length bins)) (+ -1 idx))
242                  (xvl xmax (- xvl xinc))
243                  (lst '() (cons xvl lst)))
244                 ((negative? idx) lst))
245             (vector->list bins)))))
246
247;;;@ Plot histogram of DATA.
248(define (histograph data label)
249  (define charplot:dimensions (plot-dimensions))
250  (define charplot:left-margin (plot-left-margin))
251  (if (vector? data) (set! data (vector->list data)))
252  (charplot:plot (histobins data
253                            (- (or (and charplot:dimensions
254                                        (cadr charplot:dimensions))
255                                   (output-port-width (current-output-port)))
256                               charplot:left-margin 3))
257                 label "" #t))
258
259(define (charplot:plot data xlabel ylabel . histogram?)
260  (define charplot:left-margin (plot-left-margin))
261  (define char:bar (bar-char))
262  (define char:curves (curves-chars))
263  (define clen (string-length char:curves))
264  (set! histogram? (if (null? histogram?) #f (car histogram?)))
265  (set! data (charplot:data->lists data))
266  (let* ((pra (charplot:make-array))
267         (plot-height (- (car (array-dimensions pra)) 3))
268         (plot-width (- (cadr (array-dimensions pra)) charplot:left-margin 4))
269         (extrema (coordinate-extrema data))
270         (xmax (caar extrema))
271         (xmin (cadar extrema))
272         (ymax (apply max (map car (cdr extrema))))
273         (ymin (apply min (map cadr (cdr extrema))))
274         (xscale (charplot:find-scale plot-width (- xmax xmin)))
275         (yscale (charplot:find-scale plot-height (- ymax ymin)))
276         (ix-min (- (charplot:scale-it xmin xscale) charplot:left-margin))
277         (ybot (charplot:scale-it ymin yscale))
278         (iy-min (+ ybot plot-height)))
279    (charplot:init-array pra xlabel ylabel xmin xscale ymin yscale)
280    (for-each (if histogram?
281                  ;;display data bars
282                  (lambda (datum)
283                    (define x (- (charplot:scale-it (car datum) xscale) ix-min))
284                    (do ((y (charplot:scale-it (cadr datum) yscale) (+ -1 y)))
285                        ((< y ybot))
286                      (array-set! pra char:bar (- iy-min y) x)))
287                  ;;display data points
288                  (lambda (datum)
289                    (define x (- (charplot:scale-it (car datum) xscale) ix-min))
290                    (define cdx 0)
291                    (for-each
292                     (lambda (y)
293                       (array-set! pra (string-ref char:curves cdx)
294                                   (- iy-min (charplot:scale-it y yscale)) x)
295                       (set! cdx (modulo (+ 1 cdx) clen)))
296                     (cdr datum))))
297              data)
298    (array-for-each write-char pra)
299    (if (not (eqv? #\newline (apply array-ref pra
300                                    (map (lambda (x) (+ -1 x))
301                                         (array-dimensions pra)))))
302        (newline))))
303
304(define (charplot:plot-function func vlo vhi . npts)
305  (set! npts (if (null? npts) 64 (car npts)))
306  (let ((dats (make-array (A:floR64b) npts 2)))
307    (array-index-map! (make-shared-array dats (lambda (idx) (list idx 0)) npts)
308                      (lambda (idx)
309                        (+ vlo (* (- vhi vlo) (/ idx (+ -1 npts))))))
310    (array-map! (make-shared-array dats (lambda (idx) (list idx 1)) npts)
311                func
312                (make-shared-array dats (lambda (idx) (list idx 0)) npts))
313    (charplot:plot dats "" "")))
314;@
315(define (plot . args)
316  (if (procedure? (car args))
317      (apply charplot:plot-function args)
318      (apply charplot:plot args)))
Note: See TracBrowser for help on using the repository browser.