source: project/release/4/intarweb/trunk/tests/run.scm @ 12502

Last change on this file since 12502 was 12502, checked in by sjamaan, 11 years ago

Final (hopefully) finetuning of product-unparser

File size: 27.3 KB
Line 
1(require-extension test extras regex uri-generic intarweb)
2
3(define-syntax test-error*
4  (syntax-rules ()
5    ((_ ?msg (?error-type ...) ?expr)
6     (let-syntax ((expression:
7                   (syntax-rules ()
8                     ((_ ?expr)
9                      (condition-case (begin ?expr "<no error thrown>")
10                                      ((?error-type ...) '(?error-type ...))
11                                      (exn () (##sys#slot exn 1)))))))
12       (test ?msg '(?error-type ...) (expression: ?expr))))
13    ((_ ?msg ?error-type ?expr)
14     (test-error* ?msg (?error-type) ?expr))
15    ((_ ?error-type ?expr)
16     (test-error* (sprintf "~S" '?expr) ?error-type ?expr))))
17
18(define (test-read-headers str)
19  (call-with-input-string str
20    (lambda (in)
21      (read-headers in))))
22
23(test-group "Headers"
24  (test-group "Single headers"
25   (parameterize ((single-headers '(foo qux))
26                  (header-parsers `((foo . ,(single identity))
27                                    (qux . ,(single identity)))))
28     (let ((headers (test-read-headers "foo: bar\r\nqux:\t   \tmooh\t   \r\n\r\n")))
29       (test "Basic test"
30             '("bar") (header-values 'foo headers))
31       ;; RFC 2616 4.2
32       (test "Extra spaces are ignored"
33             '("mooh") (header-values 'qux headers)))
34     (let ((headers (test-read-headers "foo: bar\r\n qux: mooh\r\nquux: mumble\r\n\r\n")))
35       ;; RFC 2616 2.2
36       (test "Continuation chars"
37             '("bar qux: mooh") (header-values 'foo headers)))
38     ;; Not in RFC but common behaviour - also, robustness principle
39     (let ((headers (test-read-headers "foo: bar\r\nfoo: qux\r\n")))
40       (test "Multiple headers for singular header types discarded"
41             '("qux") (header-values 'foo headers)))))
42  ;; All this RFC 2616 4.2
43  (test-group "Multi-headers"
44   (parameterize ((header-parsers `((foo . ,(multiple identity)))))
45     (let ((headers (test-read-headers "foo: bar\r\nfoo: qux\r\nquux: mumble\r\n\r\n")))
46       (test "Multiple headers"
47             '("bar" "qux") (header-values 'foo headers)))
48     (let ((headers (test-read-headers "Foo: bar\r\nFoO: qux\r\nquux: mumble\r\n\r\n")))
49       (test "Multiple headers: case insensitivity"
50             '("bar" "qux") (header-values 'foo headers)))
51     (let ((headers (test-read-headers "foo: bar, qux\r\nquux: mumble\r\n\r\n")))
52       (test "Comma-separated headers"
53             '("bar" "qux") (header-values 'foo headers)))
54     (let ((headers (test-read-headers "foo: \"ba\\\"r, qux\"\r\nfoo: mooh\r\n\r\n")))
55       (test "Quoted headers"
56             '("ba\"r, qux" "mooh") (header-values 'foo headers))))
57   ;; RFC 2616 4.5
58   ;; "Unrecognized header fields are treated as entity-header fields."
59   ;;
60   ;; RFC 2616 7.1
61   ;; "Unrecognized header fields SHOULD be ignored by the recipient and MUST be
62   ;;  forwarded by transparent proxies."
63   (let ((headers (test-read-headers "unknown: foo, bar\r\nunknown: blah\r\n\r\n")))
64     (test "Unknown headers are not parsed and put into lists"
65           '("foo, bar" "blah") (header-values 'unknown headers))))
66  (test-group "Miscellaneous"
67    (parameterize ((header-parsers `((foo . ,(multiple identity)))))
68      (test-error "Missing header contents" (test-read-headers "foo\r\n\r\n"))
69      ;; RFC 2616 2.2
70      ;; "The backslash character ("\") MAY be used as a single-character
71      ;; quoting mechanism only within quoted-string and comment constructs."
72      ;;     quoted-pair = "\" CHAR
73      ;; CHAR implies any char, *including* CR/LF. This is clarified by RFC 822,
74      ;; on which RFC 2616 is based.
75      ;; Apparently, even \CRLF is allowed (as opposed to \CR\LF)
76      (test "Embedded newlines"
77            '("bar\r\nqux")
78            ;; XXX Should we interpret "\\\r\n" as "\r\n", too?
79            (header-values 'foo (test-read-headers "Foo: \"bar\\\r\\\nqux\""))))))
80
81(test-group "Specialized header parsers"
82  (test-group "Host"
83    (test "Hostname and port"
84          '(("foo.example.com" . 8080))
85          (header-values 'host (test-read-headers "Host: foo.example.com:8080")))
86    (test "Hostname, no port"
87          '(("foo.example.com" . 80))
88          (header-values 'host (test-read-headers "Host: foo.example.com"))))
89  (test-group "Quality parameter"
90   (let* ((headers (test-read-headers "Accept: text/plain; Q=0.5, text/html, text/plain; q=0.123456, application/pdf; q=1.2345, text/xml; q=-0.234, text/whatever; q="))
91          (accept  (header-contents 'accept headers)))
92     ;; RFC 2616 3.6: "All transfer-coding values are case insensitive".
93     ;; This includes the parameter name (attribute) and value.
94     (test "Explicit quality value (case-insensitive)"
95           0.5 (get-quality (first accept)))
96     (test "Explicit quality encoding value"
97           'text/plain (get-value (first accept)))
98     ;; RFC 2616 3.9
99     (test "Implicit quality value"
100           1.0 (get-quality (second accept)))
101     (test "Implicit quality encoding value"
102           'text/html (get-value (second accept)))
103     (test "Quality values have only three digits"
104           0.123 (get-quality (third accept)))
105     (test "Quality values maximum is 1.0"
106           1.0 (get-quality (fourth accept)))
107     (test "Quality values minimum is 0.0"
108           0.0 (get-quality (fifth accept)))
109     (test "Missing quality value ok"
110           1.0 (get-quality (sixth accept)))))
111
112  (test-group "Symbol-parser-ci"
113    (let* ((headers (test-read-headers "Accept-Ranges: FoO")))
114      (test "Case-insensitive"
115            '(foo) (header-values 'accept-ranges headers))))
116 
117  (test-group "Symbol-parser"
118    (let* ((headers (test-read-headers "Allow: FoO, foo")))
119      (test "Case-sensitive"
120            '(FoO foo) (header-values 'allow headers))))
121
122  (test-group "Natnum-parser"
123    (parameterize ((single-headers '(foo bar qux mooh))
124                   (header-parsers `((foo . ,(single natnum-parser))
125                                     (bar . ,(single natnum-parser))
126                                     (qux . ,(single natnum-parser))
127                                     (mooh . ,(single natnum-parser)))))
128     (let ((headers (test-read-headers "Foo: 10\r\nBar: abc\r\nQux: -10\r\nMooh: 1.6")))
129       (test "Simple test"
130             10 (header-value 'foo headers))
131       (test "No number defaults to 0"
132             0 (header-value 'bar headers))
133       (test "No negative numbers"
134             0 (header-value 'qux headers))
135       ;; This is a "feature" in the interest of the robustness principle
136       (test "Rounding of real numbers"
137             2 (header-value 'mooh headers)))))
138
139  (test-group "Cache-control-parser"
140    (let ((headers (test-read-headers "Cache-control: max-age=10, private")))
141      (test "max-age is a number"
142            '(max-age . 10) (get-value (header-list-ref 'max-age (header-contents 'cache-control headers))))
143      (test "private without value"
144            '(private . #t) (get-value (header-list-ref 'private (header-contents 'cache-control headers)))))
145    (let ((headers (test-read-headers "Cache-control: private=\"accept-encoding, accept-ranges\"\r\nCache-control: must-revalidate")))
146      (test "private with values"
147            '(private . (accept-encoding accept-ranges))
148            (get-value (header-list-ref 'private (header-contents 'cache-control headers))))
149      (test "Acts like a multi-header"
150            '(must-revalidate . #t) (get-value (header-list-ref 'must-revalidate (header-contents 'cache-control headers))))))
151
152  ;; RFC 2616, 14.15
153  ;; Also: RFC 1864 (Base64) and RF1321 (MD5)
154  ;; XXX TODO: See if binary strings are useful with the MD5 egg, otherwise
155  ;; we need an additional decoding step
156  (test-group "md5-parser"
157    (let ((headers (test-read-headers "Content-md5: Q2hlY2sgSW50ZWdyaXR5IQ==")))
158      (test "md5 is base64-decoded"
159            "Check Integrity!"
160            (header-value 'content-md5 headers))))
161
162  (test-group "Range-parser"
163    (let ((headers (test-read-headers "content-range: bytes 500-999/1234")))
164      (test "Simple range"
165            '(500 999 1234)
166            (header-value 'content-range headers))))
167
168  ;; XXX SRFI-19!
169  (test-group "http-time-parser"
170    (let ((headers (test-read-headers "Date: Sun, 06 Nov 1994 08:49:37 GMT")))
171      (test "RFC822/RFC1123 time"
172            0
173            (header-value 'date headers)))
174    (let ((headers (test-read-headers "Date: Sunday, 06-Nov-94 08:49:37 GMT")))
175      (test "RFC850 time"
176            0
177            (header-value 'date headers)))
178    (let ((headers (test-read-headers "Date: Sun Nov  6 08:49:37 1994")))
179      (test "asctime time"
180            0
181            (header-value 'date headers))))
182
183  (test-group "entity-tag-parser"
184    (let ((headers (test-read-headers "Etag: \"foo\"")))
185      (test "Strong tag"
186            '(strong . "foo")
187            (header-value 'etag headers)))
188    (let ((headers (test-read-headers "Etag: W/\"bar\"")))
189      (test "Weak tag"
190            '(weak . "bar")
191            (header-value 'etag headers)))
192    (let ((headers (test-read-headers "Etag: \"\"")))
193      (test "Empty tag"
194            '(strong . "")
195            (header-value 'etag headers)))
196    (let ((headers (test-read-headers "Etag: \"W/bar\"")))
197        (test "Strong tag, containing W/ prefix"
198              '(strong . "W/bar")
199              (header-value 'etag headers))))
200
201  (test-group "Product parser"
202    (test "Simple product"
203          '(("Mozilla" "5.0" #f))
204          (header-value 'user-agent (test-read-headers "User-Agent: Mozilla/5.0\r\n")))
205    (test "Product with comment"
206          '(("Mozilla" #f "foo"))
207          (header-value 'user-agent (test-read-headers "User-Agent: Mozilla (foo)\r\n")))   
208    (test "Realistic product (comments, semicolons)"
209          '(("Mozilla" "5.0" "X11; U; NetBSD amd64; en-US; rv:1.9.0.3") ("Gecko" "2008110501" #f) ("Minefield" "3.0.3" #f))
210          (header-value 'user-agent (test-read-headers "User-Agent: Mozilla/5.0 (X11; U; NetBSD amd64; en-US; rv:1.9.0.3) Gecko/2008110501 Minefield/3.0.3\r\n"))))
211
212  (test-group "Set-Cookie-parser"
213    (let* ((headers (test-read-headers "Set-Cookie: foo=\"bar\"")))
214      (test "Simple name/value pair"
215            '("foo" . "bar")
216            (get-value (first (header-contents 'set-cookie headers)))))
217    (let ((headers (test-read-headers "Set-Cookie: foo=bar=qux; max-age=10")))
218      (test "Cookie with = signs"
219            '("foo" . "bar=qux")
220            (get-value (first (header-contents 'set-cookie headers)))))
221    (let* ((headers (test-read-headers "Set-Cookie: foo=bar; Comment=\"Hi, there!\", qux=mooh\r\nSet-Cookie: mumble=mutter")))
222      (test "Comment"
223            "Hi, there!"
224            (get-param 'comment
225                       (first (header-contents 'set-cookie headers))))
226      (test "Multiple cookies in one header"
227            '("qux" . "mooh")
228            (get-value (second (header-contents 'set-cookie headers))))
229      (test "Multiple cookies in multiple headers"
230            '("mumble" . "mutter")
231            (get-value (third (header-contents 'set-cookie headers))))
232      (test "Missing \"secure\" value"
233            #f
234            (get-param 'secure
235                       (third (header-contents 'set-cookie headers)))))
236    (let* ((headers (test-read-headers "Set-Cookie: foo=; expires=Sunday, 20-Jul-08 15:23:42 GMT; secure; path = / ")))
237      (test "Missing value"
238            '("foo" . "")
239            (get-value (first (header-contents 'set-cookie headers))))
240      (test "Old-style cookie expires value"
241            ;; Should use something like
242            ;; (string->date foo "~A, ~d-~b-~y ~H:~M:~S ~z") in an "en" locale
243            0
244            (get-param 'expires
245                       (first (header-contents 'set-cookie headers))))
246      (test "Secure value"
247            #t
248            (get-param 'secure
249                       (first (header-contents 'set-cookie headers))))
250      (test "Path"
251            "/"
252            (get-param 'path
253                       (first (header-contents 'set-cookie headers))))))
254 
255  (test-group "Cookie-parser"
256    (let* ((headers (test-read-headers "Cookie: foo=bar; $Path=/; qux=mooh; $unknown=something")))
257      (test "Multiple cookies in the same header"
258            '(("foo" . "bar") . ("qux" . "mooh"))
259            (cons
260             (get-value (first  (header-contents 'cookie headers)))
261             (get-value (second (header-contents 'cookie headers)))))
262      (test "Parameters of cookies (spaces stripped)"
263            "/"
264            (get-param '$path (first (header-contents 'cookie headers))))
265      (test "Parameters of cookies"
266            "something"
267            (get-param '$unknown (second (header-contents 'cookie headers)))))
268    (let* ((headers (test-read-headers "Cookie: $Version=\"1\"; foo=bar; $Path=/; qux=mooh; $unknown=something")))
269      (test "Version string is used for all cookies"
270            (cons 1 1)
271            (cons
272             (get-param '$version (first (header-contents 'cookie headers)))
273             (get-param '$version (second (header-contents 'cookie headers))))))))
274
275(test-group "Headers"
276  (test "Simple test"
277        `(bar qux)
278        (header-values 'foo (headers `((foo bar qux)))))
279  (test "Multi headers are folded"
280        `(bar qux)
281        (header-values 'foo (headers `((foo bar)
282                                       (foo qux)))))
283  (test "Single headers are unique"
284        `(qux)
285        (header-values 'foo (parameterize ((single-headers '(foo)))
286                                    (headers `((foo bar)
287                                               (foo qux))))))
288  (test "Extra single headers are ignored"
289        `(qux)
290        (header-values 'foo (parameterize ((single-headers '(foo)))
291                                    (headers `((foo bar qux))))))
292  (test "Parameters"
293        `((bar . qux))
294        (get-params
295         (car (header-contents 'foo (headers `((foo #(mooh ((bar . qux))))))))))
296  (test "Multi headers are folded into old headers"
297        `(bar qux)
298        (header-values 'foo (headers `((foo qux))
299                                     (headers `((foo bar)))))))
300
301(define (test-unparse-headers h)
302  (call-with-output-string
303   (lambda (o)
304     (unparse-headers (headers h) o))))
305
306(test-group "Unparsers"
307  (test-group "Default unparser"
308    (test "String"
309          "Foo: bar\r\n"
310          (test-unparse-headers `((foo "bar"))))
311    (test "Multiple strings"
312          "Foo: bar, qux\r\n"
313          (test-unparse-headers `((foo "bar" "qux"))))
314    (test "Auto-quoting on commas and whitespace"
315          "Foo: \"bar, qux\", \"mooh blah\"\r\n"
316          (test-unparse-headers `((foo "bar, qux" "mooh blah"))))
317    ;; RFC 2616 2.2
318    (test "Escaping quotes"
319          "Foo: \"bar \\\" qux\", mooh\r\n"
320          (test-unparse-headers `((foo "bar \" qux" "mooh"))))
321    (test "Escaping control characters"
322          "Foo: \"bar\\\r\\\x01qux\"\r\n"
323          (test-unparse-headers `((foo "bar\r\x01qux"))))
324    ;; Unfortunately, there are no or very few HTTP implementations
325    ;; which understand that newlines can be escaped with a backslash
326    ;; in a quoted string. That's why we don't allow it.
327    ;; The user is expected to escape the newlines according to the type
328    ;; of header (URLencoding, removing the newlines from cookies, etc)
329    (test-error* "Embedded newlines throw an error"
330                 (http unencoded-header)
331                 (test-unparse-headers `((foo "bar\n\x01qux"))))
332    (test "Alist"
333          "Foo: bar=qux, mooh=mumble\r\n"
334          (test-unparse-headers `((foo (bar . qux) (mooh . mumble)))))
335    (test "Alist with escapes"
336          "Foo: bar=qux, mooh=\"mum, ble\"\r\n"
337          (test-unparse-headers `((foo (bar . "qux") (mooh . "mum, ble")))))
338    (test "URI"
339          "Foo: http://foo.com/bar\r\n"
340          (test-unparse-headers `((foo ,(uri-reference "http://foo.com/bar")))))
341    (test "Parameters"
342          "Foo: bar; qux=mooh; mumble=mutter; blah\r\n"
343          (test-unparse-headers `((foo #(bar ((qux . mooh)
344                                              (mumble . mutter)
345                                              (blah . #t)
346                                              (feh . #f))))))))
347  (test-group "Entity-tag unparser"
348    (test "Weak tag"
349          "Etag: W/blah\r\n"
350          (test-unparse-headers `((etag (weak . "blah")))))
351    (test "Strong tag"
352          "Etag: blah\r\n"
353          (test-unparse-headers `((etag (strong . "blah")))))
354    (test "Strong tag starting with W/"
355          "Etag: \"W/blah\"\r\n"
356          (test-unparse-headers `((etag (strong . "W/blah"))))))
357  (test-group "Host unparser"
358    (test "Default port is 80, left out"
359          "Host: foo.example.com\r\n"
360          (test-unparse-headers `((host ("foo.example.com" . 80)))))
361    (test "Different port"
362          "Host: foo.example.com:8080\r\n"
363          (test-unparse-headers `((host ("foo.example.com" . 8080))))))
364  (test-group "Product unparser"
365    (test "Product with comments"
366          "User-Agent: Mozilla (X11) Gecko/2008110501\r\n"
367          (test-unparse-headers `((user-agent (("Mozilla" #f "X11") ("Gecko" "2008110501" #f))))))
368    (test "Realistic product"
369          "User-Agent: Mozilla/5.0 (X11; U; NetBSD amd64; en-US; rv:1.9.0.3) Gecko/2008110501 Minefield/3.0.3\r\n"
370          (test-unparse-headers `((user-agent (("Mozilla" "5.0" "X11; U; NetBSD amd64; en-US; rv:1.9.0.3") ("Gecko" "2008110501" #f) ("Minefield" "3.0.3" #f))))))))
371
372(define (test-read-request str)
373  (call-with-input-string str
374    (lambda (in)
375      (read-request in))))
376
377(test-group "Read-request"
378  (parameterize ((request-parsers `(,(lambda (line in)
379                                       (and (string=? line "foo") 'foo))
380                                    ,(lambda (line in)
381                                       (and (string=? line "bar") 'bar)))))
382    (test-error* (http unknown-protocol-line) (test-read-request "qux"))
383    (test-error* (http unknown-protocol-line) (test-read-request ""))
384    (test 'foo (test-read-request "foo"))
385    (test 'bar (test-read-request "bar")))
386  (test-group "HTTP/0.9"
387    (let ((req (test-read-request "GET /path/to/stuff?arg1=val1&arg2=val2\r\n")))
388      (test 0 (request-major req))
389      (test 9 (request-minor req))
390      (test 'GET (request-method req))
391      (test (uri-reference "/path/to/stuff?arg1=val1&arg2=val2") (request-uri req))
392      (test (headers '()) (request-headers req)))
393    ; RFC 1945 5.0 does not mention case-sensitivity for the method in HTTP/0.9.
394    ; It only mentions it in the context of HTTP/1.x (section 5.1.1).
395    ; We obey the BNF syntax rule in 2.1:
396    ;     "literal" - Quotation marks surround literal text.
397    ;                 Unless stated otherwise, the text is case-insensitive.
398    ; Section 4.1 defines:
399    ;     Simple-Request  = "GET" SP Request-URI CRLF
400    (test "Method is case-insensitive" 'GET (request-method (test-read-request "geT /path\r\n")))
401    (test-error "0.9 only knows GET" (test-read-request "PUT /path")))
402  (test-group "HTTP/1.0"
403    (let ((req (test-read-request "GET /path/to/stuff?arg1=val1&arg2=val2 HTTP/1.0\r\n\r\n")))
404      (test 1 (request-major req))
405      (test 0 (request-minor req))
406      (test 'GET (request-method req))
407      (test (uri-reference "/path/to/stuff?arg1=val1&arg2=val2") (request-uri req))
408      (test (headers '()) (request-headers req)))
409    (test 'PUT (request-method (test-read-request "PUT /path HTTP/1.0\r\n"))))
410  (test-group "HTTP/1.1" ; No need to test all things we test for 1.0
411   (let ((req (test-read-request "GET /path/to/stuff?arg1=val1&arg2=val2 HTTP/1.1\r\n\r\n")))
412     (test 1 (request-major req))
413     (test 1 (request-minor req)))
414   (test 'PUT (request-method (test-read-request "PUT /path HTTP/1.1\r\n\r\n")))
415   ; RFC 2616 5.1.1
416   (test "Method is case-sensitive" 'geT (request-method (test-read-request "geT /path HTTP/1.1\r\n\r\n")))
417   ; RFC 2616 3.1 + case-insensitivity BNF rule
418   (test "Protocol is case-insensitive" '1 (request-minor (test-read-request "GET /path htTP/1.1\r\n\r\n"))))) ;; TODO: Chunking
419
420(define (test-write-request req . outputs)
421  (call-with-output-string
422    (lambda (out)
423      (request-port-set! req out)
424      (let ((r (write-request req)))
425       (for-each (lambda (output)
426                   (display output (request-port r)))
427                 outputs)))))
428
429(test-group "Write request"
430  ;; This can also be called Simple-Request as per RFC 1945 4.1
431  ;; RFC 2616 19.6 also states we should recognise 0.9 requests, but if
432  ;; we understand those we should also be able to generate them because
433  ;; a 0.9 server does not understand 1.x requests.
434  (test-group "HTTP/0.9"
435    (let ((req (make-request major: 0 minor: 9
436                             method: 'GET
437                             uri: (uri-reference "/foo/bar.html"))))
438      (test "Always empty headers"
439            "GET /foo/bar.html\r\n"
440            (test-write-request (update-request req
441                                                headers:
442                                                (headers `((foo bar))))
443                                ""))
444      (test "Always GET"
445            "GET /foo/bar.html\r\n"
446            (test-write-request (update-request req method: 'POST)))))
447  (test-group "HTTP/1.0"
448    (let ((req (make-request major: 1 minor: 0
449                             method: 'GET
450                             uri: (uri-reference "/foo/bar.html"))))
451      (test "Headers"
452            "GET /foo/bar.html HTTP/1.0\r\nFoo: bar\r\n\r\ntest"
453            (test-write-request
454             (update-request req
455                             headers: (headers `((foo bar))))
456             "test"))
457      (test "Chunking ignored"
458            "GET /foo/bar.html HTTP/1.0\r\nTransfer-Encoding: chunked\r\n\r\nfoobar"
459            (test-write-request
460             (update-request req
461                             headers: (headers `((transfer-encoding chunked))))
462             "foo" "bar"))))
463  (test-group "HTTP/1.1"
464    (let ((req (make-request major: 1 minor: 1
465                             method: 'GET
466                             uri: (uri-reference "/foo/bar.html"))))
467      (test "Headers"
468            "GET /foo/bar.html HTTP/1.1\r\nFoo: bar\r\n\r\ntest"
469            (test-write-request
470             (update-request req
471                             headers: (headers `((foo bar))))
472             "test"))
473      (test "Chunking"
474            "GET /foo/bar.html HTTP/1.1\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n"
475            (test-write-request
476             (update-request req
477                             headers: (headers `((transfer-encoding chunked))))
478             "foo" "1234567890")))))
479
480(define (test-read-response input-string)
481  (call-with-input-string input-string
482    (lambda (in)
483      (read-response in))))
484
485(test-group "Read response"
486  (test-group "HTTP/1.1"
487    (let ((res (test-read-response "HTTP/1.1 303 See other\r\nFoo: bar\r\n\r\nContents")))
488      (test "Version detection"
489            '(1 . 1)
490            (cons (response-major res) (response-minor res)))
491      (test "Status"
492            '(303 . "See other")
493            (cons (response-code res) (response-reason res)))
494      (test "Headers"
495            '("bar")
496            (header-values 'foo (response-headers res)))
497      (test "Contents"
498            "Contents"
499            (read-string #f (response-port res))))
500    (let ((res (test-read-response "HTTP/1.1 200 OK\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n")))
501      (test "Chunking"
502            "foo1234567890"
503            (read-string #f (response-port res)))))
504  (test-group "HTTP/1.0"
505    (let ((res (test-read-response "HTTP/1.0 303 See other\r\nFoo: bar\r\n\r\nContents")))
506      (test "Version detection"
507            '(1 . 0)
508            (cons (response-major res) (response-minor res)))
509      (test "Status"
510            '(303 . "See other")
511            (cons (response-code res) (response-reason res)))
512      (test "Headers"
513            '("bar")
514            (header-values 'foo (response-headers res)))
515      (test "Contents"
516            "Contents"
517            (read-string #f (response-port res))))
518    (let ((res (test-read-response "HTTP/1.0 200 OK\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n")))
519      (test "Chunking ignored"
520            "3\r\nfoo\r\na\r\n1234567890\r\n"
521            (read-string #f (response-port res)))))
522  (test-group "HTTP/0.9"
523    (let ((res (test-read-response "Doesn't matter what's here\r\nLine 2")))
524      (test "Always OK status"
525            '(200 . "OK")
526            (cons (response-code res) (response-reason res)))
527      (test "Version detection; fallback to 0.9"
528            '(0 . 9)
529            (cons (response-major res) (response-minor res)))
530      (test "No headers"
531            (headers '()) (response-headers res))
532      (test "Contents"
533            "Doesn't matter what's here\r\nLine 2"
534            (read-string #f (response-port res))))))
535
536(define (test-write-response res . outputs)
537  (call-with-output-string
538    (lambda (out)
539      (response-port-set! res out)
540      (let ((r (write-response res)))
541       (for-each (lambda (output)
542                   (display output (response-port r)))
543                 outputs)))))
544
545(test-group "Write response"
546  (test-group "HTTP/0.9"
547    (let ((res (make-response major: 0 minor: 9
548                              code: 200 reason: "OK")))
549      (test "Headers ignored"
550            "These are the contents\r\n"
551            (test-write-response
552             (update-response res headers: (headers `((foo bar))))
553             "These are the contents\r\n"))))
554  (test-group "HTTP/1.0"
555    (let ((res (make-response major: 1 minor: 0
556                              code: 200 reason: "OK")))
557      (test "Headers used"
558            "HTTP/1.0 200 OK\r\nFoo: bar\r\n\r\nThese are the contents\r\n"
559            (test-write-response
560             (update-response res headers: (headers `((foo bar))))
561             "These are the contents\r\n"))
562      (test "Status code"
563            "HTTP/1.0 303 See other\r\n\r\nThese are the contents\r\n"
564            (test-write-response
565             (update-response res code: 303 reason: "See other")
566             "These are the contents\r\n"))
567      (test "Chunking ignored"
568            "HTTP/1.0 200 OK\r\nTransfer-Encoding: chunked\r\n\r\nfoo1234567890"
569            (test-write-response
570             (update-response
571              res
572              headers: (headers `((transfer-encoding chunked))))
573             "foo" "1234567890"))))
574  (test-group "HTTP/1.1"
575   (let ((res (make-response major: 1 minor: 1
576                             code: 200 reason: "OK")))
577     (test "Headers used"
578           "HTTP/1.1 200 OK\r\nFoo: bar\r\n\r\nThese are the contents\r\n"
579            (test-write-response
580             (update-response res headers: (headers `((foo bar))))
581             "These are the contents\r\n"))
582     (test "Status code"
583           "HTTP/1.1 303 See other\r\n\r\nThese are the contents\r\n"
584           (test-write-response
585            (update-response res code: 303 reason: "See other")
586            "These are the contents\r\n"))
587     (test "Chunking"
588           "HTTP/1.1 200 OK\r\nTransfer-Encoding: chunked\r\n\r\n3\r\nfoo\r\na\r\n1234567890\r\n"
589           (test-write-response
590            (update-response
591             res
592             headers: (headers `((transfer-encoding chunked))))
593            "foo" "1234567890")))))
594
595;; TODO:
596;; - Fix the parsing system so it's not so broken (more comfortable combinators)
597;; - Test malformed headers
598;; - When headers are malformed, what to do? Return #f for value and let
599;;    single/multiple discard them? Throw an exception?
600;; - Add parsing capability for quoted-pairs inside tokens and comments
601;; - Use SRFI-19
602;; - Rethink the auto-chunking stuff. Maybe this should be done at a higher level
603;; - Think about a good naming convention to distinguish parsers that accept
604;;    one argument (an already-tokenized string) or multiple (raw header data)
Note: See TracBrowser for help on using the repository browser.