source: project/release/4/spiffy/trunk/spiffy.scm @ 12527

Last change on this file since 12527 was 12527, checked in by sjamaan, 12 years ago

Add logging support

File size: 15.1 KB
Line 
1;;
2;; Spiffy the web server
3;;
4; Copyright (c) 2007-2008, Peter Bex
5; Copyright (c) 2000-2005, Felix L. Winkelmann
6; All rights reserved.
7;
8; Redistribution and use in source and binary forms, with or without
9; modification, are permitted provided that the following conditions
10; are met:
11;
12; 1. Redistributions of source code must retain the above copyright
13;    notice, this list of conditions and the following disclaimer.
14; 2. Redistributions in binary form must reproduce the above copyright
15;    notice, this list of conditions and the following disclaimer in the
16;    documentation and/or other materials provided with the distribution.
17; 3. Neither the name of the author nor the names of its
18;    contributors may be used to endorse or promote products derived
19;    from this software without specific prior written permission.
20;
21; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
24; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
25; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
26; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
27; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
28; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
30; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
31; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
32; OF THE POSSIBILITY OF SUCH DAMAGE.
33;
34; Please report bugs, suggestions and ideas to the Chicken Trac
35; ticket tracking system (assign tickets to user 'sjamaan'):
36; http://trac.callcc.org
37
38(module spiffy
39  (start-server with-headers send-status send-static-file log-to
40   write-logged-response
41   current-request remote-address local-address
42   current-response current-file current-pathinfo
43   server-software root-path server-port index-files mime-type-map
44   default-mime-type file-extension-handlers default-host vhost-map
45   access-log error-log debug-log
46   handle-directory handle-not-found handle-exception handle-access-logging
47   restart-request htmlize)
48
49(import chicken scheme extras ports files data-structures)
50(require-extension srfi-1 srfi-18 posix tcp regex
51                   intarweb uri-generic sendfile matchable)
52
53(define version 4)
54(define release 0)
55
56;;; Request processing information
57(define current-request  (make-parameter #f))
58(define current-response (make-parameter #f))
59(define current-file     (make-parameter #f))
60(define current-pathinfo (make-parameter #f))
61(define local-address    (make-parameter #f))
62(define remote-address   (make-parameter #f))
63
64;;; Configuration
65(define server-software  (make-parameter (conc "Spiffy/" version "." release)))
66(define root-path        (make-parameter "./web"))
67(define server-port      (make-parameter 8080))
68(define index-files      (make-parameter '("index.html" "index.xhtml")))
69(define mime-type-map
70  (make-parameter
71   '(("xml" . text/xml)
72     ("html" . text/html)
73     ("xhtml" . text/xhtml+xml)
74     ("js"  . text/javascript)
75     ("pdf" . application/pdf)
76     ("css" . text/css)
77     ("png" . image/png)
78     ("ico" . image/x-icon)
79     ("gif" . image/gif)
80     ("jpeg" . image/jpeg)
81     ("jpg" . image/jpeg)
82     ("svg" . image/svg+xml)
83     ("bmp" . image/bmp)
84     ("txt" . text/plain))))
85(define default-mime-type (make-parameter 'application/octet-stream))
86(define file-extension-handlers (make-parameter '()))
87(define default-host (make-parameter "localhost")) ;; XXX Can we do without?
88(define vhost-map (make-parameter `((".*" . ,(lambda (continue) (continue))))))
89(define access-log (make-parameter #f))
90(define error-log (make-parameter (current-error-port)))
91(define debug-log (make-parameter #f))
92
93;;; Custom handlers
94(define handle-directory
95  (make-parameter
96   (lambda (path)
97     (send-status 403 "Forbidden"))))
98(define handle-file
99  (make-parameter
100   (lambda (path)
101     (let* ((ext (pathname-extension path))
102            (handler (alist-ref ext (file-extension-handlers)
103                                string-ci=? send-static-file)))
104       (handler path)))))
105(define handle-not-found
106  (make-parameter
107   (lambda (path)
108     (send-status 404 "Not found"
109                  "<p>The resource you requested could not be found</p>"))))
110(define handle-exception
111  (make-parameter
112   (lambda (exn chain)
113     (send-status 500 "Internal server error" (build-error-message exn chain)))))
114
115;; This is very powerful, but it also means people need to write quite
116;; a bit of code to change the line slightly. In this respect Apache-style
117;; log format strings could be better...
118(define handle-access-logging
119  (make-parameter
120   (lambda ()
121     (log-to (access-log)
122             "~A [~A] \"~A ~A HTTP/~A.~A\" ~A"
123             (remote-address)
124             (seconds->string (current-seconds))
125             (request-method (current-request))
126             (uri->string (request-uri (current-request)))
127             (request-major (current-request))
128             (request-minor (current-request))
129             (let ((product (header-contents 'user-agent
130                                             (request-headers (current-request)))))
131               (if product
132                   (product-unparser 'user-agent product)
133                   "**Unknown product**"))))))
134
135;;;; End of configuration parameters
136
137(define (with-output-to-log log thunk)
138  (when log
139    (if (output-port? log)
140        (with-output-to-port log thunk)
141        (with-output-to-file log thunk append:))))
142
143(define (log-to log fmt . rest)
144  (with-output-to-log log
145    (lambda ()
146      (apply printf fmt rest)
147      (newline))))
148
149(define build-error-message
150  (let* ((cpa condition-property-accessor)
151         (exn-message (cpa 'exn 'message "(no message)"))
152         (exn-location (cpa 'exn 'location "(unknown location)"))
153         (exn-arguments (cpa 'exn 'arguments '()))
154         (exn? (condition-predicate 'exn)))
155    (lambda (exn chain)
156      (with-output-to-string
157        (lambda ()
158          (if (exn? exn)
159              (begin
160                (display "<h2>Error:")
161                (and-let* ((loc (exn-location exn)))
162                  (printf " (<em>~A</em>)" (htmlize (->string loc))))
163                (printf "</h2>\n<h3>~A</h3>\n" (htmlize (exn-message exn)))
164                (unless (null? (exn-arguments exn))
165                        (printf "<ul>")
166                        (for-each
167                         (lambda (a)
168                           (##sys#with-print-length-limit 120 (lambda () (printf "<li>~S</li>" (htmlize (->string a))))))
169                         (exn-arguments exn))
170                        (printf "</ul>"))
171                (printf "<pre>~a</pre>" (htmlize chain)))
172              (begin
173                (##sys#with-print-length-limit
174                 120
175                 (lambda ()
176                   (printf "<h2>Uncaught exception:</h2>\n~S" exn))))))))))
177
178(define (extension->mime-type ext)
179  (alist-ref (or ext "") (mime-type-map) string-ci=? (default-mime-type)))
180
181(define (write-logged-response)
182  ((handle-access-logging))
183  (write-response (current-response)))
184
185;; A simple utility procedure to render a status code with message
186(define (send-status code reason #!optional text)
187  (parameterize ((current-response
188                  (update-response (current-response)
189                                   code: code
190                                   reason: reason
191                                   headers:
192                                   (headers
193                                    `((content-type text/html))
194                                    (response-headers (current-response))))))
195    (write-logged-response)
196    (with-output-to-port (response-port (current-response))
197      (lambda ()
198        (print "<?xml version=\"1.0\" encoding=\"iso-8859-1\" ?>")
199        (print "<!DOCTYPE html")
200        (print "  PUBLIC \"-//W3C//DTD XHTML 1.0 Strict//EN\"")
201        (print "         \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd\">")
202        (print "<html xmlns=\"http://www.w3.org/1999/xhtml\" ")
203        (print "      xml:lang=\"en\" lang=\"en\">")
204        (print "  <head>")
205        (printf "    <title>~A - ~A</title>\n" code reason)
206        (print "  </head>")
207        (print "  <body>")
208        (printf "    <h1>~A - ~A</h1>\n" code reason)
209        (if text (display text))
210        (print "  </body>")
211        (print "</html>")))))
212
213(define (send-static-file filename)
214  (let ((path (make-pathname (root-path) filename)))
215    (with-headers `((content-length ,(file-size path))
216                    (content-type ,(extension->mime-type (pathname-extension filename))))
217      (lambda ()
218        (write-logged-response)
219        (let ((fd (file-open path (+ open/binary open/rdonly))))
220          (handle-exceptions exn (begin
221                                   (file-close fd)
222                                   (signal exn))
223                             (sendfile fd (response-port (current-response))))
224          (file-close fd))))))
225
226(define (with-headers new-headers thunk)
227  (parameterize ((current-response
228                  (update-response
229                   (current-response)
230                   headers: (headers new-headers
231                                     (response-headers (current-response))))))
232    (thunk)))
233
234(define (process-directory path)
235  (let ((index-page (find (lambda (ip)
236                            (file-exists?
237                             (make-pathname (list (root-path) path) ip)))
238                          (index-files))))
239    (if index-page
240        (process-entry (make-pathname path index-page) '())
241        ((handle-directory) (make-pathname "/" path)))))
242
243;; If an URL is missing a trailing slash, instead of directly serving
244;; its index-file, redirect to the URL _with_ trailing slash.  This
245;; prevents problems with relative references since the directory
246;; would be seen as the file component in the path and get replaced.
247(define (redirect-directory-root path)
248  (let* ((newloc (make-pathname path "/"))
249         (url (uri-relative-to (uri-reference newloc)
250                               (request-uri (current-request)))))
251    (with-headers `((location ,url))
252      (lambda () (send-status 301 "Moved permanently")))))
253
254(define (process-entry current-path remaining-path)
255  (let ((path (make-pathname (root-path) current-path)))
256    (cond
257     ;; TODO Check if there's a registered URI-handler first
258     ((directory? path)
259      (match remaining-path
260       (()    (redirect-directory-root (make-pathname "/" current-path)))
261       (("/") (process-directory current-path))
262       (else  (process-entry (make-pathname current-path (car remaining-path))
263                             (cdr remaining-path)))))
264     ((file-exists? path)
265      (parameterize ((current-pathinfo remaining-path)
266                     (current-file (make-pathname "/" current-path)))
267        ((handle-file) (current-file)))) ;; hmm, not too useful
268     (else ((handle-not-found) (list "/" current-path))))))
269
270;; Determine the vhost and port to use. This follows RFC 2616, section 5.2:
271;; If request URL is absolute, use that.  Otherwise, look at the Host header.
272;; In HTTP >= 1.1, a Host line is required, as per section 14.23 of
273;; RFC 2616.  If no host line is present, it returns the default host
274;; for HTTP/1.0.
275(define (determine-vhost/port)
276  (let* ((request-uri (request-uri (current-request)))
277         (request-host (uri-host request-uri))
278         (host-header (header-value 'host (request-headers (current-request)))))
279    (if request-host
280        (values request-host (or (uri-port request-uri) 80))
281        (if host-header
282            (values (car host-header) (cdr host-header))
283            (if (and (= (request-major (current-request)) 1)
284                     (>= (request-minor (current-request)) 1))
285                (values #f #f)
286                (values (default-host) 80))))))
287
288(define (normalize-current-request-uri)
289  (receive (host port) (determine-vhost/port)
290    (if host
291        (update-request (current-request)
292                        uri: (uri-relative-to
293                              (request-uri (current-request))
294                              ;; XXX
295                              (absolute-uri (conc "http://" host ":" port))))
296        (current-request))))
297
298(define request-restarter (make-parameter #f)) ; Internal parameter
299
300(define (restart-request req)
301  ((request-restarter) req (request-restarter)))
302
303(define (handle-incoming-request in out)
304  (receive (local remote)
305    (tcp-addresses in)
306    (parameterize ((remote-address remote)
307                   (local-address local)
308                   (current-request (read-request in))
309                   (current-response
310                    (make-response port: out
311                                   headers: (headers
312                                             `((content-type text/html))))))
313      (let ((path (uri-path (request-uri (current-request)))))
314        (receive (req cont)
315          (call/cc (lambda (c) (values (normalize-current-request-uri) c)))
316          (parameterize ((current-request req)
317                         (request-restarter cont))
318            (handle-exceptions exn ((handle-exception) exn
319                                    (with-output-to-string print-call-chain))
320                               (if (and (uri-host (request-uri (current-request))) (pair? path))
321                                   (let* ((host (uri-host (request-uri (current-request))))
322                                          (handler (alist-ref host
323                                                              (vhost-map)
324                                                              (lambda (h _)
325                                                                (if (not (regexp? h))
326                                                                    (string-match (regexp h #t) host)
327                                                                    (string-match h host))))))
328                                     (if handler
329                                         (handler (lambda () (process-entry "" path)))
330                                         ;; Is this ok?
331                                         (send-status 404 "Not found" "<p>Host not found</p>")))
332                                   ;; No host in the request? That's an error.
333                                   (send-status 400 "Bad request"
334                                                "<p>Your client sent a request that the server did not understand</p>")))))
335        ;; For now, just close the ports and allow the thread to exit
336        (close-output-port out)
337        (close-input-port in)))))
338
339(define (htmlize str)
340  (string-translate* str '(("<" . "&lt;")    (">" . "&gt;")
341                           ("\"" . "&quot;") ("&" . "&amp;"))))
342
343(define (start-server #!key (port (server-port)))
344  (parameterize ((load-verbose #f))
345   (letrec ((listener (tcp-listen port))
346            (accept-loop (lambda ()
347                           (receive (in out)
348                             (tcp-accept listener)
349                             (thread-start!
350                              (make-thread (lambda ()
351                                             (handle-incoming-request in out))))
352                             (accept-loop)))))
353     (accept-loop))))
354
355)
Note: See TracBrowser for help on using the repository browser.