source: project/chicken/trunk/setup-api.scm @ 13632

Last change on this file since 13632 was 13632, checked in by Kon Lovett, 12 years ago

Renamed 'dir' -> 'nam' in 'extension-name-and-version'.

File size: 24.6 KB
Line 
1;;;; setup-api.scm - build + installation API for eggs
2;
3; Copyright (c) 2008-2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library srfi-1 regex utils posix srfi-13 extras ports data-structures files)
28
29; This code is partially quite messy and the API is not overly consistent,
30; mainly because it has grown "organically" while the old chicken-setup program
31; evolved. The code was extracted and put into this module, without much
32; cleaning up. Nevertheless, it should work.
33
34(module setup-api
35
36    (move-file 
37     (run execute)
38     compile
39     make make/proc
40     host-extension
41     install-extension install-program install-script
42     setup-verbose-flag
43     setup-install-flag installation-prefix chicken-prefix 
44     find-library find-header 
45     program-path remove-file* 
46     patch yes-or-no? abort-setup
47     setup-root-directory create-directory/parents
48     test-compile try-compile copy-file run-verbose
49     required-chicken-version required-extension-version cross-chicken
50     sudo-install keep-intermediates
51     version>=?
52     extension-name-and-version
53     extension-name
54     extension-version
55     create-temporary-directory
56     remove-directory
57     remove-extension
58     read-info
59     shellpath)
60 
61  (import scheme chicken foreign
62          regex utils posix ports extras data-structures
63          srfi-1 srfi-13 files)
64
65;;; Constants, variables and parameters
66
67(define-constant setup-file-extension "setup-info")
68
69(define *installed-executables* 
70  `(("chicken" . ,(foreign-value "C_CHICKEN_PROGRAM" c-string))
71    ("csc" . ,(foreign-value "C_CSC_PROGRAM" c-string))
72    ("csi" . ,(foreign-value "C_CSI_PROGRAM" c-string))
73    ("chicken-bug" . ,(foreign-value "C_CHICKEN_BUG_PROGRAM" c-string))))
74
75(define *cc* (foreign-value "C_TARGET_CC" c-string))
76(define *cxx* (foreign-value "C_TARGET_CXX" c-string))
77(define *target-cflags* (foreign-value "C_TARGET_CFLAGS" c-string))
78(define *target-libs* (foreign-value "C_TARGET_MORE_LIBS" c-string))
79(define *target-lib-home* (foreign-value "C_TARGET_LIB_HOME" c-string))
80(define *sudo* #f)
81(define *windows-shell* (foreign-value "C_WINDOWS_SHELL" bool))
82
83(define *windows*
84  (and (eq? (software-type) 'windows) 
85       (build-platform) ) )
86
87(register-feature! 'chicken-setup)
88
89(define host-extension (make-parameter #f))
90
91(define *chicken-bin-path*
92  (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
93        (make-pathname p "bin") )
94      (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )
95
96(define *doc-path*
97  (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
98        (make-pathname p "share/chicken/doc") )
99      (make-pathname
100       (foreign-value "C_INSTALL_SHARE_HOME" c-string) 
101       "doc")))
102
103(define chicken-prefix
104  (or (getenv "CHICKEN_PREFIX")
105      (let ((m (string-match "(.*)/bin/?" *chicken-bin-path*)))
106        (if m
107            (cadr m)
108            "/usr/local") ) ) )
109
110(define (shellpath str)
111  (qs (normalize-pathname str)))
112
113(define (cross-chicken) (##sys#fudge 39))
114
115(define *csc-options* '())
116(define *base-directory* (current-directory))
117
118(define setup-root-directory      (make-parameter *base-directory*))
119(define setup-verbose-flag        (make-parameter #f))
120(define setup-install-flag        (make-parameter #t))
121(define program-path              (make-parameter *chicken-bin-path*))
122(define keep-intermediates (make-parameter #f))
123
124; Setup shell commands
125
126(define *copy-command*)
127(define *remove-command*)
128(define *move-command*)
129(define *chmod-command*)
130(define *ranlib-command*)
131
132(define (windows-user-install-setup)
133  (set! *copy-command*        'copy)
134  (set! *remove-command*      "del /Q /S")
135  (set! *move-command*        'move)
136  (set! *chmod-command*       "chmod")
137  (set! *ranlib-command*      "ranlib") )
138
139(define (unix-user-install-setup)
140  (set! *copy-command*        "cp -r")
141  (set! *remove-command*      "rm -fr")
142  (set! *move-command*        'mv)
143  (set! *chmod-command*       "chmod")
144  (set! *ranlib-command*      "ranlib") )
145
146(define (windows-sudo-install-setup)
147  (set! *sudo* #f)
148  (print "Warning: cannot install as superuser with Windows") )
149
150(define (unix-sudo-install-setup)
151  (set! *copy-command*        "sudo cp -r")
152  (set! *remove-command*      "sudo rm -fr")
153  (set! *move-command*        "sudo mv")
154  (set! *chmod-command*       "sudo chmod")
155  (set! *ranlib-command*      "sudo ranlib") )
156
157(define (user-install-setup)
158  (set! *sudo* #f)
159  (if *windows-shell*
160      (windows-user-install-setup)
161      (unix-user-install-setup) ) )
162
163(define (sudo-install-setup)
164  (set! *sudo* #t)
165  (if *windows-shell*
166      (windows-sudo-install-setup)
167      (unix-sudo-install-setup) ) )
168
169(define (sudo-install . args)
170  (cond ((null? args)   *sudo*)
171        ((car args)     (sudo-install-setup))
172        (else           (user-install-setup)) ) )
173
174; User setup by default
175(user-install-setup)
176
177
178(define create-directory/parents
179  (let ()
180    (define create-directory-0
181      (let ([create-directory create-directory])
182        (lambda (dir)
183          (let loop ([dir dir])
184            (when (and dir (not (directory? dir)))
185              (loop (pathname-directory dir))
186              (create-directory dir))) ) ) )
187    (define (verb dir)
188      (when (setup-verbose-flag) (printf "  creating directory `~a'~%~!" dir)) )
189    (if *windows-shell*
190        (lambda (dir)
191          (verb dir)
192          (create-directory-0 dir) ) 
193        (lambda (dir)
194          (verb dir)
195          ($system (sprintf "mkdir -p ~a" (shellpath dir) ) ) ) ) ) )
196
197(define abort-setup (make-parameter exit))
198
199(define (yes-or-no? str #!key default (abort (abort-setup)))
200  (let loop ()
201    (printf "~%~A (yes/no/abort) " str)
202    (when default (printf "[~A] " default))
203    (flush-output)
204    (let ((ln (read-line)))
205      (cond ((eof-object? ln) (set! ln "abort"))
206            ((and default (string=? "" ln)) (set! ln default)) )
207      (cond ((string-ci=? "yes" ln) #t)
208            ((string-ci=? "no" ln) #f)
209            ((string-ci=? "abort" ln) (abort))
210            (else
211             (printf "~%Please enter \"yes\", \"no\" or \"abort\".~%")
212             (loop) ) ) ) ) )
213 
214(define (patch which rx subst)
215  (when (setup-verbose-flag) (printf "patching ~A ...~%" which))
216  (if (list? which)
217      (with-output-to-file (cadr which)
218       (lambda ()
219         (with-input-from-file (car which)
220           (lambda ()
221             (let loop ()
222               (let ((ln (read-line)))
223                 (unless (eof-object? ln)
224                   (write-line (string-substitute rx subst ln #t)) 
225                   (loop) ) ) ) ) ) ) )
226      (let ((tmp (create-temporary-file)))
227        (patch (list tmp tmp) rx subst)
228        ($system 
229         (sprintf "~A ~A ~A" *move-command* (shellpath tmp)
230                  (shellpath which))))))
231
232(define run-verbose (make-parameter #t))
233
234(define (fixpath prg)
235  (cond ((string=? prg "csc")
236         (string-intersperse 
237          (cons* (shellpath
238                  (make-pathname 
239                   *chicken-bin-path*
240                   (cdr (assoc prg *installed-executables*))))
241                 "-feature" "compiling-extension"
242                 (if (host-extension) "-host" "")
243                 *csc-options*) 
244          " ") )
245        ((assoc prg *installed-executables*) =>
246         (lambda (a) (shellpath (make-pathname *chicken-bin-path* (cdr a)))))
247        (else prg) ) )
248
249(define (fixmaketarget file)
250  (if (and (equal? "so" (pathname-extension file))
251           (not (string=? "so" ##sys#load-dynamic-extension)) )
252      (pathname-replace-extension file ##sys#load-dynamic-extension)
253      file) )
254
255(define (execute explist)
256  (define (smooth lst)
257    (let ((slst (map ->string lst)))
258      (string-intersperse (cons (fixpath (car slst)) (cdr slst)) " ") ) )
259  (for-each
260   (lambda (cmd)
261     (when (run-verbose) (printf "  ~A~%~!" cmd))
262     ($system cmd))
263   (map smooth explist) ) )
264
265(define-syntax run
266  (syntax-rules ()
267    ((_ exp ...)
268     (execute (list `exp ...)))))
269
270(define-syntax compile
271  (syntax-rules ()
272    ((_ exp ...)
273     (run (csc exp ...)))))
274
275
276;;; "make" functionality
277
278(define (make:find-matching-line str spec)
279  (let ((match? (lambda (s) (string=? s str))))
280    (let loop ((lines spec))
281      (cond
282       ((null? lines) #f)
283       (else (let* ((line (car lines))
284                    (names (if (string? (car line))
285                               (list (car line))
286                               (car line))))
287               (if (any match? names)
288                   line
289                   (loop (cdr lines)))))))))
290
291(define (make:form-error s p) (error (sprintf "~a: ~s" s p)))
292(define (make:line-error s p n) (error (sprintf "~a: ~s for line: ~a" s p n)))
293
294(define (make:check-spec spec)
295  (and (or (list? spec) (make:form-error "specification is not a list" spec))
296       (or (pair? spec) (make:form-error "specification is an empty list" spec))
297       (every
298        (lambda (line)
299          (and (or (and (list? line) (<= 2 (length line) 3))
300                   (make:form-error "list is not a list with 2 or 3 parts" line))
301               (or (or (string? (car line))
302                       (and (list? (car line))
303                            (every string? (car line))))
304                   (make:form-error "line does not start with a string or list of strings" line))
305               (let ((name (car line)))
306                 (or (list? (cadr line))
307                     (make:line-error "second part of line is not a list" (cadr line) name)
308                     (every (lambda (dep)
309                               (or (string? dep)
310                                   (make:form-error "dependency item is not a string" dep)))
311                             (cadr line)))
312                 (or (null? (cddr line))
313                     (procedure? (caddr line))
314                     (make:line-error "command part of line is not a thunk" (caddr line) name)))))
315        spec)))
316
317(define (make:check-argv argv)
318  (or (string? argv)
319      (every string? argv)
320      (error "argument is not a string or string list" argv)))
321
322(define (make:make/proc/helper spec argv)
323  (when (vector? argv) (set! argv (vector->list argv)))
324  (make:check-spec spec)
325  (make:check-argv argv)
326  (letrec ((made '())
327           (exn? (condition-predicate 'exn))
328           (exn-message (condition-property-accessor 'exn 'message))
329           (make-file
330            (lambda (s indent)
331              (let* ((line (make:find-matching-line s spec))
332                     (s2 (fixmaketarget s)) 
333                     (date (and (file-exists? s2)
334                                (file-modification-time s2))))
335                (when (setup-verbose-flag)
336                  (printf "make: ~achecking ~a~%" indent s2))
337                (if line
338                    (let ((deps (cadr line)))
339                      (for-each (let ((new-indent (string-append " " indent)))
340                                  (lambda (d) (make-file d new-indent)))
341                                deps)
342                      (let ((reason
343                             (or (not date)
344                                 (any (lambda (dep)
345                                          (let ((dep2 (fixmaketarget dep)))
346                                            (unless (file-exists? dep2)
347                                              (error (sprintf "dependancy ~a was not made~%" dep2)))
348                                            (and (> (file-modification-time dep2) date)
349                                                 dep2)) )
350                                        deps))))
351                        (when reason
352                          (let ((l (cddr line)))
353                            (unless (null? l)
354                              (set! made (cons s made))
355                              (when (setup-verbose-flag)
356                                (printf "make: ~amaking ~a~a~%"
357                                        indent
358                                        s2
359                                        (cond
360                                         ((not date)
361                                          (string-append " because " s2 " does not exist"))
362                                         ((string? reason)
363                                          (string-append " because " reason " changed"))
364                                         (else
365                                          (string-append (sprintf " just because (reason: ~a date: ~a)" 
366                                                                  reason date)))) ) )
367                              (handle-exceptions exn
368                                  (begin
369                                    (printf "make: Failed to make ~a: ~a~%"
370                                            (car line)
371                                            (if (exn? exn)
372                                                (exn-message exn)
373                                                exn))
374                                    (signal exn) )
375                                ((car l))))))))
376                    (unless date
377                      (error (sprintf "don't know how to make ~a" s2))))))))
378    (cond
379     ((string? argv) (make-file argv ""))
380     ((null? argv) (make-file (caar spec) ""))
381     (else (for-each (lambda (f) (make-file f "")) argv)))
382    (when (setup-verbose-flag)
383      (for-each (lambda (item)
384                  (printf "make: made ~a~%" item))
385        (reverse made)))) )
386
387(define make/proc
388  (case-lambda
389   ((spec) (make:make/proc/helper spec '()))
390   ((spec argv)
391    (make:make/proc/helper
392     spec
393     (if (vector? argv)
394         (vector->list argv)
395         argv) ) ) ) )
396
397(define-syntax make
398  (lambda (form r c)
399    (##sys#check-syntax 'make form '(_ _ . #(_ 0 1)))
400    (let ((spec (cadr form))
401          (%list (r 'list))
402          (%lambda (r 'lambda)))
403      (let ((form-error (lambda (s . p) (apply error s spec p))))
404        (and (or (list? spec) (form-error "illegal specification (not a sequence)"))
405             (or (pair? spec) (form-error "empty specification"))
406             (every
407              (lambda (line)
408                (and (or (and (list? line) (>= (length line) 2))
409                         (form-error "clause does not have at least 2 parts" line))
410                     (let ((name (car line)))
411                       (or (list? (cadr line))
412                           (make:line-error "second part of clause is not a sequence" (cadr line) name)))))
413              spec))
414        `(,(r 'make/proc)
415          (list ,@(map (lambda (line)
416                         `(,%list ,(car line)
417                                  (,%list ,@(cadr line))
418                                  ,@(let ((l (cddr line)))
419                                      (if (null? l)
420                                          '()
421                                          `((,%lambda () ,@l))))))
422                       spec))
423          ,@(if (null? (cddr form))
424                '('())
425                (cddr form)))))))
426
427
428;;; Processing setup scripts
429
430(define (make-setup-info-pathname fn #!optional (rpath (repository-path)))
431  (make-pathname rpath fn setup-file-extension) )
432
433(define installation-prefix
434  (make-parameter (or (getenv "CHICKEN_INSTALL_PREFIX") #f)))
435
436(define (write-info id files info)
437  (let ((info `((files ,@files) 
438                ,@info)) )
439    (when (setup-verbose-flag) (printf "writing info ~A -> ~S ...~%" id info))
440    (let* ((sid (->string id))
441           (setup-file (make-setup-info-pathname sid (repo-path #t))))
442      (cond (*sudo*
443             (let ((tmp (create-temporary-file)))
444               (with-output-to-file tmp (cut pp info))
445               (run (,*move-command* ,(shellpath tmp) ,(shellpath setup-file)))))
446            (else (with-output-to-file setup-file (cut pp info))))
447      (unless *windows-shell* (run (,*chmod-command* a+r ,(shellpath setup-file)))))))
448
449(define (copy-file from to #!optional (err #t) (prefix (installation-prefix)))
450  (let ((from (if (pair? from) (car from) from))
451        (to (let ((to-path (if (pair? from) (make-pathname to (cadr from)) to)))
452              (if (and prefix (not (string-prefix? prefix to-path)))
453                  (make-pathname prefix to-path) to-path))))
454    (ensure-directory to)
455    (cond ((or (glob? from) (file-exists? from))
456           (begin
457             (run (,*copy-command* ,(shellpath from) ,(shellpath to))) 
458             to))
459          (err (error "file does not exist" from))
460          (else (warning "file does not exist" from)))))
461
462(define (move-file from to)
463  (let ((from  (if (pair? from) (car from) from))
464        (to    (if (pair? from) (make-pathname to (cadr from)) to)))
465    (ensure-directory to)
466    (run (,*move-command* ,(shellpath from) ,(shellpath to)) ) ) )
467
468(define (remove-file* dir)
469  (run (,*remove-command* ,(shellpath dir)) ) )
470
471(define (make-dest-pathname path file)
472  (if (list? file)
473      (make-dest-pathname path (cadr file))
474      (if (absolute-pathname? file)
475          file
476          (make-pathname path file) ) ) )
477
478(define (check-filelist flist)
479  (map (lambda (f)
480         (cond ((string? f) f)
481               ((and (list? f) (every string? f)) f)
482               ((and (pair? f) (list (car f) (cdr f))))
483               (else (error "invalid file-specification" f)) ) )
484       flist) )
485
486(define (translate-extension f #!optional default)
487  (pathname-replace-extension f
488   (let ((ext (pathname-extension f)))
489     (cond ((not ext) default)
490           ((equal? "so" ext) ##sys#load-dynamic-extension)
491           ((equal? "a" ext) (if *windows-shell* "lib" "a"))
492           (else ext)))))
493
494
495;;; Installation
496
497(define (install-extension id files #!optional (info '()))
498  (when (setup-install-flag)
499    (let* ((files (check-filelist (if (list? files) files (list files))))
500           (rpath (repo-path))
501           (rpathd (repo-path #t))
502           (dests (map (lambda (f)
503                         (let ((from (if (pair? f) (car f) f))
504                               (to (make-dest-pathname rpathd f)) )
505                           (when (and (not *windows*) 
506                                      (equal? "so" (pathname-extension to)))
507                             (run (,*remove-command* ,(shellpath to)) ))
508                           (copy-file from to)
509                           (unless *windows-shell*
510                             (run (,*chmod-command* a+r ,(shellpath to))))
511                           (and-let* ((static (assq 'static info)))
512                             (when (and (eq? (software-version) 'macosx)
513                                        (equal? (cadr static) from) 
514                                        (equal? (pathname-extension to) "a"))
515                               (run (,*ranlib-command* ,(shellpath to)) ) ))
516                           (make-dest-pathname rpath f)))
517                       files) ) )
518      (and-let* ((docs (assq 'documentation info)))
519        (print "\n* Installing documentation files in " *doc-path* ":")
520        (for-each
521         (lambda (f)
522           (copy-file f (make-pathname *doc-path* f) #f) )
523         (cdr docs))
524        (newline))
525      (and-let* ((exs (assq 'examples info)))
526        (print "\n* Installing example files in " *doc-path* ":")
527        (for-each
528         (lambda (f)
529           (let ((destf (make-pathname *doc-path* f)))
530             (copy-file f destf #f)
531             (unless *windows-shell*
532               (run (chmod a+rx ,destf)) ) ))
533         (cdr exs))
534        (newline))
535      (write-info id dests info) ) ) )
536
537(define (install-program id files #!optional (info '()))
538  (define (exify f)
539    (translate-extension
540     f
541     (if *windows-shell* "exe" #f) ) )
542  (when (setup-install-flag)
543    (let* ((files (check-filelist (if (list? files) files (list files))))
544           (ppath ((lambda (pre) (if pre (make-pathname pre (program-path)) (program-path)))
545                   (installation-prefix)))
546           (files (if *windows*
547                      (map (lambda (f)
548                             (if (list? f) 
549                                 (list (exify (car f)) (exify (cadr f)))
550                                 (exify f) ) )
551                           files)
552                      files) ) 
553           (dests (map (lambda (f)
554                         (let ((from (if (pair? f) (car f) f))
555                               (to (make-dest-pathname ppath f)) )
556                           (copy-file from to) 
557                           (unless *windows-shell*
558                                   (run (,*chmod-command* a+r ,(shellpath to))))
559                           to) )
560                       files) ) )
561      (write-info id dests info) ) ) )
562
563(define (install-script id files #!optional (info '()))
564  (when (setup-install-flag)
565    (let* ((files (check-filelist (if (list? files) files (list files))))
566           (ppath ((lambda (pre) (if pre (make-pathname pre (program-path)) (program-path)))
567                   (installation-prefix)))
568           (pfiles (map (lambda (f)
569                          (let ((from (if (pair? f) (car f) f))
570                                (to (make-dest-pathname ppath f)) )
571                            (copy-file from to) 
572                            (unless *windows-shell*
573                                    (run (,*chmod-command* a+r ,(shellpath to))))
574                            to) )
575                        files) ) )
576      (unless *windows-shell*
577        (run (,*chmod-command* a+rx ,(string-intersperse pfiles " "))) )
578      (write-info id pfiles info) ) ) )
579
580
581;;; More helper stuff
582
583(define (repo-path #!optional ddir?)
584  (let ((p (if (and ddir? (installation-prefix))
585               (make-pathname (installation-prefix) (repository-path))
586               (repository-path))) )
587    (ensure-directory p)
588    p) )
589
590(define (ensure-directory path)
591  (and-let* ((dir (pathname-directory path)))
592    (if (file-exists? dir)
593        (unless (directory? dir)
594          (error "cannot create directory: a file with the same name already exists") )
595        (begin
596          (create-directory dir)
597          (unless *windows-shell*
598                  (run (,*chmod-command* a+x ,(shellpath dir))))))))
599
600(define (try-compile code #!key c++ (cc (if c++ *cxx* *cc*)) (cflags "") (ldflags "") 
601                     (verb (setup-verbose-flag)) (compile-only #f))
602  (let* ((fname (create-temporary-file "c"))
603         (oname (pathname-replace-extension fname "o"))
604         (r (begin
605              (with-output-to-file fname (cut display code))
606              (system 
607               (let ((cmd (conc
608                           cc " "
609                           (if compile-only "-c" "") " "
610                           cflags " " *target-cflags* " "
611                           fname " "
612                           (if compile-only
613                               "" 
614                               (conc "-L" *target-lib-home* " " ldflags " " *target-libs*) )
615                           " >/dev/null "
616                           (if verb "" "2>&1") ) ) )
617                 (when verb (print cmd " ..."))
618                 cmd) ) ) ) )
619    (when verb (print (if (zero? r) "succeeded." "failed.")))
620    ($system (sprintf "~A ~A" *remove-command* (shellpath fname)))
621    (zero? r) ) )
622
623(define (required-chicken-version v)
624  (when (string-ci<? (chicken-version) (->string v))
625    (error (sprintf "CHICKEN version ~a or higher is required" v)) ) )
626
627(define (upgrade-message ext msg)
628  (error
629   (sprintf
630    "the required extension `~s' ~a - please run~%~%  chicken-install ~a~%~%and repeat the current installation operation."
631    ext msg ext) ) )
632
633(define (required-extension-version . args)
634  (let loop ((args args))
635    (cond ((null? args) #f)
636          ((and (list? args) (>= (length args) 2))
637           (let* ((ext (car args))
638                  (version (cadr args))
639                  (more (cddr args))
640                  (info (extension-information ext))
641                  (version (->string version)) )
642             (if info
643                 (let ((ver (and (assq 'version info) (cadr (assq 'version info)))))
644                   (cond ((not ver) (upgrade-message ext "has no associated version information"))
645                         ((string-ci<? (->string ver) version)
646                          (upgrade-message 
647                           ext
648                           (sprintf "is older than ~a, which is what this extension requires"
649                                    version) ) )
650                         (else (loop more)) ) ) 
651                 (upgrade-message ext "is not installed") ) ) )
652          (else
653           (error 'required-extension-information "bad argument format" args)) ) ) )
654
655(define test-compile try-compile)
656
657(define (find-library name proc)
658  (test-compile 
659   (sprintf "#ifdef __cplusplus~%extern \"C\"~%#endif~%char ~a();~%int main() { ~a(); return 0; }~%" proc proc)
660   ldflags: (conc "-l" name) ) )
661
662(define (find-header name)
663  (test-compile
664   (sprintf "#include <~a>\nint main() { return 0; }\n" name)
665   compile-only: #t) )
666
667(define (version>=? v1 v2)
668  (define (version->list v)
669    (map (lambda (x) (or (string->number x) x))
670         (string-split-fields "[-\\._]" v #:infix)))
671  (let loop ((p1 (version->list v1))
672             (p2 (version->list v2)))
673    (cond ((null? p1) (null? p2))
674          ((null? p2))
675          ((number? (car p1))
676           (and (if (number? (car p2))
677                    (>= (car p1) (car p2))
678                    (string>=? (number->string (car p1)) (car p2)))
679                (loop (cdr p1) (cdr p2))))
680          ((number? (car p2))
681           (and (string>=? (car p1) (number->string (car p2)))
682                (loop (cdr p1) (cdr p2))))
683          ((string>=? (car p1) (car p2)) (loop (cdr p1) (cdr p2)))
684          (else #f))))
685
686(define extension-name-and-version
687  (make-parameter '("" "")
688    (lambda (x)
689      (cond [(or (not x) (null? x))
690             '("" "") ]
691            [(and (list? x) (= 2 (length x)))
692             (let ([nam (car x)]
693                   [ver (cadr x)]
694                   [ensure-string (lambda (x) (if (or (not x) (null? x)) "" (->string x)))])
695               (list (ensure-string nam) (ensure-string ver)) ) ]
696            [else
697             (warning "invalid extension-name-and-version" x)
698             (extension-name-and-version) ] ) ) ) )
699
700(define (extension-name)
701  (car (extension-name-and-version)) )
702
703(define (extension-version #!optional defver)
704  (let ([ver (cadr (extension-name-and-version))])
705    (if (string-null? ver)
706        (and defver (->string defver))
707        ver ) ) )
708
709(define (read-info egg)
710  (with-input-from-file
711      (make-pathname (repository-path) egg ".setup-info")
712    read))
713
714(define (create-temporary-directory)
715  (let ((dir (or (getenv "TMPDIR") (getenv "TEMP") (getenv "TMP") "/tmp")))
716    (let loop ()
717      (let* ((n (##sys#fudge 16))       ; current milliseconds
718             (pn (make-pathname dir (string-append "chicken-install-" (number->string n 16)) "tmp")))
719        (cond ((file-exists? pn) (loop))
720              (else (create-directory pn) pn))))))
721
722(define (remove-directory dir #!optional (strict #t))
723  (cond ((not (file-exists? dir))
724         (if strict
725             (error 'remove-directory "cannot remove - directory not found" dir)
726             #f))
727        (*sudo*
728         ($system (sprintf "sudo rm -fr ~a" (shellpath dir))))
729        (else
730         (let walk ((dir dir))
731           (let ((files (directory dir #t)))
732             (for-each
733              (lambda (f)
734                (unless (or (string=? "." f) (string=? ".." f))
735                  (let ((p (make-pathname dir f)))
736                    (if (directory? p)
737                        (walk p) 
738                        (delete-file p)))))
739              files)
740             (delete-directory dir)))) ))
741
742(define (remove-extension egg)
743  (and-let* ((files (assq 'files (read-info egg))))
744    (for-each remove-file* (cdr files)))
745  (remove-file* (make-pathname (repository-path) egg "setup-info")))
746
747(define ($system str)
748  (let ((r (system
749            (if *windows-shell*
750                (string-append "\"" str "\"")   ; double quotes, yes - thanks to Matthew Flatt
751                str))))
752    (unless (zero? r)
753      (error "shell command failed with nonzero exit status" r str))))
754
755)
Note: See TracBrowser for help on using the repository browser.