source: project/release/3/uri-generic/trunk/uri-generic.scm @ 13446

Last change on this file since 13446 was 13446, checked in by sjamaan, 11 years ago

Merge latest (minor) change from release 4

File size: 35.0 KB
Line 
1;;
2;; Definitions and parsing routines for Uniform Resource Identifiers (RFC 3986).
3;;
4;; Based on the Haskell URI library by  Graham Klyne <gk@ninebynine.org>.
5;;
6;; Copyright 2008-2009 Ivan Raikov, Peter Bex.
7;;
8;;
9;;  Redistribution and use in source and binary forms, with or without
10;;  modification, are permitted provided that the following conditions
11;;  are met:
12;;
13;;  - Redistributions of source code must retain the above copyright
14;;  notice, this list of conditions and the following disclaimer.
15;;
16;;  - Redistributions in binary form must reproduce the above
17;;  copyright notice, this list of conditions and the following
18;;  disclaimer in the documentation and/or other materials provided
19;;  with the distribution.
20;;
21;;  - Neither name of the copyright holders nor the names of its
22;;  contributors may be used to endorse or promote products derived
23;;  from this software without specific prior written permission.
24;;
25;;  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND THE
26;;  CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES,
27;;  INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
28;;  MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
29;;  DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR THE
30;;  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
31;;  SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
32;;  LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
33;;  USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
34;;  AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
35;;  LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
36;;  ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
37;;  POSSIBILITY OF SUCH DAMAGE.
38;;
39
40(require-extension syntax-case)
41(require-extension matchable)
42(require-extension defstruct)
43(require-extension srfi-1)
44(require-extension srfi-4)
45
46(define-extension uri-generic)
47
48(declare
49 (not usual-integrations)
50 (fixnum)
51 (inline)
52 (lambda-lift)
53 (export uri-reference update-uri update-authority
54         uri-reference? uri-auth uri-authority uri-scheme uri-path uri-query
55         uri-fragment uri-host uri-port uri-username uri-password
56         authority? authority-host authority-port
57         authority-username authority-password
58         
59         uri? absolute-uri absolute-uri? uri->string uri->list 
60         relative-ref? uri-relative-to uri-relative-from 
61         uri-decode-string uri-encode-string 
62         uri-normalize-case uri-normalize-path-segments
63         char-set:gen-delims char-set:sub-delims
64         char-set:uri-reserved char-set:uri-unreserved))
65
66(cond-expand
67   (utf8-strings (use utf8-srfi-13 utf8-srfi-14))
68   (else (use srfi-13 srfi-14)))
69
70(defstruct URI      scheme authority path query fragment)
71(defstruct URIAuth  username password host port)
72
73(define-record-printer (URI x out)
74  (fprintf out "#(URI scheme=~S authority=~A path=~S query=~S fragment=~S)"
75           (URI-scheme x)
76           (URI-authority x)
77           (URI-path x)
78           (URI-query x)
79           (URI-fragment x)))
80
81(define-record-printer (URIAuth x out)
82  (fprintf out "#(URIAuth host=~S port=~A)"
83           (URIAuth-host x)
84           (URIAuth-port x)))
85
86(define uri-reference? URI?)
87
88(define uri-auth       URI-authority )
89(define uri-authority  URI-authority )
90(define uri-scheme     URI-scheme )
91(define uri-path       URI-path )
92(define uri-query      URI-query )
93(define uri-fragment   URI-fragment )
94
95(define (uri-host x)
96  (let ((auth (URI-authority x)))
97    (and auth (URIAuth-host auth))))
98
99(define (uri-port x)
100  (let ((auth (URI-authority x)))
101    (and auth (URIAuth-port auth))))
102
103(define (uri-username x)
104  (let ((auth (URI-authority x)))
105    (and auth (URIAuth-username auth))))
106
107(define (uri-password x)
108  (let ((auth (URI-authority x)))
109    (and auth (URIAuth-password auth))))
110
111(define authority? URIAuth?)
112(define authority-host URIAuth-host)
113(define authority-port URIAuth-port)
114(define authority-username URIAuth-username)
115(define authority-password URIAuth-password)
116
117(define update-authority
118  (let ((unset (list 'unset)))
119    (lambda (auth #!key (host unset) (port unset) (username unset) (password unset))
120      (make-URIAuth host: (if (eq? host unset) (URIAuth-host auth) host)
121                    port: (if (eq? port unset) (URIAuth-port auth) port)
122                    username: (if (eq? username unset) (URIAuth-username auth) username)
123                    password: (if (eq? password unset) (URIAuth-password auth) password)))))
124
125(define update-uri
126  (let ((unset (list 'unset)))
127   (lambda (uri . key/values)
128     (apply
129      (lambda (#!key
130               (scheme (URI-scheme uri)) (path (URI-path uri))
131               (query (URI-query uri)) (fragment (URI-fragment uri))
132               (auth unset) (authority unset))
133        (let* ((base-auth (or
134                           (cond
135                            ((not (eq? unset auth)) auth)
136                            ((not (eq? unset authority)) authority)
137                            (else (URI-authority uri)))
138                           (make-URIAuth)))
139               (updated-auth (apply update-authority base-auth key/values))
140               (final-auth (if (equal? (make-URIAuth) updated-auth)
141                               #f
142                               updated-auth)))
143          (make-URI scheme: scheme path: path query: query fragment: fragment
144                    authority: final-auth))) key/values))))
145
146;; Character classes
147 
148(define (hexdigit-char? c)    (and (char? c) (char-set-contains? char-set:hex-digit c)))
149
150(define (unreserved-char? c)  (and (char? c) (char-set-contains? char-set:uri-unreserved c)))
151
152(define (scheme-char? c)      (and (char? c) (char-set-contains? char-set:scheme c)))
153
154(define (ipv-future-char? c)  (and (char? c) (char-set-contains? char-set:ipv-future c)))
155
156(define (pct-encoded? c)      (match c ((#\% h1 h2) #t) (else #f)))
157
158
159;; Helper functions for character parsing
160 
161(define (uchar extras)
162  (let ((extras-set (or (and (char-set? extras) extras) (string->char-set extras))))
163    (lambda (c) (or (pct-encoded? c) (unreserved-char? c) 
164                    (char-set-contains? char-set:sub-delims c) 
165                    (char-set-contains? extras-set c) ))))
166 
167(define (many pred?)
168  (lambda (s)
169    (let loop ((lst (list)) (rst s))
170      (cond ((null? rst)        (list (reverse lst) rst))
171            ((pred? (car rst))  (loop (cons (car rst) lst) (cdr rst)))
172            (else               (list (reverse lst) rst))))))
173
174(define (many1 pred?)
175  (lambda (s)
176    (let ((a1 (and (not (null? s)) (pred? (car s)) (car s))))
177      (and a1 (match ((many pred?) (cdr s))
178                     ((as rst)  (list (cons a1 as) rst))
179                     (else #f))))))
180
181
182(define (count-min-max m n pred?)
183  (lambda (s) 
184    (let loop ((m m) (n n) (lst (list)) (rst s))
185      (cond ((and (pair? rst) (positive? m))
186             (if (pred? (car rst))
187                 (loop (- m 1) (- n 1) (cons (car rst) lst) (cdr rst)) #f))
188            ((or (<= n 0) (null? rst))   (list (reverse lst) rst))
189            (else
190             (if (pred? (car rst))
191                 (loop 0 (- n 1) (cons (car rst) lst) (cdr rst))
192                 (list (reverse lst) rst)))))))
193
194;; Parser combinators
195
196(define (consume f) 
197  (lambda (s)
198    (let loop ((lst (list)) (rst s))
199      (match (f rst)
200             ((a rst)  (loop (cons a lst) rst))
201             (else  (list (reverse lst) rst))))))
202
203
204(define (consume-count n f)
205  (lambda (s)
206    (let loop ((n n) (lst (list)) (rst s))
207      (if (positive? n)
208          (match (or (f rst) (list #f s))
209                 ((x rst)  (and x (loop (- n 1) (cons x lst) rst))))
210          (list (reverse lst) rst)))))
211
212
213(define (consume-min-max m n f)
214  (lambda (s) 
215    (let loop ((m m) (n n) (lst (list)) (rst s))
216      (cond ((positive? m)
217             (match (f rst)
218                    ((a1 rst) (loop (- m 1) (- n 1) (cons a1 lst) rst))
219                    (else #f)))
220            ((<= n 0)   (list (reverse lst) rst))
221            (else
222             (match (f rst)
223                    ((a1 rst) (loop 0 (- n 1) (cons a1 lst) rst))
224                    (else #f)))))))
225
226;; Helper function for malformed ip address error messages
227
228(define (try-ip-literal->string s)
229  (let loop ((lst (list))  (rst s))
230    (match rst ((#\] . rst)  (uri-char-list->string (reverse lst)))
231           (()  (uri-char-list->string (reverse lst)))
232           (else (loop (cons (car rst) lst) (cdr rst))))))
233
234;; RFC 3986, section 2.1
235;;
236;; Returns a 'pct-encoded' sequence of octets.
237;;
238(define (pct-encode char-list char-set)
239  (define (hex-digit i)
240    (and (>= i 0) (< i 16)
241         (car (string->list (string-upcase (number->string i 16))))))
242  (reverse (fold (lambda (c cl)
243                   (if (char-set-contains? char-set c)
244                       (let* ((x (char->integer c))
245                              (h1 (hex-digit (quotient x 16)))
246                              (h2 (hex-digit (remainder x 16))))
247                         (cons `(#\% ,h1 ,h2) cl))
248                       (cons c cl)))
249                 (list) char-list)))
250
251;; Inverse operation: 'pct-decode' a sequence of octets.
252
253(define (pct-decode char-list char-set)
254  (define (octet-decode h1 h2)
255    (string->number (list->string (list h1 h2)) 16))
256  (map (lambda (c)
257        (match c
258               ((#\% h1 h2) (let ((dc (integer->char (octet-decode h1 h2))))
259                              (if (char-set-contains? char-set dc) dc c)))
260               (else c)))
261       char-list))
262
263
264;; RFC3986, section 2.2
265;;
266;; Reserved characters.
267;;
268
269(define char-set:gen-delims (string->char-set ":/?#[]@"))
270(define char-set:sub-delims (string->char-set "!$&'()*+,;="))
271
272(define char-set:uri-reserved (char-set-union char-set:gen-delims char-set:sub-delims))
273
274;;  RFC3986, section 2.3
275;;
276;;  "Unreserved" characters.
277;;
278
279(define char-set:uri-unreserved 
280  (char-set-union char-set:letter+digit (string->char-set "-_.~")))
281
282
283
284;;  RFC3986, section 3
285;;
286;;   URI         = scheme ":" hier-part [ "?" query ] [ "#" fragment ]
287;;
288;;   hier-part   = "//" authority path-abempty
289;;               / path-abs
290;;               / path-rootless
291;;               / path-empty
292
293;; TODO: Export a modified version of this one, to match absolute-uri
294;;       (modified = throw an error instead of #f)
295(define (uri s)
296  (let ((s (if (string? s) (uri-string->normalized-char-list s) s)))
297    (match (scheme s)
298           ((us rst)
299            (match-let* (((ua up rst)   (hier-part rst))
300                         ((uq rst)      (match rst ((#\? . rst) (query rst))
301                                               (else (list #f rst))))
302                         ((uf rst)      (match rst ((#\# . rst) (fragment rst))
303                                               (else (list #f rst)))))
304                        (make-URI scheme: (string->symbol (list->string us)) authority: ua 
305                                  path: (uri-path-list->path up) query: (and uq (uri-char-list->string uq))
306                                  fragment: (and uf (uri-char-list->string uf)))))
307         (else #f))))
308
309(define (uri? u)
310  (and (uri-reference? u) (uri-scheme u) #t))
311
312(define (uri-path-list->path pcl)
313  (let ((cs (char-set-union char-set:uri-unreserved (char-set #\/))))
314    (match pcl
315           (('/ . rst) (cons '/ (map (lambda (c)
316                                       (uri-char-list->string (pct-decode c cs)))
317                                     rst)))
318           (else (map (lambda (c)
319                        (uri-char-list->string (pct-decode c cs)))
320                      pcl)))))
321
322(define (hier-part s)
323  (match s ((#\/ #\/ . rst) 
324            (match-let* (((ua rst)  (authority rst))
325                         ((up rst)  (path-abempty rst)))
326                        (list ua up rst)))
327         (else (match-let (((up rst) (or (path-abs s) (path-rootless s) (list '() s))))
328                          (list #f up rst)))))
329
330;;  RFC3986, section 3.1
331
332(define scheme0 (many scheme-char?))
333(define (scheme s)
334  (match (scheme0 s)
335         ((ss (#\: . rst))  (list ss rst))
336         (else #f)))
337
338(define char-set:scheme
339  (char-set-union char-set:letter+digit (string->char-set "+-.")))
340
341
342;;  RFC3986, section 3.2
343;;
344;;     authority     = [ userinfo "@" ] host [ ":" port ]
345
346(define (authority s)
347  (match-let* (((uu uw rst)   (or (userinfo s) (list #f #f s)))
348               ((uh rst)      (host rst))
349               ((up rst)      (or (port rst) (list #f rst))))
350              (list (make-URIAuth username: (and uu (uri-char-list->string uu)) 
351                                  password: (and uw (uri-char-list->string uw))
352                                  host: (uri-char-list->string uh) 
353                                  port: (and (pair? up) (string->number (list->string up))))
354                    rst)))
355
356;;  RFC3986, section 3.2.1
357;;
358;;     userinfo      = *( unreserved / pct-encoded / sub-delims / ":" )
359;;
360;; We split this up in the leading part without colons ("username") and
361;; everything after that ("password"), including extra colons.
362;;
363;; The RFC is not very clear, but it does mention this:
364;;   "The userinfo subcomponent may consist of a user name and,
365;;    optionally, scheme-specific information about how to gain
366;;    authorization to access the resource."
367;;
368;; The grammar allows multiple colons, and the RFC then continues:
369;;   "Applications should not render as clear text any data after
370;;    the first colon (":") character found within a userinfo
371;;    subcomponent unless the data after the colon is the empty
372;;    string (indicating no password)."
373
374(define userinfo0  (many (uchar ";&=+$,")))
375(define userinfo1  (many (uchar ";&=+$,:")))
376
377(define (userinfo s)
378  (match (userinfo0 s)
379         ((uu ( #\: . rst))   (match (userinfo1 rst)
380                                     ((up ( #\@ . rst) ) (list uu up rst))
381                                     (else #f)))
382         ((uu ( #\@ . rst)) (list uu #f rst))
383         (else #f)))
384
385
386;;  RFC3986, section 3.2.2
387;;
388;;     host          = IP-literal / IPv4address / reg-name
389;;     IP-literal    = "[" ( IPv6address / IPvFuture  ) "]"
390;;     IPvFuture     = "v" 1*HEXDIG "." 1*( unreserved / sub-delims / ":" )
391
392(define (host s)  (or (ip-literal s) (ipv4-address s) (reg-name s)))
393
394(define (ip-literal s)
395  (match s ((#\[ . rst) 
396            (match (or (ipv6-address rst) (ipv-future rst))
397                   ((ua (#\] . rst))  (list ua rst))
398                   (else (error 'ip-literal "malformed ip literal" (try-ip-literal->string rst)))))
399         (else #f)))
400
401(define ipv-future0  (many ipv-future-char?))
402
403(define (ipv-future s)
404  (match s ((#\v (? hexdigit-char?) #\. . rst)  (ipv-future0 rst))
405         (else #f)))
406
407(define char-set:ipv-future 
408  (char-set-union char-set:uri-unreserved char-set:sub-delims (char-set #\;)))
409
410
411
412;; IPv6address =                                  6( h16 ":" ) ls32
413;;                   /                       "::" 5( h16 ":" ) ls32
414;;                   / [               h16 ] "::" 4( h16 ":" ) ls32
415;;                   / [ *1( h16 ":" ) h16 ] "::" 3( h16 ":" ) ls32
416;;                   / [ *2( h16 ":" ) h16 ] "::" 2( h16 ":" ) ls32
417;;                   / [ *3( h16 ":" ) h16 ] "::"    h16 ":"   ls32
418;;                   / [ *4( h16 ":" ) h16 ] "::"              ls32
419;;                   / [ *5( h16 ":" ) h16 ] "::"              h16
420;;                   / [ *6( h16 ":" ) h16 ] "::"
421
422;;       ls32        = ( h16 ":" h16 ) / IPv4address
423;;                   ; least-significant 32 bits of address
424
425;;       h16         = 1*4HEXDIG
426;;                   ; 16 bits of address represented in hexadecimal
427
428
429(define (ipv6-address s)
430  (or (match (u6-h4c s) ;; 6( h16 ":" ) ls32
431
432             ((a2 rst)  (match (ls32 rst)
433                               ((a3 rst)  (list (append (concatenate a2) a3) rst))
434                               (else #f)))
435             (else #f))
436      (match s          ;; "::" 5( h16 ":" ) ls32
437             ((#\: #\: . rst) 
438              (match (u5-h4c rst)
439                     ((a2 rst)  (match (ls32 rst)
440                                       ((a3 rst)  (list (append (list #\: #\:) (concatenate a2) a3) rst))
441                                       (else #f)))))
442             (else #f))
443      (match (u_opt_n_h4c_h4 0 s)
444             ((a1 rst) (match rst
445                              ((#\: #\: . rst) 
446                               (match (u4-h4c rst)
447                                      ((a2 rst)  (match (ls32 rst)
448                                                        ((a3 rst) 
449                                                         (list (append (concatenate a1) (list #\: #\:) 
450                                                                       (concatenate a2) a3) rst))
451                                                        (else #f)))
452                                      (else #f)
453                                      ))
454                              (else #f)))
455              (else #f))
456      (match (u_opt_n_h4c_h4 1 s)
457             ((a1 rst) 
458                      (match rst       
459                              ((#\: #\: . rst) 
460                               (match (u3-h4c rst)
461                                      ((a2 rst)  (match (ls32 rst)
462                                                        ((a3 rst) 
463                                                         (list (append (concatenate a1) (list #\: #\:) 
464                                                                       (concatenate a2) a3) rst))
465                                                        (else #f)))
466                                      (else #f)
467                                      ))
468                              (else #f)))
469              (else #f))
470      (match (u_opt_n_h4c_h4 2 s)
471             ((a1 rst) (match rst       
472                              ((#\: #\: . rst) 
473                               (match (u2-h4c rst)
474                                      ((a2 rst)  (match (ls32 rst)
475                                                        ((a3 rst)  (list (append (concatenate a1) (list #\: #\:) 
476                                                                                 (concatenate a2) a3) rst))
477                                                        (else #f)))
478                                      (else #f)
479                                      ))
480                              (else #f)))
481              (else #f))
482      (match (u_opt_n_h4c_h4 3 s)
483             ((a1 rst) (match rst       
484                              ((#\: #\: . rst) 
485                               (match (h4c rst)
486                                      ((a2 rst)  (match (ls32 rst)
487                                                        ((a3 rst)  (list (append (concatenate a1) (list #\: #\:) 
488                                                                                 (concatenate a2) a3) rst))
489                                                        (else #f)))
490                                      (else #f)
491                                      ))
492                              (else #f)))
493              (else #f))
494      (match (u_opt_n_h4c_h4 4 s)
495             ((a1 rst) (match rst       
496                              ((#\: #\: . rst) 
497                               (match (ls32 rst)
498                                      ((a3 rst)  (list (append (concatenate a1) (list #\: #\:) a3) rst))
499                                      (else #f)))
500                              (else #f)))
501              (else #f))
502      (match (u_opt_n_h4c_h4 5 s)
503             ((a1 rst) (match rst       
504                              ((#\: #\: . rst) 
505                               (match (h4 rst)
506                                      ((a3 rst)  (list (append (concatenate a1) (list #\: #\:) a3) rst))
507                                      (else #f)))
508                              (else #f)))
509              (else #f))
510      (match (u_opt_n_h4c_h4 6 s)
511             ((a1 rst) (match rst       
512                              ((#\: #\: . rst) 
513                               (list (append (concatenate a1) (list #\: #\:)) rst))
514                              (else #f)))
515              (else #f))
516      (error 'ipv6-address "malformed ipv6 address" (try-ip-literal->string s))))
517
518
519
520(define (u_opt_n_h4c_h4 n s)
521  (match ((consume-min-max 0 n h4c) s)
522         ((a1 rst)  (match (h4 rst)
523                           ((a2 rst) (list (append a1 (list a2)) rst))
524                           (else #f)))
525         (else #f)))
526
527(define (ls32 s)
528  (match (h4c s)
529         ((a1 rst) (match (h4 rst)
530                          ((a2 rst)  (list (append a1 a2) rst))
531                          (else (ipv4-address s))))
532         (else (ipv4-address s))))
533
534(define (h4c s)
535  (match (h4 s)
536         ((a1 (#\: (and r1 (not #\:)) . rst))
537          (list (append a1 (list #\:)) (cons r1 rst)))
538         (else #f)))
539
540(define u6-h4c (consume-count 6 h4c))
541(define u5-h4c (consume-count 5 h4c))
542(define u4-h4c (consume-count 4 h4c))
543(define u3-h4c (consume-count 3 h4c))
544(define u2-h4c (consume-count 2 h4c))
545
546(define h4 (count-min-max 1 4 hexdigit-char?))
547
548(define (ipv4-address s)
549  (match (dec-octet s)
550         ((a1 (#\. rst)) 
551          (match (dec-octet rst)
552                 ((a2 (#\. rst)) 
553                  (match (dec-octet rst)
554                         ((a3 (#\. rst)) 
555                          (match (dec-octet rst)
556                                 ((a4 rst)  (list (append a1 #\. a2 #\. a3 #\. a4) rst))
557                                 (else #f)))
558                         (else #f)))
559                 (else #f)))
560         (else #f)))
561
562(define (ipv4-octet? lst)
563  (and (every (lambda (x) (char-set-contains? char-set:digit x)) lst)
564       (let ((num (string->number (list->string lst))))
565         (and num (>= num 0) (<= num 255)))))
566
567(define (dec-octet s)
568  (match ((count-min-max 1 3 char-numeric?) s)
569         (((and a1 (? ipv4-octet?)) rst)  (list a1 rst))
570         (else #f)))
571
572(define reg-name
573  (count-min-max 0 255 (lambda (c) (or (pct-encoded? c) 
574                                       (unreserved-char? c) 
575                                       (char-set-contains? char-set:sub-delims c) ))))
576
577;;  RFC3986, section 3.2.3
578;;
579;;     port          = *DIGIT
580
581(define port0 (many char-numeric?))
582
583(define (port s)
584  (match s ((#\: . rst)  (port0 rst))
585         (else #f)))
586
587
588;;
589;;  RFC3986, section 3.3
590;;
591;;   path          = path-abempty    ; begins with "/" or is empty
592;;                 / path-abs        ; begins with "/" but not "//"
593;;                 / path-noscheme   ; begins with a non-colon segment
594;;                 / path-rootless   ; begins with a segment
595;;                 / path-empty      ; zero characters
596;;
597;;  oddly, "path" is never used in the grammar. The following are used
598;;  in "hier-part" and "relative-ref", however:
599;;
600;;   path-abempty  = *( "/" segment )
601;;   path-abs      = "/" [ segment-nz *( "/" segment ) ]
602;;   path-noscheme = segment-nzc *( "/" segment )
603;;   path-rootless = segment-nz *( "/" segment )
604;;   path-empty    = 0<pchar>
605;;
606;;   segment       = *pchar
607;;   segment-nz    = 1*pchar
608;;   segment-nzc   = 1*( unreserved / pct-encoded / sub-delims / "@" )
609;;
610;;   pchar         = unreserved / pct-encoded / sub-delims / ":" / "@"
611
612(define (slash-segment s)
613  (match s
614         ((#\/ . rst)
615          (or (slash-segment rst)
616              (match (segment rst)
617                     ((ss rst)  (list ss rst))
618                     (else #f))))
619         (else  #f)))
620
621(define pchar (uchar ":@"))
622
623(define segment (many pchar))
624
625(define segment-nz (many1 pchar))
626
627(define segment-nzc (many1 (uchar "@")))
628
629(define (path-abempty s)
630  (match ((consume slash-segment) s)
631         ((() rst) (list (list) rst))
632         ((path rst) (list (cons '/ path) rst))))
633
634(define (path-abs s)
635  (match s
636         ((#\/)          (list (list '/ (list))  (list)))
637         ((#\/ . rst)    (match (path-rootless rst)
638                                ((lst rst) (list (cons '/ lst) rst))
639                                (else #f)))
640         (else #f)))
641
642(define (path-noscheme s)
643  (match (segment-nzc s)
644         ((s1 rst)  (match ((consume slash-segment) rst)
645                           ((ss rst) (list (cons s1 ss) rst))))
646         (else #f)))
647
648(define (path-rootless s)
649  (match (segment-nz s)
650         ((s1 rst)  (match ((consume slash-segment) rst)
651                           ((ss rst) (list (cons s1 ss) rst))))
652         (else #f)))
653
654;;  RFC3986, section 3.4
655;;
656;;   query         = *( pchar / "/" / "?" )
657
658(define query0  (many (uchar ":@/?")))
659(define (query s)
660  (match (query0 s)
661         ((ss rst)  (list ss rst))
662         (else #f)))
663
664;;  RFC3986, section 3.5
665;;   fragment         = *( pchar / "/" / "?" )
666
667(define fragment0  (many (uchar ":@/?")))
668(define (fragment s)
669  (match (fragment0 s)
670         ((ss rst)  (list ss rst))
671         (else #f)))
672
673;;  Reference, Relative and Absolute URI forms
674;;
675;;  RFC3986, section 4.1
676
677(define (uri-reference s)
678  (let ((s (if (string? s) (uri-string->normalized-char-list s) s)))
679    (or (uri s) (relative-ref s))))
680
681;; (define uri-reference? URI) ; Already defined as URI? (struct predicate)
682
683;;  RFC3986, section 4.2
684;;
685;;   relative-URI  = relative-part [ "?" query ] [ "#" fragment ]
686;;
687;;   relative-part = "//" authority path-abempty
688;;                 / path-abs
689;;                 / path-noscheme
690;;                 / path-empty
691
692;; TODO: Export a modified version of this  (one that accepts a string
693;;       and throws an exception instead of returning #f)
694(define (relative-ref s)
695  (and (not (scheme s))
696       (match-let* (((ua up rst)  (relative-part s))
697                    ((uq rst)     (match rst ((#\? . rst) (query rst))
698                                         (else (list #f rst))))
699                    ((uf rst)     (match rst ((#\# . rst) (fragment rst))
700                                         (else (list #f rst)))))
701                   (make-URI scheme: #f authority: ua path: (uri-path-list->path up) 
702                             query: (and uq (uri-char-list->string uq))
703                             fragment: (and uf (uri-char-list->string uf))))))
704
705(define (relative-ref? u)
706  (and (uri-reference? u) (not (uri-scheme u))))
707
708(define (relative-part s)
709  (match s
710         ((#\/ #\/ . rst)
711          (match-let* (((ua rst)  (authority rst))
712                       ((up rst)  (path-abempty rst)))
713                      (list ua up rst)))
714         (else (match-let* (((up rst)  (or (path-abs s) (path-noscheme s) (list (list) s))))
715                           (list #f up rst))))) 
716
717
718
719;;  RFC3986, section 4.3
720
721(define (absolute-uri s)
722  (let ((s (if (string? s) (uri-string->normalized-char-list s) s)))
723    (match (scheme s)
724           ((us rst) 
725            (match-let* (((ua up rst)  (hier-part rst))
726                         ((uq rst)     (match rst ((#\? . rst)  (query rst))
727                                              (else (list #f rst)))))
728                        (match rst
729                               ((#\# . rst) (error 'absolute-uri "fragments are not permitted in absolute URI"))
730                               (else (make-URI scheme: (string->symbol (list->string us)) authority: ua 
731                                               path: (uri-path-list->path up)
732                                               query: (and uq (uri-char-list->string uq))
733                                               fragment: #f)))))
734           (else (error 'absolute-uri "no scheme found in URI string")))))
735                     
736
737(define (absolute-uri? u)
738  (and (uri-reference? u) (not (relative-ref? u)) (not (uri-fragment u))))
739
740;; Turns a URI into a string.
741;;
742;; Uses a supplied function to map the userinfo part of the URI.
743;;
744
745(define (uri->string uri . rest)
746   (let-optionals rest ((userinfomap (lambda (u pw) (string-append u ":******" ))))
747    (match uri
748           (($ URI scheme authority path query fragment)
749            (string-append
750             ((lambda (x) (or (and x (string-append (->string x) ":")) ""))  scheme)
751             (if authority
752                 (string-append (uri-auth->string authority userinfomap))
753                 "")
754             (path->string path)
755             (if query (string-append "?" query) "")
756             (if fragment (string-append  "#" fragment) "")))
757           (else #f))))
758
759(define (uri-auth->string uri-auth userinfomap)
760  (match uri-auth
761         (($ URIAuth username password host port)
762          (string-append "//" (if username
763                                  ((lambda (x) (or (and x (string-append x "@")) ""))
764                                   (userinfomap username password)) "")
765                         host ((lambda (x) (or (and x (string-append ":" (->string x))) ""))
766                               port)))
767         (else #f)))
768                         
769(define (path->string path)
770  (match path
771         (('/ . segments)     (string-append "/" (join-segments segments)))
772         (((? protect?) . _)  (join-segments (cons "." path)))
773         (else                (join-segments path))))
774
775(define (join-segments segments)
776  (string-intersperse
777   (map (lambda (segment)
778          (uri-encode-string segment (char-set #\/)))
779        segments) "/"))
780
781;; Section 4.2; if the first segment contains a colon, it must be prefixed "./"
782(define (protect? sa) (string-index sa #\:))
783
784; specific: ((uri-authority uri) (uri-path uri) (uri-query uri)).
785
786(define (uri->list uri . rest)
787  (let-optionals rest ((userinfomap (lambda (u pw) (string-append u ":******" ))))
788    (match uri
789           (($ URI scheme authority path query fragment)
790            `(,scheme (,(uri-auth->list authority userinfomap) ,path ,query) ,fragment))
791           (else #f))))
792
793(define (uri-auth->list uri-auth userinfomap)
794  (match uri-auth
795         (($ URIAuth username password regname port)
796          `(,(if (and username password) (userinfomap username password) #f) ,regname ,port ))
797         (else #f)))
798                         
799
800;;  Percent encoding and decoding
801
802(define (uri-encode-string str #!optional (char-set (char-set-complement
803                                                     char-set:uri-unreserved)))
804  (let ((clst (string->list str)))
805    (uri-char-list->string
806     (pct-encode clst char-set))))
807
808(define (uri-decode-string str #!optional (char-set char-set:full))
809  (uri-char-list->string (pct-decode (uri-string->char-list str) char-set)))
810   
811(define (uri-string->normalized-char-list str)
812  (pct-decode (uri-string->char-list str) char-set:uri-unreserved))
813
814
815;; Convert a URI character list to a string
816
817(define (uri-char-list->string s)
818  (reverse-list->string 
819   (fold (lambda (x ax)
820           (cond ((char? x) (cons x ax))
821                 ((list? x) (append-reverse x ax)))) (list) s)))
822   
823;; Convert a string to a URI character list
824
825(define (uri-string->char-list s)
826  (let loop ((cs (list)) (lst (string->list s)))
827    (if (null? lst) (reverse cs)
828        (match lst
829               ((#\% h1 h2 . rst)  (loop (cons (list #\% h1 h2) cs) rst))
830               (((and c (? char?)) . rst)  (loop (cons c cs) rst))))))
831   
832;;
833;;  Resolving a relative URI relative to a base URI
834;;
835;;  Returns a new URI which represents the value of the first URI
836;;  interpreted as relative to the second URI.
837;;
838;;  For example:
839;;
840;;  (uri->string (relative-to (uri-reference "foo") (uri "http://bar.org/")) )
841;;         => "http://bar.org/foo"
842;;
843;;  Algorithm from RFC3986, section 5.2.2
844;;
845
846(define (uri-relative-to ref base)
847  (and (uri-reference? ref) (uri-reference? base)
848       (cond ((uri-scheme ref)      (just-segments ref))
849             ((uri-authority ref)   (let ((x (just-segments ref)))
850                                      (URI-scheme-set! x (uri-scheme base))
851                                      x))
852
853             ((let ((p (uri-path ref))) (and (not (null? p)) p)) =>
854              (lambda (ref-path)
855                (if (and (pair? ref-path) (eq? '/ (car ref-path)))
856                    (let ((x (just-segments ref)))
857                      (URI-scheme-set! x (uri-scheme base))
858                      (URI-authority-set! x (uri-auth base))
859                      x)
860                    (let ((x (udup ref)))
861                      (URI-scheme-set! x (uri-scheme base))
862                      (URI-authority-set! x (uri-auth base))
863                      (URI-path-set! x (merge-paths base x))
864                      (just-segments x)))))
865             ((uri-query ref)       (let ((x (udup ref)))
866                                      (URI-scheme-set! x (uri-scheme base))
867                                      (URI-authority-set! x (uri-auth base))
868                                      (URI-path-set! x (list ""))
869                                      (URI-path-set! x (merge-paths base x))
870                                      (just-segments x)))
871
872             (else                  (let ((x (just-segments ref)))
873                                      (URI-scheme-set! x (uri-scheme base))
874                                      (URI-authority-set! x (uri-auth base))
875                                      (URI-path-set! x (uri-path base))
876                                      (URI-query-set! x (uri-query base))
877                                      x)))))
878
879(define (just-segments u)
880  (let ((p (remove-dot-segments (uri-path u))))
881    (make-URI scheme: (uri-scheme u) authority: (uri-auth u) path: p
882              query: (uri-query u) fragment: (uri-fragment u))))
883
884(define (merge0 pb pr)
885  (let* ((rpb  (reverse pb))
886         (pb1  (reverse (if (pair? rpb) (cdr rpb) rpb))))
887    (append pb1 pr)))
888
889(define (merge-paths b r)
890  (let ((ba (uri-authority b))
891        (pb (uri-path b))
892        (pr (uri-path r)))
893    (let ((mp (if (and ba (null? pb))
894                  (merge0 '(/ "") pr) ; RFC3986, section 5.2.3, first bullet
895                  (merge0 pb pr))))
896      mp)))
897
898;;  Remove dot segments, but protect leading '/' character
899
900(define (remove-dot-segments ps)
901  (match ps
902         (('/ . rst)   (cons '/ (elim-dots rst)))
903         (else         (elim-dots ps))))
904
905(define (elim-dots ps)
906  (let loop ((ps ps) (lst (list)))
907    (if (null? ps) (reverse lst)
908        (match ps
909               (("." . rst)
910                (loop rst (match lst
911                                 (("" dir . rest) lst)
912                                 ((file . rest) (cons "" lst))
913                                 (else (list "")))))
914               ((".." . rst)
915                (loop rst (match lst
916                                 (("" dir . rest) (cons "" rest))
917                                 ((file . rest) (cons "" rest))
918                                 (else (list "")))))
919               (("")
920                (loop (list) (match lst
921                                    (("" . rst2) lst)
922                                    (else (cons "" lst)))))
923               ((x . rst)
924                (loop rst (match lst
925                                 (("" . rst2) (cons x rst2))
926                                 (else (cons x lst)))))))))
927
928;;
929;; Finding a URI relative to a base URI
930;;
931;; Returns a new URI which represents the relative location of the
932;; first URI with respect to the second URI.  Thus, the values
933;; supplied are expected to be absolute URIs, and the result returned
934;; may be a relative URI.
935;;
936;; Example:
937;;
938;; (uri->string
939;;  (uri-relative-from (uri "http://example.com/Root/sub1/name2#frag")
940;;                     (uri "http://example.com/Root/sub2/name2#frag")))
941;;    ==> "../sub1/name2#frag"
942;;
943
944
945(define (uri-relative-from uabs base)
946  (cond ((ucdiff? uri-scheme uabs base)      (udup uabs))
947        ((ucdiff? uri-authority uabs base)   (let ((x (udup uabs)))
948                                               (URI-scheme-set! x #f)
949                                               x))
950        ;; Special case: no relative representation for http://a/ -> http://a
951        ;; ....unless that should be a path of ("..")
952        ((null? (uri-path uabs))             (let ((x (udup uabs)))
953                                               (URI-scheme-set! x #f)
954                                               x))
955        ((ucdiff? uri-path uabs base)       
956         (let ((x    (udup uabs))
957               (path (rel-path-from (remove-body-dot-segments (uri-path uabs))
958                                    (remove-body-dot-segments (uri-path base)))))
959           (URI-scheme-set! x #f)
960           (URI-authority-set! x #f)
961           (URI-path-set! x path)
962           x))
963        ((ucdiff? uri-query uabs base) 
964         (let ((x (udup uabs)))
965           (URI-scheme-set! x #f)
966           (URI-authority-set! x #f)
967           (URI-path-set! x (list))
968           x))
969        (else                            
970         (let ((x (udup uabs)))
971           (URI-scheme-set! x #f)
972           (URI-authority-set! x #f)
973           (URI-query-set! x #f)
974           (URI-path-set! x (list))
975           x))))
976
977
978(define (udup u)
979  (make-URI scheme: (uri-scheme u) authority: (uri-auth u) path: (uri-path u)
980            query: (uri-query u) fragment: (uri-fragment u)))
981
982(define (ucdiff? sel u1 u2)
983  (let ((s1 (sel u1))
984        (s2 (sel u2)))
985    (not (cond ((and (URIAuth? s1) (URIAuth? s2))
986                (not (or (ucdiff? uri-username u1 u2) (ucdiff? uri-host u1 u2) (ucdiff? uri-port u1 u2))))
987               ((and (list? s1) (list? s2))       (every equal? s1 s2))
988               ((and (string? s1) (string? s2))   (string=? s1 s2))
989               (else                              (eq? s1 s2))))))
990
991(define (remove-body-dot-segments p)
992  (or (and (pair? p)
993           (let ((r (reverse p)))
994             (reverse (cons (car r) (remove-dot-segments (cdr r))))))
995      p))
996
997(define (rel-path-from pabs base)
998  (match (list pabs base)
999         ((pabs ()) pabs)
1000         ((() base) (list))
1001         ;; Construct a relative path segment if the paths share a
1002         ;; leading segment other than a leading '/'
1003         ((('/ . (and sa1 (ra1 . ra2))) ('/ . (and sb1 (rb1 . rb2))))
1004          (make-rel-path
1005           (if (string=? ra1 rb1)
1006               (rel-path-from1 sa1 sb1)
1007               pabs)))
1008         (else (error 'rel-path-from "Both URI paths must be absolute" pabs base))))
1009
1010(define (make-rel-path x)
1011  (match x
1012         ((or ('/ . rst) ("." . rst) (".." rst)) x)
1013         (else (cons "." x))))
1014
1015;;  rel-path-from1 strips off trailing names from the supplied paths,
1016
1017(define (rel-path-from1 pabs base)
1018  (match-let* (((na . sa)  (reverse pabs)) 
1019               ((nb . sb)  (reverse base)))
1020     (let ((rp (rel-segs-from (reverse sa) (reverse sb))))
1021       (if (null? rp)  (cond ((string=? na nb)  (list))
1022                             (else              (list na)))
1023           (append rp (list na))))))
1024
1025                         
1026;;  rel-segs-from discards any common leading segments from both paths,
1027;;  then invokes dif-segs-from to calculate a relative path from the end
1028;;  of the base path to the end of the target path.  The final name is
1029;;  handled separately, so this deals only with "directory" segments.
1030
1031(define (rel-segs-from sabs base)
1032  (cond ((and (null? sabs) (null? base))  (list))
1033        ((or (null? sabs) (null? base))   (dif-segs-from sabs base))
1034        (else (match-let (((sa1 . ra1) sabs)
1035                          ((sb1 . rb1) base))
1036                         (if (string=? sa1 sb1)
1037                             (rel-segs-from ra1 rb1)
1038                             (dif-segs-from sabs base))))))
1039
1040;;  dif-segs-from calculates a path difference from base to target,
1041;;  not including the final name at the end of the path (i.e. results
1042;;  always ends with '/')
1043;;
1044;;  This function operates under the invariant that the supplied value
1045;;  of sabs is the desired path relative to the beginning of base.
1046;;  Thus, when base is empty, the desired path has been found.
1047
1048(define (dif-segs-from sabs base)
1049  (if (null? base) sabs (dif-segs-from (cons ".." sabs)  (cdr base))))
1050
1051
1052
1053;; Other normalization functions
1054;;
1055;; Case normalization; cf. RFC3986 section 6.2.2.1
1056
1057(define (uri-normalize-case uri)
1058  (let* ((normalized-uri (uri-reference (normalize-pct-encoding (uri->string uri (lambda (user pass) (conc user ":" pass))))))
1059         (scheme         (string->symbol (string-downcase (->string (uri-scheme uri)))))
1060         (host           (normalize-pct-encoding (string-downcase (uri-host uri)))))
1061    (update-uri normalized-uri scheme: scheme host: host)))
1062
1063(define (normalize-pct-encoding str)
1064  (uri-char-list->string
1065   (map (lambda (c) (match c
1066                           ((#\% h1 h2)  `(#\% ,(char-upcase h1) ,(char-upcase h2)))
1067                           (else c)))
1068        (uri-string->normalized-char-list str))))
1069
1070;;  Path segment normalization; cf. RFC3986 section 6.2.2.4
1071
1072(define (uri-normalize-path-segments uri)
1073  (let ((u1      (udup uri))
1074        (path    (remove-dot-segments (uri-path uri))))
1075    (URI-path-set! u1 path)
1076    u1))
Note: See TracBrowser for help on using the repository browser.