source: project/chicken/trunk/compiler-syntax.scm @ 15817

Last change on this file since 15817 was 15817, checked in by felix winkelmann, 10 years ago

avoid inlining map/for-each for possibly side-effecting operator

File size: 8.1 KB
Line 
1;;;; compiler-syntax.scm - compiler syntax used internally
2;
3; Copyright (c) 2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(declare 
28  (unit compiler-syntax) )
29
30
31(include "compiler-namespace")
32(include "tweaks.scm")
33
34
35;;; Compiler macros (that operate in the expansion phase)
36
37(define compiler-syntax-statistics '())
38
39(set! ##sys#compiler-syntax-hook
40  (lambda (name result)
41    (let ((a (alist-ref name compiler-syntax-statistics eq? 0)))
42      (set! compiler-syntax-statistics
43        (alist-update! name (add1 a) compiler-syntax-statistics)))))
44
45(define (r-c-s names transformer #!optional (se '()))
46  (let ((t (cons (##sys#er-transformer transformer) se)))
47    (for-each
48     (lambda (name)
49       (##sys#put! name '##compiler#compiler-syntax t) )
50     (if (symbol? names) (list names) names) ) ) )
51
52(define-syntax define-internal-compiler-syntax
53  (syntax-rules ()
54    ((_ (names . llist) (se ...) . body)
55     (r-c-s 
56      'names (lambda llist . body) 
57      `((se . ,(##sys#primitive-alias 'se)) ...)))))
58
59(define-internal-compiler-syntax ((for-each ##sys#for-each #%for-each) x r c)
60  (pair?)
61  (let ((%let (r 'let))
62        (%if (r 'if))
63        (%loop (r 'loop))
64        (%begin (r 'begin))
65        (%and (r 'and))
66        (%pair? (r 'pair?))
67        (%lambda (r 'lambda))
68        (lsts (cddr x)))
69    (if (and (memq 'for-each standard-bindings) ; we have to check this because the db (and thus
70             (> (length+ x) 2)                   ; intrinsic marks) isn't set up yet
71             (or (and (pair? (cadr x))
72                      (c %lambda (caadr x)))
73                 (symbol? (cadr x))))
74        (let ((vars (map (lambda _ (gensym)) lsts)))
75          `(,%let ,%loop ,(map list vars lsts)
76                  (,%if (,%and ,@(map (lambda (v) `(,%pair? ,v)) vars))
77                        (,%begin
78                         (,(cadr x)
79                          ,@(map (lambda (v) `(##sys#slot ,v 0)) vars))
80                         (##core#app 
81                          ,%loop
82                          ,@(map (lambda (v) `(##sys#slot ,v 1)) vars) ) ))))
83        x)))
84
85(define-internal-compiler-syntax ((map ##sys#map #%map) x r c)
86  (pair?)
87  (let ((%let (r 'let))
88        (%if (r 'if))
89        (%loop (r 'loop))
90        (%res (r 'res))
91        (%cons (r 'cons))
92        (%set! (r 'set!))
93        (%result (r 'result))
94        (%node (r 'node))
95        (%quote (r 'quote))
96        (%lambda (r 'lambda))
97        (%and (r 'and))
98        (%pair? (r 'pair?))
99        (lsts (cddr x)))
100    (if (and (memq 'map standard-bindings) ; s.a.
101             (> (length+ x) 2)
102             (or (and (pair? (cadr x))
103                      (c %lambda (caadr x)))
104                 (symbol? (cadr x))))
105        (let ((vars (map (lambda _ (gensym)) lsts)))
106          `(,%let ((,%result (,%quote ()))
107                   (,%node #f))
108                  (,%let ,%loop ,(map list vars lsts)
109                       (,%if (,%and ,@(map (lambda (v) `(,%pair? ,v)) vars))
110                             (,%let ((,%res
111                                      (,%cons
112                                       (,(cadr x)
113                                        ,@(map (lambda (v) `(##sys#slot ,v 0)) vars))
114                                       (,%quote ()))))
115                                    (,%if ,%node
116                                          (##sys#setslot ,%node 1 ,%res)
117                                          (,%set! ,%result ,%res))
118                                    (,%set! ,%node ,%res)
119                                    (,%loop
120                                     ,@(map (lambda (v) `(##sys#slot ,v 1)) vars)))
121                             ,%result))))
122        x)))
123
124(define-internal-compiler-syntax ((o #%o) x r c) ()
125  (if (and (fx> (length x) 1)
126           (memq 'o extended-bindings) ) ; s.a.
127      (let ((%tmp (r 'tmp)))
128        `(,(r 'lambda) (,%tmp) ,(fold-right list %tmp (cdr x))))
129      x))
130
131(define-internal-compiler-syntax ((sprintf #%sprintf format #%format) x r c)
132  (display write fprintf number->string write-char open-output-string get-output-string)
133  (let* ((out (gensym 'out))
134         (code (compile-format-string 
135                (if (memq (car x) '(sprintf #%sprintf))
136                    'sprintf
137                    'format)
138                out 
139                x
140                (cdr x)
141                r c)))
142    (if code
143        `(,(r 'let) ((,out (,(r 'open-output-string))))
144          ,code
145          (,(r 'get-output-string) ,out))
146        x)))
147
148(define-internal-compiler-syntax ((fprintf #%fprintf) x r c) 
149  (display write fprintf number->string write-char open-output-string get-output-string)
150  (if (>= (length x) 3)
151      (let ((code (compile-format-string 
152                   'fprintf (cadr x) 
153                   x (cddr x)
154                   r c)))
155        (or code x))
156      x))
157
158(define-internal-compiler-syntax ((printf #%printf) x r c)
159  (display write fprintf number->string write-char open-output-string get-output-string)
160  (let ((code (compile-format-string 
161               'printf '##sys#standard-output
162               x (cdr x)
163               r c)))
164    (or code x)))
165
166(define (compile-format-string func out x args r c)
167  (call/cc
168   (lambda (return)
169     (and (>= (length args) 1)
170          (memq func extended-bindings) ; s.a.
171          (or (string? (car args))
172              (and (list? (car args))
173                   (c (r 'quote) (caar args))
174                   (string? (cadar args))))
175          (let ((fstr (if (string? (car args)) (car args) (cadar args)))
176                (args (cdr args)))
177            (define (fail ret? msg . args)
178              (let ((ln (get-line x)))
179                (compiler-warning 
180                 'syntax
181                 "(~a) in format string ~s~a, ~?" 
182                 func fstr 
183                 (if ln (sprintf " in line ~a" ln) "")
184                 msg args) ) 
185              (when ret? (return #f)))
186            (let ((code '())
187                  (index 0)
188                  (len (string-length fstr)) 
189                  (%display (r 'display))
190                  (%write (r 'write))
191                  (%write-char (r 'write-char))
192                  (%out (r 'out))
193                  (%fprintf (r 'fprintf))
194                  (%let (r 'let))
195                  (%number->string (r 'number->string)))
196              (define (fetch)
197                (let ((c (string-ref fstr index)))
198                  (set! index (fx+ index 1))
199                  c) )
200              (define (next)
201                (if (null? args)
202                    (fail #t "too few arguments to formatted output procedure")
203                    (let ((x (car args)))
204                      (set! args (cdr args))
205                      x) ) )
206              (define (endchunk chunk)
207                (when (pair? chunk)
208                  (push 
209                   (if (= 1 (length chunk))
210                       `(,%write-char ,(car chunk) ,%out)
211                       `(,%display ,(reverse-list->string chunk) ,%out)))))
212              (define (push exp)
213                (set! code (cons exp code)))
214              (let loop ((chunk '()))
215                (cond ((>= index len)
216                       (unless (null? args)
217                         (fail #f "too many arguments to formatted output procedure"))
218                       (endchunk chunk)
219                       `(,%let ((,%out ,out))
220                               ,@(reverse code)))
221                      (else
222                       (let ((c (fetch)))
223                         (if (eq? c #\~)
224                             (let ((dchar (fetch)))
225                               (endchunk chunk)
226                               (case (char-upcase dchar)
227                                 ((#\S) (push `(,%write ,(next) ,%out)))
228                                 ((#\A) (push `(,%display ,(next) ,%out)))
229                                 ((#\C) (push `(,%write-char ,(next) ,%out)))
230                                 ((#\B) (push `(,%display (,%number->string ,(next) 2) ,%out)))
231                                 ((#\O) (push `(,%display (,%number->string ,(next) 8) ,%out)))
232                                 ((#\X) (push `(,%display (,%number->string ,(next) 16) ,%out)))
233                                 ((#\!) (push `(##sys#flush-output ,%out)))
234                                 ((#\?)
235                                  (let* ([fstr (next)]
236                                         [lst (next)] )
237                                    (push `(##sys#apply ,%fprintf ,%out ,fstr ,lst))))
238                                 ((#\~) (push `(,write-char #\~ ,%out)))
239                                 ((#\% #\N) (push `(,%write-char #\newline ,%out)))
240                                 (else
241                                  (if (char-whitespace? dchar)
242                                      (let skip ((c (fetch)))
243                                        (if (char-whitespace? c)
244                                            (skip (fetch))
245                                            (set! index (sub1 index))))
246                                      (fail #t "illegal format-string character `~c'" dchar) ) ) )
247                               (loop '()) )
248                             (loop (cons c chunk)))))))))))))
Note: See TracBrowser for help on using the repository browser.