source: project/chicken/trunk/chicken-install.scm @ 12956

Last change on this file since 12956 was 12956, checked in by felix winkelmann, 12 years ago

possibly fixed mingw quoting hell - a bow before Matthew Flatt, who is a master hacker

File size: 16.3 KB
Line 
1;;;; chicken-install.scm
2;
3; Copyright (c) 2008-2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library setup-download setup-api)
28(require-library srfi-1 posix data-structures utils ports regex ports extras
29                 srfi-13 files)
30
31
32(module main ()
33 
34  (import scheme chicken srfi-1 posix data-structures utils ports regex ports extras
35          srfi-13 files)
36  (import setup-download setup-api)
37 
38  (import foreign)
39
40  (define +default-repository-files+
41    '("setup-api.so" "setup-api.import.so"
42      "setup-utils.so" "setup-utils.import.so"
43      "setup-download.so" "setup-download.import.so"
44      "chicken.import.so"
45      "lolevel.import.so"
46      "srfi-1.import.so"
47      "srfi-4.import.so"
48      "data-structures.import.so"
49      "ports.import.so"
50      "files.import.so"
51      "posix.import.so"
52      "srfi-13.import.so"
53      "srfi-69.import.so"
54      "extras.import.so"
55      "regex.import.so"
56      "srfi-14.import.so"
57      "tcp.import.so"
58      "foreign.import.so"
59      "scheme.import.so"
60      "srfi-18.import.so"
61      "utils.import.so"
62      "csi.import.so"
63      "irregex.import.so"
64      "compiler.import.so"))
65
66  (define *program-path*
67    (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
68          (make-pathname p "bin") )
69        (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )
70
71  (define *keep* #f)
72  (define *force* #f)
73  (define *prefix* #f)
74  (define *host-extension* #f)
75  (define *run-tests* #f)
76  (define *retrieve-only* #f)
77  (define *no-install* #f)
78  (define *username* #f)
79  (define *password* #f)
80  (define *default-sources* '())
81  (define *default-location* #f)
82  (define *default-transport* 'http)
83  (define *windows-shell* (foreign-value "C_WINDOWS_SHELL" bool))
84
85  (define-constant +module-db+ "modules.db")
86  (define-constant +defaults-file+ "setup.defaults")
87
88  (define (load-defaults)
89    (let ((deff (make-pathname (chicken-home) +defaults-file+)))
90      (cond ((not (file-exists? deff)) '())
91            (else
92             (set! *default-sources* (read-file deff))
93             (pair? *default-sources*)))))
94
95  (define (deps key meta)
96    (or (and-let* ((d (assq key meta)))
97          (cdr d))
98        '()))
99
100  (define (init-repository dir)
101    (let ((src (repository-path))
102          (copy (if *windows-shell*
103                    "copy" 
104                    "cp -r")))
105      (print "copying required files to " dir " ...")
106      (for-each
107       (lambda (f)
108         ($system (sprintf "~a ~a ~a" copy (shellpath (make-pathname src f)) (shellpath dir))))
109       +default-repository-files+)))
110 
111  (define (ext-version x)
112    (cond ((or (eq? x 'chicken)
113               (equal? x "chicken")
114               (member (->string x) ##sys#core-library-modules))
115           (chicken-version) )
116          ((extension-information x) =>
117           (lambda (info)
118             (let ((a (assq 'version info)))
119               (if a
120                   (->string (cadr a))
121                   "1.0.0"))))
122          (else #f)))
123
124  (define (outdated-dependencies meta)
125    (let ((ds (append
126               (deps 'depends meta) 
127               (deps 'needs meta)
128               (if *run-tests* (deps 'test-depends meta) '()))))
129      (let loop ((deps ds) (missing '()) (upgrade '()))
130        (if (null? deps)
131            (values (reverse missing) (reverse upgrade))
132            (let ((dep (car deps))
133                  (rest (cdr deps)))
134              (cond ((or (symbol? dep) (string? dep))
135                     (loop rest
136                           (if (ext-version dep)
137                               missing
138                               (cons (->string dep) missing))
139                           upgrade))
140                    ((and (list? dep) (= 2 (length dep))
141                          (or (string? (car dep)) (symbol? (car dep))))
142                     (let ((v (ext-version (car dep))))
143                       (cond ((not v) 
144                              (warning
145                               "installed extension has unknown version - assuming it is outdated" 
146                               (car dep))
147                              (loop rest missing 
148                                    (alist-cons 
149                                     (->string (car dep))
150                                     (->string (cadr dep))
151                                     upgrade)))
152                             ((version>=? (->string (cadr dep)) v)
153                              (loop rest missing
154                                    (alist-cons
155                                     (->string (car dep)) (->string (cadr dep))
156                                     upgrade)))
157                             (else (loop rest missing upgrade)))))
158                    (else
159                     (warning
160                      "invalid dependency syntax in extension meta information" 
161                      dep)
162                     (loop rest missing upgrade))))))))
163
164    (define *eggs+dirs* '())
165    (define *checked* '())
166    (define *csi* (shellpath (make-pathname *program-path* "csi")))
167
168    (define (try name version)
169      (let loop ((defs (if (and *default-location* *default-transport*)
170                           `(((location ,*default-location*)
171                              (transport ,*default-transport*)))
172                           *default-sources*)))
173        (and (pair? defs)
174             (let* ((def (car defs))
175                    (loc (cadr (or (assq 'location def)
176                                   (error "missing location entry" def))))
177                    (trans (cadr (or (assq 'transport def)
178                                     (error "missing transport entry" def)))))
179               (or (condition-case
180                       (retrieve-extension 
181                        name trans loc
182                        version: version
183                        destination: (and *retrieve-only* (current-directory))
184                        tests: *run-tests*
185                        username: *username* 
186                        password: *password*)
187                     ((exn net) 
188                      (print "TCP connect timeout")
189                      #f)
190                     ((exn http-fetch)
191                      (print "HTTP protocol error")
192                      #f)
193                     (e () (abort e)))
194                   (begin
195                     (set! *default-sources* (delete def *default-sources* eq?))
196                     (loop (cdr defs))))))))
197
198    (define (retrieve eggs)
199      (print "retrieving ...")
200      (for-each
201       (lambda (egg)
202         (cond ((assoc egg *eggs+dirs*) =>
203                (lambda (a)
204                  ;; push to front
205                  (set! *eggs+dirs* (cons a (delete a *eggs+dirs* eq?))) ) )
206               (else
207                (let* ((name (if (pair? egg) (car egg) egg))
208                       (version (and (pair? egg) (cdr egg)))
209                       (dir (try name version)))
210                  (unless dir
211                    (error "extension or version not found"))
212                  (print " " name " located at " dir)
213                  (set! *eggs+dirs* (alist-cons name dir *eggs+dirs*))))) )
214       eggs)
215      (unless *retrieve-only*
216        (for-each
217         (lambda (e+d)
218           (unless (member (car e+d) *checked*)
219             (set! *checked* (cons (car e+d) *checked*))
220             (let ((mfile (make-pathname (cdr e+d) (car e+d) "meta")))
221               (cond ((file-exists? mfile)
222                      (let ((meta (with-input-from-file mfile read)))
223                        (print "checking dependencies for `" (car e+d) "' ...")
224                        (let-values (((missing upgrade) (outdated-dependencies meta)))
225                          (when (pair? missing)
226                            (print " missing: " (string-intersperse missing ", "))
227                            (retrieve missing))
228                          (when (and (pair? upgrade)
229                                     (or *force*
230                                         (yes-or-no? 
231                                          (string-concatenate
232                                           (append
233                                            (list "The following installed extensions are outdated, because `"
234                                                  (car e+d) "' requires later versions:\n")
235                                            (map (lambda (e)
236                                                   (sprintf 
237                                                    "  ~a (~a -> ~a)~%"
238                                                    (car e) 
239                                                    (let ((v (assq 'version (extension-information (car e)))))
240                                                      (if v (cadr v) "???"))
241                                                    (cdr e)))
242                                                 upgrade)
243                                            '("\nDo you want to replace the existing extensions?")))
244                                          "no") ) )
245                            (let ((ueggs (unzip1 upgrade)))
246                              (print " upgrade: " (string-intersperse ueggs ", "))
247                              (for-each
248                               (lambda (e)
249                                 (print "removing previously installed extension `" e "' ...")
250                                 (remove-extension e) )
251                               ueggs)
252                              (retrieve ueggs))))))
253                     (else
254                      (warning 
255                       (string-append
256                        "extension `" (car e+d) "' has no .meta file "
257                        "- assuming it has no dependencies")))))))
258         *eggs+dirs*)))
259
260    (define (install eggs)
261      (retrieve eggs)
262      (unless *retrieve-only*
263        (for-each ; we assume the order reflects the dependency tree...
264         (lambda (e+d)
265           (print "installing " (car e+d) " ...")
266           (print "changing current directory to " (cdr e+d))
267           (parameterize ((current-directory (cdr e+d)))
268             (let ((cmd (sprintf
269                         "~a -bnq -e \"(require-library setup-api)\" -e \"(import setup-api)\" ~a ~a ~a ~a ~a ~a"
270                         *csi*
271                         (if (sudo-install) "-e \"(sudo-install #t)\"" "")
272                         (if *keep* "-e \"(keep-intermediates #t)\"" "")
273                         (if *no-install* "-e \"(setup-install-flag #f)\"" "")
274                         (if *host-extension* "-e \"(host-extension #t)\"" "")
275                         (if *prefix* 
276                             (sprintf "-e \"(installation-prefix \\\"~a\\\")\"" *prefix*)
277                             "")
278                         (shellpath (make-pathname (cdr e+d) (car e+d) "setup")))))
279               (print "  " cmd)
280               ($system cmd))
281             (when (and *run-tests*
282                        (file-exists? "tests")
283                        (directory? "tests")
284                        (file-exists? "tests/run.scm") )
285               (current-directory "tests")
286               (let ((cmd (sprintf "~a -s run.scm ~a" *csi* (car e+d))))
287                 (print "  " cmd)
288                 ($system cmd))))) 
289         *eggs+dirs*)))
290
291  (define (cleanup)
292    (unless *keep*
293      (and-let* ((tmpdir (temporary-directory)))
294        (remove-directory tmpdir))))
295
296  (define (update-db)
297    (let* ((files (glob (make-pathname (repository-path) "*.import.*")))
298           (tmpdir (create-temporary-directory))
299           (dbfile (make-pathname tmpdir +module-db+))
300           (rx (regexp ".*/([^/]+)\\.import\\.(scm|so)")))
301      (fluid-let ((##sys#warnings-enabled #f))
302        (for-each
303         (lambda (f)
304           (let ((m (string-match rx f)))
305             (eval `(import ,(string->symbol (cadr m))))))
306         files))
307      (print "generating database")
308      (let ((db
309             (sort
310              (append-map
311               (lambda (m)
312                 (let* ((mod (cdr m))
313                        (mname (##sys#module-name mod)))
314                   (print* " " mname)
315                   (let-values (((_ ve se) (##sys#module-exports mod)))
316                     (append
317                      (map (lambda (se) (list (car se) 'syntax mname)) se)
318                      (map (lambda (ve) (list (car ve) 'value mname)) ve)))))
319               ##sys#module-table) 
320              (lambda (e1 e2)
321                (string<? (symbol->string (car e1)) (symbol->string (car e2)))))))
322        (newline)
323        (with-output-to-file dbfile
324          (lambda ()
325            (for-each (lambda (x) (write x) (newline)) db)))
326        (copy-file dbfile (make-pathname (repository-path) +module-db+))
327        (remove-directory tmpdir))))
328
329  (define ($system str)
330    (let ((r (system
331              (if *windows-shell*
332                  (string-append "\"" str "\"")
333                  str))))
334      (unless (zero? r)
335        (error "shell command terminated with nonzero exit code" r str))))
336
337  (define (usage code)
338    (print #<<EOF
339usage: chicken-install [OPTION | EXTENSION[:VERSION]] ...
340
341  -h   -help                    show this message and exit
342  -v   -version                 show version and exit
343       -force                   don't ask, install even if versions don't match
344  -k   -keep                    keep temporary files
345  -l   -location LOCATION       install from given location instead of default
346  -t   -transport TRANSPORT     use given transport instead of default
347  -s   -sudo                    use sudo(1) for installing or removing files
348  -r   -retrieve                only retrieve egg into current directory, don't install
349  -n   -no-install              do not install, just build (implies `-keep')
350  -p   -prefix PREFIX           change installation prefix to PREFIX
351       -host-extension          when cross-compiling, compile extension for host
352       -test                    run included test-cases, if available
353       -username USER           set username for transports that require this
354       -password PASS           set password for transports that require this
355  -i   -init DIRECTORY          initialize empty alternative repository
356  -u   -update-db               update export database
357EOF
358);|
359    (exit code))
360
361  (define *short-options* '(#\h #\k #\l #\t #\s #\p #\r #\n #\v #\i #\u))
362
363  (define (main args)
364    (let ((defaults (load-defaults))
365          (update #f)
366          (rx "([^:]+):(.+)"))
367      (let loop ((args args) (eggs '()))
368        (cond ((null? args)
369               (cond (update (update-db))
370                     (else
371                      (when (null? eggs)
372                        (let ((setups (glob "*.setup")))
373                          (cond ((pair? setups)
374                                 (set! *eggs+dirs*
375                                   (append
376                                    (map (lambda (s) (cons (pathname-file s) ".")) setups)
377                                    *eggs+dirs*)))
378                                (else
379                                 (print "no setup-scripts to process")
380                                 (exit 1))) ) )
381                      (unless defaults
382                        (unless *default-transport* 
383                          (error "no default transport defined - please use `-transport' option"))
384                        (unless *default-location* 
385                          (error "no default location defined - please use `-location' option")))
386                      (install (reverse eggs)))))
387              (else
388               (let ((arg (car args)))
389                 (cond ((or (string=? arg "-help") 
390                            (string=? arg "-h")
391                            (string=? arg "--help"))
392                        (usage 0))
393                       ((string=? arg "-force")
394                        (set! *force* #t)
395                        (loop (cdr args) eggs))
396                       ((or (string=? arg "-k") (string=? arg "-keep"))
397                        (set! *keep* #t)
398                        (loop (cdr args) eggs))
399                       ((or (string=? arg "-s") (string=? arg "-sudo"))
400                        (sudo-install #t)
401                        (loop (cdr args) eggs))
402                       ((or (string=? arg "-r") (string=? arg "-retrieve"))
403                        (set! *retrieve-only* #t)
404                        (loop (cdr args) eggs))
405                       ((or (string=? arg "-l") (string=? arg "-location"))
406                        (unless (pair? (cdr args)) (usage 1))
407                        (set! *default-location* (cadr args))
408                        (loop (cddr args) eggs))
409                       ((or (string=? arg "-t") (string=? arg "-transport"))
410                        (unless (pair? (cdr args)) (usage 1))
411                        (set! *default-transport* (string->symbol (cadr args)))
412                        (loop (cddr args) eggs))
413                       ((or (string=? arg "-p") (string=? arg "-prefix"))
414                        (unless (pair? (cdr args)) (usage 1))
415                        (set! *prefix* (cadr args))
416                        (loop (cddr args) eggs))
417                       ((or (string=? arg "-n") (string=? arg "-no-install"))
418                        (set! *keep* #t)
419                        (set! *no-install* #t)
420                        (loop (cdr args) eggs))
421                       ((or (string=? arg "-v") (string=? arg "-version"))
422                        (print (chicken-version))
423                        (exit 0))
424                       ((or (string=? arg "-u") (string=? arg "-update-db"))
425                        (set! update #t)
426                        (loop (cdr args) eggs))
427                       ((or (string=? arg "-i") (string=? arg "-init"))
428                        (unless (pair? (cdr args)) (usage 1))
429                        (init-repository (cadr args))
430                        (exit 0))
431                       ((string=? "-test" arg)
432                        (set! *run-tests* #t)
433                        (loop (cdr args) eggs))
434                       ((string=? "-host-extension" arg)
435                        (set! *host-extension* #t)
436                        (loop (cdr args) eggs))
437                       ((string=? "-username" arg)
438                        (unless (pair? (cdr args)) (usage 1))
439                        (set! *username* (cadr args))
440                        (loop (cddr args) eggs))
441                       ((string=? "-password" arg)
442                        (unless (pair? (cdr args)) (usage 1))
443                        (set! *password* (cadr args))
444                        (loop (cddr args) eggs))
445                       ((and (positive? (string-length arg))
446                             (char=? #\- (string-ref arg 0)))
447                        (if (> (string-length arg) 2)
448                            (let ((sos (string->list (substring arg 1))))
449                              (if (null? (lset-intersection eq? *short-options* sos))
450                                  (loop (append (map (cut string #\- <>) sos) (cdr args)) eggs)
451                                  (usage 1)))
452                            (usage 1)))
453                       ((equal? "setup" (pathname-extension arg))
454                        (let ((egg (pathname-file arg)))
455                          (set! *eggs+dirs*
456                            (alist-cons
457                             egg
458                             (let ((dir (pathname-directory arg)))
459                               (if dir
460                                   (if (absolute-pathname? dir)
461                                       dir
462                                       (make-pathname (current-directory) dir) )
463                                   (current-directory)))
464                             *eggs+dirs*))
465                          (loop (cdr args) (cons egg eggs))))
466                       ((string-match rx arg) =>
467                        (lambda (m)
468                          (loop (cdr args) (alist-cons (cadr m) (caddr m) eggs))))
469                       (else (loop (cdr args) (cons arg eggs))))))))))
470
471  (register-feature! 'chicken-install)
472  (define ##compiler#compiler-macro-environment '()) ; only to make `compiler' import work
473
474  (handle-exceptions ex
475      (begin
476        (print-error-message ex (current-error-port))
477        (cleanup)
478        (exit 1))
479    (main (command-line-arguments))
480    (cleanup))
481 
482)
Note: See TracBrowser for help on using the repository browser.