source: project/maintenance/make-branch.scm @ 7369

;;;; make-branch.scm - Copy egg directories into release branch - felix
; 
; (call without arguments for usage information)


(use utils runcmd miscmacros srfi-1)


(run-verbose #t)

(define *repository*
  "https://galinha.ucpel.tche.br/svn/chicken-eggs")

(define *ignore*
  '("maintenance"
    "release"
    "doc-indices"
    "wiki"
    "salmonella-custom-feeds"
    "chicken") )

(define *release* #f)
(define *eggs* #f)

(let loop ((args (command-line-arguments)))
  (match args
    (() #f)
    (("--dry-run" . more)
     (dry-run #t)
     (loop more) )
    ((x . more)
     (cond (*release*
            (push! x *eggs*)
            (loop more) )
           (else 
            (set! *release* (make-pathname "release" x))
            (loop more) ) ) ) ) )

(unless *release*
  (print "usage: make-branch.scm [--dry-run] RELEASE [FILENAME ...]")
  (exit 1))

(unless (file-exists? *release*)
  (error "no such release or invalid working directory" *release*))

(unless *eggs*
  (set! *eggs*
    (lset-difference 
     string=?
     (filter directory? (directory "."))
     *ignore*)))

(unless (dry-run)
  (print* "\nCopying " (length *eggs*) " eggs into release branch " *release*
          ".\n\n  Do you want to continue? ")
  (unless (string=? "yes" (read-line))
    (print "aborted.")
    (exit) ) )

(for-each
 (lambda (egg)
   (cond ((file-exists? (make-pathname *release* egg))
          (print egg ": branch already exists") )
         (else
          (when (and (not (null? (directory egg)))
                     (or (file-exists? (make-pathname egg "trunk"))
                         (file-exists? (make-pathname egg egg "setup")) 
                         (begin
                           (print* "\n`" egg "' doesn't seem to be an egg. Copy? ")
                           (string=? "yes" (read-line)))) )
            (run (svn cp ,(make-pathname *repository* egg)
                      ,(make-pathname (list *repository* *release*) egg) ) ) ) ) ) )
 (reverse *eggs*))