source: project/release/4/intarweb/trunk/intarweb.scm @ 14978

Last change on this file since 14978 was 14978, checked in by sjamaan, 11 years ago

Implement SAFE? and IDEMPOTENT? predicates for methods/requests

File size: 25.2 KB
Line 
1;;
2;; Intarweb is an improved HTTP library for Chicken
3;;
4; Copyright (c) 2008-2009, Peter Bex
5; All rights reserved.
6;
7; Redistribution and use in source and binary forms, with or without
8; modification, are permitted provided that the following conditions
9; are met:
10;
11; 1. Redistributions of source code must retain the above copyright
12;    notice, this list of conditions and the following disclaimer.
13; 2. Redistributions in binary form must reproduce the above copyright
14;    notice, this list of conditions and the following disclaimer in the
15;    documentation and/or other materials provided with the distribution.
16; 3. Neither the name of the author nor the names of its
17;    contributors may be used to endorse or promote products derived
18;    from this software without specific prior written permission.
19;
20; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
21; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
22; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
23; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
24; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
25; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
26; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
27; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
29; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
30; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
31; OF THE POSSIBILITY OF SUCH DAMAGE.
32
33(provide 'intarweb)
34
35(module intarweb
36  (read-line-limit replace-header-contents replace-header-contents!
37   remove-header remove-header!
38   update-header-contents update-header-contents! headers single-headers
39   headers? headers->list http-name->symbol symbol->http-name
40   header-parsers header-unparsers unparse-header unparse-headers
41   safe-methods safe? idempotent-methods idempotent? keep-alive?
42   
43   make-request request? request-major request-major-set!
44   request-minor request-minor-set!
45   request-method request-method-set! request-uri request-uri-set!
46   request-headers request-headers-set! request-port request-port-set!
47   update-request set-request!
48
49   request-parsers read-request request-unparsers write-request read-headers
50   http-0.9-request-parser http-1.x-request-parser
51   http-0.9-request-unparser http-1.x-request-unparser
52   
53   make-response response? response-major response-major-set!
54   response-minor response-minor-set!
55   response-code response-code-set! response-reason response-reason-set!
56   response-headers response-headers-set! response-port response-port-set!
57   update-response set-response!
58   
59   write-response response-parsers response-unparsers read-response
60   http-0.9-response-parser http-1.x-response-parser
61   http-0.9-response-unparser http-1.x-response-unparser
62
63   ;; http-header-parsers
64   header-contents header-values header-value
65   get-value get-params get-param get-quality
66
67   split-multi-header parse-token parse-comment
68   parse-parameters parse-value+parameters multiple single
69   make-key/value-subparser
70   
71   rfc1123-string->time rfc850-string->time asctime-string->time
72   http-date-string->time
73   rfc1123-subparser rfc850-subparser  asctime-subparser http-date-subparser
74   quality-subparser unknown-header-parser
75   symbol-subparser symbol-subparser-ci natnum-subparser
76   host/port-subparser base64-subparser range-subparser
77   entity-tag-parser product-parser mailbox-subparser if-range-parser
78   retry-after-subparser via-parser warning-parser key/value-subparser
79   set-cookie-parser cache-control-parser pragma-parser te-parser
80   cookie-parser
81
82   unparse-params must-be-quoted-chars quote-string unparse-token
83   default-header-unparser entity-tag-unparser host/port-unparser
84   product-unparser rfc1123-unparser
85   )
86
87  (import scheme chicken foreign)
88 
89  (use extras ports data-structures srfi-1 srfi-13 srfi-14 regex posix
90       base64 defstruct uri-common)
91
92(define read-line-limit (make-parameter 1024)) ; #f if you want no limit
93
94;; Make headers a new type, to force the use of the HEADERS procedure
95;; and ensure only proper header values are passed to all procedures
96;; that deal with headers.
97(define-record headers v)
98
99(define-record-printer (headers h out)
100  (fprintf out "#(headers: ~S)"
101           (headers-v h)))
102
103(define headers->list headers-v)
104
105(define (remove-header! name headers)
106  (let loop ((h (headers-v headers)))
107    (cond
108     ((null? h) headers)
109     ((eq? name (caar h))
110      (set-cdr! h (cdr h))
111      headers)
112     (else (loop (cdr h))))))
113
114(define (remove-header name headers)
115  (make-headers
116   (let loop ((h (headers-v headers)))
117     (cond
118      ((null? h) h)
119      ((eq? name (caar h)) (loop (cdr h)))
120      (else (cons (car h) (loop (cdr h))))))))
121
122;; XXX: Do we need these replace procedures in the exports list?  It
123;; looks like we can use update everywhere.
124(define (replace-header-contents! name contents headers)
125  (let loop ((h (headers-v headers)))
126    (cond
127     ((null? h)
128      (headers-v-set!
129       headers (cons (cons name contents) (headers-v headers)))
130      headers)
131     ((eq? name (caar h))
132      (set-cdr! (car h) contents)
133      headers)
134     (else (loop (cdr h))))))
135
136(define (replace-header-contents name contents headers)
137  (make-headers
138   (let loop ((h (headers-v headers)))
139     (cond
140      ((null? h) (cons (cons name contents) h))
141      ((eq? name (caar h))
142       (cons (cons (caar h) contents) (cdr h)))
143      (else (cons (car h) (loop (cdr h))))))))
144
145(define (make-updater replacer)
146  (lambda (name contents headers)
147    (let ((old (header-contents name headers '())))
148      (replacer name
149                (if (member name (single-headers))
150                    (list (last contents))
151                    (append old contents))
152                headers))))
153
154(define update-header-contents  (make-updater replace-header-contents))
155(define update-header-contents! (make-updater replace-header-contents!))
156
157(define http-name->symbol (compose string->symbol string-downcase!))
158(define symbol->http-name (compose string-titlecase symbol->string))
159
160;; Make a header set from a literal expression by folding in the headers
161;; with any previous ones
162(define (headers headers-to-be #!optional (old-headers (make-headers '())))
163  (fold (lambda (h new-headers)
164          (update-header-contents
165           (car h)
166           (map (lambda (v)
167                  (if (vector? v) v (vector v '()))) ; normalize to vector
168                (cdr h))
169           new-headers))
170        old-headers
171        headers-to-be))
172
173(define normalized-uri (compose uri-normalize-path-segments uri-reference))
174
175(include "header-parsers") ; Also includes header unparsers
176
177;; Any unknown headers are considered to be multi-headers, always
178(define single-headers
179  (make-parameter '(accept-ranges age authorization content-length
180                    content-location content-md5 content-type date etag
181                    expect expires host if-modified-since if-unmodified-since
182                    last-modified location max-forwards proxy-authorization
183                    range referer retry-after server transfer-encoding
184                    user-agent www-authenticate)))
185
186(define string->http-method string->symbol)
187(define http-method->string symbol->string)
188
189;; Hack to insert trailer in chunked ports
190(define *end-of-transfer-object* (list 'eot))
191
192;; Make an output port automatically "chunked"
193(define (chunked-output-port port)
194  (make-output-port (lambda (s) ; write
195                      (if (eq? *end-of-transfer-object* s)
196                          (fprintf port "0\r\n\r\n") ; trailer?
197                          (fprintf port "~X\r\n~A\r\n" (string-length s) s)))
198                    (lambda ()  ; close
199                      (close-output-port port))
200                    (lambda ()  ; flush
201                      (flush-output port))))
202
203;; Make an input port automatically "chunked"
204(define (chunked-input-port port)
205  (let* ((chunk-length 0)
206         (position 0)
207         (check-position (lambda ()
208                           (when (and position (>= position chunk-length))
209                             (unless (zero? chunk-length)
210                                     (read-line port)) ; read \r\n data trailer
211                             (let* ((line (read-line port)))
212                               (if (eof-object? line)
213                                   (set! position #f)
214                                   (begin
215                                     (set! chunk-length (string->number line 16))
216                                     (if chunk-length
217                                         (set! position 0)
218                                         (set! position #f)))))))))
219    (make-input-port (lambda ()         ; read
220                       (check-position)
221                       (if position
222                           (let ((char (read-char port)))
223                             (if (not (eof-object? char))
224                                 (set! position (add1 position)))
225                             char)
226                           #!eof))
227                     (lambda ()          ; ready?
228                       (check-position)
229                       (and position (char-ready? port)))
230                     (lambda ()          ; close
231                       (close-input-port port))
232                     (lambda ()          ; peek
233                       (check-position)
234                       (if position
235                           (peek-char port)
236                           #!eof)))))
237
238(define safe-methods
239  (make-parameter '(GET HEAD)))
240
241;; RFC2616, Section 9.1.1
242(define (safe? obj)
243  (let ((method (if (request? obj) (request-method obj) obj)))
244    (not (not (member method (safe-methods))))))
245
246(define idempotent-methods
247  (make-parameter '(GET HEAD PUT DELETE OPTIONS TRACE)))
248
249;; RFC2616, Section 9.1.2
250(define (idempotent? obj)
251  (let ((method (if (request? obj) (request-method obj) obj)))
252    (not (not (member method (idempotent-methods))))))
253
254(define (keep-alive? obj)
255  (let ((major (if (request? obj) (request-major obj) (response-major obj)))
256        (minor (if (request? obj) (request-minor obj) (response-minor obj)))
257        (con   (header-value 'connection (if (request? obj)
258                                             (request-headers obj)
259                                             (response-headers obj)))))
260   (if (and (= major 1) (> minor 0))
261       (not (eq? con 'close))
262       ;; RFC 2068, section 19.7.1 (see also RFC 2616, section 19.6.2)
263       (eq? con 'keep-alive))))
264
265;;;;;;;;;;;;;;;;;;;;;;;;;
266;;;; Request parsing ;;;;
267;;;;;;;;;;;;;;;;;;;;;;;;;
268
269;; This includes parsers for all RFC-defined headers
270(define header-parsers
271  (make-parameter
272   `((accept . ,(multiple symbol-subparser-ci
273                          `((q . ,quality-subparser))))
274     (accept-charset . ,(multiple symbol-subparser-ci
275                                  `((q . ,quality-subparser))))
276     (accept-encoding . ,(multiple symbol-subparser-ci
277                                   `((q . ,quality-subparser))))
278     (accept-language . ,(multiple symbol-subparser-ci
279                                   `((q . ,quality-subparser))))
280     (accept-ranges . ,(single symbol-subparser-ci))
281     (age . ,(single natnum-subparser))
282     (allow . ,(multiple symbol-subparser))
283     (authorization . ,(single symbol-subparser-ci))
284     (cache-control . ,cache-control-parser)
285     (connection . ,(multiple symbol-subparser-ci))
286     (content-encoding . ,(multiple symbol-subparser-ci))
287     (content-language . ,(multiple symbol-subparser-ci))
288     (content-length . ,(single natnum-subparser))
289     (content-location . ,(single normalized-uri))
290     (content-md5 . ,(single base64-subparser))
291     (content-range . ,(single range-subparser))
292     (content-type . ,(single symbol-subparser-ci))
293     (date . ,(single http-date-subparser))
294     (etag . ,entity-tag-parser)
295     (expect . ,(single (make-key/value-subparser '())))
296     (expires . ,(single http-date-subparser))
297     (from . ,(multiple mailbox-subparser))
298     (host . ,(single host/port-subparser))
299     (if-match . ,if-match-parser)
300     (if-modified-since . ,(single http-date-subparser))
301     (if-none-match . ,if-match-parser)
302     (if-range . ,if-range-parser)
303     (if-unmodified-since . ,(single http-date-subparser))
304     (last-modified . ,(single http-date-subparser))
305     (location . ,(single normalized-uri))
306     (max-forwards . ,(single natnum-subparser))
307     (pragma . ,pragma-parser)
308     (proxy-authenticate . ,(multiple symbol-subparser-ci))
309     (proxy-authorization . ,(single symbol-subparser-ci))
310     (range . ,(multiple range-subparser))
311     (referer . ,(single normalized-uri))
312     (retry-after . ,(single retry-after-subparser))
313     (server . ,product-parser)
314     (te . ,te-parser)
315     (trailer . ,(multiple symbol-subparser-ci))
316     (transfer-encoding . ,(single symbol-subparser-ci))
317     (upgrade . ,(multiple update-header-contents!))
318     (user-agent . ,product-parser)
319     (vary . ,(multiple symbol-subparser-ci))
320     (via . ,via-parser)
321     (warning . ,warning-parser)
322     (www-authenticate . ,(single symbol-subparser-ci))
323     ;; RFC 2109
324     (set-cookie . ,set-cookie-parser)
325     (cookie . ,cookie-parser)
326     ;; RFC 2965?
327     )))
328
329;; The parser is supposed to return a list of header values for its header
330(define (parse-header name contents)
331  (let* ((default unknown-header-parser)
332         (parser (alist-ref name (header-parsers) eq? default)))
333    (parser contents)))
334
335(define (parse-header-line line headers)
336  (or
337   (and-let* ((colon-idx   (string-index line #\:))
338              (header-name (http-name->symbol (string-take line colon-idx)))
339              (contents    (string-trim-both (string-drop line (add1 colon-idx)))))
340             (update-header-contents!
341              header-name (parse-header header-name contents) headers))
342   (signal-http-condition "Bad header line" 'header-error 'contents line)))
343
344(define (read-headers port)
345  (let ((first-line (read-line port)))
346    (if (or (eof-object? first-line) (string-null? first-line))
347        (make-headers '())
348        (let loop ((prev-line first-line)
349                   (line      (read-line port))
350                   (headers   (make-headers '())))
351          (if (or (eof-object? line) (string-null? line))
352              (if (string-null? prev-line)
353                  headers
354                  (parse-header-line prev-line headers))
355              (if (char-whitespace? (string-ref line 0)) ; Continuation char?
356                  (loop (string-append prev-line line)
357                        (read-line port)
358                        headers)
359                  (if (string=? (string-take-right prev-line 1) "\\") ; escaped?
360                      ;; XXX Test if this works with all combinations of \r\n
361                      ;; with prepended backslashes. We don't care about
362                      ;; malformed stuff like "foo\\\\\n" or \ with missing "
363                      (loop (string-append prev-line "\n" line)
364                            (read-line port)
365                            headers)
366                      (loop line (read-line port)
367                            (parse-header-line prev-line headers)))))))))
368
369(define (signal-http-condition msg type . more-info)
370  (signal (make-composite-condition
371           (make-property-condition 'http)
372           (apply make-property-condition type more-info)
373           (make-property-condition 'exn 'message msg))))
374
375(defstruct request
376  (method 'GET) uri (major 1) (minor 1) (headers (make-headers '())) port)
377
378;; This removes the dependency on regex-case and is simpler
379(define-syntax regex-let
380  (syntax-rules ()
381    ((regex-let str regex (name ...) body ...)
382     (let ((values (string-match regex str)))
383       (and values (apply (lambda (name ...) body ...) values))))))
384
385;; Perhaps we should have header parsers indexed by version or
386;; something like that, so you can define the maximum version. Useful
387;; for when expecting a response. Then we group request/response parsers
388;; together, as with request/response unparsers.
389(define (http-0.9-request-parser line in)
390  (regex-let
391   line "[Gg][Ee][Tt] +([^ \t]+)"
392   (_ uri)
393   (make-request method: 'GET uri: (normalized-uri uri)
394                 major: 0 minor: 9
395                 port: in)))
396
397;; XXX This actually parses anything >= HTTP/1.0
398(define (http-1.x-request-parser line in)
399  (regex-let
400   line "([a-zA-Z]+) +([^ \t]+) +[Hh][Tt][Tt][Pp]/([0-9]+)\\.([0-9]+)"
401   (_ method uri major minor)
402   (make-request method: (string->http-method method) uri: (normalized-uri uri)
403                 major: (string->number major)
404                 minor: (string->number minor)
405                 headers: (read-headers in)
406                 port: in)))
407
408(define request-parsers   ; order matters here
409  (make-parameter (list http-1.x-request-parser http-0.9-request-parser)))
410
411(define (read-request inport)
412  (let* ((line (read-line inport (read-line-limit)))
413         ;; A bit ugly, but simpler than the alternatives
414         (line (if (eof-object? line) "" line)))
415    ;; Try each parser in turn to process the request-line.
416    ;; A parser returns either #f or a request object
417    (let loop ((parsers (request-parsers)))
418      (if (null? parsers)
419          (signal-http-condition "Unknown protocol" 'unknown-protocol-line
420                                 'line line)
421          (or ((car parsers) line inport) (loop (cdr parsers)))))))
422
423;;;;;;;;;;;;;;;;;;;;;;;;;;;
424;;;; Request unparsing ;;;;
425;;;;;;;;;;;;;;;;;;;;;;;;;;;
426
427(define header-unparsers
428  (make-parameter
429   `((etag . ,entity-tag-unparser)
430     (expires . ,rfc1123-unparser)
431     (host . ,host/port-unparser)
432     (if-modified-since . ,rfc1123-unparser)
433     (if-unmodified-since . ,rfc1123-unparser)
434     (last-modified . ,rfc1123-unparser)
435     (user-agent . ,product-unparser)
436     (server . ,product-unparser))))
437
438(define (unparse-header header-name header-value)
439  (let* ((def default-header-unparser)
440         (unparser (alist-ref header-name (header-unparsers) eq? def)))
441   (unparser header-name header-value)))
442
443(define (unparse-headers headers out)
444  (for-each
445     (lambda (h)
446       (let* ((name (car h))
447              (name-s (symbol->http-name name))
448              (contents (cdr h)))
449         (fprintf out "~A: ~A\r\n" name-s (unparse-header name contents))))
450     (headers-v headers)))
451
452(define (write-request-line request)
453  (fprintf (request-port request)
454           "~A ~A HTTP/~A.~A\r\n"
455           (http-method->string (request-method request))
456           (uri->string (request-uri request))
457           (request-major request)
458           (request-minor request)))
459
460(define (http-0.9-request-unparser request)
461  (fprintf (request-port request)
462           "GET ~A\r\n"
463           (uri->string (request-uri request)))
464  request)
465
466(define (http-1.0-request-unparser request)
467  (and-let* (((= (request-major request) 1))
468             ((= (request-minor request) 0))
469             (o (request-port request)))
470    (write-request-line request)
471    (unparse-headers (request-headers request) o)
472    (display "\r\n" o)
473    request))
474
475;; XXX This actually unparses anything >= HTTP/1.1
476(define (http-1.x-request-unparser request)
477  (and-let* (((or (> (request-major request) 1)
478                  (and (= (request-major request) 1)
479                       (> (request-minor request) 0))))
480             (o (request-port request)))
481    (write-request-line request)
482    (unparse-headers (request-headers request) o)
483    (display "\r\n" o)
484    (if (memq 'chunked (header-values 'transfer-encoding
485                                      (request-headers request)))
486        (update-request request
487                        port: (chunked-output-port (request-port request)))
488        request)))
489
490(define request-unparsers  ; order matters here
491  (make-parameter (list http-1.x-request-unparser
492                        http-1.0-request-unparser
493                        http-0.9-request-unparser)))
494
495(define (write-request request)
496  ;; Try each unparser in turn to write the request-line.
497  ;; An unparser returns either #f or a new request object.
498  (let loop ((unparsers (request-unparsers)))
499    (if (null? unparsers)
500        (signal-http-condition "Unknown protocol" 'unknown-protocol
501                               'major (request-major request)
502                               'minor (request-minor request))
503        (or ((car unparsers) request) (loop (cdr unparsers))))))
504
505;;;;;;;;;;;;;;;;;;;;;;;;;;;;
506;;;; Response unparsing ;;;;
507;;;;;;;;;;;;;;;;;;;;;;;;;;;;
508
509(defstruct response
510  (code 200) (reason "OK") (major 1) (minor 1) (headers (make-headers '())) port)
511
512(define (http-0.9-response-unparser response)
513  response) ;; The response-body will just follow
514
515(define (write-response-line response)
516  (fprintf (response-port response)
517           "HTTP/~A.~A ~A ~A\r\n"
518           (response-major response)
519           (response-minor response)
520           (response-code response)
521           (response-reason response)))
522
523(define (http-1.0-response-unparser response)
524  (and-let* (((= (response-major response) 1))
525             ((= (response-minor response) 0))
526             (o (response-port response)))
527    (write-response-line response)
528    (unparse-headers (response-headers response) o)
529    (display "\r\n" o)
530    response))
531
532;; XXX This actually unparses anything >= HTTP/1.1
533(define (http-1.x-response-unparser response)
534  (and-let* (((or (> (response-major response) 1)
535                  (and (= (response-major response) 1)
536                       (> (response-minor response) 0))))
537             (o (response-port response)))
538    (write-response-line response)
539    (unparse-headers (response-headers response) o)
540    (display "\r\n" o)
541    (if (memq 'chunked (header-values 'transfer-encoding
542                                      (response-headers response)))
543        (update-response response
544                         port: (chunked-output-port (response-port response)))
545        response)))
546
547(define response-unparsers
548  (make-parameter (list http-1.x-response-unparser
549                        http-1.0-response-unparser
550                        http-0.9-response-unparser)))
551
552(define (write-response response)
553  ;; Try each unparser in turn to write the response-line.
554  ;; An unparser returns either #f or a new response object.
555  (let loop ((unparsers (response-unparsers)))
556    (if (null? unparsers)
557        (signal-http-condition "Unknown protocol" 'unknown-protocol
558                               'major (response-major response)
559                               'minor (response-minor response))
560        (or ((car unparsers) response) (loop (cdr unparsers))))))
561
562;;;;;;;;;;;;;;;;;;;;;;;;;;
563;;;; Response parsing ;;;;
564;;;;;;;;;;;;;;;;;;;;;;;;;;
565
566;; I don't like this code. Clean it up!
567(define (http-1.x-response-parser line in)
568  (regex-let
569   line "[Hh][Tt][Tt][Pp]/([0-9]+)\\.([0-9]+) +([0-9]+) +(.*)"
570   (_ major minor code reason)
571   (let ((major (string->number major))
572         (minor (string->number minor)))
573     (and (or (> major 1)
574              (and (= major 1)
575                   (> minor 0)))
576          (let ((response (make-response code: (string->number code)
577                                         reason: reason
578                                         major: major
579                                         minor: minor
580                                         headers: (read-headers in)
581                                         port: in)))
582            (if (memq 'chunked (header-values 'transfer-encoding
583                                              (response-headers response)))
584                (update-response response
585                                 port: (chunked-input-port
586                                        (response-port response)))
587                response))))))
588
589(define (http-1.0-response-parser line in)
590  (regex-let
591   line "[Hh][Tt][Tt][Pp]/1\\.0 +([0-9]+) +(.*)"
592   (_ code reason)
593   (let ((response (make-response code: (string->number code) reason: reason
594                                  major: 1 minor: 0
595                                  headers: (read-headers in)
596                                  port: in)))
597     response)))
598
599;; You can't "detect" a 0.9 response, because there is no response line.
600;; It will simply output the body directly, so we will just assume that
601;; if we can't recognise the output string, we just got a 0.9 response.
602;; If this is not desired, just change response-parsers to exclude this one.
603(define (http-0.9-response-parser line in)
604  (make-response code: 200 reason: "OK"
605                 major: 0 minor: 9
606                 ;; XXX This is wrong, it re-inserts \r\n, while it may have
607                 ;; been a \n only. To work around this, we'd have to write
608                 ;; a custom read-line procedure.
609                 ;; However, it does not matter much because HTTP 0.9 is only
610                 ;; defined to ever return text/html, no binary or any other
611                 ;; content type.
612                 port: (call-with-input-string (string-append line "\r\n")
613                         (lambda (str)
614                           (make-concatenated-port str in)))))
615
616(define response-parsers ;; order matters here
617  (make-parameter (list http-1.x-response-parser http-1.0-response-parser http-0.9-response-parser)))
618
619(define (read-response inport)
620  (let* ((line (read-line inport (read-line-limit)))
621         (line (if (eof-object? line) "" line)))
622    (let loop ((parsers (response-parsers)))
623      (if (null? parsers)
624          (signal-http-condition "Unknown protocol" 'unknown-protocol-line
625                                 'line line)
626          (or ((car parsers) line inport) (loop (cdr parsers)))))))
627
628)
Note: See TracBrowser for help on using the repository browser.