source: project/release/4/intarweb/trunk/header-parsers.scm @ 11947

;; Change the accuracy of a number to 'digits' number of digits to the
;; right of the decimal point.
(define (chop-number num digits)
  (let ((factor (expt 10 digits)))
    (/ (round (* num factor)) factor)))

(define (quality-parser str)
  ;; Anything that's not a number is seen as if the value is missing, hence 1.0
  (let* ((num       (or (string->number str) 1.0))
         (imprecise (chop-number num 3)))
    (max 0.0 (min 1.0 imprecise))))

;; TODO: Make this use SRFI-19
(define (rfc822-time-parser str)
  0)

;; Get the raw contents of a header
(define (header-contents name headers #!optional (default #f))
  (alist-ref name (headers-v headers) eq? default))

;; Get all values of a header
(define (header-values header-name headers)
  (map (cut vector-ref <> 0) (header-contents header-name headers '())))

;; Get the value of a header which is an alist
;; Example: header = ((foo . bar) (qux . mooh)), header-list-ref foo
;; will return bar.  (the header itself is encoded in a param+value
(define (header-list-ref value headers #!optional (equal? eq?))
  (find (lambda (h) (equal? (car (get-value h)) value)) headers))

;; Get the value from one header entry
(define get-value (cut vector-ref <> 0))

;; Get all params from one header entry
(define get-params (cut vector-ref <> 1))

;; Get one specific parameter from one header entry
(define (get-param param contents)
  (alist-ref param (vector-ref contents 1) eq?))

;; Get-param, except if no quality is present return 1
(define (get-quality header-contents)
  (or (get-param 'q header-contents) 1.0))

;;;; Header parsers

;; Find a matching endpoint for a token, ignoring escaped copies of the token
(define (escaped-string-end str start stop-char-set)
  (let ((len (string-length str)))
    (let loop ((start start))
      (let ((pos (string-index str (char-set-adjoin stop-char-set #\\) start)))
        (if pos
            (if (char=? #\\ (string-ref str pos))
                ;; Escaped matching closing symbol
                (if (= len (add1 pos))
                    pos
                    (loop (+ pos 2)))
                ;; Reached the matching closing symbol
                pos)
            len))))) ; No matching closing symbol?  "Insert" it at the end

;; RFC 2616 4.2 says multi-headers are a comma-separated list of tokens
(define (split-multi-header value)
  (let ((len (string-length value)))
    (let loop ((result '())
               (start-pos 0)   ; Where the current header value starts
               (search-pos 0)) ; Where the searching starts
      (or (and-let* (((< search-pos len))
                     (pos (string-index value (char-set #\, #\") search-pos)))
            (if (char=? #\, (string-ref value pos))
                (loop (cons (string-copy value start-pos pos) result) (add1 pos) (add1 pos))
                (let ((end-pos (escaped-string-end value (add1 pos) (char-set #\"))))
                  (loop result start-pos (add1 end-pos)))))
          (reverse (cons (string-drop value start-pos) result))))))

;; Remove all escape characters from the input, recognising "escaped escapes"
(define (unescape str)
  (let ((last-char (sub1 (string-length str))))
    (let loop ((result "")
               (start-pos 0))
      (or (and-let* ((pos (string-index str #\\ start-pos)))
            (if (= pos last-char)
                (string-append result (string-copy str start-pos))
                (loop (string-append result (string-copy str start-pos pos)
                                     (string-copy str (add1 pos) (+ pos 2)))
                      (+ pos 2))))
          (string-append result (string-copy str start-pos))))))

;; Try to parse a token, starting at the provided offset, up until the
;; char-set where we should stop.  Returns two values: the token or #f if
;; there is no token left, and the position on which the token ends.
(define (parse-token value start-pos stop-char-set)
  (if (>= start-pos (string-length value))
      (values #f start-pos)
      (let ((stop (char-set-adjoin stop-char-set #\")))
        (let ((pos (string-index value stop start-pos)))
          (if pos
              (if (not (char=? #\" (string-ref value pos)))
                  (values (string-trim-both (string-copy value start-pos pos))
                          pos) ; Stop-char found, but no quoting
                  (let ((end-pos (escaped-string-end value (add1 pos)
                                                     (char-set #\"))))
                    ;; Found the double quote? Recurse on the remainder
                    (receive (rest final-pos)
                      (parse-token value (add1 end-pos) stop-char-set)
                      (values (string-append
                               (string-trim-both
                                (string-copy value start-pos pos))
                               (if (= pos end-pos)
                                   (unescape (string-copy value (add1 pos)))
                                   (unescape (string-copy value (add1 pos) end-pos)))
                               (or rest ""))
                              final-pos))))
              ;; Nothing found?  Then the remainder of the string is the token
              (values (string-trim-both (string-copy value start-pos))
                      (string-length value)))))))

;; Just put all header strings in a list, so we can pass it on
;; Make no assumptions about the contents (only value, don't try to parse params)
;; This is different from (multiple (without-params generic-header-parser))
;; because this does not assume it can split up comma-separated values
(define (unknown-header-parser name contents headers)
  (update-header-contents! name (list (vector contents '())) headers))

(define (parse-parameters string start-pos param-parsers)
  (let loop ((start-pos start-pos)
             (params '()))
    (receive (key pos)
      (parse-token string start-pos (char-set #\; #\=))
      (if key
          (if (and (< pos (string-length string)) (char=? (string-ref string pos) #\=))
              (receive (value pos)
                (parse-token string (add1 pos) (char-set #\;))
                (let ((key (string->symbol (string-downcase key))))
                  ;; In case of no value ("foo="), use the empty string as value
                  (let ((value ((alist-ref key param-parsers eq? identity) (or value ""))))
                    (loop (add1 pos) (cons (cons key value) params)))))
              ;; Missing value is interpreted as "present",
              ;; so #t. If not present, it's #f when looking it up
              (loop (add1 pos) (cons (cons (string->symbol key) #t) params)))
          (values (reverse params) pos)))))

(define (parse-value+parameters string start-pos value-parser param-parsers)
  (receive (value pos)
    (parse-token string start-pos (char-set #\;))
    (if (not value)
        (values #f pos) ;; XXX this is wrong and not expected by the caller!
        (receive (params pos)
          (parse-parameters string (add1 pos) param-parsers)
          (values (vector (value-parser value) params) pos)))))

(define (with-params value-parser parameter-parsers)
  (lambda (entry)
    (receive (type+params pos)
      (parse-value+parameters entry 0 value-parser parameter-parsers)
      type+params)))

(define (multiple other-parser #!optional (parameter-parsers '()))
  (lambda (name entries headers)
    (fold (lambda (entry headers)
            (update-header-contents!
             name
             (list ((with-params other-parser parameter-parsers) entry))
             headers))
          headers
          (split-multi-header entries))))

(define (single other-parser #!optional (parameter-parsers '()))
  (lambda (name contents headers)
    (replace-header-contents!
     name
     (list ((with-params other-parser parameter-parsers) contents))
     headers)))

(define (key/values key/value-parsers)
  (lambda (k/v)
    ;; We're abusing parse-parameters here to read value
    ;; instead of params.  This is weird, but it works :)
    (receive (key+value pos)
      (parse-parameters k/v 0 key/value-parsers)
      (car key+value))))

(define symbol-parser-ci
  (compose string->symbol string-trim-both string-downcase))

(define symbol-parser
  (compose string->symbol string-trim-both))

(define (natnum-parser contents)
  (let ((num (string->number contents)))
    (if num (inexact->exact (max 0 (round num))) 0)))

(define (host-parser contents)
  (let ((idx (string-index-right contents #\:)))
    (if idx
        (cons (substring/shared contents 0 idx)
              (inexact->exact
               (round (or (string->number (substring/shared contents (add1 idx)))
                          80))))
        (cons contents 80))))

; base64 of 128 bit hex digest as per RFC1864
(define md5-parser base64:decode)

;; bytes <start>-<end>/<total>
(define (range-parser s)
  (and-let* ((parts (string-match "bytes[ \t]+([0-9]+)-([0-9]+)/([0-9]+)" s)))
            (map string->number (drop parts 1))))

;; rfc1123-date | rfc850-date | asctime-date
(define http-time-parser rfc822-time-parser)

;; (W/)<string>
(define (entity-tag-parser name contents headers)
  (let ((contents (string-trim-both contents)))
    (replace-header-contents!
     name
     (list (if (string-prefix? "W/" contents)
               (vector `(weak . ,(parse-token contents 2 (char-set))) '())
               (vector `(strong . ,(parse-token contents 0 (char-set))) '())))
     headers)))

;;;; MAJOR TODOs
;; RFC822/1123 mailbox parser - just strings for now
(define mailbox-parser identity)

;; Either an entity-tag or a http-date
(define if-range-parser identity)

;; Either delta-seconds or RFC822 timestamp
(define (retry-after-parser contents)
  (if (string-match "[ \t]*[0-9]+[ \t]*" contents)
      (natnum-parser contents)
      (rfc822-time-parser contents)))

;; Tricky - see 2616 14.45
;; We probably shouldn't try to do too much parsing here
(define via-parser (multiple identity))

;; Tricky - see 2616 14.46
(define warning-parser (multiple identity))
;;;; END MAJOR TODOs

(define (key/value-parser str)
  (let ((idx (string-index str #\=)))
    (cons (string-take str idx) (string-drop str (add1 idx)))))

;; The 'expires' header defined by the Netscape cookie spec contains
;; an embedded comma.  RFC 2109 cookies use Max-Age instead.
(define (old-style-cookie? cookie)
  (not (not (string-search (regexp "^[^=\"]+=[^;]*;.*expires[[:space:]]*=" #f) cookie))))

(define set-cookie-parser
  (let ((param-parsers `((expires . ,rfc822-time-parser)
                         (max-age . ,string->number)
                         (version . ,string->number))))
    (lambda (name contents headers)
      (if (old-style-cookie? contents)
          (update-header-contents!
           name
           (list ((with-params key/value-parser param-parsers) contents))
           headers)
          ((multiple key/value-parser param-parsers) name contents headers)))))

(define cache-control-parser
  (let ((splitter (lambda (str) ;; Is this correct?
                    (map (compose string->symbol string-trim-both)
                         (string-split str ",")))))
    (multiple
     (key/values `((max-age . ,natnum-parser)
                   (s-maxage . ,natnum-parser)
                   (max-stale . ,natnum-parser)
                   (min-fresh . ,natnum-parser)
                   (private . ,splitter)
                   (no-cache . ,splitter))))))

;; This too
(define (pragma-parser name value headers)
  (update-header-contents! name (parse-parameters value 0 `()) headers))

;; This one includes q parser
(define (te-parser name value headers)
  (update-header-contents! name (parse-parameters value 0 `((q . ,quality-parser))) headers))

;; Cookie headers are also braindead: there can be several cookies in one header,
;; separated by either commas or semicolons. The only way to distinguish a
;; new cookie from a parameter of the current cookie is the dollar in front
;; of all parameter names.
;; Also, there's a $Version attribute that prepends all cookies, which is
;; considered to apply to all cookies that follow.
;;
;; This code is a bit of a hack in the way it abuses parse-parameters
(define (cookie-parser name value headers)
  ;; Get all attributes (dollar-prefixed params) and remaining cookies & params
  (define (split-attribs pairs)
    (span (lambda (pair)
            (string-prefix? "$" (symbol->string (car pair))))
          pairs))
  (receive (params pos)
    (parse-parameters value 0 `(($version . ,string->number)
                               ($port . ,string->number)))
    (receive (global-attrs remaining)
      (split-attribs params)
      (let loop ((remaining remaining)
                 (cookies '()))
        (if (null? remaining)
            (update-header-contents! name (reverse cookies) headers)
            (let ((cookie (cons (symbol->string (caar remaining))
                                (cdar remaining)))
                  (params (cdr remaining)))
              (receive (local-attrs rest)
                (split-attribs params)
                (let* ((all-attrs (append global-attrs local-attrs))
                       (result (vector cookie all-attrs)))
                  (loop rest (cons result cookies))))))))))

;;; Unparsers ;;;
(define (unparse-params params unparsers)
  (let loop ((params params)
             (results '()))
    (if (null? params)
        (string-join (reverse results) "; " 'prefix)
        (let* ((unparser (alist-ref unparsers (caar params) eq?
                                    (lambda (name value)
                                      (case value
                                        ;; #t means param is present (no value)
                                        ((#t) (->string name))
                                        ;; #f means param is missing
                                        ((#f) #f)
                                        (else (conc name "=" value))))))
               (str (unparser (caar params) (cdar params))))
          (loop (cdr params) (if str (cons str results) results))))))

(define must-be-quoted-chars (char-set-adjoin char-set:iso-control #\"))

(define quote-string
  (let ((smap (map (lambda (c)
                     (cons (string c)
                           (string-append "\\" (string c))))
                   (char-set->list must-be-quoted-chars))))
    (lambda (string)
      (let ((error-chars (char-set #\newline)))
        (if (string-any error-chars string)
            (signal-http-condition "Unencoded newline in header contents! Please encode the newline in a way appropriate for this header"
                                   'unencoded-header 'value string)
            (string-append "\"" (string-translate* string smap) "\""))))))

(define unparse-token
  (let* ((trigger-quoting-chars (char-set-union
                                 (char-set-adjoin must-be-quoted-chars #\, #\; #\=)
                                 char-set:blank)))
   (lambda (token)
     (if (string-any trigger-quoting-chars token)
         (quote-string token)
         token))))

;; There's no need to make a specific header unparser for every header type.
;; Usually, the Scheme value representing a header can unambiguously be
;; unparsed into a header just by checking its type.
(define (default-header-unparser header-name header-contents)
  (let loop ((headers (reverse header-contents))
             (result '()))
    (if (null? headers)
        (sprintf "~A: ~A\r\n"
                 (header-name->string header-name)
                 (string-join result ", "))
        (let* ((contents (get-value (car headers)))
               (value (cond
                       ((pair? contents) ; alist?
                        (if (eq? (cdr contents) #t)
                            (unparse-token (->string (car contents)))
                            (conc (unparse-token (->string (car contents))) "="
                                  (unparse-token (->string (cdr contents))))))
                       ((uri? contents) (unparse-token (uri->string contents)))
                       (else (unparse-token (->string contents)))))
               (parameter-unparsers '())) ; Maybe we want to make this a param
         (loop (cdr headers)
               (cons
                (string-append
                 value
                 (unparse-params (get-params (car headers))
                                 parameter-unparsers))
                result))))))

(define (etag-unparser header-name header-contents)
  (let ((contents (get-value (car header-contents))))
   (sprintf "~A: ~A\r\n"
            (header-name->string header-name)
            (string-append
             (if (eq? 'weak (car contents)) "W/" "")
             (if (string-prefix? "W/" (cdr contents))
                 (quote-string (cdr contents))
                 (unparse-token (cdr contents)))))))

(define (host-unparser header-name header-contents)
  (let ((contents (get-value (car header-contents))))
   ;; XXX: urlencode?
   (sprintf "~A: ~A\r\n"
            (header-name->string header-name)
            (if (= (cdr contents) 80)
                (car contents)
                (conc (car contents) ":" (cdr contents))))))