source: project/chicken/trunk/chicken-install.scm @ 12786

Last change on this file since 12786 was 12786, checked in by felix winkelmann, 11 years ago

removed setup-utils (merged into setup-api)

File size: 15.8 KB
Line 
1;;;; chicken-install.scm
2;
3; Copyright (c) 2008, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library setup-download setup-api)
28(require-library srfi-1 posix data-structures utils ports regex ports extras
29                 srfi-13 files)
30
31
32(foreign-declare #<<EOF
33#ifndef C_INSTALL_BIN_HOME
34# define C_INSTALL_BIN_HOME   NULL
35#endif
36EOF
37)
38
39
40(module main ()
41 
42  (import scheme chicken srfi-1 posix data-structures utils ports regex ports extras
43          srfi-13 files)
44  (import setup-download setup-api)
45 
46  (import foreign)
47
48  (define +default-repository-files+
49    '("setup-api.so" "setup-api.import.so"
50      "setup-utils.so" "setup-utils.import.so"
51      "setup-download.so" "setup-download.import.so"
52      "chicken.import.so"
53      "lolevel.import.so"
54      "srfi-1.import.so"
55      "srfi-4.import.so"
56      "data-structures.import.so"
57      "ports.import.so"
58      "files.import.so"
59      "posix.import.so"
60      "srfi-13.import.so"
61      "srfi-69.import.so"
62      "extras.import.so"
63      "regex.import.so"
64      "srfi-14.import.so"
65      "tcp.import.so"
66      "foreign.import.so"
67      "scheme.import.so"
68      "srfi-18.import.so"
69      "utils.import.so"
70      "csi.import.so"))
71
72  (define *program-path*
73    (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
74          (make-pathname p "bin") )
75        (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )
76
77  (define *keep* #f)
78  (define *force* #f)
79  (define *prefix* #f)
80  (define *host-extension* #f)
81  (define *run-tests* #f)
82  (define *retrieve-only* #f)
83  (define *no-install* #f)
84  (define *username* #f)
85  (define *password* #f)
86  (define *default-sources* '())
87  (define *default-location* #f)
88  (define *default-transport* 'http)
89
90  (define-constant +module-db+ "modules.db")
91  (define-constant +defaults-file+ "setup.defaults")
92
93  (define (load-defaults)
94    (let ((deff (make-pathname (chicken-home) +defaults-file+)))
95      (cond ((not (file-exists? deff)) '())
96            (else
97             (set! *default-sources* (read-file deff))
98             (pair? *default-sources*)))))
99
100  (define (deps key meta)
101    (or (and-let* ((d (assq key meta)))
102          (cdr d))
103        '()))
104
105  (define (init-repository dir)
106    (let ((src (repository-path))
107          (copy (if (or (feature? 'mingw32) (feature? 'msvc))
108                    "copy" 
109                    "cp -r")))
110      (print "copying required files to " dir " ...")
111      (for-each
112       (lambda (f)
113         (system* "~a ~a ~a" copy (make-pathname src f) dir))
114       +default-repository-files+)))
115
116  (define (ext-version x)
117    (cond ((or (eq? x 'chicken)
118               (equal? x "chicken")
119               (member (->string x) ##sys#core-library-modules))
120           (chicken-version) )
121          ((extension-information x) =>
122           (lambda (info)
123             (and-let* ((a (assq 'version info)))
124               (->string (cadr a)))))
125          (else #f)))
126
127  (define (outdated-dependencies meta)
128    (let ((ds (append
129               (deps 'depends meta) 
130               (deps 'needs meta)
131               (if *run-tests* (deps 'test-depends meta) '()))))
132      (let loop ((deps ds) (missing '()) (upgrade '()))
133        (if (null? deps)
134            (values (reverse missing) (reverse upgrade))
135            (let ((dep (car deps))
136                  (rest (cdr deps)))
137              (cond ((or (symbol? dep) (string? dep))
138                     (loop rest
139                           (if (ext-version dep)
140                               missing
141                               (cons (->string dep) missing))
142                           upgrade))
143                    ((and (list? dep) (= 2 (length dep))
144                          (or (string? (car dep)) (symbol? (car dep))))
145                     (let ((v (ext-version (car dep))))
146                       (cond ((not v) 
147                              (warning
148                               "installed extension has unknown version - assuming it is outdated" 
149                               (car dep))
150                              (loop rest missing 
151                                    (alist-cons 
152                                     (->string (car dep))
153                                     (->string (cadr dep))
154                                     upgrade)))
155                             ((version>=? (->string (cadr dep)) v)
156                              (loop rest missing
157                                    (alist-cons
158                                     (->string (car dep)) (->string (cadr dep))
159                                     upgrade)))
160                             (else (loop rest missing upgrade)))))
161                    (else
162                     (warning
163                      "invalid dependency syntax in extension meta information" 
164                      dep)
165                     (loop rest missing upgrade))))))))
166
167    (define *eggs+dirs* '())
168    (define *checked* '())
169
170    (define (try name version)
171      (let loop ((defs (if (and *default-location* *default-transport*)
172                           `(((location ,*default-location*)
173                              (transport ,*default-transport*)))
174                           *default-sources*)))
175        (and (pair? defs)
176             (let* ((def (car defs))
177                    (loc (cadr (or (assq 'location def)
178                                   (error "missing location entry" def))))
179                    (trans (cadr (or (assq 'transport def)
180                                     (error "missing transport entry" def)))))
181               (or (condition-case
182                       (retrieve-extension 
183                        name trans loc
184                        version: version
185                        destination: (and *retrieve-only* (current-directory))
186                        tests: *run-tests*
187                        username: *username* 
188                        password: *password*)
189                     ((exn net) 
190                      (print "TCP connect timeout")
191                      #f)
192                     ((exn http-fetch)
193                      (print "HTTP protocol error")
194                      #f)
195                     (e () (abort e)))
196                   (begin
197                     (set! *default-sources* (delete def *default-sources* eq?))
198                     (loop (cdr defs))))))))
199
200    (define (retrieve eggs)
201      (print "retrieving ...")
202      (for-each
203       (lambda (egg)
204         (cond ((assoc egg *eggs+dirs*) =>
205                (lambda (a)
206                  ;; push to front
207                  (set! *eggs+dirs* (cons a (delete a *eggs+dirs* eq?))) ) )
208               (else
209                (let* ((name (if (pair? egg) (car egg) egg))
210                       (version (and (pair? egg) (cdr egg)))
211                       (dir (try name version)))
212                  (unless dir
213                    (error "extension or version not found"))
214                  (print " " name " located at " dir)
215                  (set! *eggs+dirs* (alist-cons name dir *eggs+dirs*))))) )
216       eggs)
217      (unless *retrieve-only*
218        (for-each
219         (lambda (e+d)
220           (unless (member (car e+d) *checked*)
221             (set! *checked* (cons (car e+d) *checked*))
222             (let ((mfile (make-pathname (cdr e+d) (car e+d) "meta")))
223               (cond ((file-exists? mfile)
224                      (let ((meta (with-input-from-file mfile read)))
225                        (print "checking dependencies for `" (car e+d) "' ...")
226                        (let-values (((missing upgrade) (outdated-dependencies meta)))
227                          (when (pair? missing)
228                            (print " missing: " (string-intersperse missing ", "))
229                            (retrieve missing))
230                          (when (and (pair? upgrade)
231                                     (or *force*
232                                         (yes-or-no? 
233                                          (string-concatenate
234                                           (append
235                                            (list "The following installed extensions are outdated, because `"
236                                                  (car e+d) "' requires later versions:\n")
237                                            (map (lambda (e)
238                                                   (sprintf 
239                                                    "  ~a (~a -> ~a)~%"
240                                                    (car e) 
241                                                    (let ((v (assq 'version (extension-information (car e)))))
242                                                      (if v (cadr v) "???"))
243                                                    (cdr e)))
244                                                 upgrade)
245                                            '("\nDo you want to replace the existing extensions?")))
246                                          "no") ) )
247                            (let ((ueggs (unzip1 upgrade)))
248                              (print " upgrade: " (string-intersperse ueggs ", "))
249                              (for-each
250                               (lambda (e)
251                                 (print "removing previously installed extension `" e "' ...")
252                                 (remove-extension e) )
253                               ueggs)
254                              (retrieve ueggs))))))
255                     (else
256                      (warning 
257                       (string-append
258                        "extension `" (car e+d) "' has no .meta file "
259                        "- assuming it has no dependencies")))))))
260         *eggs+dirs*)))
261
262    (define (install eggs)
263      (retrieve eggs)
264      (unless *retrieve-only*
265        (for-each ; we assume the order reflects the dependency tree...
266         (lambda (e+d)
267           (print "installing " (car e+d) " ...")
268           (print "changing current directory to " (cdr e+d))
269           (parameterize ((current-directory (cdr e+d)))
270             (let ((cmd (sprintf
271                         "~a/csi -bnq -e \"(require-library setup-api)\" -e \"(import setup-api)\" ~a ~a ~a ~a ~a ~a"
272                         *program-path*
273                         (if (sudo-install) "-e \"(sudo-install #t)\"" "")
274                         (if *keep* "-e \"(keep-intermediates #t)\"" "")
275                         (if *no-install* "-e \"(setup-install-flag #f)\"" "")
276                         (if *host-extension* "-e \"(host-extension #t)\"" "")
277                         (if *prefix* 
278                             (sprintf "-e \"(installation-prefix \\\"~a\\\")\"" *prefix*)
279                             "")
280                         (make-pathname (cdr e+d) (car e+d) "setup"))))
281               (system* cmd))
282             (when (and *run-tests*
283                        (file-exists? "tests")
284                        (directory? "tests")
285                        (file-exists? "tests/run.scm") )
286               (current-directory "tests")
287               (let ((cmd (sprintf "~a/csi -s run.scm ~a" *program-path* (car e+d))))
288                 (print cmd)
289                 (system* cmd)))))
290         *eggs+dirs*)))
291
292  (define (cleanup)
293    (unless *keep*
294      (and-let* ((tmpdir (temporary-directory)))
295        (remove-directory tmpdir))))
296
297  (define (update-db)
298    (let* ((files (glob (make-pathname (repository-path) "*.import.*")))
299           (tmpdir (create-temporary-directory))
300           (dbfile (make-pathname tmpdir +module-db+)))
301      (fluid-let ((##sys#warnings-enabled #f))
302        (for-each
303         (lambda (f)
304           (let ((m (string-match ".*/([^/]+)\\.import\\.(scm|so)" f)))
305             (eval `(import ,(string->symbol (cadr m))))))
306         files))
307      (print "generating database")
308      (let ((db
309             (sort
310              (append-map
311               (lambda (m)
312                 (let* ((mod (cdr m))
313                        (mname (##sys#module-name mod)))
314                   (print* " " mname)
315                   (let-values (((_ ve se) (##sys#module-exports mod)))
316                     (append
317                      (map (lambda (se) (list (car se) 'syntax mname)) se)
318                      (map (lambda (ve) (list (car ve) 'value mname)) ve)))))
319               ##sys#module-table) 
320              (lambda (e1 e2)
321                (string<? (symbol->string (car e1)) (symbol->string (car e2)))))))
322        (newline)
323        (with-output-to-file dbfile
324          (lambda ()
325            (for-each (lambda (x) (write x) (newline)) db)))
326        (copy-file dbfile (make-pathname (repository-path) +module-db+))
327        (remove-directory tmpdir))))
328
329  (define (usage code)
330    (print #<<EOF
331usage: chicken-install [OPTION | EXTENSION[:VERSION]] ...
332
333  -h   -help                    show this message and exit
334  -v   -version                 show version and exit
335       -force                   don't ask, install even if versions don't match
336  -k   -keep                    keep temporary files
337  -l   -location LOCATION       install from given location instead of default
338  -t   -transport TRANSPORT     use given transport instead of default
339  -s   -sudo                    use sudo(1) for installing or removing files
340  -r   -retrieve                only retrieve egg into current directory, don't install
341  -n   -no-install              do not install, just build (implies `-keep')
342  -p   -prefix PREFIX           change installation prefix to PREFIX
343       -host-extension          when cross-compiling, compile extension for host
344       -test                    run included test-cases, if available
345       -username USER           set username for transports that require this
346       -password PASS           set password for transports that require this
347  -i   -init DIRECTORY          initialize empty alternative repository
348  -u   -update-db               update export database
349EOF
350);|
351    (exit code))
352
353  (define *short-options* '(#\h #\k #\l #\t #\s #\p #\r #\n #\v #\i #\u))
354
355  (define (main args)
356    (let ((defaults (load-defaults))
357          (update #f))
358      (let loop ((args args) (eggs '()))
359        (cond ((null? args)
360               (cond (update (update-db))
361                     (else
362                      (when (null? eggs)
363                        (let ((setups (glob "*.setup")))
364                          (cond ((pair? setups)
365                                 (set! *eggs+dirs*
366                                   (append
367                                    (map (lambda (s) (cons (pathname-file s) ".")) setups)
368                                    *eggs+dirs*)))
369                                (else
370                                 (print "no setup-scripts to process")
371                                 (exit 1))) ) )
372                      (unless defaults
373                        (unless *default-transport* 
374                          (error "no default transport defined - please use `-transport' option"))
375                        (unless *default-location* 
376                          (error "no default location defined - please use `-location' option")))
377                      (install (reverse eggs)))))
378              (else
379               (let ((arg (car args)))
380                 (cond ((or (string=? arg "-help") 
381                            (string=? arg "-h")
382                            (string=? arg "--help"))
383                        (usage 0))
384                       ((string=? arg "-force")
385                        (set! *force* #t)
386                        (loop (cdr args) eggs))
387                       ((or (string=? arg "-k") (string=? arg "-keep"))
388                        (set! *keep* #t)
389                        (loop (cdr args) eggs))
390                       ((or (string=? arg "-s") (string=? arg "-sudo"))
391                        (sudo-install #t)
392                        (loop (cdr args) eggs))
393                       ((or (string=? arg "-r") (string=? arg "-retrieve"))
394                        (set! *retrieve-only* #t)
395                        (loop (cdr args) eggs))
396                       ((or (string=? arg "-l") (string=? arg "-location"))
397                        (unless (pair? (cdr args)) (usage 1))
398                        (set! *default-location* (cadr args))
399                        (loop (cddr args) eggs))
400                       ((or (string=? arg "-t") (string=? arg "-transport"))
401                        (unless (pair? (cdr args)) (usage 1))
402                        (set! *default-transport* (string->symbol (cadr args)))
403                        (loop (cddr args) eggs))
404                       ((or (string=? arg "-p") (string=? arg "-prefix"))
405                        (unless (pair? (cdr args)) (usage 1))
406                        (set! *prefix* (cadr args))
407                        (loop (cddr args) eggs))
408                       ((or (string=? arg "-n") (string=? arg "-no-install"))
409                        (set! *keep* #t)
410                        (set! *no-install* #t)
411                        (loop (cdr args) eggs))
412                       ((or (string=? arg "-v") (string=? arg "-version"))
413                        (print (chicken-version))
414                        (exit 0))
415                       ((or (string=? arg "-u") (string=? arg "-update-db"))
416                        (set! update #t)
417                        (loop (cdr args) eggs))
418                       ((or (string=? arg "-i") (string=? arg "-init"))
419                        (unless (pair? (cdr args)) (usage 1))
420                        (init-repository (cadr args))
421                        (exit 0))
422                       ((string=? "-test" arg)
423                        (set! *run-tests* #t)
424                        (loop (cdr args) eggs))
425                       ((string=? "-host-extension" arg)
426                        (set! *host-extension* #t)
427                        (loop (cdr args) eggs))
428                       ((string=? "-username" arg)
429                        (unless (pair? (cdr args)) (usage 1))
430                        (set! *username* (cadr args))
431                        (loop (cddr args) eggs))
432                       ((string=? "-password" arg)
433                        (unless (pair? (cdr args)) (usage 1))
434                        (set! *password* (cadr args))
435                        (loop (cddr args) eggs))
436                       ((and (positive? (string-length arg))
437                             (char=? #\- (string-ref arg 0)))
438                        (if (> (string-length arg) 2)
439                            (let ((sos (string->list (substring arg 1))))
440                              (if (null? (lset-intersection eq? *short-options* sos))
441                                  (loop (append (map (cut string #\- <>) sos) (cdr args)) eggs)
442                                  (usage 1)))
443                            (usage 1)))
444                       ((equal? "setup" (pathname-extension arg))
445                        (let ((egg (pathname-file arg)))
446                          (set! *eggs+dirs*
447                            (alist-cons
448                             egg
449                             (let ((dir (pathname-directory arg)))
450                               (if dir
451                                   (if (absolute-pathname? dir)
452                                       dir
453                                       (make-pathname (current-directory) dir) )
454                                   (current-directory)))
455                             *eggs+dirs*))
456                          (loop (cdr args) (cons egg eggs))))
457                       ((string-match "([^:]+):(.+)" arg) =>
458                        (lambda (m)
459                          (loop (cdr args) (alist-cons (cadr m) (caddr m) eggs))))
460                       (else (loop (cdr args) (cons arg eggs))))))))))
461
462  (handle-exceptions ex
463      (begin
464        (print-error-message ex (current-error-port))
465        (cleanup)
466        (exit 1))
467    (main (command-line-arguments))
468    (cleanup))
469 
470)
Note: See TracBrowser for help on using the repository browser.