source: project/release/4/http-client/trunk/http-client.scm @ 15112

Last change on this file since 15112 was 15112, checked in by sjamaan, 10 years ago

Add POST regular formdata support

File size: 16.1 KB
Line 
1;;
2;; Convenient HTTP client library
3;;
4; Copyright (c) 2009, Peter Bex
5; Parts copyright (c) 2000-2004, Felix L. Winkelmann
6; All rights reserved.
7;
8; Redistribution and use in source and binary forms, with or without
9; modification, are permitted provided that the following conditions
10; are met:
11;
12; 1. Redistributions of source code must retain the above copyright
13;    notice, this list of conditions and the following disclaimer.
14; 2. Redistributions in binary form must reproduce the above copyright
15;    notice, this list of conditions and the following disclaimer in the
16;    documentation and/or other materials provided with the distribution.
17; 3. Neither the name of the author nor the names of its
18;    contributors may be used to endorse or promote products derived
19;    from this software without specific prior written permission.
20;
21; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
24; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
25; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
26; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
27; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
28; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
30; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
31; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
32; OF THE POSSIBILITY OF SUCH DAMAGE.
33
34(module http-client
35  (max-retry-attempts max-redirect-depth retry-request? client-software
36   remove-connection! close-connection! close-all-connections!
37   call-with-input-request with-input-from-request call-with-response)
38
39(import chicken scheme)
40(use srfi-1 srfi-13 srfi-18 srfi-69
41     ports extras tcp data-structures
42     openssl intarweb uri-common)
43
44(define-record http-connection base-uri inport outport)
45
46(define max-retry-attempts (make-parameter 1))
47(define max-redirect-depth (make-parameter 5))
48
49(define retry-request? (make-parameter idempotent?))
50
51(define client-software
52  (make-parameter (list (list "Chicken Scheme HTTP-client" "0.1" #f))))
53
54;; TODO: find a smarter storage mechanism
55(define cookie-jar (list))
56
57(define connections
58  (make-parameter (make-hash-table
59                   (lambda (a b)
60                     (and (equal? (uri-port a) (uri-port b))
61                          (equal? (uri-host a) (uri-host b))))
62                   (lambda (uri . maybe-bound)
63                     (apply string-hash
64                            (sprintf "~S ~S" (uri-host uri) (uri-port uri))
65                            maybe-bound)))))
66
67(define connections-owner
68  (make-parameter (current-thread)))
69
70(define (ensure-local-connections)
71  (unless (eq? (connections-owner) (current-thread))
72    (connections (make-hash-table equal?))
73    (connections-owner (current-thread))))
74
75(define (port-closed? p)
76  (##sys#check-port p 'port-closed?)
77  (##sys#slot p 8))
78
79(define (get-connection uri)
80  (ensure-local-connections)
81  (and-let* ((con (hash-table-ref/default (connections) uri #f)))
82    (if (or (port-closed? (http-connection-inport con))
83            (port-closed? (http-connection-outport con)))
84        (begin (close-connection! uri) #f)
85        con)))
86
87(define (add-connection! uri con)
88  (ensure-local-connections)
89  (hash-table-set! (connections) uri con))
90
91(define (remove-connection! uri-or-con)
92  ;; Ensure the connection is closed, then remove it from the hashtable
93  (let ((con (close-connection! uri-or-con)))
94    (hash-table-delete! (connections) (http-connection-base-uri con))))
95
96(define (close-connection! uri-or-con)
97  (ensure-local-connections)
98  (and-let* ((con (if (http-connection? uri-or-con)
99                      uri-or-con
100                      (hash-table-ref/default (connections) uri-or-con #f))))
101    (close-input-port (http-connection-inport con))
102    (close-output-port (http-connection-outport con))
103    con))
104
105(define (close-all-connections!)
106  (ensure-local-connections)
107  (hash-table-walk
108   (connections)
109   (lambda (uri con)
110     (hash-table-delete! (connections) uri)
111     (close-input-port (http-connection-inport con))
112     (close-output-port (http-connection-outport con)))))
113
114(define (ensure-connection! uri)
115  (or (get-connection uri)
116      (receive (in out)
117        (case (uri-scheme uri)
118          ((#f http) (tcp-connect (uri-host uri) (uri-port uri)))
119          ((https) (ssl-connect (uri-host uri) (uri-port uri)))
120          (else (error "Unknown URI scheme" (uri-scheme uri))))
121        (let ((con (make-http-connection uri in out)))
122          (add-connection! uri con)
123          con))))
124
125(define (make-delimited-input-port port len)
126  (if (not len)
127      port ;; no need to delimit anything
128      (let ((pos 0))
129        (make-input-port (lambda () ; read
130                           (if (= pos len)
131                               #!eof
132                               (let ((char (read-char port)))
133                                 (set! pos (add1 pos))
134                                 char)))
135                         (lambda () ; char-ready?
136                           (if (= pos len)
137                               #f
138                               (char-ready? port)))
139                         (lambda () ; close
140                           (close-input-port port))))))
141
142(define (read-response-data response)
143  (let ((len (header-value 'content-length (response-headers response))))
144    ;; If the header is not available, this will read until EOF
145    (read-string len (response-port response))))
146
147(define (add-headers req)
148  (let* ((uri (request-uri req))
149         (cookies (get-cookies-for-uri (request-uri req)))
150         (h `(,@(if (not (null? cookies)) `((cookie . ,cookies)) '())
151              (host ,(cons (uri-host uri) (uri-port uri)))
152              (user-agent ,(client-software)))))
153    (update-request req headers: (headers h (request-headers req)))))
154
155(define (http-client-error loc msg specific . rest)
156  (raise (make-composite-condition
157          (make-property-condition 'exn 'location loc 'message msg)
158          (apply make-property-condition specific rest))))
159
160;; RFC 2965, section 3.3.3
161(define (cookie-eq? a b)
162  (let ((ref (lambda (cookie attr) (get-param attr cookie ""))))
163    (and (eq?         (car (get-value a)) (car (get-value b)))
164         (string-ci=? (ref a 'domain)     (ref b 'domain))
165         (string=?    (ref a 'path)       (ref b 'path)))))
166
167(define (store-cookie! cookie)
168  (let loop ((jar cookie-jar))
169    (cond
170     ((null? jar) (set! cookie-jar (cons cookie cookie-jar)) cookie-jar)
171     ((cookie-eq? cookie (car jar))
172      (set-car! jar cookie)
173      cookie-jar)
174     (else (loop (cdr jar))))))
175
176(define (domain-match? uri pattern)
177  (let ((target (uri-host uri)))
178    (or (string-ci=? target pattern)
179        (and (string-prefix? "." pattern)
180             (string-suffix-ci? pattern target)))))
181
182;; Things might be simpler if we used path list representation...
183(define (path-match? uri path)
184  (and (uri-path-absolute? uri)
185       (let loop ((path (cdr (string-split path "/" #t)))
186                  (uri-path (cdr (uri-path uri))))
187         (or (null? path)               ; done
188             (and (not (null? uri-path))
189                  (or (and (string-null? (car path)) (null? (cdr path)))
190
191                      (and (string=? (car path) (car uri-path))
192                           (loop (cdr path) (cdr uri-path)))))))))
193
194(define (get-cookies-for-uri uri)
195  (sort!
196   (filter (lambda (c)
197             (and (domain-match? uri (get-param 'domain c))
198                  (member (uri-port uri)
199                          (get-param 'port c (list (uri-port uri))))
200                  (path-match? uri (get-param 'path c))
201                  (if (get-param 'secure c)
202                      (member (uri-scheme uri) '(https shttp))
203                      #t)))
204           cookie-jar)
205   (lambda (a b)
206     (< (string-length (get-param 'path a))
207        (string-length (get-param 'path b))))))
208
209(define (process-set-cookie! con uri r)
210  (let ((prefix-contains-dots?
211         (lambda (host pattern)
212           (string-index host #\. 0 (string-contains-ci host pattern)))))
213    (for-each (lambda (c)
214                (and-let* (((path-match? uri (get-param 'path c)))
215                           ;; really, path should be in separated form!
216                           (path (get-param 'path c (string-join (cdr (uri-path uri)) "/")))
217                           ;; domain must start with dot. Add to intarweb!
218                           (dn (get-param 'domain c (uri-host uri)))
219                           (idx (string-index dn #\.))
220                           ((domain-match? uri dn))
221                           ((not (prefix-contains-dots? (uri-host uri) dn))))
222                  ;; Store only the cookie values we understand
223                  ;; and make it a Cookie: header.
224                  (store-cookie! (vector (get-value c)
225                                         `((version . ,(get-param 'version c))
226                                           (path . ,path)
227                                           (domain . ,dn))))))
228              (header-contents 'set-cookie (response-headers r) '()))
229    (for-each (lambda (c)
230                (and-let* (((get-param 'version c)) ; required for set-cookie2
231                           (path (get-param 'path c (string-join (cdr (uri-path uri)) "/")))
232                           ((path-match? uri (get-param 'path c)))
233                           (dn (get-param 'domain c (uri-host uri)))
234                           ((or (string-ci=? dn ".local")
235                                (and (not (string-null? dn))
236                                     (string-index dn #\. 1))))
237                           ((domain-match? uri dn))
238                           ((not (prefix-contains-dots? (uri-host uri) dn)))
239                           ;; This is a little bit too messy for my tastes...
240                           ;; Can't use #f because that would shortcut and-let*
241                           (ports-value (get-param 'port c 'any))
242                           (ports (if (eq? ports-value #t)
243                                      (list (uri-port uri))
244                                      ports-value))
245                           ((or (eq? ports 'any)
246                                (member (uri-port uri) ports))))
247                  ;; Store only the cookie values we understand
248                  ;; and make it a Cookie: header.
249                  (store-cookie! (vector (get-value c)
250                                         `((version . ,(get-param 'version c))
251                                           (path . ,path)
252                                           (domain . ,dn)
253                                           (port . ,(if (eq? ports 'any)
254                                                        #f
255                                                        ports)))))))
256              (header-contents 'set-cookie2 (response-headers r) '()))))
257
258(define (call-with-response req writer reader)
259  (let loop ((attempts 0)
260             (redirects 0)
261             (uri (request-uri req)))
262    (condition-case
263     (let* ((con (ensure-connection! uri))
264            (req (add-headers (update-request
265                               req port: (http-connection-outport con)
266                               uri: uri)))
267            (request (write-request req))
268            ;; Writer should be prepared to be called several times
269            ;; Maybe try and figure out a good way to use the
270            ;; "Expect: 100-continue" header to prevent too much writing?
271            ;; Unfortunately RFC2616 says it's unreliable (8.2.3)...
272            (_ (writer request))
273            (response (read-response (http-connection-inport con)))
274            (cleanup! (lambda ()
275                        (unless (and (keep-alive? request)
276                                     (keep-alive? response))
277                          (close-connection! con)))))
278       (process-set-cookie! con uri response)
279       (cond
280        ;; TODO: According to spec, we should provide the user with a choice
281        ;; when it's not a GET or HEAD request...
282        ((member (response-code response) '(301 302 303 307))
283         ;; Clear out data, throwing it away
284         (read-response-data response)
285         (cleanup!)
286         ;; Maybe we should switch to GET on 302 too?  It's not compliant,
287         ;; but very widespread and there's enough software that depends
288         ;; on that behaviour, which might break horribly otherwise...
289         (when (= (response-code response) 303)
290           (request-method-set! request 'GET)) ; Switch to GET
291         (let ((new-uri (header-value 'location (response-headers response))))
292           (if (or (not (max-redirect-depth)) ; unlimited?
293                   (<= redirects (max-redirect-depth)))
294               (loop attempts
295                     (add1 redirects)
296                     (uri-relative-to new-uri uri))
297               (http-client-error 'send-request
298                                  "Maximum number of redirects exceeded"
299                                  'redirect-depth-exceeded
300                                  'uri new-uri))))
301        (else (let ((data (reader response)))
302                (cleanup!)
303                (values data (request-uri req) response)))))
304     (exn (exn i/o net)
305          (close-connection! uri)
306          (if (and (or (not (max-retry-attempts)) ; unlimited?
307                       (<= attempts (max-retry-attempts)))
308                   ((retry-request?) req))
309              (loop (add1 attempts) redirects uri)
310              (signal exn)))
311     (exn ()
312          ;; Never leave the port in an unknown/inconsistent state
313          ;; (the error could have occurred while reading, so there
314          ;;  might be data left in the buffer)
315          (close-connection! uri)
316          (raise exn)))))
317
318(define (call-with-input-request uri-or-request writer reader)
319  ;; "writer" is an alist to be encoded as form?
320  (let* ((postdata (and (list? writer) (form-urlencode writer separator: "&")))
321         (writer (if writer
322                     (if postdata
323                         (lambda (p)
324                           (display postdata p)
325                           (close-output-port p))
326                         writer)
327                     (lambda x (void))))
328         (uri (cond ((uri? uri-or-request) uri-or-request)
329                    ((string? uri-or-request) (uri-reference uri-or-request))
330                    (else (request-uri uri-or-request))))
331         (req (if (request? uri-or-request) uri-or-request (make-request)))
332         (req (if postdata
333                  (update-request
334                   req
335                   headers: (headers
336                             `((content-length ,(string-length postdata)))
337                             (request-headers req)))
338                  req)))
339    (call-with-response
340     req
341     (lambda (request)
342       (let ((port (request-port request)))
343         (writer port)))
344     (lambda (response)
345       (let ((port (make-delimited-input-port
346                    (response-port response)
347                    (header-value 'content-length (response-headers response)))))
348         (if (= 200 (response-class response)) ; Everything cool?
349             (reader port)
350             (http-client-error
351              'call-with-input-request
352              ;; Message
353              (sprintf (case (response-class response)
354                         ((400) "Client error: ~A ~A")
355                         ((500) "Server error: ~A ~A")
356                         (else "Unexpected server response: ~A ~A"))
357                       (response-code response) (response-reason response))
358              ;; Specific type
359              (case (response-class response)
360                ((400) 'client-error)
361                ((500) 'server-error)
362                (else 'unexpected-server-response))
363              'response response
364              'body (read-string #f port))))))))
365
366(define (with-input-from-request uri-or-request writer reader)
367  (call-with-input-request uri-or-request
368                           (if (procedure? writer)
369                               (lambda (p) (with-output-to-port p writer))
370                               writer) ;; Assume it's an alist
371                           (lambda (p) (with-input-from-port p reader))))
372
373)
Note: See TracBrowser for help on using the repository browser.