source: project/release/4/http-client/trunk/http-client.scm @ 15114

Last change on this file since 15114 was 15114, checked in by sjamaan, 11 years ago

Get rid of weird remove-connection! procedure

File size: 16.0 KB
Line 
1;;
2;; Convenient HTTP client library
3;;
4; Copyright (c) 2009, Peter Bex
5; Parts copyright (c) 2000-2004, Felix L. Winkelmann
6; All rights reserved.
7;
8; Redistribution and use in source and binary forms, with or without
9; modification, are permitted provided that the following conditions
10; are met:
11;
12; 1. Redistributions of source code must retain the above copyright
13;    notice, this list of conditions and the following disclaimer.
14; 2. Redistributions in binary form must reproduce the above copyright
15;    notice, this list of conditions and the following disclaimer in the
16;    documentation and/or other materials provided with the distribution.
17; 3. Neither the name of the author nor the names of its
18;    contributors may be used to endorse or promote products derived
19;    from this software without specific prior written permission.
20;
21; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
24; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
25; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
26; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
27; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
28; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
30; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
31; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
32; OF THE POSSIBILITY OF SUCH DAMAGE.
33
34(module http-client
35  (max-retry-attempts max-redirect-depth retry-request? client-software
36   close-connection! close-all-connections!
37   call-with-input-request with-input-from-request call-with-response)
38
39(import chicken scheme)
40(use srfi-1 srfi-13 srfi-18 srfi-69
41     ports extras tcp data-structures
42     openssl intarweb uri-common)
43
44;; TODO: Add cookie management API to export list
45
46(define-record http-connection base-uri inport outport)
47
48(define max-retry-attempts (make-parameter 1))
49(define max-redirect-depth (make-parameter 5))
50
51(define retry-request? (make-parameter idempotent?))
52
53(define client-software
54  (make-parameter (list (list "Chicken Scheme HTTP-client" "0.1" #f))))
55
56;; TODO: find a smarter storage mechanism
57(define cookie-jar (list))
58
59(define connections
60  (make-parameter (make-hash-table
61                   (lambda (a b)
62                     (and (equal? (uri-port a) (uri-port b))
63                          (equal? (uri-host a) (uri-host b))))
64                   (lambda (uri . maybe-bound)
65                     (apply string-hash
66                            (sprintf "~S ~S" (uri-host uri) (uri-port uri))
67                            maybe-bound)))))
68
69(define connections-owner
70  (make-parameter (current-thread)))
71
72(define (ensure-local-connections)
73  (unless (eq? (connections-owner) (current-thread))
74    (connections (make-hash-table equal?))
75    (connections-owner (current-thread))))
76
77(define (port-closed? p)
78  (##sys#check-port p 'port-closed?)
79  (##sys#slot p 8))
80
81(define (get-connection uri)
82  (ensure-local-connections)
83  (and-let* ((con (hash-table-ref/default (connections) uri #f)))
84    (if (or (port-closed? (http-connection-inport con))
85            (port-closed? (http-connection-outport con)))
86        (begin (close-connection! uri) #f)
87        con)))
88
89(define (add-connection! uri con)
90  (ensure-local-connections)
91  (hash-table-set! (connections) uri con))
92
93(define (close-connection! uri-or-con)
94  (ensure-local-connections)
95  (and-let* ((con (if (http-connection? uri-or-con)
96                      uri-or-con
97                      (hash-table-ref/default (connections) uri-or-con #f))))
98    (close-input-port (http-connection-inport con))
99    (close-output-port (http-connection-outport con))
100    (hash-table-delete! (connections) (http-connection-base-uri con))))
101
102(define (close-all-connections!)
103  (ensure-local-connections)
104  (hash-table-walk
105   (connections)
106   (lambda (uri con)
107     (hash-table-delete! (connections) uri)
108     (close-input-port (http-connection-inport con))
109     (close-output-port (http-connection-outport con)))))
110
111(define (ensure-connection! uri)
112  (or (get-connection uri)
113      (receive (in out)
114        (case (uri-scheme uri)
115          ((#f http) (tcp-connect (uri-host uri) (uri-port uri)))
116          ((https) (ssl-connect (uri-host uri) (uri-port uri)))
117          (else (error "Unknown URI scheme" (uri-scheme uri))))
118        (let ((con (make-http-connection uri in out)))
119          (add-connection! uri con)
120          con))))
121
122(define (make-delimited-input-port port len)
123  (if (not len)
124      port ;; no need to delimit anything
125      (let ((pos 0))
126        (make-input-port (lambda () ; read
127                           (if (= pos len)
128                               #!eof
129                               (let ((char (read-char port)))
130                                 (set! pos (add1 pos))
131                                 char)))
132                         (lambda () ; char-ready?
133                           (if (= pos len)
134                               #f
135                               (char-ready? port)))
136                         (lambda () ; close
137                           (close-input-port port))))))
138
139(define (read-response-data response)
140  (let ((len (header-value 'content-length (response-headers response))))
141    ;; If the header is not available, this will read until EOF
142    (read-string len (response-port response))))
143
144(define (add-headers req)
145  (let* ((uri (request-uri req))
146         (cookies (get-cookies-for-uri (request-uri req)))
147         (h `(,@(if (not (null? cookies)) `((cookie . ,cookies)) '())
148              (host ,(cons (uri-host uri) (uri-port uri)))
149              (user-agent ,(client-software)))))
150    (update-request req headers: (headers h (request-headers req)))))
151
152(define (http-client-error loc msg specific . rest)
153  (raise (make-composite-condition
154          (make-property-condition 'exn 'location loc 'message msg)
155          (apply make-property-condition specific rest))))
156
157;; RFC 2965, section 3.3.3
158(define (cookie-eq? a b)
159  (let ((ref (lambda (cookie attr) (get-param attr cookie ""))))
160    (and (eq?         (car (get-value a)) (car (get-value b)))
161         (string-ci=? (ref a 'domain)     (ref b 'domain))
162         (string=?    (ref a 'path)       (ref b 'path)))))
163
164(define (store-cookie! cookie)
165  (let loop ((jar cookie-jar))
166    (cond
167     ((null? jar) (set! cookie-jar (cons cookie cookie-jar)) cookie-jar)
168     ((cookie-eq? cookie (car jar))
169      (set-car! jar cookie)
170      cookie-jar)
171     (else (loop (cdr jar))))))
172
173(define (domain-match? uri pattern)
174  (let ((target (uri-host uri)))
175    (or (string-ci=? target pattern)
176        (and (string-prefix? "." pattern)
177             (string-suffix-ci? pattern target)))))
178
179;; Things might be simpler if we used path list representation...
180(define (path-match? uri path)
181  (and (uri-path-absolute? uri)
182       (let loop ((path (cdr (string-split path "/" #t)))
183                  (uri-path (cdr (uri-path uri))))
184         (or (null? path)               ; done
185             (and (not (null? uri-path))
186                  (or (and (string-null? (car path)) (null? (cdr path)))
187
188                      (and (string=? (car path) (car uri-path))
189                           (loop (cdr path) (cdr uri-path)))))))))
190
191(define (get-cookies-for-uri uri)
192  (sort!
193   (filter (lambda (c)
194             (and (domain-match? uri (get-param 'domain c))
195                  (member (uri-port uri)
196                          (get-param 'port c (list (uri-port uri))))
197                  (path-match? uri (get-param 'path c))
198                  (if (get-param 'secure c)
199                      (member (uri-scheme uri) '(https shttp))
200                      #t)))
201           cookie-jar)
202   (lambda (a b)
203     (< (string-length (get-param 'path a))
204        (string-length (get-param 'path b))))))
205
206(define (process-set-cookie! con uri r)
207  (let ((prefix-contains-dots?
208         (lambda (host pattern)
209           (string-index host #\. 0 (string-contains-ci host pattern)))))
210    (for-each (lambda (c)
211                (and-let* (((path-match? uri (get-param 'path c)))
212                           ;; really, path should be in separated form!
213                           (path (get-param 'path c (string-join (cdr (uri-path uri)) "/")))
214                           ;; domain must start with dot. Add to intarweb!
215                           (dn (get-param 'domain c (uri-host uri)))
216                           (idx (string-index dn #\.))
217                           ((domain-match? uri dn))
218                           ((not (prefix-contains-dots? (uri-host uri) dn))))
219                  ;; Store only the cookie values we understand
220                  ;; and make it a Cookie: header.
221                  (store-cookie! (vector (get-value c)
222                                         `((version . ,(get-param 'version c))
223                                           (path . ,path)
224                                           (domain . ,dn))))))
225              (header-contents 'set-cookie (response-headers r) '()))
226    (for-each (lambda (c)
227                (and-let* (((get-param 'version c)) ; required for set-cookie2
228                           (path (get-param 'path c (string-join (cdr (uri-path uri)) "/")))
229                           ((path-match? uri (get-param 'path c)))
230                           (dn (get-param 'domain c (uri-host uri)))
231                           ((or (string-ci=? dn ".local")
232                                (and (not (string-null? dn))
233                                     (string-index dn #\. 1))))
234                           ((domain-match? uri dn))
235                           ((not (prefix-contains-dots? (uri-host uri) dn)))
236                           ;; This is a little bit too messy for my tastes...
237                           ;; Can't use #f because that would shortcut and-let*
238                           (ports-value (get-param 'port c 'any))
239                           (ports (if (eq? ports-value #t)
240                                      (list (uri-port uri))
241                                      ports-value))
242                           ((or (eq? ports 'any)
243                                (member (uri-port uri) ports))))
244                  ;; Store only the cookie values we understand
245                  ;; and make it a Cookie: header.
246                  (store-cookie! (vector (get-value c)
247                                         `((version . ,(get-param 'version c))
248                                           (path . ,path)
249                                           (domain . ,dn)
250                                           (port . ,(if (eq? ports 'any)
251                                                        #f
252                                                        ports)))))))
253              (header-contents 'set-cookie2 (response-headers r) '()))))
254
255(define (call-with-response req writer reader)
256  (let loop ((attempts 0)
257             (redirects 0)
258             (uri (request-uri req)))
259    (condition-case
260     (let* ((con (ensure-connection! uri))
261            (req (add-headers (update-request
262                               req port: (http-connection-outport con)
263                               uri: uri)))
264            (request (write-request req))
265            ;; Writer should be prepared to be called several times
266            ;; Maybe try and figure out a good way to use the
267            ;; "Expect: 100-continue" header to prevent too much writing?
268            ;; Unfortunately RFC2616 says it's unreliable (8.2.3)...
269            (_ (writer request))
270            (response (read-response (http-connection-inport con)))
271            (cleanup! (lambda ()
272                        (unless (and (keep-alive? request)
273                                     (keep-alive? response))
274                          (close-connection! con)))))
275       (process-set-cookie! con uri response)
276       (cond
277        ;; TODO: According to spec, we should provide the user with a choice
278        ;; when it's not a GET or HEAD request...
279        ((member (response-code response) '(301 302 303 307))
280         ;; Clear out data, throwing it away
281         (read-response-data response)
282         (cleanup!)
283         ;; Maybe we should switch to GET on 302 too?  It's not compliant,
284         ;; but very widespread and there's enough software that depends
285         ;; on that behaviour, which might break horribly otherwise...
286         (when (= (response-code response) 303)
287           (request-method-set! request 'GET)) ; Switch to GET
288         (let ((new-uri (header-value 'location (response-headers response))))
289           (if (or (not (max-redirect-depth)) ; unlimited?
290                   (<= redirects (max-redirect-depth)))
291               (loop attempts
292                     (add1 redirects)
293                     (uri-relative-to new-uri uri))
294               (http-client-error 'send-request
295                                  "Maximum number of redirects exceeded"
296                                  'redirect-depth-exceeded
297                                  'uri new-uri))))
298        (else (let ((data (reader response)))
299                (cleanup!)
300                (values data (request-uri req) response)))))
301     (exn (exn i/o net)
302          (close-connection! uri)
303          (if (and (or (not (max-retry-attempts)) ; unlimited?
304                       (<= attempts (max-retry-attempts)))
305                   ((retry-request?) req))
306              (loop (add1 attempts) redirects uri)
307              (signal exn)))
308     (exn ()
309          ;; Never leave the port in an unknown/inconsistent state
310          ;; (the error could have occurred while reading, so there
311          ;;  might be data left in the buffer)
312          (close-connection! uri)
313          (raise exn)))))
314
315(define (call-with-input-request uri-or-request writer reader)
316  ;; "writer" is an alist to be encoded as form?
317  (let* ((postdata (and (list? writer) (form-urlencode writer separator: "&")))
318         (writer (if writer
319                     (if postdata
320                         (lambda (p)
321                           (display postdata p)
322                           (close-output-port p))
323                         writer)
324                     (lambda x (void))))
325         (uri (cond ((uri? uri-or-request) uri-or-request)
326                    ((string? uri-or-request) (uri-reference uri-or-request))
327                    (else (request-uri uri-or-request))))
328         (req (if (request? uri-or-request) uri-or-request (make-request)))
329         (req (if postdata
330                  (update-request
331                   req
332                   headers: (headers
333                             `((content-length ,(string-length postdata)))
334                             (request-headers req)))
335                  req)))
336    (call-with-response
337     req
338     (lambda (request)
339       (let ((port (request-port request)))
340         (writer port)))
341     (lambda (response)
342       (let ((port (make-delimited-input-port
343                    (response-port response)
344                    (header-value 'content-length (response-headers response)))))
345         (if (= 200 (response-class response)) ; Everything cool?
346             (reader port)
347             (http-client-error
348              'call-with-input-request
349              ;; Message
350              (sprintf (case (response-class response)
351                         ((400) "Client error: ~A ~A")
352                         ((500) "Server error: ~A ~A")
353                         (else "Unexpected server response: ~A ~A"))
354                       (response-code response) (response-reason response))
355              ;; Specific type
356              (case (response-class response)
357                ((400) 'client-error)
358                ((500) 'server-error)
359                (else 'unexpected-server-response))
360              'response response
361              'body (read-string #f port))))))))
362
363(define (with-input-from-request uri-or-request writer reader)
364  (call-with-input-request uri-or-request
365                           (if (procedure? writer)
366                               (lambda (p) (with-output-to-port p writer))
367                               writer) ;; Assume it's an alist
368                           (lambda (p) (with-input-from-port p reader))))
369
370)
Note: See TracBrowser for help on using the repository browser.