source: project/release/4/estraier-client/estraier-client.scm @ 15849

Last change on this file since 15849 was 15849, checked in by sjamaan, 10 years ago

Improve exception handling (thanks to DerGuteMoritz?)

File size: 16.3 KB
Line 
1;;
2;; Hyper Estraier client library
3;;
4; Copyright (c) 2009, Peter Bex
5; All rights reserved.
6;
7; Redistribution and use in source and binary forms, with or without
8; modification, are permitted provided that the following conditions
9; are met:
10;
11; 1. Redistributions of source code must retain the above copyright
12;    notice, this list of conditions and the following disclaimer.
13; 2. Redistributions in binary form must reproduce the above copyright
14;    notice, this list of conditions and the following disclaimer in the
15;    documentation and/or other materials provided with the distribution.
16; 3. Neither the name of the author nor the names of its
17;    contributors may be used to endorse or promote products derived
18;    from this software without specific prior written permission.
19;
20; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
21; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
22; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
23; FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
24; COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
25; INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
26; (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
27; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28; HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
29; STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
30; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
31; OF THE POSSIBILITY OF SUCH DAMAGE.
32;
33; Please report bugs, suggestions and ideas to the Chicken Trac
34; ticket tracking system (assign tickets to user 'sjamaan'):
35; http://trac.callcc.org
36
37(module estraier-client
38  (get-node-info get-cache-usage optimize-node sync-node document-uri->id
39   list-documents put-document delete-document get-document
40   update-attributes document-attribute document-keywords find-documents
41   unregister-user register-admin-user register-guest-user
42   
43   ;; these could be useful on their own, so export them too
44   read-attributes read-draft write-attributes write-draft
45
46   shutdown-master sync-master backup-master rotate-log
47   list-nodes add-node delete-node clear-node list-users add-user delete-user)
48
49(import chicken scheme)
50(use data-structures extras ports srfi-1 srfi-13 http-client uri-common intarweb)
51
52;; Exhaust input port with web-server's output (yes, confusing) and return void
53(define (discard-output in)
54  (let loop ((line (read-line in)))
55    (if (eof-object? line) (void) (loop (read-line in)))))
56
57(define (http->estraier-exn exn loc specific . rest)
58  (make-composite-condition
59   (make-property-condition
60    'exn 'location loc
61    'message ((condition-property-accessor 'exn 'message) exn))
62   (make-property-condition 'estraier-client)
63   (apply make-property-condition specific rest)))
64
65(define (exec loc uri writer reader)
66  (condition-case
67      ;; Estraier doesn't understand the preferred ";" separator
68      (parameterize ((form-urlencoded-separator "&"))
69        (call-with-input-request uri writer reader))
70    (exn (client-error)
71         (case (response-code
72                ((condition-property-accessor 'client-error 'response) exn))
73           ((400) (signal (http->estraier-exn exn loc 'args)))
74           ((401) (signal (http->estraier-exn exn loc 'auth)))
75           ((403) (signal (http->estraier-exn exn loc 'perm)))
76           ((404) (signal (http->estraier-exn exn loc 'node)))
77           ((500) (signal (http->estraier-exn exn loc 'server)))
78           (else  (signal exn))))))
79
80;; Read one block of data. The Hyper Estraier API sends data out in blocks
81;; separated by newlines.  The lines in the block are returned as a list
82(define (read-block inport)
83  (let loop ((result (list))
84             (line (read-line inport)))
85    (if (or (eof-object? line) (string-null? line))
86        (reverse! result)
87        (loop (cons line result) (read-line inport)))))
88
89(define (split-attrib-line attrib-line)
90  (let ((idx (string-index attrib-line #\=)))
91    (cons (string->symbol (string-take attrib-line idx))
92          (string-drop attrib-line (add1 idx)))))
93
94;; Helper procedure for checking that id xor uri is supplied
95(define (id/uri->alist id uri)
96  (cond
97   ((and id (not uri)) `((id . ,id)))
98   ((and uri (not id)) `((uri . ,uri)))
99   (else (error "You must supply either an id or a uri"))))
100
101;;;; Node API
102
103(define (node-uri base-uri node action . args)
104  (let* ((rel (update-uri (uri-reference "") path: (list "node" node action)))
105         (uri (if (uri-reference? base-uri)
106                  (uri-relative-to rel base-uri)
107                  (uri-relative-to rel (uri-reference base-uri)))))
108    (apply update-uri uri args)))
109
110(define (get-node-info base-uri node)
111  (exec
112   'get-node-info
113   (node-uri base-uri node "inform")
114   #f
115   (lambda (in)
116     (let* ((db-info (string-split (car (read-block in)) "\t" #t))
117            (admins (read-block in))
118            (guests (read-block in)))
119       ;; According to the docs, there's more info after GUESTS but I can't
120       ;; seem to get this, so let's just read out just to be sure (for now)
121       (discard-output in)
122       `((name . ,(first db-info))
123         (label . ,(second db-info))
124         (document-count . ,(string->number (third db-info)))
125         (word-count . ,(string->number (fourth db-info)))
126         (size . ,(string->number (fifth db-info)))
127         (admin-users . ,admins)
128         (guest-users . ,guests))))))
129
130(define (get-cache-usage base-uri node)
131  (string->number
132   (exec 'get-cache-usage (node-uri base-uri node "cacheusage") #f read-line)))
133
134(define (optimize-node base-uri node)
135  (exec 'optimize-node (node-uri base-uri node "optimize") #f discard-output))
136
137(define (sync-node base-uri node)
138  (exec 'sync-node (node-uri base-uri node "sync") #f discard-output))
139
140(define (list-documents base-uri node #!key max prev)
141  (exec 'list-documents
142        (node-uri base-uri node "list" query: `((max . ,max) (prev . ,prev)))
143        #f
144        (lambda (in)
145          (map (lambda (line)
146                 (map cons
147                      `(@id @uri @digest @cdate @mdate @adate @title @author
148                            @type @lang @genre @size @weight @misc)
149                      (string-split line "\t" #t)))
150               (read-lines in)))))
151
152(define (write-attributes outport attributes)
153  (for-each (lambda (attrib)
154              (fprintf outport "~A=~A\r\n" (car attrib) (cdr attrib)))
155            attributes))
156
157;; Write out a document in "draft" format to the specified output port.
158(define (write-draft outport attributes contents)
159  (write-attributes outport attributes)
160  (fprintf outport "\r\n")
161  ;; What if there's a newline in the text?
162  (for-each (lambda (line) (fprintf outport "~A\r\n" line)) contents))
163
164(define (read-attributes inport)
165  (map split-attrib-line
166       ;; Remove control commands like %VECTOR for now
167       (filter (lambda (line)
168                 (string-index line #\=))
169               (read-block inport))))
170
171;; Read a document in "draft" format from the specified input port.
172(define (read-draft inport)
173  (let* ((metadata (read-attributes inport))
174         (document (read-lines inport)))
175    (values document metadata)))
176
177(define (put-document base-uri node contents attribs)
178  (exec
179   'put-document
180   (make-request uri: (node-uri base-uri node "put_doc")
181                 method: 'POST major: 1 minor: 0
182                 headers: (headers '((content-type text/x-estraier-draft))))
183   (call-with-output-string ; use string because it wants content-length
184     ;; Can't write @digest because that would invalidate the document
185     (lambda (out) (write-draft out (alist-delete '@digest attribs) contents)))
186   discard-output))
187
188(define (delete-document base-uri node #!key id uri)
189  (exec 'delete-document
190        (node-uri base-uri node "out_doc" query: (id/uri->alist id uri))
191        #f discard-output))
192
193(define (document-uri->id base-uri node uri)
194  (exec 'document-uri->id
195        (node-uri base-uri node "uri_to_id"
196                  query: `((uri . ,uri))) #f read-line))
197
198(define (get-document base-uri node #!key id uri)
199  (apply values
200         (exec
201          'get-document
202          (node-uri base-uri node "get_doc" query: (id/uri->alist id uri))
203          #f (lambda (in)
204               (call-with-values (lambda () (read-draft in)) list)))))
205
206;; This requires the new attributes plus all the old attribs, it
207;; simply replaces the document's attributes.  This also means it
208;; requires both @uri and @id!  Anything not present is reset or
209;; removed.  It's identical to put-document, except for the doc body.
210(define (update-attributes base-uri node attribs)
211  (exec
212   'update-attributes
213   (make-request uri: (node-uri base-uri node "edit_doc")
214                 method: 'POST major: 1 minor: 0
215                 headers: (headers '((content-type text/x-estraier-draft))))
216   (call-with-output-string ; use string because it wants content-length
217     ;; Can't write @digest because that would invalidate the document
218     (lambda (out) (write-attributes out (alist-delete '@digest attribs))))
219   discard-output))
220
221(define (document-attribute base-uri node attrib #!key id uri)
222  (exec 'document-attribute
223        (node-uri base-uri node "get_doc_attr"
224                  query: (cons `(attr . ,attrib) (id/uri->alist id uri)))
225        #f read-line))
226
227(define (document-keywords base-uri node #!key id uri)
228  (exec 'document-keywords
229        (node-uri base-uri node "etch_doc" query: (id/uri->alist id uri))
230        #f
231        (lambda (in)
232          (let loop ((line (read-line in))
233                     (keywords (list)))
234            (if (eof-object? line)
235                (reverse! keywords) ;; preserve keyword document order
236                (let ((kwd/score (string-split line "\t" #t)))
237                  (loop (read-line in)
238                        (cons (cons (first kwd/score)
239                                    (string->number (second kwd/score)))
240                              keywords))))))))
241
242;; Attrs are ANDed together.  All attribute phrases must match
243(define (find-documents base-uri node #!key phrase (attr-phrases '())
244                        order max options auxiliary distinct depth
245                        wwidth hwidth awidth skip mask)
246  (when (> (length attr-phrases) 10)
247    (error (string-append "You can't provide more than 10 attribute phrases. "
248                          "This is a limitation of the estraier API. Sorry!")))
249  ;; Normalise attr-phrases list to attr, attr1, ... attr9
250  (let ((attrs (map (lambda (a i)
251                      (if (zero? i)
252                          (cons 'attr a)
253                          (cons (sprintf "attr~A" i) a)))
254                    attr-phrases
255                    (iota 10))))
256   (apply
257    values
258    (exec 'find-documents
259          (node-uri base-uri node "search"
260                    query: `((phrase . ,phrase) (order . ,order)
261                             (max . ,max)       (options . ,options)
262                             (depth . ,depth)   (wwidth . ,wwidth)
263                             (hwidth . ,hwidth) (awidth . ,awidth)
264                             (skip . ,skip)     (mask . ,mask)
265                             (auxiliary . ,auxiliary)
266                             (distinct . ,distinct)
267                             ,@attrs))
268          #f
269          (lambda (in)
270            (let* ((delimiter (read-line in))
271                   (meta
272                    (let next-line ((line (read-line in))
273                                    (metadata (list)))
274                      ;; There's a pointless blank line at the end... skip over it
275                      (if (string-null? line)
276                          (next-line (read-line in) metadata)
277                          (if (string-prefix? delimiter line)
278                              (reverse! metadata) ; done, continue to snippets
279                              (let ((data (string-split line "\t" #t)))
280                                (next-line (read-line in)
281                                           (cons (cons (string->symbol (car data))
282                                                       (cdr data))
283                                                 metadata)))))))
284                   (documents
285                    (let next-document ((docs (list)))
286                      (let ((attribs (read-attributes in)))
287                        (let next-line ((matches (list))
288                                        (line  (read-line in)))
289                          (cond
290                           ;; We're not relying on :END here since it would
291                           ;; complicate matters with zero search results.
292                           ((eof-object? line)
293                            (reverse! docs))
294                           ((string-prefix? delimiter line)
295                            (next-document (cons (cons (reverse! matches) attribs)
296                                                 docs)))
297                           ;; Discard pointless empty lines.. there's at least
298                           ;; one at the end of each block.
299                           ((string-null? line)
300                            (next-line matches (read-line in)))
301                           (else
302                            (let* ((idx (string-index line #\tab))
303                                   (highlight (and idx (string-take line idx)))
304                                   (match (if idx
305                                              (string-drop line (add1 idx))
306                                              line)))
307                              (next-line (cons (cons highlight match) matches)
308                                         (read-line in))))))))))
309              (list documents meta)))))))
310
311(define (_set-user loc base-uri node name mode)
312  (exec loc (node-uri base-uri node "_set_user"
313                      query: `((name . ,name) (mode . ,mode)))
314        #f read-lines))
315
316(define (unregister-user base-uri node name)
317  (_set-user 'unregister-user base-uri node name 0))
318
319(define (register-admin-user base-uri node name)
320  (_set-user 'register-admin-user base-uri node name 1))
321
322(define (register-guest-user base-uri node name)
323  (_set-user 'register-guest-user base-uri node name 2))
324
325;; TODO: _set_link
326
327;;;; Master API
328
329(define (master-uri base-uri action . args)
330  (let ((uri (if (uri-reference? base-uri)
331                 (apply update-uri base-uri args)
332                 (apply update-uri (uri-reference base-uri) args))))
333    (update-uri (uri-relative-to (uri-reference "./master") uri)
334                query: (alist-update! 'action action (uri-query uri)))))
335
336(define (shutdown-master base-uri)
337  (exec 'shutdown-master (master-uri base-uri "shutdown") #f discard-output))
338
339(define (sync-master base-uri)
340  (exec 'sync-master (master-uri base-uri "sync") #f discard-output))
341
342(define (backup-master base-uri)
343  (exec 'backup-master (master-uri base-uri "backup") #f discard-output))
344
345(define (rotate-log base-uri)
346  (exec 'rotate-log (master-uri base-uri "logrtt") #f discard-output))
347
348(define (list-nodes base-uri)
349  (map (lambda (line)
350         (string-split line "\t" #t))
351       (exec 'list-nodes (master-uri base-uri "nodelist") #f read-lines)))
352
353(define (add-node base-uri node-name #!optional node-label)
354  (exec 'add-node
355        (master-uri base-uri "nodeadd"
356                    query: `((name . ,node-name) (label . ,node-label)))
357        #f discard-output))
358
359(define (delete-node base-uri node-name)
360  (exec 'delete-node
361        (master-uri base-uri "nodedel" query: `((name . ,node-name)))
362        #f discard-output))
363
364(define (clear-node base-uri node-name)
365  (exec 'clear-node
366        (master-uri base-uri "nodeclr" query: `((name . ,node-name)))
367        #f discard-output))
368
369(define (list-users base-uri)
370  (exec 'list-users
371        (master-uri base-uri "userlist")
372        #f
373        (lambda (in)
374          (let loop ((line (read-line in))
375                     (lines (list)))
376            (if (eof-object? line)
377                (reverse! lines)
378                (loop (read-line in)
379                      (cons (string-split line "\t" #t) lines)))))))
380
381(define (add-user base-uri username password
382                  #!key flags fullname description)
383  (exec 'add-user
384        (make-request uri: (master-uri base-uri "useradd")
385                      method: 'POST major: 1 minor: 0)
386        `((name . ,username) (passwd . ,password)
387          (flags . ,flags) (fname . ,fullname) (misc . ,description))
388        discard-output))
389
390(define (delete-user base-uri username)
391  (exec 'delete-user
392        (master-uri base-uri "userdel" query: `((name . ,username)))
393        #f discard-output))
394
395)
Note: See TracBrowser for help on using the repository browser.