source: project/chicken/trunk/compiler-syntax.scm @ 15795

Last change on this file since 15795 was 15795, checked in by felix winkelmann, 11 years ago

added compiler-syntax for map (not enabled yet)

File size: 7.6 KB
Line 
1;;;; compiler-syntax.scm - compiler syntax used internally
2;
3; Copyright (c) 2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(declare 
28  (unit compiler-syntax) )
29
30
31(include "compiler-namespace")
32(include "tweaks.scm")
33
34
35;;; Compiler macros (that operate in the expansion phase)
36
37(define compiler-syntax-statistics '())
38
39(set! ##sys#compiler-syntax-hook
40  (lambda (name result)
41    (let ((a (alist-ref name compiler-syntax-statistics eq? 0)))
42      (set! compiler-syntax-statistics
43        (alist-update! name (add1 a) compiler-syntax-statistics)))))
44
45(define (r-c-s names transformer #!optional (se '()))
46  (let ((t (cons (##sys#er-transformer transformer) se)))
47    (for-each
48     (lambda (name)
49       (##sys#put! name '##compiler#compiler-syntax t) )
50     (if (symbol? names) (list names) names) ) ) )
51
52(define-syntax define-internal-compiler-syntax
53  (syntax-rules ()
54    ((_ (names . llist) (se ...) . body)
55     (r-c-s 
56      'names (lambda llist . body) 
57      `((se . ,(##sys#primitive-alias 'se)) ...)))))
58
59(define-internal-compiler-syntax ((for-each ##sys#for-each #%for-each) x r c)
60  (pair?)
61  (let ((%let (r 'let))
62        (%if (r 'if))
63        (%loop (r 'loop))
64        (%lst (r 'lst))
65        (%begin (r 'begin))
66        (%pair? (r 'pair?)))
67    (if (and (memq 'for-each standard-bindings) ; we have to check this because the db (and thus
68             (= 3 (length x)))                   ; intrinsic marks) isn't set up yet
69        `(,%let ,%loop ((,%lst ,(caddr x)))
70                (,%if (,%pair? ,%lst)
71                      (,%begin
72                       (,(cadr x) (##sys#slot ,%lst 0))
73                       (##core#app ,%loop (##sys#slot ,%lst 1))) ) )
74        x)))
75
76#+xxx
77(define-internal-compiler-syntax ((map ##sys#map #%map) x r c)
78  (pair?)
79  (let ((%let (r 'let))
80        (%let* (r 'let*))
81        (%if (r 'if))
82        (%loop (r 'loop))
83        (%lst (r 'lst))
84        (%res (r 'res))
85        (%cons (r 'cons))
86        (%set! (r 'set!))
87        (%result (r 'result))
88        (%x (r 'x))
89        (%node (r 'node))
90        (%quote (r 'quote))
91        (%pair? (r 'pair?)))
92    (if (and (memq 'map standard-bindings) ; s.a.
93             (= 3 (length x)))
94        `(,%let ((,%result (,%quote ()))
95                 (,%node #f))
96                (,%let ,%loop ((,%lst ,(caddr x)))
97                       (,%if (,%pair? ,%lst)
98                             (,%let* ((,%x (##sys#slot ,%lst 0))
99                                      (,%res (,%cons (,(cadr x) ,%x) (,%quote ()))))
100                                     (,%if ,%node
101                                           (##sys#setslot ,%node 1 ,%res)
102                                           (,%set! ,%result ,%res))
103                                     (,%set! ,%node ,%res)
104                                     (,%loop (##sys#slot ,%lst 1)))
105                             ,%result)))
106        x)))
107
108(define-internal-compiler-syntax ((o #%o) x r c) ()
109  (if (and (fx> (length x) 1)
110           (memq 'o extended-bindings) ) ; s.a.
111      (let ((%tmp (r 'tmp)))
112        `(,(r 'lambda) (,%tmp) ,(fold-right list %tmp (cdr x))))
113      x))
114
115(define-internal-compiler-syntax ((sprintf #%sprintf format #%format) x r c)
116  (display write fprintf number->string write-char open-output-string get-output-string)
117  (let* ((out (gensym 'out))
118         (code (compile-format-string 
119                (if (memq (car x) '(sprintf #%sprintf))
120                    'sprintf
121                    'format)
122                out 
123                x
124                (cdr x)
125                r c)))
126    (if code
127        `(,(r 'let) ((,out (,(r 'open-output-string))))
128          ,code
129          (,(r 'get-output-string) ,out))
130        x)))
131
132(define-internal-compiler-syntax ((fprintf #%fprintf) x r c) 
133  (display write fprintf number->string write-char open-output-string get-output-string)
134  (if (>= (length x) 3)
135      (let ((code (compile-format-string 
136                   'fprintf (cadr x) 
137                   x (cddr x)
138                   r c)))
139        (or code x))
140      x))
141
142(define-internal-compiler-syntax ((printf #%printf) x r c)
143  (display write fprintf number->string write-char open-output-string get-output-string)
144  (let ((code (compile-format-string 
145               'printf '##sys#standard-output
146               x (cdr x)
147               r c)))
148    (or code x)))
149
150(define (compile-format-string func out x args r c)
151  (call/cc
152   (lambda (return)
153     (and (>= (length args) 1)
154          (memq func extended-bindings) ; s.a.
155          (or (string? (car args))
156              (and (list? (car args))
157                   (c (r 'quote) (caar args))
158                   (string? (cadar args))))
159          (let ((fstr (if (string? (car args)) (car args) (cadar args)))
160                (args (cdr args)))
161            (define (fail ret? msg . args)
162              (let ((ln (get-line x)))
163                (compiler-warning 
164                 'syntax
165                 "(~a) in format string ~s~a, ~?" 
166                 func fstr 
167                 (if ln (sprintf " in line ~a" ln) "")
168                 msg args) ) 
169              (when ret? (return #f)))
170            (let ((code '())
171                  (index 0)
172                  (len (string-length fstr)) 
173                  (%display (r 'display))
174                  (%write (r 'write))
175                  (%write-char (r 'write-char))
176                  (%out (r 'out))
177                  (%fprintf (r 'fprintf))
178                  (%let (r 'let))
179                  (%number->string (r 'number->string)))
180              (define (fetch)
181                (let ((c (string-ref fstr index)))
182                  (set! index (fx+ index 1))
183                  c) )
184              (define (next)
185                (if (null? args)
186                    (fail #t "too few arguments to formatted output procedure")
187                    (let ((x (car args)))
188                      (set! args (cdr args))
189                      x) ) )
190              (define (endchunk chunk)
191                (when (pair? chunk)
192                  (push 
193                   (if (= 1 (length chunk))
194                       `(,%write-char ,(car chunk) ,%out)
195                       `(,%display ,(reverse-list->string chunk) ,%out)))))
196              (define (push exp)
197                (set! code (cons exp code)))
198              (let loop ((chunk '()))
199                (cond ((>= index len)
200                       (unless (null? args)
201                         (fail #f "too many arguments to formatted output procedure"))
202                       (endchunk chunk)
203                       `(,%let ((,%out ,out))
204                               ,@(reverse code)))
205                      (else
206                       (let ((c (fetch)))
207                         (if (eq? c #\~)
208                             (let ((dchar (fetch)))
209                               (endchunk chunk)
210                               (case (char-upcase dchar)
211                                 ((#\S) (push `(,%write ,(next) ,%out)))
212                                 ((#\A) (push `(,%display ,(next) ,%out)))
213                                 ((#\C) (push `(,%write-char ,(next) ,%out)))
214                                 ((#\B) (push `(,%display (,%number->string ,(next) 2) ,%out)))
215                                 ((#\O) (push `(,%display (,%number->string ,(next) 8) ,%out)))
216                                 ((#\X) (push `(,%display (,%number->string ,(next) 16) ,%out)))
217                                 ((#\!) (push `(##sys#flush-output ,%out)))
218                                 ((#\?)
219                                  (let* ([fstr (next)]
220                                         [lst (next)] )
221                                    (push `(##sys#apply ,%fprintf ,%out ,fstr ,lst))))
222                                 ((#\~) (push `(,write-char #\~ ,%out)))
223                                 ((#\% #\N) (push `(,%write-char #\newline ,%out)))
224                                 (else
225                                  (if (char-whitespace? dchar)
226                                      (let skip ((c (fetch)))
227                                        (if (char-whitespace? c)
228                                            (skip (fetch))
229                                            (set! index (sub1 index))))
230                                      (fail #t "illegal format-string character `~c'" dchar) ) ) )
231                               (loop '()) )
232                             (loop (cons c chunk)))))))))))))
Note: See TracBrowser for help on using the repository browser.