source: project/release/4/estraier-client/estraier-client.scm @ 15856

Last change on this file since 15856 was 15856, checked in by sjamaan, 10 years ago

Fix exception conversion

File size: 17.2 KB
Line 
1;;
2;; Hyper Estraier client library
3;;
4; Copyright (c) 2009, Peter Bex
5; All rights reserved.
6;
7; Redistribution and use in source and binary forms, with or without
8; modification, are permitted provided that the following conditions
9; are met:
10;
11; 1. Redistributions of source code must retain the above copyright
12;    notice, this list of conditions and the following disclaimer.
13; 2. Redistributions in binary form must reproduce the above copyright
14;    notice, this list of conditions and the following disclaimer in the
15;    documentation and/or other materials provided with the distribution.
16; 3. Neither the name of the author nor the names of its
17;    contributors may be used to endorse or promote products derived
18;    from this software without specific prior written permission.
19;
20; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
21; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
22; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
23; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
24; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
25; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
26; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
27; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
29; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
30; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
31; OF THE POSSIBILITY OF SUCH DAMAGE.
32;
33; Please report bugs, suggestions and ideas to the Chicken Trac
34; ticket tracking system (assign tickets to user 'sjamaan'):
35; http://trac.callcc.org
36
37(module estraier-client
38  (get-node-info get-cache-usage optimize-node sync-node document-uri->id
39   list-documents put-document delete-document get-document
40   update-attributes document-attribute document-keywords find-documents
41   unregister-user register-admin-user register-guest-user
42   
43   ;; these could be useful on their own, so export them too
44   read-attributes read-draft write-attributes write-draft
45
46   shutdown-master sync-all-nodes backup-master rotate-log
47   list-nodes add-node delete-node clear-node list-users add-user delete-user)
48
49(import chicken scheme)
50(use data-structures extras ports regex srfi-1 srfi-13
51     http-client uri-common intarweb)
52
53;; Exhaust input port with web-server's output (yes, confusing) and return void
54(define (discard-output in)
55  (let loop ((line (read-line in)))
56    (if (eof-object? line) (void) (loop (read-line in)))))
57
58(define (estraier-exn loc message specific . rest)
59  (make-composite-condition
60   (make-property-condition 'exn 'location loc 'message message)
61   (make-property-condition 'estraier-client)
62   (apply make-property-condition specific rest)))
63
64(define (http->estraier-exn exn loc specific . rest)
65  (let ((msg ((condition-property-accessor 'exn 'message) exn)))
66    (apply estraier-exn loc msg specific rest)))
67
68(define (exec loc uri writer reader)
69  (condition-case
70      ;; Estraier doesn't understand the preferred ";" separator
71      (parameterize ((form-urlencoded-separator "&"))
72        (call-with-input-request uri writer reader))
73    (exn (client-error)
74         (case (response-code
75                ((condition-property-accessor 'client-error 'response) exn))
76           ((400) (signal (http->estraier-exn exn loc 'args)))
77           ((401) (signal (http->estraier-exn exn loc 'auth)))
78           ((403) (signal (http->estraier-exn exn loc 'perm)))
79           ((404) (signal (http->estraier-exn exn loc 'node)))
80           (else  (signal exn))))
81    (exn (server-error)
82         (case (response-code
83                ((condition-property-accessor 'client-error 'response) exn))
84           ((500) (signal (http->estraier-exn exn loc 'server)))
85           (else  (signal exn))))))
86
87;; Read one block of data. The Hyper Estraier API sends data out in blocks
88;; separated by newlines.  The lines in the block are returned as a list
89(define (read-block inport)
90  (let loop ((result (list))
91             (line (read-line inport)))
92    (if (or (eof-object? line) (string-null? line))
93        (reverse! result)
94        (loop (cons line result) (read-line inport)))))
95
96(define (split-attrib-line attrib-line)
97  (let ((idx (string-index attrib-line #\=)))
98    (cons (string->symbol (string-take attrib-line idx))
99          (string-drop attrib-line (add1 idx)))))
100
101(define (line->node-info line)
102  (let ((info (string-split line "\t" #t)))
103    `((name . ,(first info))
104      (label . ,(second info))
105      (document-count . ,(string->number (third info)))
106      (word-count . ,(string->number (fourth info)))
107      (size . ,(string->number (fifth info))))))
108
109(define (line->user-info line)
110  (let ((info (string-split line "\t" #t)))
111    (map cons '(name password flags fullname misc) info)))
112
113;; Flatten all whitespace types to one regular whitespace.  Draft syntax
114;; assigns special meaning to tabs/newlines but has no way to escape that.
115(define (kill-special-whitespace str)
116  (string-substitute '(+ whitespace) " " str))
117
118(define (write-attributes outport attributes)
119  (for-each (lambda (attrib)
120              (fprintf outport "~A=~A\r\n"
121                       (kill-special-whitespace (->string (car attrib)))
122                       (kill-special-whitespace (->string (cdr attrib)))))
123            attributes))
124
125;; Write out a document in "draft" format to the specified output port.
126(define (write-draft outport attributes contents)
127  (write-attributes outport attributes)
128  (fprintf outport "\r\n")
129  (for-each (lambda (line)
130              (fprintf outport "~A\r\n" (kill-special-whitespace line)))
131            contents))
132
133(define (read-attributes inport)
134  (map split-attrib-line
135       ;; Remove control commands like %VECTOR for now
136       (filter (lambda (line)
137                 (string-index line #\=))
138               (read-block inport))))
139
140;; Read a document in "draft" format from the specified input port.
141(define (read-draft inport)
142  (let* ((metadata (read-attributes inport))
143         (document (read-lines inport)))
144    (values document metadata)))
145
146;; Helper procedure for checking that id xor uri is supplied
147(define (id/uri->alist loc id uri)
148  (cond
149   ((and id (not uri)) `((id . ,id)))
150   ((and uri (not id)) `((uri . ,uri)))
151   (else
152    (signal (estraier-exn loc "You must supply either an id or a uri" 'args)))))
153
154;;;; Node API
155
156(define (node-uri base-uri node action . args)
157  (let* ((rel (update-uri (uri-reference "") path: (list "node" node action)))
158         (uri (if (uri-reference? base-uri)
159                  (uri-relative-to rel base-uri)
160                  (uri-relative-to rel (uri-reference base-uri)))))
161    (apply update-uri uri args)))
162
163(define (get-node-info base-uri node)
164  (exec
165   'get-node-info
166   (node-uri base-uri node "inform")
167   #f
168   (lambda (in)
169     (let* ((node-info (line->node-info (car (read-block in))))
170            (admins (read-block in))
171            (guests (read-block in)))
172       ;; According to the docs, there's more info after GUESTS but I can't
173       ;; seem to get this, so let's just read out just to be sure (for now)
174       (discard-output in)
175       `(,@node-info (admin-users . ,admins) (guest-users . ,guests))))))
176
177(define (get-cache-usage base-uri node)
178  (string->number
179   (exec 'get-cache-usage (node-uri base-uri node "cacheusage") #f read-line)))
180
181(define (optimize-node base-uri node)
182  (exec 'optimize-node (node-uri base-uri node "optimize") #f discard-output))
183
184(define (sync-node base-uri node)
185  (exec 'sync-node (node-uri base-uri node "sync") #f discard-output))
186
187(define (list-documents base-uri node #!key max prev)
188  (exec 'list-documents
189        (node-uri base-uri node "list" query: `((max . ,max) (prev . ,prev)))
190        #f
191        (lambda (in)
192          (map (lambda (line)
193                 (map cons
194                      `(@id @uri @digest @cdate @mdate @adate @title @author
195                            @type @lang @genre @size @weight @misc)
196                      (string-split line "\t" #t)))
197               (read-lines in)))))
198
199(define (put-document base-uri node contents attribs)
200  (exec
201   'put-document
202   (make-request uri: (node-uri base-uri node "put_doc")
203                 method: 'POST major: 1 minor: 0
204                 headers: (headers '((content-type text/x-estraier-draft))))
205   (call-with-output-string ; use string because it wants content-length
206     ;; Can't write @digest because that would invalidate the document
207     (lambda (out) (write-draft out (alist-delete '@digest attribs) contents)))
208   discard-output))
209
210(define (delete-document base-uri node #!key id uri)
211  (exec 'delete-document
212        (node-uri base-uri node "out_doc"
213                  query: (id/uri->alist 'delete-document id uri))
214        #f discard-output))
215
216(define (document-uri->id base-uri node uri)
217  (exec 'document-uri->id
218        (node-uri base-uri node "uri_to_id"
219                  query: `((uri . ,uri))) #f read-line))
220
221(define (get-document base-uri node #!key id uri)
222  (apply values
223         (exec
224          'get-document
225          (node-uri base-uri node "get_doc"
226                    query: (id/uri->alist 'get-document id uri))
227          #f (lambda (in)
228               (call-with-values (lambda () (read-draft in)) list)))))
229
230;; This requires the new attributes plus all the old attribs, it
231;; simply replaces the document's attributes.  This also means it
232;; requires both @uri and @id!  Anything not present is reset or
233;; removed.  It's identical to put-document, except for the doc body.
234(define (update-attributes base-uri node attribs)
235  (exec
236   'update-attributes
237   (make-request uri: (node-uri base-uri node "edit_doc")
238                 method: 'POST major: 1 minor: 0
239                 headers: (headers '((content-type text/x-estraier-draft))))
240   (call-with-output-string ; use string because it wants content-length
241     ;; Can't write @digest because that would invalidate the document
242     (lambda (out) (write-attributes out (alist-delete '@digest attribs))))
243   discard-output))
244
245(define (document-attribute base-uri node attrib #!key id uri)
246  (exec 'document-attribute
247        (node-uri base-uri node "get_doc_attr"
248                  query: (cons `(attr . ,attrib)
249                               (id/uri->alist 'document-attribute id uri)))
250        #f read-line))
251
252(define (document-keywords base-uri node #!key id uri)
253  (exec 'document-keywords
254        (node-uri base-uri node "etch_doc"
255                  query: (id/uri->alist 'document-keywords id uri))
256        #f
257        (lambda (in)
258          (let loop ((line (read-line in))
259                     (keywords (list)))
260            (if (eof-object? line)
261                (reverse! keywords) ;; preserve keyword document order
262                (let ((kwd/score (string-split line "\t" #t)))
263                  (loop (read-line in)
264                        (cons (cons (first kwd/score)
265                                    (string->number (second kwd/score)))
266                              keywords))))))))
267
268;; Attrs are ANDed together.  All attribute phrases must match
269(define (find-documents base-uri node #!key phrase (attr-phrases '())
270                        order max options auxiliary distinct depth
271                        wwidth hwidth awidth skip mask)
272  (when (> (length attr-phrases) 10)
273    (signal
274     (estraier-exn 'find-documents
275                   (conc "You can't provide more than 10 attribute phrases. "
276                         "This is a limitation of the estraier API. Sorry!")
277                   'args)))
278  ;; Normalise attr-phrases list to attr, attr1, ... attr9
279  (let ((attrs (map (lambda (a i)
280                      (if (zero? i)
281                          (cons 'attr a)
282                          (cons (sprintf "attr~A" i) a)))
283                    attr-phrases
284                    (iota 10))))
285   (apply
286    values
287    (exec 'find-documents
288          (node-uri base-uri node "search"
289                    query: `((phrase . ,phrase) (order . ,order)
290                             (max . ,max)       (options . ,options)
291                             (depth . ,depth)   (wwidth . ,wwidth)
292                             (hwidth . ,hwidth) (awidth . ,awidth)
293                             (skip . ,skip)     (mask . ,mask)
294                             (auxiliary . ,auxiliary)
295                             (distinct . ,distinct)
296                             ,@attrs))
297          #f
298          (lambda (in)
299            (let* ((delimiter (read-line in))
300                   (meta
301                    (let next-line ((line (read-line in))
302                                    (metadata (list)))
303                      ;; There's a pointless blank line at the end... skip over it
304                      (if (string-null? line)
305                          (next-line (read-line in) metadata)
306                          (if (string-prefix? delimiter line)
307                              (reverse! metadata) ; done, continue to snippets
308                              (let ((data (string-split line "\t" #t)))
309                                (next-line (read-line in)
310                                           (cons (cons (string->symbol (car data))
311                                                       (cdr data))
312                                                 metadata)))))))
313                   (documents
314                    (let next-document ((docs (list)))
315                      (let ((attribs (read-attributes in)))
316                        (let next-line ((matches (list))
317                                        (line  (read-line in)))
318                          (cond
319                           ;; We're not relying on :END here since it would
320                           ;; complicate matters with zero search results.
321                           ((eof-object? line)
322                            (reverse! docs))
323                           ((string-prefix? delimiter line)
324                            (next-document (cons (cons (reverse! matches) attribs)
325                                                 docs)))
326                           ;; Discard pointless empty lines.. there's at least
327                           ;; one at the end of each block.
328                           ((string-null? line)
329                            (next-line matches (read-line in)))
330                           (else
331                            (let* ((idx (string-index line #\tab))
332                                   (highlight (and idx (string-take line idx)))
333                                   (match (if idx
334                                              (string-drop line (add1 idx))
335                                              line)))
336                              (next-line (cons (cons highlight match) matches)
337                                         (read-line in))))))))))
338              (list documents meta)))))))
339
340(define (_set-user loc base-uri node name mode)
341  (exec loc (node-uri base-uri node "_set_user"
342                      query: `((name . ,name) (mode . ,mode)))
343        #f read-lines))
344
345(define (unregister-user base-uri node name)
346  (_set-user 'unregister-user base-uri node name 0))
347
348(define (register-admin-user base-uri node name)
349  (_set-user 'register-admin-user base-uri node name 1))
350
351(define (register-guest-user base-uri node name)
352  (_set-user 'register-guest-user base-uri node name 2))
353
354;; TODO: _set_link
355
356;;;; Master API
357
358(define (master-uri base-uri action . args)
359  (let ((uri (if (uri-reference? base-uri)
360                 (apply update-uri base-uri args)
361                 (apply update-uri (uri-reference base-uri) args))))
362    (update-uri (uri-relative-to (uri-reference "./master") uri)
363                query: (alist-update! 'action action (uri-query uri)))))
364
365(define (shutdown-master base-uri)
366  (exec 'shutdown-master (master-uri base-uri "shutdown") #f discard-output))
367
368(define (sync-all-nodes base-uri)
369  (exec 'sync-all-nodes (master-uri base-uri "sync") #f discard-output))
370
371(define (backup-master base-uri)
372  (exec 'backup-master (master-uri base-uri "backup") #f discard-output))
373
374(define (rotate-log base-uri)
375  (exec 'rotate-log (master-uri base-uri "logrtt") #f discard-output))
376
377(define (list-nodes base-uri)
378  (map line->node-info
379       (exec 'list-nodes (master-uri base-uri "nodelist") #f read-lines)))
380
381(define (add-node base-uri node-name #!optional node-label)
382  (exec 'add-node
383        (master-uri base-uri "nodeadd"
384                    query: `((name . ,node-name) (label . ,node-label)))
385        #f discard-output))
386
387(define (delete-node base-uri node-name)
388  (exec 'delete-node
389        (master-uri base-uri "nodedel" query: `((name . ,node-name)))
390        #f discard-output))
391
392(define (clear-node base-uri node-name)
393  (exec 'clear-node
394        (master-uri base-uri "nodeclr" query: `((name . ,node-name)))
395        #f discard-output))
396
397(define (list-users base-uri)
398  (exec 'list-users
399        (master-uri base-uri "userlist")
400        #f
401        (lambda (in) (map line->user-info (read-lines in)))))
402
403(define (add-user base-uri username password
404                  #!key flags fullname misc)
405  (exec 'add-user
406        (make-request uri: (master-uri base-uri "useradd")
407                      method: 'POST major: 1 minor: 0)
408        `((name . ,username) (passwd . ,password)
409          (flags . ,flags) (fname . ,fullname) (misc . ,misc))
410        discard-output))
411
412(define (delete-user base-uri username)
413  (exec 'delete-user
414        (master-uri base-uri "userdel" query: `((name . ,username)))
415        #f discard-output))
416
417)
Note: See TracBrowser for help on using the repository browser.