source: project/release/4/http-client/trunk/http-client.scm @ 15113

Last change on this file since 15113 was 15113, checked in by sjamaan, 11 years ago

Add note about TODO

File size: 16.2 KB
Line 
1;;
2;; Convenient HTTP client library
3;;
4; Copyright (c) 2009, Peter Bex
5; Parts copyright (c) 2000-2004, Felix L. Winkelmann
6; All rights reserved.
7;
8; Redistribution and use in source and binary forms, with or without
9; modification, are permitted provided that the following conditions
10; are met:
11;
12; 1. Redistributions of source code must retain the above copyright
13;    notice, this list of conditions and the following disclaimer.
14; 2. Redistributions in binary form must reproduce the above copyright
15;    notice, this list of conditions and the following disclaimer in the
16;    documentation and/or other materials provided with the distribution.
17; 3. Neither the name of the author nor the names of its
18;    contributors may be used to endorse or promote products derived
19;    from this software without specific prior written permission.
20;
21; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
24; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
25; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
26; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
27; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
28; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
30; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
31; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
32; OF THE POSSIBILITY OF SUCH DAMAGE.
33
34(module http-client
35  (max-retry-attempts max-redirect-depth retry-request? client-software
36   remove-connection! close-connection! close-all-connections!
37   call-with-input-request with-input-from-request call-with-response)
38
39(import chicken scheme)
40(use srfi-1 srfi-13 srfi-18 srfi-69
41     ports extras tcp data-structures
42     openssl intarweb uri-common)
43
44;; TODO: Add cookie management API to export list
45
46(define-record http-connection base-uri inport outport)
47
48(define max-retry-attempts (make-parameter 1))
49(define max-redirect-depth (make-parameter 5))
50
51(define retry-request? (make-parameter idempotent?))
52
53(define client-software
54  (make-parameter (list (list "Chicken Scheme HTTP-client" "0.1" #f))))
55
56;; TODO: find a smarter storage mechanism
57(define cookie-jar (list))
58
59(define connections
60  (make-parameter (make-hash-table
61                   (lambda (a b)
62                     (and (equal? (uri-port a) (uri-port b))
63                          (equal? (uri-host a) (uri-host b))))
64                   (lambda (uri . maybe-bound)
65                     (apply string-hash
66                            (sprintf "~S ~S" (uri-host uri) (uri-port uri))
67                            maybe-bound)))))
68
69(define connections-owner
70  (make-parameter (current-thread)))
71
72(define (ensure-local-connections)
73  (unless (eq? (connections-owner) (current-thread))
74    (connections (make-hash-table equal?))
75    (connections-owner (current-thread))))
76
77(define (port-closed? p)
78  (##sys#check-port p 'port-closed?)
79  (##sys#slot p 8))
80
81(define (get-connection uri)
82  (ensure-local-connections)
83  (and-let* ((con (hash-table-ref/default (connections) uri #f)))
84    (if (or (port-closed? (http-connection-inport con))
85            (port-closed? (http-connection-outport con)))
86        (begin (close-connection! uri) #f)
87        con)))
88
89(define (add-connection! uri con)
90  (ensure-local-connections)
91  (hash-table-set! (connections) uri con))
92
93(define (remove-connection! uri-or-con)
94  ;; Ensure the connection is closed, then remove it from the hashtable
95  (let ((con (close-connection! uri-or-con)))
96    (hash-table-delete! (connections) (http-connection-base-uri con))))
97
98(define (close-connection! uri-or-con)
99  (ensure-local-connections)
100  (and-let* ((con (if (http-connection? uri-or-con)
101                      uri-or-con
102                      (hash-table-ref/default (connections) uri-or-con #f))))
103    (close-input-port (http-connection-inport con))
104    (close-output-port (http-connection-outport con))
105    con))
106
107(define (close-all-connections!)
108  (ensure-local-connections)
109  (hash-table-walk
110   (connections)
111   (lambda (uri con)
112     (hash-table-delete! (connections) uri)
113     (close-input-port (http-connection-inport con))
114     (close-output-port (http-connection-outport con)))))
115
116(define (ensure-connection! uri)
117  (or (get-connection uri)
118      (receive (in out)
119        (case (uri-scheme uri)
120          ((#f http) (tcp-connect (uri-host uri) (uri-port uri)))
121          ((https) (ssl-connect (uri-host uri) (uri-port uri)))
122          (else (error "Unknown URI scheme" (uri-scheme uri))))
123        (let ((con (make-http-connection uri in out)))
124          (add-connection! uri con)
125          con))))
126
127(define (make-delimited-input-port port len)
128  (if (not len)
129      port ;; no need to delimit anything
130      (let ((pos 0))
131        (make-input-port (lambda () ; read
132                           (if (= pos len)
133                               #!eof
134                               (let ((char (read-char port)))
135                                 (set! pos (add1 pos))
136                                 char)))
137                         (lambda () ; char-ready?
138                           (if (= pos len)
139                               #f
140                               (char-ready? port)))
141                         (lambda () ; close
142                           (close-input-port port))))))
143
144(define (read-response-data response)
145  (let ((len (header-value 'content-length (response-headers response))))
146    ;; If the header is not available, this will read until EOF
147    (read-string len (response-port response))))
148
149(define (add-headers req)
150  (let* ((uri (request-uri req))
151         (cookies (get-cookies-for-uri (request-uri req)))
152         (h `(,@(if (not (null? cookies)) `((cookie . ,cookies)) '())
153              (host ,(cons (uri-host uri) (uri-port uri)))
154              (user-agent ,(client-software)))))
155    (update-request req headers: (headers h (request-headers req)))))
156
157(define (http-client-error loc msg specific . rest)
158  (raise (make-composite-condition
159          (make-property-condition 'exn 'location loc 'message msg)
160          (apply make-property-condition specific rest))))
161
162;; RFC 2965, section 3.3.3
163(define (cookie-eq? a b)
164  (let ((ref (lambda (cookie attr) (get-param attr cookie ""))))
165    (and (eq?         (car (get-value a)) (car (get-value b)))
166         (string-ci=? (ref a 'domain)     (ref b 'domain))
167         (string=?    (ref a 'path)       (ref b 'path)))))
168
169(define (store-cookie! cookie)
170  (let loop ((jar cookie-jar))
171    (cond
172     ((null? jar) (set! cookie-jar (cons cookie cookie-jar)) cookie-jar)
173     ((cookie-eq? cookie (car jar))
174      (set-car! jar cookie)
175      cookie-jar)
176     (else (loop (cdr jar))))))
177
178(define (domain-match? uri pattern)
179  (let ((target (uri-host uri)))
180    (or (string-ci=? target pattern)
181        (and (string-prefix? "." pattern)
182             (string-suffix-ci? pattern target)))))
183
184;; Things might be simpler if we used path list representation...
185(define (path-match? uri path)
186  (and (uri-path-absolute? uri)
187       (let loop ((path (cdr (string-split path "/" #t)))
188                  (uri-path (cdr (uri-path uri))))
189         (or (null? path)               ; done
190             (and (not (null? uri-path))
191                  (or (and (string-null? (car path)) (null? (cdr path)))
192
193                      (and (string=? (car path) (car uri-path))
194                           (loop (cdr path) (cdr uri-path)))))))))
195
196(define (get-cookies-for-uri uri)
197  (sort!
198   (filter (lambda (c)
199             (and (domain-match? uri (get-param 'domain c))
200                  (member (uri-port uri)
201                          (get-param 'port c (list (uri-port uri))))
202                  (path-match? uri (get-param 'path c))
203                  (if (get-param 'secure c)
204                      (member (uri-scheme uri) '(https shttp))
205                      #t)))
206           cookie-jar)
207   (lambda (a b)
208     (< (string-length (get-param 'path a))
209        (string-length (get-param 'path b))))))
210
211(define (process-set-cookie! con uri r)
212  (let ((prefix-contains-dots?
213         (lambda (host pattern)
214           (string-index host #\. 0 (string-contains-ci host pattern)))))
215    (for-each (lambda (c)
216                (and-let* (((path-match? uri (get-param 'path c)))
217                           ;; really, path should be in separated form!
218                           (path (get-param 'path c (string-join (cdr (uri-path uri)) "/")))
219                           ;; domain must start with dot. Add to intarweb!
220                           (dn (get-param 'domain c (uri-host uri)))
221                           (idx (string-index dn #\.))
222                           ((domain-match? uri dn))
223                           ((not (prefix-contains-dots? (uri-host uri) dn))))
224                  ;; Store only the cookie values we understand
225                  ;; and make it a Cookie: header.
226                  (store-cookie! (vector (get-value c)
227                                         `((version . ,(get-param 'version c))
228                                           (path . ,path)
229                                           (domain . ,dn))))))
230              (header-contents 'set-cookie (response-headers r) '()))
231    (for-each (lambda (c)
232                (and-let* (((get-param 'version c)) ; required for set-cookie2
233                           (path (get-param 'path c (string-join (cdr (uri-path uri)) "/")))
234                           ((path-match? uri (get-param 'path c)))
235                           (dn (get-param 'domain c (uri-host uri)))
236                           ((or (string-ci=? dn ".local")
237                                (and (not (string-null? dn))
238                                     (string-index dn #\. 1))))
239                           ((domain-match? uri dn))
240                           ((not (prefix-contains-dots? (uri-host uri) dn)))
241                           ;; This is a little bit too messy for my tastes...
242                           ;; Can't use #f because that would shortcut and-let*
243                           (ports-value (get-param 'port c 'any))
244                           (ports (if (eq? ports-value #t)
245                                      (list (uri-port uri))
246                                      ports-value))
247                           ((or (eq? ports 'any)
248                                (member (uri-port uri) ports))))
249                  ;; Store only the cookie values we understand
250                  ;; and make it a Cookie: header.
251                  (store-cookie! (vector (get-value c)
252                                         `((version . ,(get-param 'version c))
253                                           (path . ,path)
254                                           (domain . ,dn)
255                                           (port . ,(if (eq? ports 'any)
256                                                        #f
257                                                        ports)))))))
258              (header-contents 'set-cookie2 (response-headers r) '()))))
259
260(define (call-with-response req writer reader)
261  (let loop ((attempts 0)
262             (redirects 0)
263             (uri (request-uri req)))
264    (condition-case
265     (let* ((con (ensure-connection! uri))
266            (req (add-headers (update-request
267                               req port: (http-connection-outport con)
268                               uri: uri)))
269            (request (write-request req))
270            ;; Writer should be prepared to be called several times
271            ;; Maybe try and figure out a good way to use the
272            ;; "Expect: 100-continue" header to prevent too much writing?
273            ;; Unfortunately RFC2616 says it's unreliable (8.2.3)...
274            (_ (writer request))
275            (response (read-response (http-connection-inport con)))
276            (cleanup! (lambda ()
277                        (unless (and (keep-alive? request)
278                                     (keep-alive? response))
279                          (close-connection! con)))))
280       (process-set-cookie! con uri response)
281       (cond
282        ;; TODO: According to spec, we should provide the user with a choice
283        ;; when it's not a GET or HEAD request...
284        ((member (response-code response) '(301 302 303 307))
285         ;; Clear out data, throwing it away
286         (read-response-data response)
287         (cleanup!)
288         ;; Maybe we should switch to GET on 302 too?  It's not compliant,
289         ;; but very widespread and there's enough software that depends
290         ;; on that behaviour, which might break horribly otherwise...
291         (when (= (response-code response) 303)
292           (request-method-set! request 'GET)) ; Switch to GET
293         (let ((new-uri (header-value 'location (response-headers response))))
294           (if (or (not (max-redirect-depth)) ; unlimited?
295                   (<= redirects (max-redirect-depth)))
296               (loop attempts
297                     (add1 redirects)
298                     (uri-relative-to new-uri uri))
299               (http-client-error 'send-request
300                                  "Maximum number of redirects exceeded"
301                                  'redirect-depth-exceeded
302                                  'uri new-uri))))
303        (else (let ((data (reader response)))
304                (cleanup!)
305                (values data (request-uri req) response)))))
306     (exn (exn i/o net)
307          (close-connection! uri)
308          (if (and (or (not (max-retry-attempts)) ; unlimited?
309                       (<= attempts (max-retry-attempts)))
310                   ((retry-request?) req))
311              (loop (add1 attempts) redirects uri)
312              (signal exn)))
313     (exn ()
314          ;; Never leave the port in an unknown/inconsistent state
315          ;; (the error could have occurred while reading, so there
316          ;;  might be data left in the buffer)
317          (close-connection! uri)
318          (raise exn)))))
319
320(define (call-with-input-request uri-or-request writer reader)
321  ;; "writer" is an alist to be encoded as form?
322  (let* ((postdata (and (list? writer) (form-urlencode writer separator: "&")))
323         (writer (if writer
324                     (if postdata
325                         (lambda (p)
326                           (display postdata p)
327                           (close-output-port p))
328                         writer)
329                     (lambda x (void))))
330         (uri (cond ((uri? uri-or-request) uri-or-request)
331                    ((string? uri-or-request) (uri-reference uri-or-request))
332                    (else (request-uri uri-or-request))))
333         (req (if (request? uri-or-request) uri-or-request (make-request)))
334         (req (if postdata
335                  (update-request
336                   req
337                   headers: (headers
338                             `((content-length ,(string-length postdata)))
339                             (request-headers req)))
340                  req)))
341    (call-with-response
342     req
343     (lambda (request)
344       (let ((port (request-port request)))
345         (writer port)))
346     (lambda (response)
347       (let ((port (make-delimited-input-port
348                    (response-port response)
349                    (header-value 'content-length (response-headers response)))))
350         (if (= 200 (response-class response)) ; Everything cool?
351             (reader port)
352             (http-client-error
353              'call-with-input-request
354              ;; Message
355              (sprintf (case (response-class response)
356                         ((400) "Client error: ~A ~A")
357                         ((500) "Server error: ~A ~A")
358                         (else "Unexpected server response: ~A ~A"))
359                       (response-code response) (response-reason response))
360              ;; Specific type
361              (case (response-class response)
362                ((400) 'client-error)
363                ((500) 'server-error)
364                (else 'unexpected-server-response))
365              'response response
366              'body (read-string #f port))))))))
367
368(define (with-input-from-request uri-or-request writer reader)
369  (call-with-input-request uri-or-request
370                           (if (procedure? writer)
371                               (lambda (p) (with-output-to-port p writer))
372                               writer) ;; Assume it's an alist
373                           (lambda (p) (with-input-from-port p reader))))
374
375)
Note: See TracBrowser for help on using the repository browser.