source: project/chicken/trunk/chicken-install.scm @ 12933

Last change on this file since 12933 was 12933, checked in by felix winkelmann, 12 years ago

forgot to save; mingw chicken-install fails mysteriously

File size: 16.1 KB
Line 
1;;;; chicken-install.scm
2;
3; Copyright (c) 2008, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library setup-download setup-api)
28(require-library srfi-1 posix data-structures utils ports regex ports extras
29                 srfi-13 files)
30
31
32(foreign-declare #<<EOF
33#ifndef C_INSTALL_BIN_HOME
34# define C_INSTALL_BIN_HOME   NULL
35#endif
36EOF
37)
38
39
40(module main ()
41 
42  (import scheme chicken srfi-1 posix data-structures utils ports regex ports extras
43          srfi-13 files)
44  (import setup-download setup-api)
45 
46  (import foreign)
47
48  (define +default-repository-files+
49    '("setup-api.so" "setup-api.import.so"
50      "setup-utils.so" "setup-utils.import.so"
51      "setup-download.so" "setup-download.import.so"
52      "chicken.import.so"
53      "lolevel.import.so"
54      "srfi-1.import.so"
55      "srfi-4.import.so"
56      "data-structures.import.so"
57      "ports.import.so"
58      "files.import.so"
59      "posix.import.so"
60      "srfi-13.import.so"
61      "srfi-69.import.so"
62      "extras.import.so"
63      "regex.import.so"
64      "srfi-14.import.so"
65      "tcp.import.so"
66      "foreign.import.so"
67      "scheme.import.so"
68      "srfi-18.import.so"
69      "utils.import.so"
70      "csi.import.so"
71      "irregex.import.so"
72      "compiler.import.so"))
73
74  (define *program-path*
75    (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
76          (make-pathname p "bin") )
77        (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )
78
79  (define *keep* #f)
80  (define *force* #f)
81  (define *prefix* #f)
82  (define *host-extension* #f)
83  (define *run-tests* #f)
84  (define *retrieve-only* #f)
85  (define *no-install* #f)
86  (define *username* #f)
87  (define *password* #f)
88  (define *default-sources* '())
89  (define *default-location* #f)
90  (define *default-transport* 'http)
91
92  (define-constant +module-db+ "modules.db")
93  (define-constant +defaults-file+ "setup.defaults")
94
95  (define (load-defaults)
96    (let ((deff (make-pathname (chicken-home) +defaults-file+)))
97      (cond ((not (file-exists? deff)) '())
98            (else
99             (set! *default-sources* (read-file deff))
100             (pair? *default-sources*)))))
101
102  (define (deps key meta)
103    (or (and-let* ((d (assq key meta)))
104          (cdr d))
105        '()))
106
107  (define (init-repository dir)
108    (let ((src (repository-path))
109          (copy (if (or (feature? 'mingw32) (feature? 'msvc))
110                    "copy" 
111                    "cp -r")))
112      (print "copying required files to " dir " ...")
113      (for-each
114       (lambda (f)
115         (system* "~a ~a ~a" copy (make-pathname src f) dir))
116       +default-repository-files+)))
117
118  (define (ext-version x)
119    (cond ((or (eq? x 'chicken)
120               (equal? x "chicken")
121               (member (->string x) ##sys#core-library-modules))
122           (chicken-version) )
123          ((extension-information x) =>
124           (lambda (info)
125             (let ((a (assq 'version info)))
126               (if a
127                   (->string (cadr a))
128                   "1.0.0"))))
129          (else #f)))
130
131  (define (outdated-dependencies meta)
132    (let ((ds (append
133               (deps 'depends meta) 
134               (deps 'needs meta)
135               (if *run-tests* (deps 'test-depends meta) '()))))
136      (let loop ((deps ds) (missing '()) (upgrade '()))
137        (if (null? deps)
138            (values (reverse missing) (reverse upgrade))
139            (let ((dep (car deps))
140                  (rest (cdr deps)))
141              (cond ((or (symbol? dep) (string? dep))
142                     (loop rest
143                           (if (ext-version dep)
144                               missing
145                               (cons (->string dep) missing))
146                           upgrade))
147                    ((and (list? dep) (= 2 (length dep))
148                          (or (string? (car dep)) (symbol? (car dep))))
149                     (let ((v (ext-version (car dep))))
150                       (cond ((not v) 
151                              (warning
152                               "installed extension has unknown version - assuming it is outdated" 
153                               (car dep))
154                              (loop rest missing 
155                                    (alist-cons 
156                                     (->string (car dep))
157                                     (->string (cadr dep))
158                                     upgrade)))
159                             ((version>=? (->string (cadr dep)) v)
160                              (loop rest missing
161                                    (alist-cons
162                                     (->string (car dep)) (->string (cadr dep))
163                                     upgrade)))
164                             (else (loop rest missing upgrade)))))
165                    (else
166                     (warning
167                      "invalid dependency syntax in extension meta information" 
168                      dep)
169                     (loop rest missing upgrade))))))))
170
171    (define *eggs+dirs* '())
172    (define *checked* '())
173    (define *csi* (shellpath (make-pathname *program-path* "csi")))
174
175    (define (try name version)
176      (let loop ((defs (if (and *default-location* *default-transport*)
177                           `(((location ,*default-location*)
178                              (transport ,*default-transport*)))
179                           *default-sources*)))
180        (and (pair? defs)
181             (let* ((def (car defs))
182                    (loc (cadr (or (assq 'location def)
183                                   (error "missing location entry" def))))
184                    (trans (cadr (or (assq 'transport def)
185                                     (error "missing transport entry" def)))))
186               (or (condition-case
187                       (retrieve-extension 
188                        name trans loc
189                        version: version
190                        destination: (and *retrieve-only* (current-directory))
191                        tests: *run-tests*
192                        username: *username* 
193                        password: *password*)
194                     ((exn net) 
195                      (print "TCP connect timeout")
196                      #f)
197                     ((exn http-fetch)
198                      (print "HTTP protocol error")
199                      #f)
200                     (e () (abort e)))
201                   (begin
202                     (set! *default-sources* (delete def *default-sources* eq?))
203                     (loop (cdr defs))))))))
204
205    (define (retrieve eggs)
206      (print "retrieving ...")
207      (for-each
208       (lambda (egg)
209         (cond ((assoc egg *eggs+dirs*) =>
210                (lambda (a)
211                  ;; push to front
212                  (set! *eggs+dirs* (cons a (delete a *eggs+dirs* eq?))) ) )
213               (else
214                (let* ((name (if (pair? egg) (car egg) egg))
215                       (version (and (pair? egg) (cdr egg)))
216                       (dir (try name version)))
217                  (unless dir
218                    (error "extension or version not found"))
219                  (print " " name " located at " dir)
220                  (set! *eggs+dirs* (alist-cons name dir *eggs+dirs*))))) )
221       eggs)
222      (unless *retrieve-only*
223        (for-each
224         (lambda (e+d)
225           (unless (member (car e+d) *checked*)
226             (set! *checked* (cons (car e+d) *checked*))
227             (let ((mfile (make-pathname (cdr e+d) (car e+d) "meta")))
228               (cond ((file-exists? mfile)
229                      (let ((meta (with-input-from-file mfile read)))
230                        (print "checking dependencies for `" (car e+d) "' ...")
231                        (let-values (((missing upgrade) (outdated-dependencies meta)))
232                          (when (pair? missing)
233                            (print " missing: " (string-intersperse missing ", "))
234                            (retrieve missing))
235                          (when (and (pair? upgrade)
236                                     (or *force*
237                                         (yes-or-no? 
238                                          (string-concatenate
239                                           (append
240                                            (list "The following installed extensions are outdated, because `"
241                                                  (car e+d) "' requires later versions:\n")
242                                            (map (lambda (e)
243                                                   (sprintf 
244                                                    "  ~a (~a -> ~a)~%"
245                                                    (car e) 
246                                                    (let ((v (assq 'version (extension-information (car e)))))
247                                                      (if v (cadr v) "???"))
248                                                    (cdr e)))
249                                                 upgrade)
250                                            '("\nDo you want to replace the existing extensions?")))
251                                          "no") ) )
252                            (let ((ueggs (unzip1 upgrade)))
253                              (print " upgrade: " (string-intersperse ueggs ", "))
254                              (for-each
255                               (lambda (e)
256                                 (print "removing previously installed extension `" e "' ...")
257                                 (remove-extension e) )
258                               ueggs)
259                              (retrieve ueggs))))))
260                     (else
261                      (warning 
262                       (string-append
263                        "extension `" (car e+d) "' has no .meta file "
264                        "- assuming it has no dependencies")))))))
265         *eggs+dirs*)))
266
267    (define (install eggs)
268      (retrieve eggs)
269      (unless *retrieve-only*
270        (for-each ; we assume the order reflects the dependency tree...
271         (lambda (e+d)
272           (print "installing " (car e+d) " ...")
273           (print "changing current directory to " (cdr e+d))
274           (parameterize ((current-directory (cdr e+d)))
275             (let ((cmd (sprintf
276                         "~a -bnq -e \"(require-library setup-api)\" -e \"(import setup-api)\" ~a ~a ~a ~a ~a ~a"
277                         *csi*
278                         (if (sudo-install) "-e \"(sudo-install #t)\"" "")
279                         (if *keep* "-e \"(keep-intermediates #t)\"" "")
280                         (if *no-install* "-e \"(setup-install-flag #f)\"" "")
281                         (if *host-extension* "-e \"(host-extension #t)\"" "")
282                         (if *prefix* 
283                             (sprintf "-e \"(installation-prefix \\\"~a\\\")\"" *prefix*)
284                             "")
285                         (make-pathname (cdr e+d) (car e+d) "setup"))))
286               (system* (sprintf "~a" cmd)))
287             (when (and *run-tests*
288                        (file-exists? "tests")
289                        (directory? "tests")
290                        (file-exists? "tests/run.scm") )
291               (current-directory "tests")
292               (let ((cmd (sprintf "~a -s run.scm ~a" *csi* (car e+d))))
293                 (system* (sprintf "~a" cmd))))))
294         *eggs+dirs*)))
295
296  (define (cleanup)
297    (unless *keep*
298      (and-let* ((tmpdir (temporary-directory)))
299        (remove-directory tmpdir))))
300
301  (define (update-db)
302    (let* ((files (glob (make-pathname (repository-path) "*.import.*")))
303           (tmpdir (create-temporary-directory))
304           (dbfile (make-pathname tmpdir +module-db+))
305           (rx (regexp ".*/([^/]+)\\.import\\.(scm|so)")))
306      (fluid-let ((##sys#warnings-enabled #f))
307        (for-each
308         (lambda (f)
309           (let ((m (string-match rx f)))
310             (eval `(import ,(string->symbol (cadr m))))))
311         files))
312      (print "generating database")
313      (let ((db
314             (sort
315              (append-map
316               (lambda (m)
317                 (let* ((mod (cdr m))
318                        (mname (##sys#module-name mod)))
319                   (print* " " mname)
320                   (let-values (((_ ve se) (##sys#module-exports mod)))
321                     (append
322                      (map (lambda (se) (list (car se) 'syntax mname)) se)
323                      (map (lambda (ve) (list (car ve) 'value mname)) ve)))))
324               ##sys#module-table) 
325              (lambda (e1 e2)
326                (string<? (symbol->string (car e1)) (symbol->string (car e2)))))))
327        (newline)
328        (with-output-to-file dbfile
329          (lambda ()
330            (for-each (lambda (x) (write x) (newline)) db)))
331        (copy-file dbfile (make-pathname (repository-path) +module-db+))
332        (remove-directory tmpdir))))
333
334  (define (usage code)
335    (print #<<EOF
336usage: chicken-install [OPTION | EXTENSION[:VERSION]] ...
337
338  -h   -help                    show this message and exit
339  -v   -version                 show version and exit
340       -force                   don't ask, install even if versions don't match
341  -k   -keep                    keep temporary files
342  -l   -location LOCATION       install from given location instead of default
343  -t   -transport TRANSPORT     use given transport instead of default
344  -s   -sudo                    use sudo(1) for installing or removing files
345  -r   -retrieve                only retrieve egg into current directory, don't install
346  -n   -no-install              do not install, just build (implies `-keep')
347  -p   -prefix PREFIX           change installation prefix to PREFIX
348       -host-extension          when cross-compiling, compile extension for host
349       -test                    run included test-cases, if available
350       -username USER           set username for transports that require this
351       -password PASS           set password for transports that require this
352  -i   -init DIRECTORY          initialize empty alternative repository
353  -u   -update-db               update export database
354EOF
355);|
356    (exit code))
357
358  (define *short-options* '(#\h #\k #\l #\t #\s #\p #\r #\n #\v #\i #\u))
359
360  (define (main args)
361    (let ((defaults (load-defaults))
362          (update #f)
363          (rx "([^:]+):(.+)"))
364      (let loop ((args args) (eggs '()))
365        (cond ((null? args)
366               (cond (update (update-db))
367                     (else
368                      (when (null? eggs)
369                        (let ((setups (glob "*.setup")))
370                          (cond ((pair? setups)
371                                 (set! *eggs+dirs*
372                                   (append
373                                    (map (lambda (s) (cons (pathname-file s) ".")) setups)
374                                    *eggs+dirs*)))
375                                (else
376                                 (print "no setup-scripts to process")
377                                 (exit 1))) ) )
378                      (unless defaults
379                        (unless *default-transport* 
380                          (error "no default transport defined - please use `-transport' option"))
381                        (unless *default-location* 
382                          (error "no default location defined - please use `-location' option")))
383                      (install (reverse eggs)))))
384              (else
385               (let ((arg (car args)))
386                 (cond ((or (string=? arg "-help") 
387                            (string=? arg "-h")
388                            (string=? arg "--help"))
389                        (usage 0))
390                       ((string=? arg "-force")
391                        (set! *force* #t)
392                        (loop (cdr args) eggs))
393                       ((or (string=? arg "-k") (string=? arg "-keep"))
394                        (set! *keep* #t)
395                        (loop (cdr args) eggs))
396                       ((or (string=? arg "-s") (string=? arg "-sudo"))
397                        (sudo-install #t)
398                        (loop (cdr args) eggs))
399                       ((or (string=? arg "-r") (string=? arg "-retrieve"))
400                        (set! *retrieve-only* #t)
401                        (loop (cdr args) eggs))
402                       ((or (string=? arg "-l") (string=? arg "-location"))
403                        (unless (pair? (cdr args)) (usage 1))
404                        (set! *default-location* (cadr args))
405                        (loop (cddr args) eggs))
406                       ((or (string=? arg "-t") (string=? arg "-transport"))
407                        (unless (pair? (cdr args)) (usage 1))
408                        (set! *default-transport* (string->symbol (cadr args)))
409                        (loop (cddr args) eggs))
410                       ((or (string=? arg "-p") (string=? arg "-prefix"))
411                        (unless (pair? (cdr args)) (usage 1))
412                        (set! *prefix* (cadr args))
413                        (loop (cddr args) eggs))
414                       ((or (string=? arg "-n") (string=? arg "-no-install"))
415                        (set! *keep* #t)
416                        (set! *no-install* #t)
417                        (loop (cdr args) eggs))
418                       ((or (string=? arg "-v") (string=? arg "-version"))
419                        (print (chicken-version))
420                        (exit 0))
421                       ((or (string=? arg "-u") (string=? arg "-update-db"))
422                        (set! update #t)
423                        (loop (cdr args) eggs))
424                       ((or (string=? arg "-i") (string=? arg "-init"))
425                        (unless (pair? (cdr args)) (usage 1))
426                        (init-repository (cadr args))
427                        (exit 0))
428                       ((string=? "-test" arg)
429                        (set! *run-tests* #t)
430                        (loop (cdr args) eggs))
431                       ((string=? "-host-extension" arg)
432                        (set! *host-extension* #t)
433                        (loop (cdr args) eggs))
434                       ((string=? "-username" arg)
435                        (unless (pair? (cdr args)) (usage 1))
436                        (set! *username* (cadr args))
437                        (loop (cddr args) eggs))
438                       ((string=? "-password" arg)
439                        (unless (pair? (cdr args)) (usage 1))
440                        (set! *password* (cadr args))
441                        (loop (cddr args) eggs))
442                       ((and (positive? (string-length arg))
443                             (char=? #\- (string-ref arg 0)))
444                        (if (> (string-length arg) 2)
445                            (let ((sos (string->list (substring arg 1))))
446                              (if (null? (lset-intersection eq? *short-options* sos))
447                                  (loop (append (map (cut string #\- <>) sos) (cdr args)) eggs)
448                                  (usage 1)))
449                            (usage 1)))
450                       ((equal? "setup" (pathname-extension arg))
451                        (let ((egg (pathname-file arg)))
452                          (set! *eggs+dirs*
453                            (alist-cons
454                             egg
455                             (let ((dir (pathname-directory arg)))
456                               (if dir
457                                   (if (absolute-pathname? dir)
458                                       dir
459                                       (make-pathname (current-directory) dir) )
460                                   (current-directory)))
461                             *eggs+dirs*))
462                          (loop (cdr args) (cons egg eggs))))
463                       ((string-match rx arg) =>
464                        (lambda (m)
465                          (loop (cdr args) (alist-cons (cadr m) (caddr m) eggs))))
466                       (else (loop (cdr args) (cons arg eggs))))))))))
467
468  (register-feature! 'chicken-install)
469  (define ##compiler#compiler-macro-environment '()) ; only to make `compiler' import work
470
471  (handle-exceptions ex
472      (begin
473        (print-error-message ex (current-error-port))
474        (cleanup)
475        (exit 1))
476    (main (command-line-arguments))
477    (cleanup))
478 
479)
Note: See TracBrowser for help on using the repository browser.