source: project/release/3/mime/trunk/quoted-printable.scm @ 7686

;;;
;;; quoted-printable.scm - quoted-printable encoding/decoding routine
;;;  
;;;   Copyright (c) 2000-2003 Shiro Kawai, All rights reserved.
;;;   
;;;   Redistribution and use in source and binary forms, with or without
;;;   modification, are permitted provided that the following conditions
;;;   are met:
;;;   
;;;   1. Redistributions of source code must retain the above copyright
;;;      notice, this list of conditions and the following disclaimer.
;;;  
;;;   2. Redistributions in binary form must reproduce the above copyright
;;;      notice, this list of conditions and the following disclaimer in the
;;;      documentation and/or other materials provided with the distribution.
;;;  
;;;   3. Neither the name of the authors nor the names of its contributors
;;;      may be used to endorse or promote products derived from this
;;;      software without specific prior written permission.
;;;  
;;;   THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
;;;   "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
;;;   LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
;;;   A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
;;;   OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
;;;   SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
;;;   TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
;;;   PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
;;;   LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
;;;   NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
;;;   SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
;;;  
;;;  $Id: quoted-printable.scm,v 1.6 2003/07/05 03:29:12 shirok Exp $
;;;
;;; Ported to Chicken by Hans Bulfone <jsb@nil.at>


;; Ref: RFC2045 section 6.7  <http://www.rfc-editor.org/rfc/rfc2045.txt>

(declare
 (unit mime:quoted-printable)
 (usual-integrations)
 (export quoted-printable-encode quoted-printable-encode-string
         quoted-printable-decode quoted-printable-decode-string))
(require-extension srfi-13)

(define read-byte
  (let ((read-char read-char)
        (char->integer char->integer))
    (lambda ()
      (let ((ch (read-char)))
        (if (eof-object? ch)
            ch
            (char->integer ch))))))
(define write-byte
  (let ((write-char write-char)
        (integer->char integer->char))
    (lambda (b)
      (write-char (integer->char b)))))
(define (hexdigit->integer ch)
  (cond
   ((and (char>=? ch #\0) (char<=? ch #\9))
    (fx- (char->integer ch) (char->integer #\0)))
   ((and (char>=? ch #\A) (char<=? ch #\F))
    (fx+ 10 (fx- (char->integer ch) (char->integer #\A))))
   ((and (char>=? ch #\a) (char<=? ch #\f))
    (fx+ 10 (fx- (char->integer ch) (char->integer #\a))))
   (else #f)))

(define (quoted-printable-encode #!key (binary? #f))
  (define (esc c)
    (display "=")
    (display (string-pad (string-upcase (number->string c 16)) 2 #\0)))
  (let loop ((c (read-byte)) (lcnt 0))
    (cond
     ((eof-object? c))

     ((>= lcnt 73)                      ; soft newline
      (display "=\r\n")
      (loop c 0))

     ((= c #x3d)                        ; '='
      (display "=3D")
      (loop (read-byte) (+ lcnt 3)))

     ((or (= c #x20) (= c #x09))
      (let ((c1 (read-byte)))
        (if (and (not binary?) (or (eqv? c1 #x0d) (eqv? c1 #x0a)))
            (begin (esc c) (loop c1 (+ lcnt 3)))
            (begin (write-byte c) (loop c1 (+ lcnt 1))))))

     ((and (not binary?) (= c #x0d))
      (display "\r\n")
      (let ((c1 (read-byte)))
        (if (eqv? c1 #x0a)
            (loop (read-byte) 0)
            (loop c1 0))))
     ((and (not binary?) (= c #x0a))
      (display "\r\n")
      (loop (read-byte) 0))

     ((<= #x21 c #x7e)
      (write-byte c)
      (loop (read-byte) (+ lcnt 1)))

     (else
      (esc c)
      (loop (read-byte) (+ lcnt 3))))))

(define (quoted-printable-encode-string string . args)
  (with-output-to-string
    (lambda ()
      (with-input-from-string string
        (lambda ()
          (apply quoted-printable-encode args))))))

(define tab+space '(#\tab #\space))
(define (check-whitespace c chars)
  (cond
   ((or (eof-object? c) (char=? c #\newline) (char=? c #\return)) c)
   ((memv c tab+space)
    (check-whitespace (read-char) (cons c chars)))
   (else
    (for-each write-char (reverse chars))
    c)))

(define (quoted-printable-decode)
  (let loop ((c (read-char)))
    (cond
     ((eof-object? c))
     ((char=? c #\=)
      (let ((c1 (read-char)))
        (cond
         ((eof-object? c1)) ; illegal, but we recognize it as a soft newline

         ((char=? c1 #\newline)         ; soft newline
          (loop (read-char)))

         ((char=? c1 #\return)          ; soft newline
          (let ((c2 (read-char)))
            (if (char=? c2 #\newline) (loop (read-char)) (loop c2))))

         ((memv c1 tab+space)           ; possibly soft newline
          (let ((c2 (check-whitespace (read-char) (list c1 c))))
            (cond
             ((eof-object? c2))
             ((char=? c2 #\newline) (loop (read-char)))
             ((char=? c2 #\return)
              (let ((c3 (read-char)))
                (if (eqv? c3 #\newline)
                    (loop (read-char))
                    (loop c3))))
             (else (loop c2)))))

         ((hexdigit->integer c1)
          => (lambda (num1)
               (let ((c2 (read-char)))
                 (cond
                  ((eof-object? c2) (write-char c) (write-char c1))
                  ((hexdigit->integer c2)
                   => (lambda (num2)
                        (write-byte (+ (* num1 16) num2))
                        (loop (read-char))))
                  (else
                   (write-char c) (write-char c1) (loop c2))))))
         (else
          (write-char c) (loop c1)))))

     ((memv c tab+space)
      (loop (check-whitespace (read-char) (list c))))

     (else
      (write-char c) (loop (read-char))))))

(define (quoted-printable-decode-string string)
  (with-output-to-string
    (lambda ()
      (with-input-from-string string
        quoted-printable-decode))))