source: project/release/4/spiffy/trunk/spiffy.scm @ 12534

Last change on this file since 12534 was 12534, checked in by sjamaan, 12 years ago

Implement user switching

File size: 16.3 KB
Line 
1;;
2;; Spiffy the web server
3;;
4; Copyright (c) 2007-2008, Peter Bex
5; Copyright (c) 2000-2005, Felix L. Winkelmann
6; All rights reserved.
7;
8; Redistribution and use in source and binary forms, with or without
9; modification, are permitted provided that the following conditions
10; are met:
11;
12; 1. Redistributions of source code must retain the above copyright
13;    notice, this list of conditions and the following disclaimer.
14; 2. Redistributions in binary form must reproduce the above copyright
15;    notice, this list of conditions and the following disclaimer in the
16;    documentation and/or other materials provided with the distribution.
17; 3. Neither the name of the author nor the names of its
18;    contributors may be used to endorse or promote products derived
19;    from this software without specific prior written permission.
20;
21; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
24; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
25; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
26; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
27; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
28; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
30; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
31; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
32; OF THE POSSIBILITY OF SUCH DAMAGE.
33;
34; Please report bugs, suggestions and ideas to the Chicken Trac
35; ticket tracking system (assign tickets to user 'sjamaan'):
36; http://trac.callcc.org
37
38(module spiffy
39  (start-server with-headers send-status send-static-file log-to
40   write-logged-response
41   current-request remote-address local-address
42   current-response current-file current-pathinfo
43   server-software root-path server-port index-files mime-type-map
44   default-mime-type file-extension-handlers default-host vhost-map
45   access-log error-log debug-log spiffy-user spiffy-group
46   handle-directory handle-not-found handle-exception handle-access-logging
47   restart-request htmlize)
48
49(import chicken scheme extras ports files data-structures)
50(require-extension srfi-1 srfi-18 tcp regex posix
51                   intarweb uri-generic sendfile matchable)
52
53(define version 4)
54(define release 0)
55
56;;; Request processing information
57(define current-request  (make-parameter #f))
58(define current-response (make-parameter #f))
59(define current-file     (make-parameter #f))
60(define current-pathinfo (make-parameter #f))
61(define local-address    (make-parameter #f))
62(define remote-address   (make-parameter #f))
63
64;;; Configuration
65(define server-software  (make-parameter `(("Spiffy"
66                                            ,(conc version "." release)
67                                            ,(conc "Running on Chicken "
68                                                   (chicken-version))))))
69(define root-path        (make-parameter "./web"))
70(define server-port      (make-parameter 8080))
71(define index-files      (make-parameter '("index.html" "index.xhtml")))
72(define mime-type-map
73  (make-parameter
74   '(("xml" . text/xml)
75     ("html" . text/html)
76     ("xhtml" . text/xhtml+xml)
77     ("js"  . text/javascript)
78     ("pdf" . application/pdf)
79     ("css" . text/css)
80     ("png" . image/png)
81     ("ico" . image/x-icon)
82     ("gif" . image/gif)
83     ("jpeg" . image/jpeg)
84     ("jpg" . image/jpeg)
85     ("svg" . image/svg+xml)
86     ("bmp" . image/bmp)
87     ("txt" . text/plain))))
88(define default-mime-type (make-parameter 'application/octet-stream))
89(define file-extension-handlers (make-parameter '()))
90(define default-host (make-parameter "localhost")) ;; XXX Can we do without?
91(define vhost-map (make-parameter `((".*" . ,(lambda (continue) (continue))))))
92(define access-log (make-parameter #f))
93(define error-log (make-parameter (current-error-port)))
94(define debug-log (make-parameter #f))
95(define spiffy-user (make-parameter #f))
96(define spiffy-group (make-parameter #f))
97
98;;; Custom handlers
99(define handle-directory
100  (make-parameter
101   (lambda (path)
102     (send-status 403 "Forbidden"))))
103(define handle-file
104  (make-parameter
105   (lambda (path)
106     (let* ((ext (pathname-extension path))
107            (handler (alist-ref ext (file-extension-handlers)
108                                string-ci=? send-static-file)))
109       (handler path)))))
110(define handle-not-found
111  (make-parameter
112   (lambda (path)
113     (send-status 404 "Not found"
114                  "<p>The resource you requested could not be found</p>"))))
115(define handle-exception
116  (make-parameter
117   (lambda (exn chain)
118     (send-status 500 "Internal server error" (build-error-message exn chain)))))
119
120;; This is very powerful, but it also means people need to write quite
121;; a bit of code to change the line slightly. In this respect Apache-style
122;; log format strings could be better...
123(define handle-access-logging
124  (make-parameter
125   (lambda ()
126     (log-to (access-log)
127             "~A [~A] \"~A ~A HTTP/~A.~A\" ~A"
128             (remote-address)
129             (seconds->string (current-seconds))
130             (request-method (current-request))
131             (uri->string (request-uri (current-request)))
132             (request-major (current-request))
133             (request-minor (current-request))
134             (let ((product (header-contents 'user-agent
135                                             (request-headers (current-request)))))
136               (if product
137                   (product-unparser 'user-agent product)
138                   "**Unknown product**"))))))
139
140;;;; End of configuration parameters
141
142(define (with-output-to-log log thunk)
143  (when log
144    (if (output-port? log)
145        (with-output-to-port log thunk)
146        (with-output-to-file log thunk append:))))
147
148(define (log-to log fmt . rest)
149  (with-output-to-log log
150    (lambda ()
151      (apply printf fmt rest)
152      (newline))))
153
154(define build-error-message
155  (let* ((cpa condition-property-accessor)
156         (exn-message (cpa 'exn 'message "(no message)"))
157         (exn-location (cpa 'exn 'location "(unknown location)"))
158         (exn-arguments (cpa 'exn 'arguments '()))
159         (exn? (condition-predicate 'exn)))
160    (lambda (exn chain)
161      (with-output-to-string
162        (lambda ()
163          (if (exn? exn)
164              (begin
165                (display "<h2>Error:")
166                (and-let* ((loc (exn-location exn)))
167                  (printf " (<em>~A</em>)" (htmlize (->string loc))))
168                (printf "</h2>\n<h3>~A</h3>\n" (htmlize (exn-message exn)))
169                (unless (null? (exn-arguments exn))
170                        (printf "<ul>")
171                        (for-each
172                         (lambda (a)
173                           (##sys#with-print-length-limit 120 (lambda () (printf "<li>~S</li>" (htmlize (->string a))))))
174                         (exn-arguments exn))
175                        (printf "</ul>"))
176                (printf "<pre>~a</pre>" (htmlize chain)))
177              (begin
178                (##sys#with-print-length-limit
179                 120
180                 (lambda ()
181                   (printf "<h2>Uncaught exception:</h2>\n~S" exn))))))))))
182
183(define (extension->mime-type ext)
184  (alist-ref (or ext "") (mime-type-map) string-ci=? (default-mime-type)))
185
186(define (write-logged-response)
187  ((handle-access-logging))
188  (write-response (current-response)))
189
190;; A simple utility procedure to render a status code with message
191(define (send-status code reason #!optional text)
192  (parameterize ((current-response
193                  (update-response (current-response)
194                                   code: code
195                                   reason: reason
196                                   headers:
197                                   (headers
198                                    `((content-type text/html))
199                                    (response-headers (current-response))))))
200    (write-logged-response)
201    (with-output-to-port (response-port (current-response))
202      (lambda ()
203        (print "<?xml version=\"1.0\" encoding=\"iso-8859-1\" ?>")
204        (print "<!DOCTYPE html")
205        (print "  PUBLIC \"-//W3C//DTD XHTML 1.0 Strict//EN\"")
206        (print "         \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd\">")
207        (print "<html xmlns=\"http://www.w3.org/1999/xhtml\" ")
208        (print "      xml:lang=\"en\" lang=\"en\">")
209        (print "  <head>")
210        (printf "    <title>~A - ~A</title>\n" code reason)
211        (print "  </head>")
212        (print "  <body>")
213        (printf "    <h1>~A - ~A</h1>\n" code reason)
214        (if text (display text))
215        (print "  </body>")
216        (print "</html>")))))
217
218(define (send-static-file filename)
219  (let ((path (make-pathname (root-path) filename)))
220    (with-headers `((content-length ,(file-size path))
221                    (content-type ,(extension->mime-type (pathname-extension filename))))
222      (lambda ()
223        (write-logged-response)
224        (let ((fd (file-open path (+ open/binary open/rdonly))))
225          (handle-exceptions exn (begin
226                                   (file-close fd)
227                                   (signal exn))
228                             (sendfile fd (response-port (current-response))))
229          (file-close fd))))))
230
231(define (with-headers new-headers thunk)
232  (parameterize ((current-response
233                  (update-response
234                   (current-response)
235                   headers: (headers new-headers
236                                     (response-headers (current-response))))))
237    (thunk)))
238
239(define (process-directory path)
240  (let ((index-page (find (lambda (ip)
241                            (file-exists?
242                             (make-pathname (list (root-path) path) ip)))
243                          (index-files))))
244    (if index-page
245        (process-entry (make-pathname path index-page) '())
246        ((handle-directory) (make-pathname "/" path)))))
247
248;; If an URL is missing a trailing slash, instead of directly serving
249;; its index-file, redirect to the URL _with_ trailing slash.  This
250;; prevents problems with relative references since the directory
251;; would be seen as the file component in the path and get replaced.
252(define (redirect-directory-root path)
253  (let* ((newloc (make-pathname path "/"))
254         (url (uri-relative-to (uri-reference newloc)
255                               (request-uri (current-request)))))
256    (with-headers `((location ,url))
257      (lambda () (send-status 301 "Moved permanently")))))
258
259(define (process-entry current-path remaining-path)
260  (let ((path (make-pathname (root-path) current-path)))
261    (cond
262     ;; TODO Check if there's a registered URI-handler first
263     ((directory? path)
264      (match remaining-path
265       (()    (redirect-directory-root (make-pathname "/" current-path)))
266       (("/") (process-directory current-path))
267       (else  (process-entry (make-pathname current-path (car remaining-path))
268                             (cdr remaining-path)))))
269     ((file-exists? path)
270      (parameterize ((current-pathinfo remaining-path)
271                     (current-file (make-pathname "/" current-path)))
272        ((handle-file) (current-file)))) ;; hmm, not too useful
273     (else ((handle-not-found) (list "/" current-path))))))
274
275;; Determine the vhost and port to use. This follows RFC 2616, section 5.2:
276;; If request URL is absolute, use that.  Otherwise, look at the Host header.
277;; In HTTP >= 1.1, a Host line is required, as per section 14.23 of
278;; RFC 2616.  If no host line is present, it returns the default host
279;; for HTTP/1.0.
280(define (determine-vhost/port)
281  (let* ((request-uri (request-uri (current-request)))
282         (request-host (uri-host request-uri))
283         (host-header (header-value 'host (request-headers (current-request)))))
284    (if request-host
285        (values request-host (or (uri-port request-uri) 80))
286        (if host-header
287            (values (car host-header) (cdr host-header))
288            (if (and (= (request-major (current-request)) 1)
289                     (>= (request-minor (current-request)) 1))
290                (values #f #f)
291                (values (default-host) 80))))))
292
293(define (normalize-current-request-uri)
294  (receive (host port) (determine-vhost/port)
295    (if host
296        (update-request (current-request)
297                        uri: (uri-relative-to
298                              (request-uri (current-request))
299                              ;; XXX
300                              (absolute-uri (conc "http://" host ":" port))))
301        (current-request))))
302
303(define request-restarter (make-parameter #f)) ; Internal parameter
304
305(define (restart-request req)
306  ((request-restarter) req (request-restarter)))
307
308(define (handle-incoming-request in out)
309  (receive (local remote)
310    (tcp-addresses in)
311    (parameterize ((remote-address remote)
312                   (local-address local)
313                   (current-request (read-request in))
314                   (current-response
315                    (make-response port: out
316                                   headers: (headers
317                                             `((content-type text/html)
318                                               (server ,(server-software)))))))
319      (let ((path (uri-path (request-uri (current-request)))))
320        (receive (req cont)
321          (call/cc (lambda (c) (values (normalize-current-request-uri) c)))
322          (parameterize ((current-request req)
323                         (request-restarter cont))
324            (handle-exceptions exn ((handle-exception) exn
325                                    (with-output-to-string print-call-chain))
326                               (if (and (uri-host (request-uri (current-request))) (pair? path))
327                                   (let* ((host (uri-host (request-uri (current-request))))
328                                          (handler (alist-ref host
329                                                              (vhost-map)
330                                                              (lambda (h _)
331                                                                (if (not (regexp? h))
332                                                                    (string-match (regexp h #t) host)
333                                                                    (string-match h host))))))
334                                     (if handler
335                                         (handler (lambda () (process-entry "" path)))
336                                         ;; Is this ok?
337                                         (send-status 404 "Not found" "<p>Host not found</p>")))
338                                   ;; No host in the request? That's an error.
339                                   (send-status 400 "Bad request"
340                                                "<p>Your client sent a request that the server did not understand</p>")))))
341        ;; For now, just close the ports and allow the thread to exit
342        (close-output-port out)
343        (close-input-port in)))))
344
345(define (htmlize str)
346  (string-translate* str '(("<" . "&lt;")    (">" . "&gt;")
347                           ("\"" . "&quot;") ("&" . "&amp;"))))
348
349;; Do we want this here?
350(unless (eq? (build-platform) 'msvc)
351  (set-signal-handler! signal/int (lambda (sig) (exit 1))))
352
353(define (switch-user/group user group)
354  (when group    ; group first, since only superuser can switch groups
355    (let ((ginfo (group-information group)))
356      (unless ginfo
357        (error "Group does not exist" group))
358      (set! (current-group-id) (list-ref ginfo 2))))
359  (when user
360    (let ((uinfo (user-information user)))
361      (unless uinfo
362        (error "User does not exist" user))
363      (setenv "HOME" (list-ref uinfo 5))
364      (initialize-groups user (list-ref uinfo 3))
365      (unless group ; Already changed to target group?
366        (set! (current-group-id) (list-ref uinfo 3)))
367      (set! (current-user-id) (list-ref uinfo 2)))))
368
369(define (start-server #!key (port (server-port)))
370  (parameterize ((load-verbose #f))
371    (letrec ((listener (tcp-listen port))
372             (init (lambda ()
373                     (switch-user/group (spiffy-user) (spiffy-group))))
374             (accept-loop (lambda ()
375                            (receive (in out)
376                              (tcp-accept listener)
377                              (thread-start!
378                               (make-thread (lambda ()
379                                              (handle-incoming-request in out))))
380                              (accept-loop)))))
381      (init)
382      (accept-loop))))
383
384)
Note: See TracBrowser for help on using the repository browser.