source: project/chicken/trunk/compiler-syntax.scm @ 15580

Last change on this file since 15580 was 15580, checked in by felix winkelmann, 11 years ago

moved internally used compiler syntax into separate unit

File size: 6.8 KB
Line 
1;;;; compiler-syntax.scm - compiler syntax used internally
2;
3; Copyright (c) 2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(declare 
28  (unit compiler-syntax) )
29
30
31(include "compiler-namespace")
32(include "tweaks.scm")
33
34
35;;; Compiler macros (that operate in the expansion phase)
36
37(define compiler-syntax-statistics '())
38
39(set! ##sys#compiler-syntax-hook
40  (lambda (name result)
41    (let ((a (alist-ref name compiler-syntax-statistics eq? 0)))
42      (set! compiler-syntax-statistics
43        (alist-update! name (add1 a) compiler-syntax-statistics)))))
44
45(define (r-c-s names transformer #!optional (se '()))
46  (let ((t (cons (##sys#er-transformer transformer) se)))
47    (for-each
48     (lambda (name)
49       (##sys#put! name '##compiler#compiler-syntax t) )
50     (if (symbol? names) (list names) names) ) ) )
51
52(define-syntax define-internal-compiler-syntax
53  (syntax-rules ()
54    ((_ (names . llist) (se ...) . body)
55     (r-c-s 
56      'names (lambda llist . body) 
57      `((se . ,(##sys#primitive-alias 'se)) ...)))))
58
59(define-internal-compiler-syntax ((for-each ##sys#for-each #%for-each) x r c)
60  (pair?)
61  (let ((%let (r 'let))
62        (%if (r 'if))
63        (%loop (r 'loop))
64        (%lst (r 'lst))
65        (%begin (r 'begin))
66        (%pair? (r 'pair?)))
67    (if (and (memq 'for-each standard-bindings) ; we have to check this because the db (and thus
68             (= 3 (length x)))                   ; intrinsic marks) isn't set up yet
69        `(,%let ,%loop ((,%lst ,(caddr x)))
70                (,%if (,%pair? ,%lst)
71                      (,%begin
72                       (,(cadr x) (##sys#slot ,%lst 0))
73                       (##core#app ,%loop (##sys#slot ,%lst 1))) ) )
74        x)))
75
76(define-internal-compiler-syntax ((o #%o) x r c) ()
77  (if (and (fx> (length x) 1)
78           (memq 'o extended-bindings) ) ; s.a.
79      (let ((%tmp (r 'tmp)))
80        `(,(r 'lambda) (,%tmp) ,(fold-right list %tmp (cdr x))))
81      x))
82
83(define-internal-compiler-syntax ((sprintf #%sprintf format #%format) x r c)
84  (display write fprintf number->string write-char open-output-string get-output-string)
85  (let* ((out (gensym 'out))
86         (code (compile-format-string 
87                (if (memq (car x) '(sprintf #%sprintf))
88                    'sprintf
89                    'format)
90                out 
91                x
92                (cdr x)
93                r c)))
94    (if code
95        `(,(r 'let) ((,out (,(r 'open-output-string))))
96          ,code
97          (,(r 'get-output-string) ,out))
98        x)))
99
100(define-internal-compiler-syntax ((fprintf #%fprintf) x r c) 
101  (display write fprintf number->string write-char open-output-string get-output-string)
102  (if (>= (length x) 3)
103      (let ((code (compile-format-string 
104                   'fprintf (cadr x) 
105                   x (cddr x)
106                   r c)))
107        (or code x))
108      x))
109
110(define-internal-compiler-syntax ((printf #%printf) x r c)
111  (display write fprintf number->string write-char open-output-string get-output-string)
112  (let ((code (compile-format-string 
113               'printf '##sys#standard-output
114               x (cdr x)
115               r c)))
116    (or code x)))
117
118(define (compile-format-string func out x args r c)
119  (call/cc
120   (lambda (return)
121     (and (>= (length args) 1)
122          (memq func extended-bindings) ; s.a.
123          (or (string? (car args))
124              (and (list? (car args))
125                   (c (r 'quote) (caar args))
126                   (string? (cadar args))))
127          (let ((fstr (if (string? (car args)) (car args) (cadar args)))
128                (args (cdr args)))
129            (define (fail ret? msg . args)
130              (let ((ln (get-line x)))
131                (compiler-warning 
132                 'syntax
133                 "(~a) in format string ~s~a, ~?" 
134                 func fstr 
135                 (if ln (sprintf " in line ~a" ln) "")
136                 msg args) ) 
137              (when ret? (return #f)))
138            (let ((code '())
139                  (index 0)
140                  (len (string-length fstr)) 
141                  (%display (r 'display))
142                  (%write (r 'write))
143                  (%write-char (r 'write-char))
144                  (%out (r 'out))
145                  (%fprintf (r 'fprintf))
146                  (%let (r 'let))
147                  (%number->string (r 'number->string)))
148              (define (fetch)
149                (let ((c (string-ref fstr index)))
150                  (set! index (fx+ index 1))
151                  c) )
152              (define (next)
153                (if (null? args)
154                    (fail #t "too few arguments to formatted output procedure")
155                    (let ((x (car args)))
156                      (set! args (cdr args))
157                      x) ) )
158              (define (endchunk chunk)
159                (when (pair? chunk)
160                  (push 
161                   (if (= 1 (length chunk))
162                       `(,%write-char ,(car chunk) ,%out)
163                       `(,%display ,(reverse-list->string chunk) ,%out)))))
164              (define (push exp)
165                (set! code (cons exp code)))
166              (let loop ((chunk '()))
167                (cond ((>= index len)
168                       (unless (null? args)
169                         (fail #f "too many arguments to formatted output procedure"))
170                       (endchunk chunk)
171                       `(,%let ((,%out ,out))
172                               ,@(reverse code)))
173                      (else
174                       (let ((c (fetch)))
175                         (if (eq? c #\~)
176                             (let ((dchar (fetch)))
177                               (endchunk chunk)
178                               (case (char-upcase dchar)
179                                 ((#\S) (push `(,%write ,(next) ,%out)))
180                                 ((#\A) (push `(,%display ,(next) ,%out)))
181                                 ((#\C) (push `(,%write-char ,(next) ,%out)))
182                                 ((#\B) (push `(,%display (,%number->string ,(next) 2) ,%out)))
183                                 ((#\O) (push `(,%display (,%number->string ,(next) 8) ,%out)))
184                                 ((#\X) (push `(,%display (,%number->string ,(next) 16) ,%out)))
185                                 ((#\!) (push `(##sys#flush-output ,%out)))
186                                 ((#\?)
187                                  (let* ([fstr (next)]
188                                         [lst (next)] )
189                                    (push `(##sys#apply ,%fprintf ,%out ,fstr ,lst))))
190                                 ((#\~) (push `(,write-char #\~ ,%out)))
191                                 ((#\% #\N) (push `(,%write-char #\newline ,%out)))
192                                 (else
193                                  (if (char-whitespace? dchar)
194                                      (let skip ((c (fetch)))
195                                        (if (char-whitespace? c)
196                                            (skip (fetch))
197                                            (set! index (sub1 index))))
198                                      (fail #t "illegal format-string character `~c'" dchar) ) ) )
199                               (loop '()) )
200                             (loop (cons c chunk)))))))))))))
Note: See TracBrowser for help on using the repository browser.