source: project/chicken/trunk/synrules.scm @ 12083

Last change on this file since 12083 was 11903, checked in by felix winkelmann, 12 years ago

replaced primitives used by synrules to avoid primitive-renaming problem

File size: 11.0 KB
Line 
1;; Copyright (c) 1993-2001 by Richard Kelsey and Jonathan Rees.
2;; All rights reserved.
3
4;; Redistribution and use in source and binary forms, with or without
5;; modification, are permitted provided that the following conditions
6;; are met:
7;; 1. Redistributions of source code must retain the above copyright
8;;    notice, this list of conditions and the following disclaimer.
9;; 2. Redistributions in binary form must reproduce the above copyright
10;;    notice, this list of conditions and the following disclaimer in the
11;;    documentation and/or other materials provided with the distribution.
12;; 3. The name of the authors may not be used to endorse or promote products
13;;    derived from this software without specific prior written permission.
14
15;; THIS SOFTWARE IS PROVIDED BY THE AUTHORS ``AS IS'' AND ANY EXPRESS OR
16;; IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
17;; OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
18;; IN NO EVENT SHALL THE AUTHORS BE LIABLE FOR ANY DIRECT, INDIRECT,
19;; INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
20;; NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
21;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
23;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
24;; THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
25
26; The syntax-rules macro (new in R5RS)
27
28;;; [Hacked slightly by Taylor R. Campbell to make it work in his
29;;; macro expander `riaxpander'.]
30
31;; [Hacked even more by Felix L. Winkelmann to make it work in his
32;; Hi-Lo expander]
33
34; Example:
35;
36; (define-syntax or
37;   (syntax-rules ()
38;     ((or)          #f)
39;     ((or e)        e)
40;     ((or e1 e ...) (let ((temp e1))
41;                      (if temp temp (or e ...))))))
42
43
44(##sys#extend-macro-environment
45 'syntax-rules
46 '()
47 (##sys#er-transformer
48  (lambda (exp r c)
49    (##sys#check-syntax 'syntax-rules exp '#(_ 2))
50    (let ((subkeywords (cadr exp))
51          (rules (cddr exp))
52          (ellipsis '...))
53      (when (symbol? subkeywords)
54        (##sys#check-syntax 'syntax-rules exp '(_ _ list . #(_ 0)))
55        (set! ellipsis subkeywords)
56        (set! subkeywords (car rules))
57        (set! rules (cdr rules)))
58      (##sys#process-syntax-rules ellipsis rules subkeywords r c)))))
59
60
61(define (##sys#process-syntax-rules ellipsis rules subkeywords r c)
62
63  (define %append '##sys#append)
64  (define %apply '##sys#apply)
65  (define %and (r 'and))
66  (define %car '##sys#car)
67  (define %cdr '##sys#cdr)
68  (define %vector? '##sys#vector?)
69  (define %vector-length '##sys#vector-length)
70  (define %vector-ref '##sys#vector-ref)
71  (define %vector->list '##sys#vector->list)
72  (define %list->vector '##sys#list->vector)
73  (define %>= '##sys#>=)
74  (define %= '##sys#=)
75  (define %+ '##sys#+)
76  (define %i (r 'i))
77  (define %compare (r 'compare))
78  (define %cond (r 'cond))
79  (define %cons '##sys#cons)
80  (define %else (r 'else))
81  (define %eq? '##sys#eq?)
82  (define %equal? '##sys#equal?)
83  (define %input (r 'input))
84  (define %l (r 'l))
85  (define %lambda (r 'lambda))
86  (define %let (r 'let))
87  (define %let* (r 'let*))
88  (define %list? '##sys#list?)
89  (define %list (r 'list))
90  (define %loop (r 'loop))
91  (define %map1 '##sys#map)
92  (define %map '##sys#map-n)
93  (define %null? '##sys#null?)
94  (define %or (r 'or))
95  (define %pair? '##sys#pair?)
96  (define %quote (r 'quote))
97  (define %rename (r 'rename))
98  (define %tail (r 'tail))
99  (define %temp (r 'temp))
100  (define %syntax-error '##sys#syntax-error-hook)
101
102  (define (make-transformer rules)
103    `(,%lambda (,%input ,%rename ,%compare)
104               (,%let ((,%tail (,%cdr ,%input)))
105                      (,%cond ,@(map process-rule rules)
106                              (,%else 
107                               (,%syntax-error
108                                "no rule matches form"
109                                ,%input))))))
110
111  (define (process-rule rule)
112    (if (and (pair? rule)
113             (pair? (cdr rule))
114             (null? (cddr rule)))
115        (let ((pattern (cdar rule))
116              (template (cadr rule)))
117          `((,%and ,@(process-match %tail pattern))
118            (,%let* ,(process-pattern pattern
119                                      %tail
120                                      (lambda (x) x))
121                    ,(process-template template
122                                       0
123                                       (meta-variables pattern 0 '())))))
124        (##sys#syntax-error-hook "ill-formed syntax rule" rule)))
125
126  ;; Generate code to test whether input expression matches pattern
127
128  (define (process-match input pattern)
129    (cond ((symbol? pattern)
130           (if (memq pattern subkeywords)
131               `((,%compare ,input (,%rename (syntax ,pattern))))
132               `()))
133          ((segment-pattern? pattern)
134           (process-segment-match input (car pattern)))
135          ((pair? pattern)
136           `((,%let ((,%temp ,input))
137                    (,%and (,%pair? ,%temp)
138                           ,@(process-match `(,%car ,%temp) (car pattern))
139                           ,@(process-match `(,%cdr ,%temp) (cdr pattern))))))
140          ((vector? pattern)
141           (process-vector-match input pattern))
142          ((or (null? pattern) (boolean? pattern) (char? pattern))
143           `((,%eq? ,input ',pattern)))
144          (else
145           `((,%equal? ,input ',pattern)))))
146
147  (define (process-segment-match input pattern)
148    (let ((conjuncts (process-match `(,%car ,%l) pattern)))
149      (if (null? conjuncts)
150          `((,%list? ,input))           ;+++
151          `((,%let ,%loop ((,%l ,input))
152                   (,%or (,%null? ,%l)
153                         (,%and (,%pair? ,%l)
154                                (,%loop (,%cdr ,%l)))))))))
155
156   (define (process-vector-match input pattern)
157     (let* ((len (vector-length pattern))
158            (segment? (and (>= len 2)
159                           (eq? (vector-ref pattern (- len 1))
160                                ellipsis))))
161       `((,%let ((,%temp ,input))
162          (,%and (,%vector? ,%temp)
163                 ,(if segment?
164                      `(,%>= (,%vector-length ,%temp) ,(- len 2))
165                      `(,%= (,%vector-length ,%temp) ,len))
166                 ,@(let lp ((i 0))
167                     (cond
168                      ((>= i len)
169                       '())
170                      ((and (= i (- len 2)) segment?)
171                       `((,%let ,%loop ((,%i ,i))
172                            (,%or (,%>= ,%i ,len)
173                                  (,%and ,@(process-match
174                                            `(,%vector-ref ,%temp ,%i)
175                                            (vector-ref pattern (- len 2)))
176                                         (,%loop (,%+ ,%i 1)))))))
177                      (else
178                       (append (process-match `(,%vector-ref ,%temp ,i)
179                                              (vector-ref pattern i))
180                               (lp (+ i 1)))))))))))
181 
182  ;; Generate code to take apart the input expression
183  ;; This is pretty bad, but it seems to work (can't say why).
184
185  (define (process-pattern pattern path mapit)
186    (cond ((symbol? pattern)
187           (if (memq pattern subkeywords)
188               '()
189               (list (list pattern (mapit path)))))
190          ((segment-pattern? pattern)
191           (process-pattern (car pattern)
192                            %temp
193                            (lambda (x) ;temp is free in x
194                              (mapit (if (eq? %temp x)
195                                         path ;+++
196                                         `(,%map1 (,%lambda (,%temp) ,x)
197                                                  ,path))))))
198          ((pair? pattern)
199           (append (process-pattern (car pattern) `(,%car ,path) mapit)
200                   (process-pattern (cdr pattern) `(,%cdr ,path) mapit)))
201          ((vector? pattern)
202           (let* ((len (vector-length pattern))
203                  (segment? (and (>= len 2)
204                                 (eq? (vector-ref pattern (- len 1))
205                                      ellipsis))))
206             (if segment?
207                 (process-pattern (vector->list pattern) 
208                                  `(,%vector->list ,path)
209                                  mapit)
210                 (let lp ((i 0))
211                   (cond
212                    ((>= i len)
213                     '())
214                    (else
215                     (append (process-pattern (vector-ref pattern i)
216                                              `(,%vector-ref ,path ,i)
217                                              mapit)
218                             (lp (+ i 1)))))))))
219          (else '())))
220
221  ;; Generate code to compose the output expression according to template
222
223  (define (process-template template dim env)
224    (cond ((symbol? template)
225           (let ((probe (assq template env)))
226             (if probe
227                 (if (<= (cdr probe) dim)
228                     template
229                     (##sys#syntax-error-hook "template dimension error (too few ellipses?)"
230                                              template))
231                 `(,%rename (syntax ,template)))))
232          ((segment-template? template)
233           (let* ((depth (segment-depth template))
234                  (seg-dim (+ dim depth))
235                  (vars
236                   (free-meta-variables (car template) seg-dim env '())))
237             (if (null? vars)
238                 (##sys#syntax-error-hook "too many ellipses" template)
239                 (let* ((x (process-template (car template)
240                                             seg-dim
241                                             env))
242                        (gen (if (and (pair? vars)
243                                      (null? (cdr vars))
244                                      (symbol? x)
245                                      (eq? x (car vars)))
246                                 x      ;+++
247                                 `(,%map (,%lambda ,vars ,x)
248                                         ,@vars)))
249                        (gen (do ((d depth (- d 1))
250                                  (gen gen `(,%apply ,%append ,gen)))
251                                 ((= d 1)
252                                  gen))))
253                   (if (null? (segment-tail template))
254                       gen              ;+++
255                       `(,%append ,gen ,(process-template (segment-tail template)
256                                                          dim env)))))))
257          ((pair? template)
258           `(,%cons ,(process-template (car template) dim env)
259                    ,(process-template (cdr template) dim env)))
260          ((vector? template)
261           `(,%list->vector
262             ,(process-template (vector->list template) dim env)))
263          (else
264           `(,%quote ,template))))
265
266  ;; Return an association list of (var . dim)
267
268  (define (meta-variables pattern dim vars)
269    (cond ((symbol? pattern)
270           (if (memq pattern subkeywords)
271               vars
272               (cons (cons pattern dim) vars)))
273          ((segment-pattern? pattern)
274           (meta-variables (car pattern) (+ dim 1) vars))
275          ((pair? pattern)
276           (meta-variables (car pattern) dim
277                           (meta-variables (cdr pattern) dim vars)))
278          ((vector? pattern)
279           (meta-variables (vector->list pattern) dim vars))
280          (else vars)))
281
282  ;; Return a list of meta-variables of given higher dim
283
284  (define (free-meta-variables template dim env free)
285    (cond ((symbol? template)
286           (if (and (not (memq template free))
287                    (let ((probe (assq template env)))
288                      (and probe (>= (cdr probe) dim))))
289               (cons template free)
290               free))
291          ((segment-template? template)
292           (free-meta-variables (car template)
293                                dim env
294                                (free-meta-variables (cddr template)
295                                                     dim env free)))
296          ((pair? template)
297           (free-meta-variables (car template)
298                                dim env
299                                (free-meta-variables (cdr template)
300                                                     dim env free)))
301          ((vector? template)
302           (free-meta-variables (vector->list template) dim env free))
303          (else free)))
304
305  (define (segment-pattern? pattern)
306    (and (segment-template? pattern)
307         (or (null? (cddr pattern))
308             (##sys#syntax-error-hook "segment matching not implemented" pattern))))
309
310  (define (segment-template? pattern)
311    (and (pair? pattern)
312         (pair? (cdr pattern))
313         (eq? (cadr pattern) ellipsis)))
314
315  ;; Count the number of `...'s in PATTERN.
316
317  (define (segment-depth pattern)
318    (if (segment-template? pattern)
319        (+ 1 (segment-depth (cdr pattern)))
320        0))
321
322  ;; Get whatever is after the `...'s in PATTERN.
323
324  (define (segment-tail pattern)
325    (let loop ((pattern (cdr pattern)))
326      (if (and (pair? pattern)
327               (eq? (car pattern) ellipsis))
328          (loop (cdr pattern))
329          pattern)))
330
331  (make-transformer rules))
Note: See TracBrowser for help on using the repository browser.