source: project/release/4/intarweb/trunk/intarweb.scm @ 14836

Last change on this file since 14836 was 14836, checked in by sjamaan, 10 years ago

Rework parsers a little so they can return lists of values instead of headers. It makes more sense this way and makes the code a bit shorter - and paves the way for more changes to come

File size: 24.7 KB
Line 
1;;
2;; Intarweb is an improved HTTP library for Chicken
3;;
4; Copyright (c) 2008-2009, Peter Bex
5; All rights reserved.
6;
7; Redistribution and use in source and binary forms, with or without
8; modification, are permitted provided that the following conditions
9; are met:
10;
11; 1. Redistributions of source code must retain the above copyright
12;    notice, this list of conditions and the following disclaimer.
13; 2. Redistributions in binary form must reproduce the above copyright
14;    notice, this list of conditions and the following disclaimer in the
15;    documentation and/or other materials provided with the distribution.
16; 3. Neither the name of the author nor the names of its
17;    contributors may be used to endorse or promote products derived
18;    from this software without specific prior written permission.
19;
20; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
21; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
22; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
23; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
24; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
25; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
26; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
27; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
29; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
30; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
31; OF THE POSSIBILITY OF SUCH DAMAGE.
32
33(provide 'intarweb)
34
35(module intarweb
36  (read-line-limit replace-header-contents replace-header-contents!
37   remove-header remove-header!
38   update-header-contents update-header-contents! headers single-headers
39   headers? headers->list http-name->symbol symbol->http-name
40   header-parsers header-unparsers unparse-header unparse-headers
41   keep-alive?
42   
43   make-request request? request-major request-major-set!
44   request-minor request-minor-set!
45   request-method request-method-set! request-uri request-uri-set!
46   request-headers request-headers-set! request-port request-port-set!
47   update-request set-request!
48   
49   request-parsers read-request request-unparsers write-request read-headers
50   http-0.9-request-parser http-1.x-request-parser
51   http-0.9-request-unparser http-1.x-request-unparser
52   
53   make-response response? response-major response-major-set!
54   response-minor response-minor-set!
55   response-code response-code-set! response-reason response-reason-set!
56   response-headers response-headers-set! response-port response-port-set!
57   update-response set-response!
58   
59   write-response response-parsers response-unparsers read-response
60   http-0.9-response-parser http-1.x-response-parser
61   http-0.9-response-unparser http-1.x-response-unparser
62
63   ;; http-header-parsers
64   header-contents header-values header-value
65   get-value get-params get-param get-quality
66
67   split-multi-header parse-token parse-comment
68   parse-parameters parse-value+parameters multiple single
69   make-key/value-subparser
70   
71   rfc1123-string->time rfc850-string->time asctime-string->time
72   http-date-string->time
73   rfc1123-subparser rfc850-subparser  asctime-subparser http-date-subparser
74   quality-subparser unknown-header-parser
75   symbol-subparser symbol-subparser-ci natnum-subparser
76   host/port-subparser base64-subparser range-subparser
77   entity-tag-parser product-parser mailbox-subparser if-range-parser
78   retry-after-subparser via-parser warning-parser key/value-subparser
79   set-cookie-parser cache-control-parser pragma-parser te-parser
80   cookie-parser
81
82   unparse-params must-be-quoted-chars quote-string unparse-token
83   default-header-unparser entity-tag-unparser host/port-unparser
84   product-unparser rfc1123-unparser
85   )
86
87  (import scheme chicken foreign)
88 
89  (require-library srfi-1 srfi-13 regex regex-case base64 defstruct
90                   uri-common posix)
91
92  (import extras ports data-structures
93          srfi-1 srfi-13 srfi-14 regex regex-case base64
94          defstruct uri-common posix)
95
96(define read-line-limit (make-parameter 1024)) ; #f if you want no limit
97
98;; Make headers a new type, to force the use of the HEADERS procedure
99;; and ensure only proper header values are passed to all procedures
100;; that deal with headers.
101(define-record headers v)
102
103(define-record-printer (headers h out)
104  (fprintf out "#(headers: ~S)"
105           (headers-v h)))
106
107(define headers->list headers-v)
108
109(define (remove-header! name headers)
110  (let loop ((h (headers-v headers)))
111    (cond
112     ((null? h) headers)
113     ((eq? name (caar h))
114      (set-cdr! h (cdr h))
115      headers)
116     (else (loop (cdr h))))))
117
118(define (remove-header name headers)
119  (make-headers
120   (let loop ((h (headers-v headers)))
121     (cond
122      ((null? h) h)
123      ((eq? name (caar h)) (loop (cdr h)))
124      (else (cons (car h) (loop (cdr h))))))))
125
126;; XXX: Do we need these replace procedures in the exports list?  It
127;; looks like we can use update everywhere.
128(define (replace-header-contents! name contents headers)
129  (let loop ((h (headers-v headers)))
130    (cond
131     ((null? h)
132      (headers-v-set!
133       headers (cons (cons name contents) (headers-v headers)))
134      headers)
135     ((eq? name (caar h))
136      (set-cdr! (car h) contents)
137      headers)
138     (else (loop (cdr h))))))
139
140(define (replace-header-contents name contents headers)
141  (make-headers
142   (let loop ((h (headers-v headers)))
143     (cond
144      ((null? h) (cons (cons name contents) h))
145      ((eq? name (caar h))
146       (cons (cons (caar h) contents) (cdr h)))
147      (else (cons (car h) (loop (cdr h))))))))
148
149(define (make-updater replacer)
150  (lambda (name contents headers)
151    (let ((old (header-contents name headers '())))
152      (replacer name
153                (if (member name (single-headers))
154                    (list (last contents))
155                    (append old contents))
156                headers))))
157
158(define update-header-contents  (make-updater replace-header-contents))
159(define update-header-contents! (make-updater replace-header-contents!))
160
161(define http-name->symbol (compose string->symbol string-downcase!))
162(define symbol->http-name (compose string-titlecase symbol->string))
163
164;; Make a header set from a literal expression by folding in the headers
165;; with any previous ones
166(define (headers headers-to-be #!optional (old-headers (make-headers '())))
167  (fold (lambda (h new-headers)
168          (update-header-contents
169           (car h)
170           (map (lambda (v)
171                  (if (vector? v) v (vector v '()))) ; normalize to vector
172                (cdr h))
173           new-headers))
174        old-headers
175        headers-to-be))
176
177(define normalized-uri (compose uri-normalize-path-segments uri-reference))
178
179(include "header-parsers") ; Also includes header unparsers
180
181;; Any unknown headers are considered to be multi-headers, always
182(define single-headers
183  (make-parameter '(accept-ranges age authorization content-length
184                    content-location content-md5 content-type date etag
185                    expect expires host if-modified-since if-unmodified-since
186                    last-modified location max-forwards proxy-authorization
187                    range referer retry-after server transfer-encoding
188                    user-agent www-authenticate)))
189
190(define string->http-method string->symbol)
191(define http-method->string symbol->string)
192
193;; Hack to insert trailer in chunked ports
194(define *end-of-transfer-object* (list 'eot))
195
196;; Make an output port automatically "chunked"
197(define (chunked-output-port port)
198  (make-output-port (lambda (s) ; write
199                      (if (eq? *end-of-transfer-object* s)
200                          (fprintf port "0\r\n\r\n") ; trailer?
201                          (fprintf port "~X\r\n~A\r\n" (string-length s) s)))
202                    (lambda ()  ; close
203                      (close-output-port port))
204                    (lambda ()  ; flush
205                      (flush-output port))))
206
207;; Make an input port automatically "chunked"
208(define (chunked-input-port port)
209  (let* ((chunk-length 0)
210         (position 0)
211         (check-position (lambda ()
212                           (when (and position (>= position chunk-length))
213                             (unless (zero? chunk-length)
214                                     (read-line port)) ; read \r\n data trailer
215                             (let* ((line (read-line port)))
216                               (if (eof-object? line)
217                                   (set! position #f)
218                                   (begin
219                                     (set! chunk-length (string->number line 16))
220                                     (if chunk-length
221                                         (set! position 0)
222                                         (set! position #f)))))))))
223    (make-input-port (lambda ()         ; read
224                       (check-position)
225                       (if position
226                           (let ((char (read-char port)))
227                             (if (not (eof-object? char))
228                                 (set! position (add1 position)))
229                             char)
230                           #!eof))
231                     (lambda ()          ; ready?
232                       (check-position)
233                       (and position (char-ready? port)))
234                     (lambda ()          ; close
235                       (close-input-port port))
236                     (lambda ()          ; peek
237                       (check-position)
238                       (if position
239                           (peek-char port)
240                           #!eof)))))
241
242(define (keep-alive? obj)
243  (let ((major (if (request? obj) (request-major obj) (response-major obj)))
244        (minor (if (request? obj) (request-minor obj) (response-minor obj)))
245        (con   (header-value 'connection (if (request? obj)
246                                             (request-headers obj)
247                                             (response-headers obj)))))
248   (if (and (= major 1) (> minor 0))
249       (not (eq? con 'close))
250       ;; RFC 2068, section 19.7.1 (see also RFC 2616, section 19.6.2)
251       (eq? con 'keep-alive))))
252
253;;;;;;;;;;;;;;;;;;;;;;;;;
254;;;; Request parsing ;;;;
255;;;;;;;;;;;;;;;;;;;;;;;;;
256
257;; This includes parsers for all RFC-defined headers
258(define header-parsers
259  (make-parameter
260   `((accept . ,(multiple symbol-subparser-ci
261                          `((q . ,quality-subparser))))
262     (accept-charset . ,(multiple symbol-subparser-ci
263                                  `((q . ,quality-subparser))))
264     (accept-encoding . ,(multiple symbol-subparser-ci
265                                   `((q . ,quality-subparser))))
266     (accept-language . ,(multiple symbol-subparser-ci
267                                   `((q . ,quality-subparser))))
268     (accept-ranges . ,(single symbol-subparser-ci))
269     (age . ,(single natnum-subparser))
270     (allow . ,(multiple symbol-subparser))
271     (authorization . ,(single symbol-subparser-ci))
272     (cache-control . ,cache-control-parser)
273     (connection . ,(multiple symbol-subparser-ci))
274     (content-encoding . ,(multiple symbol-subparser-ci))
275     (content-language . ,(multiple symbol-subparser-ci))
276     (content-length . ,(single natnum-subparser))
277     (content-location . ,(single normalized-uri))
278     (content-md5 . ,(single base64-subparser))
279     (content-range . ,(single range-subparser))
280     (content-type . ,(single symbol-subparser-ci))
281     (date . ,(single http-date-subparser))
282     (etag . ,entity-tag-parser)
283     (expect . ,(single (make-key/value-subparser '())))
284     (expires . ,(single http-date-subparser))
285     (from . ,(multiple mailbox-subparser))
286     (host . ,(single host/port-subparser))
287     (if-match . ,if-match-parser)
288     (if-modified-since . ,(single http-date-subparser))
289     (if-none-match . ,if-match-parser)
290     (if-range . ,if-range-parser)
291     (if-unmodified-since . ,(single http-date-subparser))
292     (last-modified . ,(single http-date-subparser))
293     (location . ,(single normalized-uri))
294     (max-forwards . ,(single natnum-subparser))
295     (pragma . ,pragma-parser)
296     (proxy-authenticate . ,(multiple symbol-subparser-ci))
297     (proxy-authorization . ,(single symbol-subparser-ci))
298     (range . ,(multiple range-subparser))
299     (referer . ,(single normalized-uri))
300     (retry-after . ,(single retry-after-subparser))
301     (server . ,product-parser)
302     (te . ,te-parser)
303     (trailer . ,(multiple symbol-subparser-ci))
304     (transfer-encoding . ,(single symbol-subparser-ci))
305     (upgrade . ,(multiple update-header-contents!))
306     (user-agent . ,product-parser)
307     (vary . ,(multiple symbol-subparser-ci))
308     (via . ,via-parser)
309     (warning . ,warning-parser)
310     (www-authenticate . ,(single symbol-subparser-ci))
311     ;; RFC 2109
312     (set-cookie . ,set-cookie-parser)
313     (cookie . ,cookie-parser)
314     ;; RFC 2965?
315     )))
316
317;; The parser is supposed to return a list of header values for its header
318(define (parse-header name contents)
319  (let* ((default unknown-header-parser)
320         (parser (alist-ref name (header-parsers) eq? default)))
321    (parser contents)))
322
323(define (parse-header-line line headers)
324  (or
325   (and-let* ((colon-idx   (string-index line #\:))
326              (header-name (http-name->symbol (string-take line colon-idx)))
327              (contents    (string-trim-both (string-drop line (add1 colon-idx)))))
328             (update-header-contents!
329              header-name (parse-header header-name contents) headers))
330   (signal-http-condition "Bad header line" 'header-error 'contents line)))
331
332(define (read-headers port)
333  (let ((first-line (read-line port)))
334    (if (or (eof-object? first-line) (string-null? first-line))
335        (make-headers '())
336        (let loop ((prev-line first-line)
337                   (line      (read-line port))
338                   (headers   (make-headers '())))
339          (if (or (eof-object? line) (string-null? line))
340              (if (string-null? prev-line)
341                  headers
342                  (parse-header-line prev-line headers))
343              (if (char-whitespace? (string-ref line 0)) ; Continuation char?
344                  (loop (string-append prev-line line)
345                        (read-line port)
346                        headers)
347                  (if (string=? (string-take-right prev-line 1) "\\") ; escaped?
348                      ;; XXX Test if this works with all combinations of \r\n
349                      ;; with prepended backslashes. We don't care about
350                      ;; malformed stuff like "foo\\\\\n" or \ with missing "
351                      (loop (string-append prev-line "\n" line)
352                            (read-line port)
353                            headers)
354                      (loop line (read-line port)
355                            (parse-header-line prev-line headers)))))))))
356
357(define (signal-http-condition msg type . more-info)
358  (signal (make-composite-condition
359           (make-property-condition 'http)
360           (apply make-property-condition type more-info)
361           (make-property-condition 'exn 'message msg))))
362
363(defstruct request
364  (method 'GET) uri (major 1) (minor 1) (headers (make-headers '())) port)
365
366;; Perhaps we should have header parsers indexed by version or
367;; something like that, so you can define the maximum version. Useful
368;; for when expecting a response. Then we group request/response parsers
369;; together, as with request/response unparsers.
370(define (http-0.9-request-parser line in)
371  (regex-case line
372    ("[Gg][Ee][Tt] +([^ \t]+)"
373     (_ uri)
374     (make-request method: 'GET uri: (normalized-uri uri)
375                   major: 0 minor: 9
376                   port: in))
377    (else #f)))
378
379;; XXX This actually parses anything >= HTTP/1.0
380(define (http-1.x-request-parser line in)
381  (regex-case line
382   ("([a-zA-Z]+) +([^ \t]+) +[Hh][Tt][Tt][Pp]/([0-9]+)\\.([0-9]+)"
383    (_ method uri major minor)
384    (make-request method: (string->http-method method) uri: (normalized-uri uri)
385                  major: (string->number major)
386                  minor: (string->number minor)
387                  headers: (read-headers in)
388     port: in))
389   (else #f)))
390
391(define request-parsers   ; order matters here
392  (make-parameter (list http-1.x-request-parser http-0.9-request-parser)))
393
394(define (read-request inport)
395  (let* ((line (read-line inport (read-line-limit)))
396         ;; A bit ugly, but simpler than the alternatives
397         (line (if (eof-object? line) "" line)))
398    ;; Try each parser in turn to process the request-line.
399    ;; A parser returns either #f or a request object
400    (let loop ((parsers (request-parsers)))
401      (if (null? parsers)
402          (signal-http-condition "Unknown protocol" 'unknown-protocol-line
403                                 'line line)
404          (or ((car parsers) line inport) (loop (cdr parsers)))))))
405
406;;;;;;;;;;;;;;;;;;;;;;;;;;;
407;;;; Request unparsing ;;;;
408;;;;;;;;;;;;;;;;;;;;;;;;;;;
409
410(define header-unparsers
411  (make-parameter
412   `((etag . ,entity-tag-unparser)
413     (expires . ,rfc1123-unparser)
414     (host . ,host/port-unparser)
415     (if-modified-since . ,rfc1123-unparser)
416     (if-unmodified-since . ,rfc1123-unparser)
417     (last-modified . ,rfc1123-unparser)
418     (user-agent . ,product-unparser)
419     (server . ,product-unparser))))
420
421(define (unparse-header header-name header-value)
422  (let* ((def default-header-unparser)
423         (unparser (alist-ref header-name (header-unparsers) eq? def)))
424   (unparser header-name header-value)))
425
426(define (unparse-headers headers out)
427  (for-each
428     (lambda (h)
429       (let* ((name (car h))
430              (name-s (symbol->http-name name))
431              (contents (cdr h)))
432         (fprintf out "~A: ~A\r\n" name-s (unparse-header name contents))))
433     (headers-v headers)))
434
435(define (write-request-line request)
436  (fprintf (request-port request)
437           "~A ~A HTTP/~A.~A\r\n"
438           (http-method->string (request-method request))
439           (uri->string (request-uri request))
440           (request-major request)
441           (request-minor request)))
442
443(define (http-0.9-request-unparser request)
444  (fprintf (request-port request)
445           "GET ~A\r\n"
446           (uri->string (request-uri request)))
447  request)
448
449(define (http-1.0-request-unparser request)
450  (and-let* (((= (request-major request) 1))
451             ((= (request-minor request) 0))
452             (o (request-port request)))
453    (write-request-line request)
454    (unparse-headers (request-headers request) o)
455    (display "\r\n" o)
456    request))
457
458;; XXX This actually unparses anything >= HTTP/1.1
459(define (http-1.x-request-unparser request)
460  (and-let* (((or (> (request-major request) 1)
461                  (and (= (request-major request) 1)
462                       (> (request-minor request) 0))))
463             (o (request-port request)))
464    (write-request-line request)
465    (unparse-headers (request-headers request) o)
466    (display "\r\n" o)
467    (if (memq 'chunked (header-values 'transfer-encoding
468                                      (request-headers request)))
469        (update-request request
470                        port: (chunked-output-port (request-port request)))
471        request)))
472
473(define request-unparsers  ; order matters here
474  (make-parameter (list http-1.x-request-unparser
475                        http-1.0-request-unparser
476                        http-0.9-request-unparser)))
477
478(define (write-request request)
479  ;; Try each unparser in turn to write the request-line.
480  ;; An unparser returns either #f or a new request object.
481  (let loop ((unparsers (request-unparsers)))
482    (if (null? unparsers)
483        (signal-http-condition "Unknown protocol" 'unknown-protocol
484                               'major (request-major request)
485                               'minor (request-minor request))
486        (or ((car unparsers) request) (loop (cdr unparsers))))))
487
488;;;;;;;;;;;;;;;;;;;;;;;;;;;;
489;;;; Response unparsing ;;;;
490;;;;;;;;;;;;;;;;;;;;;;;;;;;;
491
492(defstruct response
493  (code 200) (reason "OK") (major 1) (minor 1) (headers (make-headers '())) port)
494
495(define (http-0.9-response-unparser response)
496  response) ;; The response-body will just follow
497
498(define (write-response-line response)
499  (fprintf (response-port response)
500           "HTTP/~A.~A ~A ~A\r\n"
501           (response-major response)
502           (response-minor response)
503           (response-code response)
504           (response-reason response)))
505
506(define (http-1.0-response-unparser response)
507  (and-let* (((= (response-major response) 1))
508             ((= (response-minor response) 0))
509             (o (response-port response)))
510    (write-response-line response)
511    (unparse-headers (response-headers response) o)
512    (display "\r\n" o)
513    response))
514
515;; XXX This actually unparses anything >= HTTP/1.1
516(define (http-1.x-response-unparser response)
517  (and-let* (((or (> (response-major response) 1)
518                  (and (= (response-major response) 1)
519                       (> (response-minor response) 0))))
520             (o (response-port response)))
521    (write-response-line response)
522    (unparse-headers (response-headers response) o)
523    (display "\r\n" o)
524    (if (memq 'chunked (header-values 'transfer-encoding
525                                      (response-headers response)))
526        (update-response response
527                         port: (chunked-output-port (response-port response)))
528        response)))
529
530(define response-unparsers
531  (make-parameter (list http-1.x-response-unparser
532                        http-1.0-response-unparser
533                        http-0.9-response-unparser)))
534
535(define (write-response response)
536  ;; Try each unparser in turn to write the response-line.
537  ;; An unparser returns either #f or a new response object.
538  (let loop ((unparsers (response-unparsers)))
539    (if (null? unparsers)
540        (signal-http-condition "Unknown protocol" 'unknown-protocol
541                               'major (response-major response)
542                               'minor (response-minor response))
543        (or ((car unparsers) response) (loop (cdr unparsers))))))
544
545;;;;;;;;;;;;;;;;;;;;;;;;;;
546;;;; Response parsing ;;;;
547;;;;;;;;;;;;;;;;;;;;;;;;;;
548
549;; I don't like this code. Clean it up!
550(define (http-1.x-response-parser line in)
551  (regex-case line
552    ("[Hh][Tt][Tt][Pp]/([0-9]+)\\.([0-9]+) +([0-9]+) +(.*)"
553     (_ major minor code reason)
554     (let ((major (string->number major))
555           (minor (string->number minor)))
556      (and (or (> major 1)
557               (and (= major 1)
558                    (> minor 0)))
559           (let ((response (make-response code: (string->number code)
560                                          reason: reason
561                                          major: major
562                                          minor: minor
563                                          headers: (read-headers in)
564                                          port: in)))
565             (if (memq 'chunked (header-values 'transfer-encoding
566                                               (response-headers response)))
567                 (update-response response
568                                  port: (chunked-input-port
569                                         (response-port response)))
570                 response)))))
571    (else #f)))
572
573(define (http-1.0-response-parser line in)
574  (regex-case line
575    ("[Hh][Tt][Tt][Pp]/1\\.0 +([0-9]+) +(.*)"
576     (_ code reason)
577     (let ((response (make-response code: (string->number code) reason: reason
578                                    major: 1 minor: 0
579                                    headers: (read-headers in)
580                                    port: in)))
581       response))
582    (else #f)))
583
584;; You can't "detect" a 0.9 response, because there is no response line.
585;; It will simply output the body directly, so we will just assume that
586;; if we can't recognise the output string, we just got a 0.9 response.
587;; If this is not desired, just change response-parsers to exclude this one.
588(define (http-0.9-response-parser line in)
589  (make-response code: 200 reason: "OK"
590                 major: 0 minor: 9
591                 ;; XXX This is wrong, it re-inserts \r\n, while it may have
592                 ;; been a \n only. To work around this, we'd have to write
593                 ;; a custom read-line procedure.
594                 ;; However, it does not matter much because HTTP 0.9 is only
595                 ;; defined to ever return text/html, no binary or any other
596                 ;; content type.
597                 port: (call-with-input-string (string-append line "\r\n")
598                         (lambda (str)
599                           (make-concatenated-port str in)))))
600
601(define response-parsers ;; order matters here
602  (make-parameter (list http-1.x-response-parser http-1.0-response-parser http-0.9-response-parser)))
603
604(define (read-response inport)
605  (let* ((line (read-line inport (read-line-limit)))
606         (line (if (eof-object? line) "" line)))
607    (let loop ((parsers (response-parsers)))
608      (if (null? parsers)
609          (signal-http-condition "Unknown protocol" 'unknown-protocol-line
610                                 'line line)
611          (or ((car parsers) line inport) (loop (cdr parsers)))))))
612
613)
Note: See TracBrowser for help on using the repository browser.