source: project/chicken/trunk/synrules.scm @ 13582

Last change on this file since 13582 was 13582, checked in by felix winkelmann, 11 years ago

fix for syntax-rules bug reported by Jim Ursetto

File size: 11.1 KB
Line 
1;; Copyright (c) 1993-2001 by Richard Kelsey and Jonathan Rees.
2;; All rights reserved.
3
4;; Redistribution and use in source and binary forms, with or without
5;; modification, are permitted provided that the following conditions
6;; are met:
7;; 1. Redistributions of source code must retain the above copyright
8;;    notice, this list of conditions and the following disclaimer.
9;; 2. Redistributions in binary form must reproduce the above copyright
10;;    notice, this list of conditions and the following disclaimer in the
11;;    documentation and/or other materials provided with the distribution.
12;; 3. The name of the authors may not be used to endorse or promote products
13;;    derived from this software without specific prior written permission.
14
15;; THIS SOFTWARE IS PROVIDED BY THE AUTHORS ``AS IS'' AND ANY EXPRESS OR
16;; IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
17;; OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
18;; IN NO EVENT SHALL THE AUTHORS BE LIABLE FOR ANY DIRECT, INDIRECT,
19;; INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
20;; NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
21;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
23;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
24;; THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
25
26; The syntax-rules macro (new in R5RS)
27
28;;; [Hacked slightly by Taylor R. Campbell to make it work in his
29;;; macro expander `riaxpander'.]
30
31;; [Hacked even more by Felix L. Winkelmann to make it work in his
32;; Hi-Lo expander]
33
34; Example:
35;
36; (define-syntax or
37;   (syntax-rules ()
38;     ((or)          #f)
39;     ((or e)        e)
40;     ((or e1 e ...) (let ((temp e1))
41;                      (if temp temp (or e ...))))))
42
43
44(##sys#extend-macro-environment
45 'syntax-rules
46 '()
47 (##sys#er-transformer
48  (lambda (exp r c)
49    (##sys#check-syntax 'syntax-rules exp '#(_ 2))
50    (let ((subkeywords (cadr exp))
51          (rules (cddr exp))
52          (ellipsis '...))
53      (when (symbol? subkeywords)
54        (##sys#check-syntax 'syntax-rules exp '(_ _ list . #(_ 0)))
55        (set! ellipsis subkeywords)
56        (set! subkeywords (car rules))
57        (set! rules (cdr rules)))
58      (##sys#process-syntax-rules ellipsis rules subkeywords r c)))))
59
60
61(define (##sys#process-syntax-rules ellipsis rules subkeywords r c)
62
63  (define %append '##sys#append)
64  (define %apply '##sys#apply)
65  (define %and (r 'and))
66  (define %car '##sys#car)
67  (define %cdr '##sys#cdr)
68  (define %vector? '##sys#vector?)
69  (define %vector-length '##sys#vector-length)
70  (define %vector-ref '##sys#vector-ref)
71  (define %vector->list '##sys#vector->list)
72  (define %list->vector '##sys#list->vector)
73  (define %>= '##sys#>=)
74  (define %= '##sys#=)
75  (define %+ '##sys#+)
76  (define %i (r 'i))
77  (define %compare (r 'compare))
78  (define %cond (r 'cond))
79  (define %cons '##sys#cons)
80  (define %else (r 'else))
81  (define %eq? '##sys#eq?)
82  (define %equal? '##sys#equal?)
83  (define %input (r 'input))
84  (define %l (r 'l))
85  (define %lambda (r 'lambda))
86  (define %let (r 'let))
87  (define %let* (r 'let*))
88  (define %list? '##sys#list?)
89  (define %list (r 'list))
90  (define %loop (r 'loop))
91  (define %map1 '##sys#map)
92  (define %map '##sys#map-n)
93  (define %null? '##sys#null?)
94  (define %or (r 'or))
95  (define %pair? '##sys#pair?)
96  (define %quote (r 'quote))
97  (define %rename (r 'rename))
98  (define %tail (r 'tail))
99  (define %temp (r 'temp))
100  (define %syntax-error '##sys#syntax-error-hook)
101  (define %ellipsis (r ellipsis))
102
103  (define (ellipsis? x)
104    (c x %ellipsis))
105
106  (define (make-transformer rules)
107    `(,%lambda (,%input ,%rename ,%compare)
108               (,%let ((,%tail (,%cdr ,%input)))
109                      (,%cond ,@(map process-rule rules)
110                              (,%else 
111                               (,%syntax-error
112                                "no rule matches form"
113                                ,%input))))))
114
115  (define (process-rule rule)
116    (if (and (pair? rule)
117             (pair? (cdr rule))
118             (null? (cddr rule)))
119        (let ((pattern (cdar rule))
120              (template (cadr rule)))
121          `((,%and ,@(process-match %tail pattern))
122            (,%let* ,(process-pattern pattern
123                                      %tail
124                                      (lambda (x) x))
125                    ,(process-template template
126                                       0
127                                       (meta-variables pattern 0 '())))))
128        (##sys#syntax-error-hook "ill-formed syntax rule" rule)))
129
130  ;; Generate code to test whether input expression matches pattern
131
132  (define (process-match input pattern)
133    (cond ((symbol? pattern)
134           (if (memq pattern subkeywords)
135               `((,%compare ,input (,%rename (syntax ,pattern))))
136               `()))
137          ((segment-pattern? pattern)
138           (process-segment-match input (car pattern)))
139          ((pair? pattern)
140           `((,%let ((,%temp ,input))
141                    (,%and (,%pair? ,%temp)
142                           ,@(process-match `(,%car ,%temp) (car pattern))
143                           ,@(process-match `(,%cdr ,%temp) (cdr pattern))))))
144          ((vector? pattern)
145           (process-vector-match input pattern))
146          ((or (null? pattern) (boolean? pattern) (char? pattern))
147           `((,%eq? ,input ',pattern)))
148          (else
149           `((,%equal? ,input ',pattern)))))
150
151  (define (process-segment-match input pattern)
152    (let ((conjuncts (process-match `(,%car ,%l) pattern)))
153      (if (null? conjuncts)
154          `((,%list? ,input))           ;+++
155          `((,%let ,%loop ((,%l ,input))
156                   (,%or (,%null? ,%l)
157                         (,%and (,%pair? ,%l)
158                                ,@conjuncts
159                                (,%loop (,%cdr ,%l)))))))))
160
161   (define (process-vector-match input pattern)
162     (let* ((len (vector-length pattern))
163            (segment? (and (>= len 2)
164                           (ellipsis? (vector-ref pattern (- len 1))))))
165       `((,%let ((,%temp ,input))
166          (,%and (,%vector? ,%temp)
167                 ,(if segment?
168                      `(,%>= (,%vector-length ,%temp) ,(- len 2))
169                      `(,%= (,%vector-length ,%temp) ,len))
170                 ,@(let lp ((i 0))
171                     (cond
172                      ((>= i len)
173                       '())
174                      ((and (= i (- len 2)) segment?)
175                       `((,%let ,%loop ((,%i ,i))
176                            (,%or (,%>= ,%i ,len)
177                                  (,%and ,@(process-match
178                                            `(,%vector-ref ,%temp ,%i)
179                                            (vector-ref pattern (- len 2)))
180                                         (,%loop (,%+ ,%i 1)))))))
181                      (else
182                       (append (process-match `(,%vector-ref ,%temp ,i)
183                                              (vector-ref pattern i))
184                               (lp (+ i 1)))))))))))
185 
186  ;; Generate code to take apart the input expression
187  ;; This is pretty bad, but it seems to work (can't say why).
188
189  (define (process-pattern pattern path mapit)
190    (cond ((symbol? pattern)
191           (if (memq pattern subkeywords)
192               '()
193               (list (list pattern (mapit path)))))
194          ((segment-pattern? pattern)
195           (process-pattern (car pattern)
196                            %temp
197                            (lambda (x) ;temp is free in x
198                              (mapit (if (eq? %temp x)
199                                         path ;+++
200                                         `(,%map1 (,%lambda (,%temp) ,x)
201                                                  ,path))))))
202          ((pair? pattern)
203           (append (process-pattern (car pattern) `(,%car ,path) mapit)
204                   (process-pattern (cdr pattern) `(,%cdr ,path) mapit)))
205          ((vector? pattern)
206           (let* ((len (vector-length pattern))
207                  (segment? (and (>= len 2)
208                                 (ellipsis? (vector-ref pattern (- len 1))))))
209             (if segment?
210                 (process-pattern (vector->list pattern) 
211                                  `(,%vector->list ,path)
212                                  mapit)
213                 (let lp ((i 0))
214                   (cond
215                    ((>= i len)
216                     '())
217                    (else
218                     (append (process-pattern (vector-ref pattern i)
219                                              `(,%vector-ref ,path ,i)
220                                              mapit)
221                             (lp (+ i 1)))))))))
222          (else '())))
223
224  ;; Generate code to compose the output expression according to template
225
226  (define (process-template template dim env)
227    (cond ((symbol? template)
228           (let ((probe (assq template env)))
229             (if probe
230                 (if (<= (cdr probe) dim)
231                     template
232                     (##sys#syntax-error-hook "template dimension error (too few ellipses?)"
233                                              template))
234                 `(,%rename (syntax ,template)))))
235          ((segment-template? template)
236           (let* ((depth (segment-depth template))
237                  (seg-dim (+ dim depth))
238                  (vars
239                   (free-meta-variables (car template) seg-dim env '())))
240             (if (null? vars)
241                 (##sys#syntax-error-hook "too many ellipses" template)
242                 (let* ((x (process-template (car template)
243                                             seg-dim
244                                             env))
245                        (gen (if (and (pair? vars)
246                                      (null? (cdr vars))
247                                      (symbol? x)
248                                      (eq? x (car vars)))
249                                 x      ;+++
250                                 `(,%map (,%lambda ,vars ,x)
251                                         ,@vars)))
252                        (gen (do ((d depth (- d 1))
253                                  (gen gen `(,%apply ,%append ,gen)))
254                                 ((= d 1)
255                                  gen))))
256                   (if (null? (segment-tail template))
257                       gen              ;+++
258                       `(,%append ,gen ,(process-template (segment-tail template)
259                                                          dim env)))))))
260          ((pair? template)
261           `(,%cons ,(process-template (car template) dim env)
262                    ,(process-template (cdr template) dim env)))
263          ((vector? template)
264           `(,%list->vector
265             ,(process-template (vector->list template) dim env)))
266          (else
267           `(,%quote ,template))))
268
269  ;; Return an association list of (var . dim)
270
271  (define (meta-variables pattern dim vars)
272    (cond ((symbol? pattern)
273           (if (memq pattern subkeywords)
274               vars
275               (cons (cons pattern dim) vars)))
276          ((segment-pattern? pattern)
277           (meta-variables (car pattern) (+ dim 1) vars))
278          ((pair? pattern)
279           (meta-variables (car pattern) dim
280                           (meta-variables (cdr pattern) dim vars)))
281          ((vector? pattern)
282           (meta-variables (vector->list pattern) dim vars))
283          (else vars)))
284
285  ;; Return a list of meta-variables of given higher dim
286
287  (define (free-meta-variables template dim env free)
288    (cond ((symbol? template)
289           (if (and (not (memq template free))
290                    (let ((probe (assq template env)))
291                      (and probe (>= (cdr probe) dim))))
292               (cons template free)
293               free))
294          ((segment-template? template)
295           (free-meta-variables (car template)
296                                dim env
297                                (free-meta-variables (cddr template)
298                                                     dim env free)))
299          ((pair? template)
300           (free-meta-variables (car template)
301                                dim env
302                                (free-meta-variables (cdr template)
303                                                     dim env free)))
304          ((vector? template)
305           (free-meta-variables (vector->list template) dim env free))
306          (else free)))
307
308  (define (segment-pattern? pattern)
309    (and (segment-template? pattern)
310         (or (null? (cddr pattern))
311             (##sys#syntax-error-hook "segment matching not implemented" pattern))))
312
313  (define (segment-template? pattern)
314    (and (pair? pattern)
315         (pair? (cdr pattern))
316         (ellipsis? (cadr pattern))))
317
318  ;; Count the number of `...'s in PATTERN.
319
320  (define (segment-depth pattern)
321    (if (segment-template? pattern)
322        (+ 1 (segment-depth (cdr pattern)))
323        0))
324
325  ;; Get whatever is after the `...'s in PATTERN.
326
327  (define (segment-tail pattern)
328    (let loop ((pattern (cdr pattern)))
329      (if (and (pair? pattern)
330               (ellipsis? (car pattern)))
331          (loop (cdr pattern))
332          pattern)))
333
334  (make-transformer rules))
Note: See TracBrowser for help on using the repository browser.