source: project/chicken/trunk/chicken-install.scm @ 12932

Last change on this file since 12932 was 12932, checked in by felix winkelmann, 12 years ago

attempts at fixing mingw build; probably everything broken now

File size: 16.1 KB
Line 
1;;;; chicken-install.scm
2;
3; Copyright (c) 2008, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library setup-download setup-api)
28(require-library srfi-1 posix data-structures utils ports regex ports extras
29                 srfi-13 files)
30
31
32(foreign-declare #<<EOF
33#ifndef C_INSTALL_BIN_HOME
34# define C_INSTALL_BIN_HOME   NULL
35#endif
36EOF
37)
38
39
40(module main ()
41 
42  (import scheme chicken srfi-1 posix data-structures utils ports regex ports extras
43          srfi-13 files)
44  (import setup-download setup-api)
45 
46  (import foreign)
47
48  (define +default-repository-files+
49    '("setup-api.so" "setup-api.import.so"
50      "setup-utils.so" "setup-utils.import.so"
51      "setup-download.so" "setup-download.import.so"
52      "chicken.import.so"
53      "lolevel.import.so"
54      "srfi-1.import.so"
55      "srfi-4.import.so"
56      "data-structures.import.so"
57      "ports.import.so"
58      "files.import.so"
59      "posix.import.so"
60      "srfi-13.import.so"
61      "srfi-69.import.so"
62      "extras.import.so"
63      "regex.import.so"
64      "srfi-14.import.so"
65      "tcp.import.so"
66      "foreign.import.so"
67      "scheme.import.so"
68      "srfi-18.import.so"
69      "utils.import.so"
70      "csi.import.so"
71      "irregex.import.so"
72      "compiler.import.so"))
73
74  (define *program-path*
75    (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
76          (make-pathname p "bin") )
77        (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )
78
79  (define *keep* #f)
80  (define *force* #f)
81  (define *prefix* #f)
82  (define *host-extension* #f)
83  (define *run-tests* #f)
84  (define *retrieve-only* #f)
85  (define *no-install* #f)
86  (define *username* #f)
87  (define *password* #f)
88  (define *default-sources* '())
89  (define *default-location* #f)
90  (define *default-transport* 'http)
91
92  (define-constant +module-db+ "modules.db")
93  (define-constant +defaults-file+ "setup.defaults")
94
95  (define (load-defaults)
96    (let ((deff (make-pathname (chicken-home) +defaults-file+)))
97      (cond ((not (file-exists? deff)) '())
98            (else
99             (set! *default-sources* (read-file deff))
100             (pair? *default-sources*)))))
101
102  (define (deps key meta)
103    (or (and-let* ((d (assq key meta)))
104          (cdr d))
105        '()))
106
107  (define (init-repository dir)
108    (let ((src (repository-path))
109          (copy (if (or (feature? 'mingw32) (feature? 'msvc))
110                    "copy" 
111                    "cp -r")))
112      (print "copying required files to " dir " ...")
113      (for-each
114       (lambda (f)
115         (system* "~a ~a ~a" copy (make-pathname src f) dir))
116       +default-repository-files+)))
117
118  (define (ext-version x)
119    (cond ((or (eq? x 'chicken)
120               (equal? x "chicken")
121               (member (->string x) ##sys#core-library-modules))
122           (chicken-version) )
123          ((extension-information x) =>
124           (lambda (info)
125             (let ((a (assq 'version info)))
126               (if a
127                   (->string (cadr a))
128                   "1.0.0"))))
129          (else #f)))
130
131  (define (outdated-dependencies meta)
132    (let ((ds (append
133               (deps 'depends meta) 
134               (deps 'needs meta)
135               (if *run-tests* (deps 'test-depends meta) '()))))
136      (let loop ((deps ds) (missing '()) (upgrade '()))
137        (if (null? deps)
138            (values (reverse missing) (reverse upgrade))
139            (let ((dep (car deps))
140                  (rest (cdr deps)))
141              (cond ((or (symbol? dep) (string? dep))
142                     (loop rest
143                           (if (ext-version dep)
144                               missing
145                               (cons (->string dep) missing))
146                           upgrade))
147                    ((and (list? dep) (= 2 (length dep))
148                          (or (string? (car dep)) (symbol? (car dep))))
149                     (let ((v (ext-version (car dep))))
150                       (cond ((not v) 
151                              (warning
152                               "installed extension has unknown version - assuming it is outdated" 
153                               (car dep))
154                              (loop rest missing 
155                                    (alist-cons 
156                                     (->string (car dep))
157                                     (->string (cadr dep))
158                                     upgrade)))
159                             ((version>=? (->string (cadr dep)) v)
160                              (loop rest missing
161                                    (alist-cons
162                                     (->string (car dep)) (->string (cadr dep))
163                                     upgrade)))
164                             (else (loop rest missing upgrade)))))
165                    (else
166                     (warning
167                      "invalid dependency syntax in extension meta information" 
168                      dep)
169                     (loop rest missing upgrade))))))))
170
171    (define *eggs+dirs* '())
172    (define *checked* '())
173    (define *csi* (shellpath (make-pathname *program-path* "csi")))
174
175    (define (try name version)
176      (let loop ((defs (if (and *default-location* *default-transport*)
177                           `(((location ,*default-location*)
178                              (transport ,*default-transport*)))
179                           *default-sources*)))
180        (and (pair? defs)
181             (let* ((def (car defs))
182                    (loc (cadr (or (assq 'location def)
183                                   (error "missing location entry" def))))
184                    (trans (cadr (or (assq 'transport def)
185                                     (error "missing transport entry" def)))))
186               (or (condition-case
187                       (retrieve-extension 
188                        name trans loc
189                        version: version
190                        destination: (and *retrieve-only* (current-directory))
191                        tests: *run-tests*
192                        username: *username* 
193                        password: *password*)
194                     ((exn net) 
195                      (print "TCP connect timeout")
196                      #f)
197                     ((exn http-fetch)
198                      (print "HTTP protocol error")
199                      #f)
200                     (e () (abort e)))
201                   (begin
202                     (set! *default-sources* (delete def *default-sources* eq?))
203                     (loop (cdr defs))))))))
204
205    (define (retrieve eggs)
206      (print "retrieving ...")
207      (for-each
208       (lambda (egg)
209         (cond ((assoc egg *eggs+dirs*) =>
210                (lambda (a)
211                  ;; push to front
212                  (set! *eggs+dirs* (cons a (delete a *eggs+dirs* eq?))) ) )
213               (else
214                (let* ((name (if (pair? egg) (car egg) egg))
215                       (version (and (pair? egg) (cdr egg)))
216                       (dir (try name version)))
217                  (unless dir
218                    (error "extension or version not found"))
219                  (print " " name " located at " dir)
220                  (set! *eggs+dirs* (alist-cons name dir *eggs+dirs*))))) )
221       eggs)
222      (unless *retrieve-only*
223        (for-each
224         (lambda (e+d)
225           (unless (member (car e+d) *checked*)
226             (set! *checked* (cons (car e+d) *checked*))
227             (let ((mfile (make-pathname (cdr e+d) (car e+d) "meta")))
228               (cond ((file-exists? mfile)
229                      (let ((meta (with-input-from-file mfile read)))
230                        (print "checking dependencies for `" (car e+d) "' ...")
231                        (let-values (((missing upgrade) (outdated-dependencies meta)))
232                          (when (pair? missing)
233                            (print " missing: " (string-intersperse missing ", "))
234                            (retrieve missing))
235                          (when (and (pair? upgrade)
236                                     (or *force*
237                                         (yes-or-no? 
238                                          (string-concatenate
239                                           (append
240                                            (list "The following installed extensions are outdated, because `"
241                                                  (car e+d) "' requires later versions:\n")
242                                            (map (lambda (e)
243                                                   (sprintf 
244                                                    "  ~a (~a -> ~a)~%"
245                                                    (car e) 
246                                                    (let ((v (assq 'version (extension-information (car e)))))
247                                                      (if v (cadr v) "???"))
248                                                    (cdr e)))
249                                                 upgrade)
250                                            '("\nDo you want to replace the existing extensions?")))
251                                          "no") ) )
252                            (let ((ueggs (unzip1 upgrade)))
253                              (print " upgrade: " (string-intersperse ueggs ", "))
254                              (for-each
255                               (lambda (e)
256                                 (print "removing previously installed extension `" e "' ...")
257                                 (remove-extension e) )
258                               ueggs)
259                              (retrieve ueggs))))))
260                     (else
261                      (warning 
262                       (string-append
263                        "extension `" (car e+d) "' has no .meta file "
264                        "- assuming it has no dependencies")))))))
265         *eggs+dirs*)))
266
267    (define (install eggs)
268      (retrieve eggs)
269      (unless *retrieve-only*
270        (for-each ; we assume the order reflects the dependency tree...
271         (lambda (e+d)
272           (print "installing " (car e+d) " ...")
273           (print "changing current directory to " (cdr e+d))
274           (parameterize ((current-directory (cdr e+d)))
275             (let ((cmd (sprintf
276                         "~a -bnq -e \"(require-library setup-api)\" -e \"(import setup-api)\" ~a ~a ~a ~a ~a ~a"
277                         *csi*
278                         (if (sudo-install) "-e \"(sudo-install #t)\"" "")
279                         (if *keep* "-e \"(keep-intermediates #t)\"" "")
280                         (if *no-install* "-e \"(setup-install-flag #f)\"" "")
281                         (if *host-extension* "-e \"(host-extension #t)\"" "")
282                         (if *prefix* 
283                             (sprintf "-e \"(installation-prefix \\\"~a\\\")\"" *prefix*)
284                             "")
285                         (make-pathname (cdr e+d) (car e+d) "setup"))))
286               (print cmd)
287               (system* (sprintf "~a" cmd)))
288             (when (and *run-tests*
289                        (file-exists? "tests")
290                        (directory? "tests")
291                        (file-exists? "tests/run.scm") )
292               (current-directory "tests")
293               (let ((cmd (sprintf "~a -s run.scm ~a" *csi* (car e+d))))
294                 (print cmd)
295                 (system* (sprintf "~a" cmd))))))
296         *eggs+dirs*)))
297
298  (define (cleanup)
299    (unless *keep*
300      (and-let* ((tmpdir (temporary-directory)))
301        (remove-directory tmpdir))))
302
303  (define (update-db)
304    (let* ((files (glob (make-pathname (repository-path) "*.import.*")))
305           (tmpdir (create-temporary-directory))
306           (dbfile (make-pathname tmpdir +module-db+))
307           (rx (regexp ".*/([^/]+)\\.import\\.(scm|so)")))
308      (fluid-let ((##sys#warnings-enabled #f))
309        (for-each
310         (lambda (f)
311           (let ((m (string-match rx f)))
312             (eval `(import ,(string->symbol (cadr m))))))
313         files))
314      (print "generating database")
315      (let ((db
316             (sort
317              (append-map
318               (lambda (m)
319                 (let* ((mod (cdr m))
320                        (mname (##sys#module-name mod)))
321                   (print* " " mname)
322                   (let-values (((_ ve se) (##sys#module-exports mod)))
323                     (append
324                      (map (lambda (se) (list (car se) 'syntax mname)) se)
325                      (map (lambda (ve) (list (car ve) 'value mname)) ve)))))
326               ##sys#module-table) 
327              (lambda (e1 e2)
328                (string<? (symbol->string (car e1)) (symbol->string (car e2)))))))
329        (newline)
330        (with-output-to-file dbfile
331          (lambda ()
332            (for-each (lambda (x) (write x) (newline)) db)))
333        (copy-file dbfile (make-pathname (repository-path) +module-db+))
334        (remove-directory tmpdir))))
335
336  (define (usage code)
337    (print #<<EOF
338usage: chicken-install [OPTION | EXTENSION[:VERSION]] ...
339
340  -h   -help                    show this message and exit
341  -v   -version                 show version and exit
342       -force                   don't ask, install even if versions don't match
343  -k   -keep                    keep temporary files
344  -l   -location LOCATION       install from given location instead of default
345  -t   -transport TRANSPORT     use given transport instead of default
346  -s   -sudo                    use sudo(1) for installing or removing files
347  -r   -retrieve                only retrieve egg into current directory, don't install
348  -n   -no-install              do not install, just build (implies `-keep')
349  -p   -prefix PREFIX           change installation prefix to PREFIX
350       -host-extension          when cross-compiling, compile extension for host
351       -test                    run included test-cases, if available
352       -username USER           set username for transports that require this
353       -password PASS           set password for transports that require this
354  -i   -init DIRECTORY          initialize empty alternative repository
355  -u   -update-db               update export database
356EOF
357);|
358    (exit code))
359
360  (define *short-options* '(#\h #\k #\l #\t #\s #\p #\r #\n #\v #\i #\u))
361
362  (define (main args)
363    (let ((defaults (load-defaults))
364          (update #f)
365          (rx "([^:]+):(.+)"))
366      (let loop ((args args) (eggs '()))
367        (cond ((null? args)
368               (cond (update (update-db))
369                     (else
370                      (when (null? eggs)
371                        (let ((setups (glob "*.setup")))
372                          (cond ((pair? setups)
373                                 (set! *eggs+dirs*
374                                   (append
375                                    (map (lambda (s) (cons (pathname-file s) ".")) setups)
376                                    *eggs+dirs*)))
377                                (else
378                                 (print "no setup-scripts to process")
379                                 (exit 1))) ) )
380                      (unless defaults
381                        (unless *default-transport* 
382                          (error "no default transport defined - please use `-transport' option"))
383                        (unless *default-location* 
384                          (error "no default location defined - please use `-location' option")))
385                      (install (reverse eggs)))))
386              (else
387               (let ((arg (car args)))
388                 (cond ((or (string=? arg "-help") 
389                            (string=? arg "-h")
390                            (string=? arg "--help"))
391                        (usage 0))
392                       ((string=? arg "-force")
393                        (set! *force* #t)
394                        (loop (cdr args) eggs))
395                       ((or (string=? arg "-k") (string=? arg "-keep"))
396                        (set! *keep* #t)
397                        (loop (cdr args) eggs))
398                       ((or (string=? arg "-s") (string=? arg "-sudo"))
399                        (sudo-install #t)
400                        (loop (cdr args) eggs))
401                       ((or (string=? arg "-r") (string=? arg "-retrieve"))
402                        (set! *retrieve-only* #t)
403                        (loop (cdr args) eggs))
404                       ((or (string=? arg "-l") (string=? arg "-location"))
405                        (unless (pair? (cdr args)) (usage 1))
406                        (set! *default-location* (cadr args))
407                        (loop (cddr args) eggs))
408                       ((or (string=? arg "-t") (string=? arg "-transport"))
409                        (unless (pair? (cdr args)) (usage 1))
410                        (set! *default-transport* (string->symbol (cadr args)))
411                        (loop (cddr args) eggs))
412                       ((or (string=? arg "-p") (string=? arg "-prefix"))
413                        (unless (pair? (cdr args)) (usage 1))
414                        (set! *prefix* (cadr args))
415                        (loop (cddr args) eggs))
416                       ((or (string=? arg "-n") (string=? arg "-no-install"))
417                        (set! *keep* #t)
418                        (set! *no-install* #t)
419                        (loop (cdr args) eggs))
420                       ((or (string=? arg "-v") (string=? arg "-version"))
421                        (print (chicken-version))
422                        (exit 0))
423                       ((or (string=? arg "-u") (string=? arg "-update-db"))
424                        (set! update #t)
425                        (loop (cdr args) eggs))
426                       ((or (string=? arg "-i") (string=? arg "-init"))
427                        (unless (pair? (cdr args)) (usage 1))
428                        (init-repository (cadr args))
429                        (exit 0))
430                       ((string=? "-test" arg)
431                        (set! *run-tests* #t)
432                        (loop (cdr args) eggs))
433                       ((string=? "-host-extension" arg)
434                        (set! *host-extension* #t)
435                        (loop (cdr args) eggs))
436                       ((string=? "-username" arg)
437                        (unless (pair? (cdr args)) (usage 1))
438                        (set! *username* (cadr args))
439                        (loop (cddr args) eggs))
440                       ((string=? "-password" arg)
441                        (unless (pair? (cdr args)) (usage 1))
442                        (set! *password* (cadr args))
443                        (loop (cddr args) eggs))
444                       ((and (positive? (string-length arg))
445                             (char=? #\- (string-ref arg 0)))
446                        (if (> (string-length arg) 2)
447                            (let ((sos (string->list (substring arg 1))))
448                              (if (null? (lset-intersection eq? *short-options* sos))
449                                  (loop (append (map (cut string #\- <>) sos) (cdr args)) eggs)
450                                  (usage 1)))
451                            (usage 1)))
452                       ((equal? "setup" (pathname-extension arg))
453                        (let ((egg (pathname-file arg)))
454                          (set! *eggs+dirs*
455                            (alist-cons
456                             egg
457                             (let ((dir (pathname-directory arg)))
458                               (if dir
459                                   (if (absolute-pathname? dir)
460                                       dir
461                                       (make-pathname (current-directory) dir) )
462                                   (current-directory)))
463                             *eggs+dirs*))
464                          (loop (cdr args) (cons egg eggs))))
465                       ((string-match rx arg) =>
466                        (lambda (m)
467                          (loop (cdr args) (alist-cons (cadr m) (caddr m) eggs))))
468                       (else (loop (cdr args) (cons arg eggs))))))))))
469
470  (register-feature! 'chicken-install)
471  (define ##compiler#compiler-macro-environment '()) ; only to make `compiler' import work
472
473  (handle-exceptions ex
474      (begin
475        (print-error-message ex (current-error-port))
476        (cleanup)
477        (exit 1))
478    (main (command-line-arguments))
479    (cleanup))
480 
481)
Note: See TracBrowser for help on using the repository browser.