source: project/chicken/trunk/chicken-syntax.scm @ 15700

Last change on this file since 15700 was 15600, checked in by felix winkelmann, 11 years ago

added get-condition-property

File size: 34.8 KB
Line 
1;;;; chicken-syntax.scm - non-standard syntax extensions
2;
3; Copyright (c) 2008-2009, The Chicken Team
4; Copyright (c) 2000-2007, Felix L. Winkelmann
5; All rights reserved.
6;
7; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
8; conditions are met:
9;
10;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
11;     disclaimer.
12;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
13;     disclaimer in the documentation and/or other materials provided with the distribution.
14;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
15;     products derived from this software without specific prior written permission.
16;
17; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
18; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
19; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
20; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
21; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
22; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
23; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
24; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
25; POSSIBILITY OF SUCH DAMAGE.
26
27
28(declare
29  (unit chicken-syntax)
30  (disable-interrupts)
31  (no-bound-checks)
32  (no-procedure-checks)
33  (fixnum) )
34
35(##sys#provide
36 'chicken-more-macros                   ; historical, remove later
37 'chicken-syntax)
38
39
40;;; Non-standard macros:
41
42(define ##sys#chicken-macro-environment
43  (let ((me0 (##sys#macro-environment)))
44
45(##sys#extend-macro-environment
46 'define-record '()
47 (##sys#er-transformer
48  (lambda (x r c)
49    (##sys#check-syntax 'define-record x '(_ symbol . #(symbol 0)))
50    (let* ((name (cadr x))
51           (slots (cddr x))
52           (prefix (symbol->string name))
53           (%quote (r 'quote))
54           (setters (memq #:record-setters ##sys#features))
55           (%begin (r 'begin))
56           (%define (r 'define))
57           (%getter-with-setter (r 'getter-with-setter))
58           (%lambda (r 'lambda)) )
59      `(,%begin
60          (,%define 
61           ,(string->symbol (string-append "make-" prefix))
62           (,%lambda ,slots (##sys#make-structure (,%quote ,name) ,@slots)) )
63          (,%define
64           ,(string->symbol (string-append prefix "?"))
65           (,%lambda (x) (##sys#structure? x ',name)) )
66          ,@(let mapslots ((slots slots) (i 1))
67              (if (eq? slots '())
68                  slots
69                  (let* ((slotname (symbol->string (##sys#slot slots 0)))
70                         (setr (string->symbol (string-append prefix "-" slotname "-set!")))
71                         (getr (string->symbol (string-append prefix "-" slotname)) ) )
72                    (cons
73                     `(,%begin
74                        (,%define
75                         ,setr
76                         (,%lambda (x val)
77                                   (##core#check (##sys#check-structure x (,%quote ,name)))
78                                   (##sys#block-set! x ,i val) ) )
79                        (,%define
80                         ,getr
81                         ,(if setters
82                              `(,%getter-with-setter
83                                (,%lambda (x) 
84                                          (##core#check (##sys#check-structure x (,%quote ,name)))
85                                          (##sys#block-ref x ,i) )
86                                ,setr)
87                              `(,%lambda (x)
88                                         (##core#check (##sys#check-structure x (,%quote ,name)))
89                                         (##sys#block-ref x ,i) ) ) ) )
90                     (mapslots (##sys#slot slots 1) (fx+ i 1)) ) ) ) ) ) ) ) ) )
91
92(##sys#extend-macro-environment
93 'receive
94 '()
95 (##sys#er-transformer
96 (lambda (form r c)
97   (let ((%lambda (r 'lambda))
98         (%let (r 'let)))
99     (##sys#check-syntax 'receive form '(_ _ . #(_ 0)))
100     (cond ((null? (cddr form))
101            `(##sys#call-with-values (,%lambda () ,@(cdr form)) ##sys#list) )
102           (else
103            (##sys#check-syntax 'receive form '(_ lambda-list _ . #(_ 1)))
104            (let ((vars (cadr form))
105                  (exp (caddr form))
106                  (rest (cdddr form)))
107              (if (and (pair? vars) (null? (cdr vars)))
108                  `(,%let ((,(car vars) ,exp)) ,@rest)
109                  `(##sys#call-with-values 
110                    (,%lambda () ,exp)
111                    (,%lambda ,vars ,@rest)) ) ) ) ) ))))
112
113(##sys#extend-macro-environment
114 'time '()
115 (##sys#er-transformer
116 (lambda (form r c)
117   (let ((rvar (r 't))
118         (%begin (r 'begin))
119         (%lambda (r 'lambda)))
120    `(,%begin
121       (##sys#start-timer)
122       (##sys#call-with-values 
123        (,%lambda () ,@(cdr form))
124        (,%lambda ,rvar
125                  (##sys#display-times (##sys#stop-timer))
126                  (##sys#apply ##sys#values ,rvar) ) ) ) ) ) ) )
127
128(##sys#extend-macro-environment
129 'declare '()
130 (##sys#er-transformer
131 (lambda (form r c)
132   `(##core#declare ,@(cdr form)))))
133
134(##sys#extend-macro-environment
135 'include '()
136 (##sys#er-transformer
137 (lambda (form r c)
138   (##sys#check-syntax 'include form '(_ string))
139   (let ((path (##sys#resolve-include-filename (cadr form) #t))
140         (%begin (r 'begin)))
141     (when (load-verbose) (print "; including " path " ..."))
142     `(,%begin
143       ,@(with-input-from-file path
144           (lambda ()
145             (fluid-let ((##sys#current-source-filename path))
146               (do ([x (read) (read)]
147                    [xs '() (cons x xs)] )
148                   ((eof-object? x) 
149                    (reverse xs))) ) ) ) ) ) ) ) )
150
151(##sys#extend-macro-environment
152 'assert '()
153 (##sys#er-transformer
154 (lambda (form r c)
155   (##sys#check-syntax 'assert form '#(_ 1))
156   (let* ((exp (cadr form))
157          (msg-and-args (cddr form))
158          (%if (r 'if))
159          (%quote (r 'quote))
160          (msg (if (eq? '() msg-and-args)
161                   `(##core#immutable '"assertion failed")
162                   (car msg-and-args) ) ) )
163     `(,%if (##core#check ,exp)
164            (##core#undefined)
165            (##sys#error 
166             ,msg 
167             ,@(if (fx> (length msg-and-args) 1)
168                   (cdr msg-and-args)
169                   '() ) ) ) ) )) )
170
171(##sys#extend-macro-environment
172 'ensure
173 '()
174 (##sys#er-transformer
175  (lambda (form r c)
176    (##sys#check-syntax 'ensure form '#(_ 3))
177    (let ((pred (cadr form))
178          (exp (caddr form))
179          (args (cdddr form))
180          (tmp (r 'tmp))
181          (%let (r 'let))
182          (%if (r 'if)) )
183      `(,%let ([,tmp ,exp])
184              (,%if (##core#check (,pred ,tmp))
185                    ,tmp
186                    (##sys#signal-hook
187                     #:type-error
188                     ,@(if (pair? args)
189                           args
190                           `((##core#immutable '"argument has incorrect type")
191                             ,tmp ',pred) ) ) ) ) ) ) ) )
192
193(##sys#extend-macro-environment
194 'fluid-let '()
195 (##sys#er-transformer
196  (lambda (form r c)
197    (##sys#check-syntax 'fluid-let form '(_ #((symbol _) 0) . _))
198     (let* ((clauses (cadr form))
199           (body (cddr form))
200           (ids (##sys#map car clauses))
201           (new-tmps (##sys#map (lambda (x) (r (gensym))) clauses))
202           (old-tmps (##sys#map (lambda (x) (r (gensym))) clauses))
203           (%let (r 'let))
204           (%lambda (r 'lambda)))
205       `(,%let (,@(map ##sys#list new-tmps (##sys#map cadr clauses))
206                ,@(map ##sys#list old-tmps
207                       (let loop ((n (length clauses)))
208                         (if (eq? n 0)
209                             '()
210                             (cons #f (loop (fx- n 1))) ) ) ) )
211               (##sys#dynamic-wind
212                (,%lambda ()
213                          ,@(map (lambda (ot id) `(##core#set! ,ot ,id))
214                                 old-tmps ids)
215                          ,@(map (lambda (id nt) `(##core#set! ,id ,nt))
216                                 ids new-tmps)
217                          (##core#undefined) )
218                (,%lambda () ,@body)
219                (,%lambda ()
220                          ,@(map (lambda (nt id) `(##core#set! ,nt ,id))
221                                 new-tmps ids)
222                          ,@(map (lambda (id ot) `(##core#set! ,id ,ot))
223                                 ids old-tmps)
224                          (##core#undefined) ) ) ) ) )))
225
226(##sys#extend-macro-environment
227 'eval-when '()
228 (##sys#er-transformer
229  (lambda (form r c)
230    (##sys#check-syntax 'eval-when form '#(_ 2))
231    (let* ((situations (cadr form))
232           (%begin (r 'begin))
233           (body `(,%begin ,@(cddr form)))
234           (%eval (r 'eval))
235           (%compile (r 'compile))
236           (%load (r 'load))
237           (e #f)
238           (co #f)
239           (l #f))
240      (let loop ([ss situations])
241        (if (pair? ss)
242            (let ((s (car ss)))
243              (cond ((c s %eval) (set! e #t))
244                    ((c s %load) (set! l #t))
245                    ((c s %compile) (set! co #t))
246                    (else (##sys#error "invalid situation specifier" (car ss)) ))
247              (loop (##sys#slot ss 1)) ) ) )
248      (if (memq '#:compiling ##sys#features)
249          (cond [(and co l) `(##core#compiletimetoo ,body)]
250                [co `(##core#compiletimeonly ,body)]
251                [l body]
252                [else '(##core#undefined)] )
253          (if e 
254              body
255              '(##core#undefined) ) ) ) ) ) )
256
257(##sys#extend-macro-environment
258 'parameterize '()
259 (##sys#er-transformer
260  (lambda (form r c)
261    (##sys#check-syntax 'parameterize form '#(_ 2))
262     (let* ((bindings (cadr form))
263            (body (cddr form))
264            (swap (r 'swap))
265            (%let (r 'let))
266            (%lambda (r 'lambda))
267            [params (##sys#map car bindings)]
268            [vals (##sys#map cadr bindings)]
269            [aliases (##sys#map (lambda (z) (r (gensym))) params)]
270            [aliases2 (##sys#map (lambda (z) (r (gensym))) params)] )
271       `(,%let ,(##sys#append (map ##sys#list aliases params) (map ##sys#list aliases2 vals))
272          (,%let ((,swap (,%lambda ()
273                                   ,@(map (lambda (a a2)
274                                            `(,%let ((t (,a))) (,a ,a2)
275                                                    (##core#set! ,a2 t)))
276                                          aliases aliases2) ) ) )
277                 (##sys#dynamic-wind 
278                  ,swap
279                  (,%lambda () ,@body)
280                  ,swap) ) ) ) )))
281
282(##sys#extend-macro-environment
283 'when '()
284 (##sys#er-transformer
285  (lambda (form r c)
286    (##sys#check-syntax 'when form '#(_ 2))
287    `(,(r 'if) ,(cadr form)
288      (,(r 'begin) ,@(cddr form))))))
289
290(##sys#extend-macro-environment
291 'unless '()
292 (##sys#er-transformer
293  (lambda (form r c)
294    (##sys#check-syntax 'unless form '#(_ 2))
295    `(,(r 'if) ,(cadr form)
296      (##core#undefined)
297      (,(r 'begin) ,@(cddr form))))))
298
299(##sys#extend-macro-environment
300 'set!-values '()
301 (##sys#er-transformer
302  (lambda (form r c)
303    (##sys#check-syntax 'set!-values form '(_ #(variable 0) _))
304    (let ((vars (cadr form))
305          (exp (caddr form))
306          (%lambda (r 'lambda)))
307      (cond ((null? vars)
308             ;; may this be simply "exp"?
309             `(##sys#call-with-values
310               (,%lambda () ,exp)
311               (,%lambda () (##core#undefined))) )
312            ((null? (cdr vars))
313             `(##core#set! ,(car vars) ,exp)) 
314            (else
315             (let ([aliases (map gensym vars)])
316               `(##sys#call-with-values
317                 (,%lambda () ,exp)
318                 (,%lambda ,aliases
319                           ,@(map (lambda (v a)
320                                    `(##core#set! ,v ,a))
321                                  vars aliases) ) ) ) ) ) ))))
322
323(##sys#extend-macro-environment
324 'define-values '()
325 (##sys#er-transformer
326  (lambda (form r c)
327    (##sys#check-syntax 'define-values form '(_ #(variable 0) _))
328    (for-each (cut ##sys#register-export <> (##sys#current-module)) (cadr form))
329    `(,(r 'set!-values) ,@(cdr form)))))
330
331(##sys#extend-macro-environment
332 'let-values '()
333 (##sys#er-transformer
334  (lambda (form r c)
335    (##sys#check-syntax 'let-values form '(_ list . _))
336    (let ((vbindings (cadr form))
337          (body (cddr form))
338          (%let (r 'let))
339          (%lambda (r 'lambda)))
340      (letrec ((append* (lambda (il l)
341                          (if (not (pair? il))
342                              (cons il l)
343                              (cons (car il)
344                                    (append* (cdr il) l)))))
345               (map* (lambda (proc l)
346                       (cond ((null? l) '())
347                             ((not (pair? l)) (proc l))
348                             (else (cons (proc (car l)) (map* proc (cdr l))))))))
349        (let* ([llists (map car vbindings)]
350               [vars (let loop ((llists llists) (acc '()))
351                       (if (null? llists)
352                           acc
353                           (let* ((llist (car llists))
354                                  (new-acc
355                                   (cond ((list? llist) (append llist acc))
356                                         ((pair? llist) (append* llist acc))
357                                         (else (cons llist acc)))))
358                             (loop (cdr llists) new-acc))))]
359               [aliases (map (lambda (v) (cons v (r (gensym v)))) vars)]
360               [lookup (lambda (v) (cdr (assq v aliases)))]
361               [llists2 (let loop ((llists llists) (acc '()))
362                          (if (null? llists)
363                              (reverse acc)
364                              (let* ((llist (car llists))
365                                     (new-acc
366                                      (cond ((not (pair? llist)) (cons (lookup llist) acc))
367                                            (else (cons (map* lookup llist) acc)))))
368                                (loop (cdr llists) new-acc))))])
369          (let fold ([llists llists]
370                     [exps (map (lambda (x) (cadr x)) vbindings)]
371                     [llists2 llists2] )
372            (cond ((null? llists)
373                   `(,%let ,(map (lambda (v) (##sys#list v (lookup v))) vars) ,@body) )
374                  ((and (pair? (car llists2)) (null? (cdar llists2)))
375                   `(,%let ((,(caar llists2) ,(car exps)))
376                           ,(fold (cdr llists) (cdr exps) (cdr llists2)) ) )
377                  (else
378                   `(##sys#call-with-values
379                     (,%lambda () ,(car exps))
380                     (,%lambda ,(car llists2) ,(fold (cdr llists) (cdr exps) (cdr llists2))) ) ) ) ) ) ) ) ) ) )
381
382(##sys#extend-macro-environment
383 'let*-values '()
384 (##sys#er-transformer
385  (lambda (form r c)
386    (##sys#check-syntax 'let*-values form '(_ list . _))
387    (let ((vbindings (cadr form))
388          (body (cddr form))
389          (%let (r 'let))
390          (%let-values (r 'let-values)) )
391      (let fold ([vbindings vbindings])
392        (if (null? vbindings)
393            `(,%let () ,@body)
394            `(,%let-values (,(car vbindings))
395                           ,(fold (cdr vbindings))) ) ) ))))
396
397(##sys#extend-macro-environment
398 'letrec-values '()
399 (##sys#er-transformer
400  (lambda (form r c)
401    (##sys#check-syntax 'letrec-values form '(_ list . _))
402    (let ((vbindings (cadr form))
403          (body (cddr form))
404          (%let (r 'let))
405          (%lambda (r 'lambda)))
406      (let* ([vars (apply ##sys#append (map (lambda (x) (car x)) vbindings))] 
407             [aliases (map (lambda (v) (cons v (r (gensym v)))) vars)] 
408             [lookup (lambda (v) (cdr (assq v aliases)))] )
409        `(,%let ,(map (lambda (v) (##sys#list v '(##core#undefined))) vars)
410                ,@(map (lambda (vb)
411                         `(##sys#call-with-values 
412                           (,%lambda () ,(cadr vb))
413                           (,%lambda ,(map lookup (car vb))
414                                     ,@(map (lambda (v) `(##core#set! ,v ,(lookup v))) (car vb)) ) ) )
415                       vbindings)
416                ,@body) ) ) ) ) )
417
418(##sys#extend-macro-environment
419 'nth-value 
420 `((list-ref . ,(##sys#primitive-alias 'list-ref)))
421 (##sys#er-transformer
422  (lambda (form r c)
423    (##sys#check-syntax 'nth-value form '(_ _ _))
424    (let ((v (r 'tmp))
425          (%lambda (r 'lambda)))
426      `(##sys#call-with-values
427        (,%lambda () ,(caddr form))
428        (,%lambda ,v (,(r 'list-ref) ,v ,(cadr form))))))))
429
430(##sys#extend-macro-environment
431 'define-inline '()
432 (##sys#er-transformer
433  (lambda (form r c)
434    (let ((%lambda (r 'lambda)))
435      (letrec ([quotify-proc 
436                (lambda (xs id)
437                  (##sys#check-syntax id xs '#(_ 1))
438                  (let* ([head (car xs)]
439                         [name (if (pair? head) (car head) head)]
440                         [val (if (pair? head)
441                                  `(,%lambda ,(cdr head) ,@(cdr xs))
442                                  (cadr xs) ) ] )
443                    (when (or (not (pair? val)) (not (c %lambda (car val))))
444                      (syntax-error 
445                       'define-inline "invalid substitution form - must be lambda"
446                       name) )
447                    (list name val) ) ) ] )
448        `(##core#define-inline ,@(quotify-proc (cdr form) 'define-inline)))) ) ) )
449
450(##sys#extend-macro-environment
451 'and-let* '()
452 (##sys#er-transformer
453  (lambda (form r c)
454    (##sys#check-syntax 'and-let* form '(_ #(_ 0) . _))
455    (let ((bindings (cadr form))
456          (body (cddr form))
457          (%if (r 'if))
458          (%let (r 'let)))
459      (let fold ([bs bindings])
460        (if (null? bs)
461            `(,(r 'begin) ,@body)
462            (let ([b (car bs)]
463                  [bs2 (cdr bs)] )
464              (cond [(not (pair? b)) `(,%if ,b ,(fold bs2) #f)]
465                    [(null? (cdr b)) `(,%if ,(car b) ,(fold bs2) #f)]
466                    [else
467                     (let ((var (car b)))
468                       `(,%let ((,var ,(cadr b)))
469                         (,%if ,var ,(fold bs2) #f) ) ) ] ) ) ) ) ) ) ) )
470
471(##sys#extend-macro-environment
472 'select '()
473 (##sys#er-transformer
474  (lambda (form r c)
475    (##sys#check-syntax 'select form '(_ _ . _))
476    (let ((exp (cadr form))
477          (body (cddr form))
478          (tmp (r 'tmp))
479          (%if (r 'if))
480          (%else (r 'else))
481          (%or (r 'or))
482          (%begin (r 'begin)))
483      `(,(r 'let) ((,tmp ,exp))
484        ,(let expand ((clauses body))
485           (if (not (pair? clauses))
486               '(##core#undefined)
487               (let ((clause (##sys#slot clauses 0))
488                     (rclauses (##sys#slot clauses 1)) )
489                 (##sys#check-syntax 'select clause '#(_ 1))
490                 (if (c %else (car clause))
491                     `(,%begin ,@(cdr clause))
492                     `(,%if (,%or ,@(map (lambda (x) `(##sys#eqv? ,tmp ,x)) 
493                                         (car clause) ) )
494                            (,%begin ,@(cdr clause)) 
495                            ,(expand rclauses) ) ) ) ) ) ) ) ) ) )
496
497
498;;; Optional argument handling:
499
500;;; Copyright (C) 1996 by Olin Shivers.
501;;;
502;;; This file defines three macros for parsing optional arguments to procs:
503;;;     (LET-OPTIONALS  arg-list ((var1 default1) ...) . body)
504;;;     (LET-OPTIONALS* arg-list ((var1 default1) ...) . body)
505;;;     (:OPTIONAL rest-arg default-exp)
506;;;
507;;; The LET-OPTIONALS macro is defined using the Clinger/Rees
508;;; explicit-renaming low-level macro system. You'll have to do some work to
509;;; port it to another macro system.
510;;;
511;;; The LET-OPTIONALS* and :OPTIONAL macros are defined with simple
512;;; high-level macros, and should be portable to any R4RS system.
513;;;
514;;; These macros are all careful to evaluate their default forms *only* if
515;;; their values are needed.
516;;;
517;;; The only non-R4RS dependencies in the macros are ERROR
518;;; and CALL-WITH-VALUES.
519;;;     -Olin
520
521;;; (LET-OPTIONALS arg-list ((var1 default1) ...)
522;;;   body
523;;;   ...)
524;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
525;;; This form is for binding a procedure's optional arguments to either
526;;; the passed-in values or a default.
527;;;
528;;; The expression takes a rest list ARG-LIST and binds the VARi to
529;;; the elements of the rest list. When there are no more elements, then
530;;; the remaining VARi are bound to their corresponding DEFAULTi values.
531;;; It is an error if there are more args than variables.
532;;;
533;;; - The default expressions are *not* evaluated unless needed.
534;;;
535;;; - When evaluated, the default expressions are carried out in the *outer*
536;;;   environment. That is, the DEFAULTi forms do *not* see any of the VARi
537;;;   bindings.
538;;;
539;;;   I originally wanted to have the DEFAULTi forms get eval'd in a LET*
540;;;   style scope -- DEFAULT3 would see VAR1 and VAR2, etc. But this is
541;;;   impossible to implement without side effects or redundant conditional
542;;;   tests. If I drop this requirement, I can use the efficient expansion
543;;;   shown below. If you need LET* scope, use the less-efficient
544;;;   LET-OPTIONALS* form defined below.
545;;;
546;;; Example:
547;;; (define (read-string! str . maybe-args)
548;;;   (let-optionals maybe-args ((port (current-input-port))
549;;;                              (start 0)
550;;;                              (end (string-length str)))
551;;;     ...))
552;;;
553;;; expands to:
554;;;
555;;; (let* ((body (lambda (port start end) ...))
556;;;        (end-def (lambda (%port %start) (body %port %start <end-default>)))
557;;;        (start-def (lambda (%port) (end-def %port <start-default>)))
558;;;        (port-def  (lambda () (start-def <port-def>))))
559;;;   (if (null? rest) (port-def)
560;;;       (let ((%port (car rest))
561;;;             (rest (cdr rest)))
562;;;       (if (null? rest) (start-def %port)
563;;;           (let ((%start (car rest))
564;;;                 (rest (cdr rest)))
565;;;             (if (null? rest) (end-def %port %start)
566;;;                 (let ((%end (car rest))
567;;;                       (rest (cdr rest)))
568;;;                   (if (null? rest) (body %port %start %end)
569;;;                       (error ...)))))))))
570
571
572;;; (LET-OPTIONALS args ((var1 default1) ...) body1 ...)
573
574(##sys#extend-macro-environment
575 'let-optionals 
576 `((car . ,(##sys#primitive-alias 'car))
577   (cdr . ,(##sys#primitive-alias 'cdr)))
578 (##sys#er-transformer
579  (lambda (form r c)
580    (##sys#check-syntax 'let-optionals form '(_ _ . _))
581    (let ((arg-list (cadr form))
582          (var/defs (caddr form))
583          (body (cdddr form))
584          (%if (r 'if))
585          (%let (r 'let))
586          (%lambda (r 'lambda)))
587
588      ;; This guy makes the END-DEF, START-DEF, PORT-DEF definitions above.
589      ;; I wish I had a reasonable loop macro.
590
591      (define (make-default-procs vars body-proc defaulter-names defs rename)
592        (let recur ((vars (reverse vars))
593                    (defaulter-names (reverse defaulter-names))
594                    (defs (reverse defs))
595                    (next-guy body-proc))
596          (if (null? vars) '()
597              (let ((vars (cdr vars)))
598                `((,(car defaulter-names)
599                   (,%lambda ,(reverse vars)
600                             (,next-guy ,@(reverse vars) ,(car defs))))
601                  . ,(recur vars
602                            (cdr defaulter-names)
603                            (cdr defs)
604                            (car defaulter-names)))))))
605
606
607      ;; This guy makes the (IF (NULL? REST) (PORT-DEF) ...) tree above.
608
609      (define (make-if-tree vars defaulters body-proc rest rename)
610        (let recur ((vars vars) (defaulters defaulters) (non-defaults '()))
611          (if (null? vars)
612              `(,%if (##core#check (,(r 'null?) ,rest))
613                     (,body-proc . ,(reverse non-defaults))
614                     (##sys#error (##core#immutable '"too many optional arguments") ,rest))
615              (let ((v (car vars)))
616                `(,%if (null? ,rest)
617                       (,(car defaulters) . ,(reverse non-defaults))
618                       (,%let ((,v (,(r 'car) ,rest)) ; we use car/cdr, because of rest-list optimization
619                               (,rest (,(r 'cdr) ,rest)))
620                              ,(recur (cdr vars)
621                                      (cdr defaulters)
622                                      (cons v non-defaults))))))))
623
624      (##sys#check-syntax 'let-optionals var/defs '#((variable _) 0))
625      (##sys#check-syntax 'let-optionals body '#(_ 1))
626      (let* ((vars (map car var/defs))
627             (prefix-sym (lambda (prefix sym)
628                           (string->symbol (string-append prefix (symbol->string sym)))))
629
630             ;; Private vars, one for each user var.
631             ;; We prefix the % to help keep macro-expanded code from being
632             ;; too confusing.
633             (vars2 (map (lambda (v) (r (prefix-sym "%" v)))
634                         vars))
635
636             (defs (map cadr var/defs))
637             (body-proc (r 'body))
638
639             ;; A private var, bound to the value of the ARG-LIST expression.
640             (rest-var (r '%rest))
641
642             (defaulter-names (map (lambda (var) (r (prefix-sym "def-" var)))
643                                   vars))
644
645             (defaulters (make-default-procs vars2 body-proc
646                                             defaulter-names defs gensym))
647             (if-tree (make-if-tree vars2 defaulter-names body-proc
648                                    rest-var gensym)))
649
650        `(,(r 'let*) ((,rest-var ,arg-list)
651                      (,body-proc (,%lambda ,vars . ,body))
652                      . ,defaulters)
653          ,if-tree) ) ))))
654
655
656;;; (optional rest-arg default-exp)
657;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
658;;; This form is for evaluating optional arguments and their defaults
659;;; in simple procedures that take a *single* optional argument. It is
660;;; a macro so that the default will not be computed unless it is needed.
661;;;
662;;; REST-ARG is a rest list from a lambda -- e.g., R in
663;;;     (lambda (a b . r) ...)
664;;; - If REST-ARG has 0 elements, evaluate DEFAULT-EXP and return that.
665;;; - If REST-ARG has 1 element, return that element.
666;;; - If REST-ARG has >1 element, error.
667
668(##sys#extend-macro-environment
669 'optional 
670 `((null? . ,(##sys#primitive-alias 'null?))
671   (car . ,(##sys#primitive-alias 'car))
672   (cdr . ,(##sys#primitive-alias 'cdr)) )
673 (##sys#er-transformer
674  (lambda (form r c)
675    (##sys#check-syntax 'optional form '(_ _ . #(_ 0 1)))
676    (let ((var (r 'tmp))
677          (%if (r 'if)))
678      `(,(r 'let) ((,var ,(cadr form)))
679        (,%if (,(r 'null?) ,var) 
680              ,(optional (cddr form) #f)
681              (,%if (##core#check (,(r 'null?) (,(r 'cdr) ,var)))
682                    (,(r 'car) ,var)
683                    (##sys#error
684                     (##core#immutable '"too many optional arguments") 
685                     ,var))))))))
686
687
688;;; (LET-OPTIONALS* args ((var1 default1) ... [rest]) body1 ...)
689;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
690;;; This is just like LET-OPTIONALS, except that the DEFAULTi forms
691;;; are evaluated in a LET*-style environment. That is, DEFAULT3 is evaluated
692;;; within the scope of VAR1 and VAR2, and so forth.
693;;;
694;;; - If the last form in the ((var1 default1) ...) list is not a
695;;;   (VARi DEFAULTi) pair, but a simple variable REST, then it is
696;;;   bound to any left-over values. For example, if we have VAR1 through
697;;;   VAR7, and ARGS has 9 values, then REST will be bound to the list of
698;;;   the two values of ARGS. If ARGS is too short, causing defaults to
699;;;   be used, then REST is bound to '().
700;;; - If there is no REST variable, then it is an error to have excess
701;;;   values in the ARGS list.
702
703(##sys#extend-macro-environment
704 'let-optionals* 
705 `((null? . ,(##sys#primitive-alias 'null?)))
706 (##sys#er-transformer
707  (lambda (form r c)
708    (##sys#check-syntax 'let-optionals* form '(_ _ list . _))
709    (let ((args (cadr form))
710          (var/defs (caddr form))
711          (body (cdddr form))
712          (%let (r 'let))
713          (%null? (r 'null?))
714          (%car (r 'car))
715          (%cdr (r 'cdr))
716          (%if (r 'if)))
717      (let ((rvar (r 'tmp)))
718        `(,%let ((,rvar ,args))
719                ,(let loop ([args rvar] [vardefs var/defs])
720                   (if (null? vardefs)
721                       `(,%if (##core#check (,%null? ,args))
722                              (,%let () ,@body)
723                              (##sys#error 
724                               (##core#immutable '"too many optional arguments") 
725                               ,args) )
726                       (let ([head (car vardefs)])
727                         (if (pair? head)
728                             (let ((rvar2 (r 'tmp2)))
729                               `(,%let ((,(car head) (,%if (,%null? ,args)
730                                                           ,(cadr head)
731                                                           (,%car ,args)))
732                                        (,rvar2 (,%if (,%null? ,args) 
733                                                      '()
734                                                      (,%cdr ,args))) )
735                                       ,(loop rvar2 (cdr vardefs)) ) )
736                             `(,%let ((,head ,args)) ,@body) ) ) ) ) ) ) ))))
737
738
739;;; case-lambda (SRFI-16):
740
741(##sys#extend-macro-environment
742 'case-lambda 
743 `((>= . ,(##sys#primitive-alias '>=))
744   (car . ,(##sys#primitive-alias 'car))
745   (cdr . ,(##sys#primitive-alias 'cdr))
746   (eq? . ,(##sys#primitive-alias 'eq?)))
747 (##sys#er-transformer
748  (lambda (form r c)
749    (##sys#check-syntax 'case-lambda form '(_ . _))
750    (define (genvars n)
751      (let loop ([i 0])
752        (if (fx>= i n)
753            '()
754            (cons (r (gensym)) (loop (fx+ i 1))) ) ) )
755    (require 'srfi-1)                   ; ugh...
756    (let* ((mincount (apply min (map (lambda (c)
757                                       (##sys#decompose-lambda-list 
758                                        (car c)
759                                        (lambda (vars argc rest) argc) ) )
760                                     (cdr form))))
761           (minvars (genvars mincount))
762           (rvar (r 'rvar))
763           (lvar (r 'lvar))
764           (%lambda (r 'lambda))
765           (%let (r 'let))
766           (%>= (r '>=))
767           (%eq? (r 'eq?))
768           (%car (r 'car))
769           (%cdr (r 'cdr))
770           (%if (r 'if)))
771      `(,%lambda ,(append minvars rvar)
772                 (,%let ((,lvar (length ,rvar)))
773                        ,(fold-right
774                          (lambda (c body)
775                            (##sys#decompose-lambda-list
776                             (car c)
777                             (lambda (vars argc rest)
778                               (##sys#check-syntax 'case-lambda (car c) 'lambda-list)
779                               `(,%if ,(let ([a2 (fx- argc mincount)])
780                                         (if rest
781                                             (if (zero? a2)
782                                                 #t
783                                                 `(,%>= ,lvar ,a2) )
784                                             `(,%eq? ,lvar ,a2) ) )
785                                      ,(receive (vars1 vars2)
786                                           (split-at! (take vars argc) mincount)
787                                         (let ((bindings
788                                                (let build ((vars2 vars2) (vrest rvar))
789                                                  (if (null? vars2)
790                                                      (cond (rest `(,%let ((,rest ,vrest)) ,@(cdr c)))
791                                                            ((null? (cddr c)) (cadr c))
792                                                            (else `(,%let () ,@(cdr c))) )
793                                                      (let ((vrest2 (r (gensym))))
794                                                        `(,%let ((,(car vars2) (,%car ,vrest))
795                                                                 (,vrest2 (,%cdr ,vrest)) )
796                                                                ,(if (pair? (cdr vars2))
797                                                                     (build (cdr vars2) vrest2)
798                                                                     (build '() vrest2) ) ) ) ) ) ) )
799                                           (if (null? vars1)
800                                               bindings
801                                               `(,%let ,(map list vars1 minvars) ,bindings) ) ) )
802                                      ,body) ) ) )
803                          '(##core#check (##sys#error (##core#immutable '"no matching clause in call to 'case-lambda' form")))
804                          (cdr form))))))))
805
806
807;;; Record printing:
808
809(##sys#extend-macro-environment
810 'define-record-printer '()
811 (##sys#er-transformer
812  (lambda (form r c)
813    (##sys#check-syntax 'define-record-printer form '(_ _ . _))
814    (let ([head (cadr form)]
815          [body (cddr form)])
816      (cond [(pair? head)
817             (##sys#check-syntax 
818              'define-record-printer (cons head body)
819              '((symbol symbol symbol) . #(_ 1)))
820             `(##sys#register-record-printer 
821               ',(##sys#slot head 0)
822               (,(r 'lambda) ,(##sys#slot head 1) ,@body)) ]
823            [else
824             (##sys#check-syntax 'define-record-printer (cons head body) '(symbol _))
825             `(##sys#register-record-printer ',head ,@body) ] ) ))))
826
827
828;;; Exceptions:
829
830(##sys#extend-macro-environment
831 'handle-exceptions 
832 `((call-with-current-continuation . ,(##sys#primitive-alias 'call-with-current-continuation))
833   (with-exception-handler . ,(##sys#primitive-alias 'with-exception-handler)))
834 (##sys#er-transformer
835  (lambda (form r c)
836    (##sys#check-syntax 'handle-exceptions form '(_ variable _ . _))
837  (let ((k (r 'k))
838        (args (r 'args))
839        (%lambda (r 'lambda)))
840    `((,(r 'call-with-current-continuation)
841       (,%lambda (,k)
842         (,(r 'with-exception-handler)
843          (,%lambda (,(cadr form)) (,k (,%lambda () ,(caddr form))))
844          (,%lambda ()
845            (##sys#call-with-values
846             (,%lambda () ,@(cdddr form))
847             (,%lambda 
848              ,args 
849              (,k (lambda () (##sys#apply ##sys#values ,args)))) ) ) ) ) ) ) ) ) ) )
850
851(##sys#extend-macro-environment
852 'condition-case 
853 `((else . ,(##sys#primitive-alias 'else))
854   (memv . ,(##sys#primitive-alias 'memv)))
855 (##sys#er-transformer
856  (lambda (form r c)
857    (##sys#check-syntax 'condition-case form '(_ _ . _))
858    (let ((exvar (r 'exvar))
859          (kvar (r 'kvar))
860          (%and (r 'and))
861          (%let (r 'let))
862          (%quote (r 'quote))
863          (%memv (r 'memv))
864          (%else (r 'else)))
865      (define (parse-clause c)
866        (let* ([var (and (symbol? (car c)) (car c))]
867               [kinds (if var (cadr c) (car c))]
868               [body (if var (cddr c) (cdr c))] )
869          (if (null? kinds)
870              `(,%else 
871                ,(if var
872                     `(,%let ([,var ,exvar]) ,@body)
873                     `(,%let () ,@body) ) )
874              `((,%and ,kvar ,@(map (lambda (k) `(,%memv (,%quote ,k) ,kvar)) kinds))
875                ,(if var
876                     `(,%let ([,var ,exvar]) ,@body)
877                     `(,%let () ,@body) ) ) ) ) )
878      `(,(r 'handle-exceptions) ,exvar
879        (,%let ([,kvar (,%and (##sys#structure? ,exvar (,%quote condition) )
880                              (##sys#slot ,exvar 1))])
881               (,(r 'cond) ,@(map parse-clause (cddr form))
882                (,%else (##sys#signal ,exvar)) ) )
883        ,(cadr form))))))
884
885
886;;; SRFI-9:
887
888(##sys#extend-macro-environment
889 'define-record-type
890 `((getter-with-setter . (##sys#primitive-alias 'getter-with-setter)))
891 (##sys#er-transformer
892  (lambda (form r c)
893    (##sys#check-syntax 'define-record-type form '(_ variable #(variable 1) variable . _)) 
894    (let* ((t (cadr form))
895          (conser (caddr form))
896          (pred (cadddr form))
897          (slots (cddddr form))
898          (%begin (r 'begin))
899          (%lambda (r 'lambda))
900          (%define (r 'define))
901          (%quote (r 'quote))
902          (%getter-with-setter (r 'getter-with-setter))
903          (vars (cdr conser))
904          (x (r 'x))
905          (y (r 'y))
906          (slotnames (map car slots)))
907      `(,%begin
908        (,%define ,conser
909                  (##sys#make-structure 
910                   (,%quote ,t)
911                   ,@(map (lambda (sname)
912                            (if (memq sname vars)
913                                sname
914                                '(##core#undefined) ) )
915                          slotnames) ) )
916        (,%define (,pred ,x) (##sys#structure? ,x (,%quote ,t)))
917        ,@(let loop ([slots slots] [i 1])
918            (if (null? slots)
919                '()
920                (let* ([slot (car slots)]
921                       (setters (memq #:record-setters ##sys#features))
922                       (setr? (pair? (cddr slot))) 
923                       (getr `(,%lambda (,x)
924                                        (##core#check (##sys#check-structure ,x (,%quote ,t)))
925                                        (##sys#block-ref ,x ,i) ) ) )
926                  `(,@(if setr?
927                          `((,%define (,(caddr slot) ,x ,y)
928                                      (##core#check (##sys#check-structure ,x (,%quote ,t)))
929                                      (##sys#block-set! ,x ,i ,y)) )
930                          '() )
931                    (,%define ,(cadr slot) 
932                              ,(if (and setr? setters)
933                                   `(,%getter-with-setter ,getr ,(caddr slot))
934                                   getr) )
935                    ,@(loop (cdr slots) (add1 i)) ) ) ) ) ) ) ) ) )
936
937
938;;; SRFI-26:
939
940(##sys#extend-macro-environment
941 'cut 
942 `((apply . ,(##sys#primitive-alias 'apply)))
943 (##sys#er-transformer
944  (lambda (form r c)
945    (let ((%<> (r '<>))
946          (%<...> (r '<...>))
947          (%apply (r 'apply))
948          (%begin (r 'begin))
949          (%lambda (r 'lambda)))
950      (let loop ([xs (cdr form)] [vars '()] [vals '()] [rest #f])
951        (if (null? xs)
952            (let ([rvars (reverse vars)]
953                  [rvals (reverse vals)] )
954              (if rest
955                  (let ([rv (r (gensym))])
956                    `(,%lambda (,@rvars . ,rv)
957                               (,%apply ,(car rvals) ,@(cdr rvals) ,rv) ) )
958                  `(,%lambda ,rvars ((,%begin ,(car rvals)) ,@(cdr rvals)) ) ) )
959            (cond ((c %<> (car xs))
960                   (let ([v (r (gensym))])
961                     (loop (cdr xs) (cons v vars) (cons v vals) #f) ) )
962                  ((c %<...> (car xs)) (loop '() vars vals #t))
963                  (else (loop (cdr xs) vars (cons (car xs) vals) #f)) ) ) ) ) )))
964
965(##sys#extend-macro-environment
966 'cute 
967 `((apply . ,(##sys#primitive-alias 'apply)))
968 (##sys#er-transformer
969  (lambda (form r c)
970    (let ((%let (r 'let))
971          (%lambda (r 'lambda))
972          (%apply (r 'apply))
973          (%<> (r '<>))
974          (%<...> (r '<...>)))
975      (let loop ([xs (cdr form)] [vars '()] [bs '()] [vals '()] [rest #f])
976        (if (null? xs)
977            (let ([rvars (reverse vars)]
978                  [rvals (reverse vals)] )
979              (if rest
980                  (let ([rv (r (gensym))])
981                    `(,%let 
982                      ,bs
983                      (,%lambda (,@rvars . ,rv)
984                                (,%apply ,(car rvals) ,@(cdr rvals) ,rv) ) ) )
985                  `(,%let ,bs
986                          (,%lambda ,rvars (,(car rvals) ,@(cdr rvals)) ) ) ) )
987            (cond ((c %<> (car xs))
988                   (let ([v (r (gensym))])
989                     (loop (cdr xs) (cons v vars) bs (cons v vals) #f) ) )
990                  ((c %<...> (car xs)) (loop '() vars bs vals #t))
991                  (else
992                   (let ([v (r (gensym))])
993                     (loop (cdr xs) 
994                           vars
995                           (cons (list v (car xs)) bs)
996                           (cons v vals) #f) ) ))))))))
997
998
999;;; Extension helper:
1000
1001(##sys#extend-macro-environment         ; DEPRECATED
1002 'define-extension '()
1003 (##sys#er-transformer
1004  (lambda (form r c)
1005    (##sys#check-syntax 'define-extension form '(_ symbol . _))
1006    (let ((%declare (r 'declare))
1007          (%begin (r 'begin))
1008          (%static (r 'static))
1009          (%dynamic (r 'dynamic))
1010          (%export (r 'export)))
1011      (let loop ((s '()) (d '()) (cs (cddr form)) (exports #f))
1012        (cond ((null? cs)
1013               (let ((exps (if exports
1014                               `(,%declare (,%export ,@exports))
1015                               '(,%begin))))
1016                 `(,(r 'cond-expand)
1017                   (chicken-compile-shared ,exps ,@d)
1018                   ((,(r 'not) compiling) ,@d)
1019                   (,(r 'else)
1020                    (,%declare (unit ,name))
1021                    ,exps
1022                    (,(r 'provide) (,(r 'quote) ,name))
1023                    ,@s) ) ) )
1024              ((and (pair? cs) (pair? (car cs)))
1025               (let ((t (caar cs))
1026                     (next (cdr cs)) )
1027                 (cond ((c %static t)
1028                        (loop (cons `(,%begin ,@(cdar cs)) s) d next exports))
1029                       ((c %dynamic t) 
1030                        (loop s (cons `(,%begin ,@(cdar cs)) d) next exports))
1031                       ((c %export t)
1032                        (loop s d next (append (or exports '()) (cdar cs))))
1033                       (else
1034                        (syntax-error 'define-extension "invalid clause specifier" (caar cs))) ) ) )
1035              (else
1036               (syntax-error
1037                'define-extension
1038                "invalid clause syntax" cs)) ) ) ))))
1039
1040
1041;;; SRFI-31
1042
1043(##sys#extend-macro-environment
1044 'rec '()
1045 (##sys#er-transformer
1046  (lambda (form r c)
1047    (##sys#check-syntax 'rec form '(_ _ . _))
1048    (let ((head (cadr form))
1049          (%letrec (r 'letrec)))
1050      (if (pair? head)
1051          `(,%letrec ((,(car head) 
1052                       (,(r 'lambda) ,(cdr head)
1053                        ,@(cddr form))))
1054                     ,(car head))
1055          `(,%letrec ((,head ,@(cddr form))) ,head))))))
1056
1057
1058;;; Definitions available at macroexpansion-time:
1059
1060(##sys#extend-macro-environment
1061 'define-for-syntax '()
1062 (##sys#er-transformer
1063  (lambda (form r c)
1064    (##sys#check-syntax 'define-for-syntax form '(_ _ . _))
1065    `(,(r 'begin-for-syntax)
1066      (,(r 'define) ,@(cdr form))))))
1067
1068
1069;;; use
1070
1071(##sys#extend-macro-environment
1072 'use '()
1073 (##sys#er-transformer
1074  (lambda (x r c)
1075    (##sys#check-syntax 'use x '(_ . #(_ 0)))
1076    `(##core#require-extension ,(cdr x) #t))))
1077
1078
1079;;; compiler syntax
1080
1081(##sys#extend-macro-environment
1082 'define-compiler-syntax '()
1083 (##sys#er-transformer
1084  (syntax-rules ()
1085    ((_ (name . llist) body ...)
1086     (define-compiler-syntax name (lambda llist body ...)))
1087    ((_ name transformer)
1088     (##core#define-compiler-syntax name transformer)))))
1089
1090(##sys#extend-macro-environment
1091 'let-compiler-syntax '()
1092 (##sys#er-transformer
1093  (syntax-rules ()
1094    ((_ ((name transformer) ...) body ...)
1095     (##core#let-compiler-syntax ((name transformer) ...) body ...)))))
1096
1097
1098;;; Just in case someone forgets
1099
1100(##sys#extend-macro-environment
1101 'define-macro '()
1102 (##sys#er-transformer
1103  (lambda (form r c)
1104    (syntax-error 'define-macro "`define-macro' is not supported - please use `define-syntax'"))))
1105
1106
1107(##sys#macro-subset me0 ##sys#default-macro-environment)))
1108
1109;; register features
1110
1111(eval-when (compile load eval)
1112  (register-feature! 'srfi-8 'srfi-16 'srfi-26 'srfi-31 'srfi-15 'srfi-11) )
Note: See TracBrowser for help on using the repository browser.