source: project/chicken/trunk/compiler-syntax.scm @ 15815

Last change on this file since 15815 was 15815, checked in by felix winkelmann, 10 years ago

inlining of multi-arg for-each/map

File size: 7.9 KB
Line 
1;;;; compiler-syntax.scm - compiler syntax used internally
2;
3; Copyright (c) 2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(declare 
28  (unit compiler-syntax) )
29
30
31(include "compiler-namespace")
32(include "tweaks.scm")
33
34
35;;; Compiler macros (that operate in the expansion phase)
36
37(define compiler-syntax-statistics '())
38
39(set! ##sys#compiler-syntax-hook
40  (lambda (name result)
41    (let ((a (alist-ref name compiler-syntax-statistics eq? 0)))
42      (set! compiler-syntax-statistics
43        (alist-update! name (add1 a) compiler-syntax-statistics)))))
44
45(define (r-c-s names transformer #!optional (se '()))
46  (let ((t (cons (##sys#er-transformer transformer) se)))
47    (for-each
48     (lambda (name)
49       (##sys#put! name '##compiler#compiler-syntax t) )
50     (if (symbol? names) (list names) names) ) ) )
51
52(define-syntax define-internal-compiler-syntax
53  (syntax-rules ()
54    ((_ (names . llist) (se ...) . body)
55     (r-c-s 
56      'names (lambda llist . body) 
57      `((se . ,(##sys#primitive-alias 'se)) ...)))))
58
59(define-internal-compiler-syntax ((for-each ##sys#for-each #%for-each) x r c)
60  (pair?)
61  (let ((%let (r 'let))
62        (%if (r 'if))
63        (%loop (r 'loop))
64        (%begin (r 'begin))
65        (%and (r 'and))
66        (%pair? (r 'pair?))
67        (lsts (cddr x)))
68    (if (and (memq 'for-each standard-bindings) ; we have to check this because the db (and thus
69             (> (length+ x) 2))                  ; intrinsic marks) isn't set up yet
70        (let ((vars (map (lambda _ (gensym)) lsts)))
71          `(,%let ,%loop ,(map list vars lsts)
72                  (,%if (,%and ,@(map (lambda (v) `(,%pair? ,v)) vars))
73                        (,%begin
74                         (,(cadr x)
75                          ,@(map (lambda (v) `(##sys#slot ,v 0)) vars))
76                         (##core#app 
77                          ,%loop
78                          ,@(map (lambda (v) `(##sys#slot ,v 1)) vars) ) ))))
79        x)))
80
81(define-internal-compiler-syntax ((map ##sys#map #%map) x r c)
82  (pair?)
83  (let ((%let (r 'let))
84        (%if (r 'if))
85        (%loop (r 'loop))
86        (%res (r 'res))
87        (%cons (r 'cons))
88        (%set! (r 'set!))
89        (%result (r 'result))
90        (%node (r 'node))
91        (%quote (r 'quote))
92        (%and (r 'and))
93        (%pair? (r 'pair?))
94        (lsts (cddr x)))
95    (if (and (memq 'map standard-bindings) ; s.a.
96             (> (length+ x) 2))
97        (let ((vars (map (lambda _ (gensym)) lsts)))
98          `(,%let ((,%result (,%quote ()))
99                   (,%node #f))
100                  (,%let ,%loop ,(map list vars lsts)
101                       (,%if (,%and ,@(map (lambda (v) `(,%pair? ,v)) vars))
102                             (,%let ((,%res
103                                      (,%cons
104                                       (,(cadr x)
105                                        ,@(map (lambda (v) `(##sys#slot ,v 0)) vars))
106                                       (,%quote ()))))
107                                    (,%if ,%node
108                                          (##sys#setslot ,%node 1 ,%res)
109                                          (,%set! ,%result ,%res))
110                                    (,%set! ,%node ,%res)
111                                    (,%loop
112                                     ,@(map (lambda (v) `(##sys#slot ,v 1)) vars)))
113                             ,%result))))
114        x)))
115
116(define-internal-compiler-syntax ((o #%o) x r c) ()
117  (if (and (fx> (length x) 1)
118           (memq 'o extended-bindings) ) ; s.a.
119      (let ((%tmp (r 'tmp)))
120        `(,(r 'lambda) (,%tmp) ,(fold-right list %tmp (cdr x))))
121      x))
122
123(define-internal-compiler-syntax ((sprintf #%sprintf format #%format) x r c)
124  (display write fprintf number->string write-char open-output-string get-output-string)
125  (let* ((out (gensym 'out))
126         (code (compile-format-string 
127                (if (memq (car x) '(sprintf #%sprintf))
128                    'sprintf
129                    'format)
130                out 
131                x
132                (cdr x)
133                r c)))
134    (if code
135        `(,(r 'let) ((,out (,(r 'open-output-string))))
136          ,code
137          (,(r 'get-output-string) ,out))
138        x)))
139
140(define-internal-compiler-syntax ((fprintf #%fprintf) x r c) 
141  (display write fprintf number->string write-char open-output-string get-output-string)
142  (if (>= (length x) 3)
143      (let ((code (compile-format-string 
144                   'fprintf (cadr x) 
145                   x (cddr x)
146                   r c)))
147        (or code x))
148      x))
149
150(define-internal-compiler-syntax ((printf #%printf) x r c)
151  (display write fprintf number->string write-char open-output-string get-output-string)
152  (let ((code (compile-format-string 
153               'printf '##sys#standard-output
154               x (cdr x)
155               r c)))
156    (or code x)))
157
158(define (compile-format-string func out x args r c)
159  (call/cc
160   (lambda (return)
161     (and (>= (length args) 1)
162          (memq func extended-bindings) ; s.a.
163          (or (string? (car args))
164              (and (list? (car args))
165                   (c (r 'quote) (caar args))
166                   (string? (cadar args))))
167          (let ((fstr (if (string? (car args)) (car args) (cadar args)))
168                (args (cdr args)))
169            (define (fail ret? msg . args)
170              (let ((ln (get-line x)))
171                (compiler-warning 
172                 'syntax
173                 "(~a) in format string ~s~a, ~?" 
174                 func fstr 
175                 (if ln (sprintf " in line ~a" ln) "")
176                 msg args) ) 
177              (when ret? (return #f)))
178            (let ((code '())
179                  (index 0)
180                  (len (string-length fstr)) 
181                  (%display (r 'display))
182                  (%write (r 'write))
183                  (%write-char (r 'write-char))
184                  (%out (r 'out))
185                  (%fprintf (r 'fprintf))
186                  (%let (r 'let))
187                  (%number->string (r 'number->string)))
188              (define (fetch)
189                (let ((c (string-ref fstr index)))
190                  (set! index (fx+ index 1))
191                  c) )
192              (define (next)
193                (if (null? args)
194                    (fail #t "too few arguments to formatted output procedure")
195                    (let ((x (car args)))
196                      (set! args (cdr args))
197                      x) ) )
198              (define (endchunk chunk)
199                (when (pair? chunk)
200                  (push 
201                   (if (= 1 (length chunk))
202                       `(,%write-char ,(car chunk) ,%out)
203                       `(,%display ,(reverse-list->string chunk) ,%out)))))
204              (define (push exp)
205                (set! code (cons exp code)))
206              (let loop ((chunk '()))
207                (cond ((>= index len)
208                       (unless (null? args)
209                         (fail #f "too many arguments to formatted output procedure"))
210                       (endchunk chunk)
211                       `(,%let ((,%out ,out))
212                               ,@(reverse code)))
213                      (else
214                       (let ((c (fetch)))
215                         (if (eq? c #\~)
216                             (let ((dchar (fetch)))
217                               (endchunk chunk)
218                               (case (char-upcase dchar)
219                                 ((#\S) (push `(,%write ,(next) ,%out)))
220                                 ((#\A) (push `(,%display ,(next) ,%out)))
221                                 ((#\C) (push `(,%write-char ,(next) ,%out)))
222                                 ((#\B) (push `(,%display (,%number->string ,(next) 2) ,%out)))
223                                 ((#\O) (push `(,%display (,%number->string ,(next) 8) ,%out)))
224                                 ((#\X) (push `(,%display (,%number->string ,(next) 16) ,%out)))
225                                 ((#\!) (push `(##sys#flush-output ,%out)))
226                                 ((#\?)
227                                  (let* ([fstr (next)]
228                                         [lst (next)] )
229                                    (push `(##sys#apply ,%fprintf ,%out ,fstr ,lst))))
230                                 ((#\~) (push `(,write-char #\~ ,%out)))
231                                 ((#\% #\N) (push `(,%write-char #\newline ,%out)))
232                                 (else
233                                  (if (char-whitespace? dchar)
234                                      (let skip ((c (fetch)))
235                                        (if (char-whitespace? c)
236                                            (skip (fetch))
237                                            (set! index (sub1 index))))
238                                      (fail #t "illegal format-string character `~c'" dchar) ) ) )
239                               (loop '()) )
240                             (loop (cons c chunk)))))))))))))
Note: See TracBrowser for help on using the repository browser.