source: project/chicken/trunk/chicken-install.scm @ 12227

Last change on this file since 12227 was 12227, checked in by felix winkelmann, 12 years ago
  • added helpful script for testing in build dir
  • chicken-install checks for TCP timeouts and handles multiple default sources to download from
  • alias-global-hook is saved and restored when loading compiler extensions
  • making bootstrap automaticaly makes confclean
File size: 13.2 KB
Line 
1;;;; chicken-install.scm
2;
3; Copyright (c) 2008, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library setup-utils setup-download)
28(require-library srfi-1 posix data-structures utils ports regex ports extras
29                 srfi-13 files)
30
31
32#+(not csi)
33(foreign-declare #<<EOF
34#ifndef C_INSTALL_BIN_HOME
35# define C_INSTALL_BIN_HOME   NULL
36#endif
37EOF
38)
39
40
41(module main ()
42 
43  (import scheme chicken srfi-1 posix data-structures utils ports regex ports extras
44          srfi-13 files)
45  (import setup-utils setup-download)
46 
47  #+(not csi) (import foreign)
48
49  (define *program-path*
50    (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
51          (make-pathname p "bin") )
52        (cond-expand
53         (csi (make-pathname (current-directory) "bin"))                        ; just for debugging
54         (else (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )) )
55
56  (define *keep* #f)
57  (define *force* #f)
58  (define *sudo* #f)
59  (define *prefix* #f)
60  (define *host-extension* #f)
61  (define *run-tests* #f)
62  (define *retrieve-only* #f)
63  (define *no-install* #f)
64  (define *username* #f)
65  (define *password* #f)
66  (define *default-sources* '())
67  (define *default-location* #f)
68  (define *default-transport* 'http)
69
70  (define (load-defaults)
71    (let ((deff (make-pathname (repository-path) "setup.defaults")))
72      (cond ((not (file-exists? deff)) '())
73            (else
74             (set! *default-sources* (read-file deff))
75             (pair? *default-sources*)))))
76
77  (define (deps key meta)
78    (or (and-let* ((d (assq key meta)))
79          (cdr d))
80        '()))
81
82  (define (ext-version x)
83    (cond ((or (eq? x 'chicken)
84               (equal? x "chicken")
85               (member (->string x) ##sys#core-library-modules))
86           (chicken-version) )
87          ((extension-information x) =>
88           (lambda (info)
89             (and-let* ((a (assq 'version info)))
90               (->string (cadr a)))))
91          (else #f)))
92
93  (define (outdated-dependencies meta)
94    (let ((ds (append
95               (deps 'depends meta) 
96               (deps 'needs meta)
97               (if *run-tests* (deps 'test-depends meta) '()))))
98      (let loop ((deps ds) (missing '()) (upgrade '()))
99        (if (null? deps)
100            (values (reverse missing) (reverse upgrade))
101            (let ((dep (car deps))
102                  (rest (cdr deps)))
103              (cond ((or (symbol? dep) (string? dep))
104                     (loop rest
105                           (if (ext-version dep)
106                               missing
107                               (cons (->string dep) missing))
108                           upgrade))
109                    ((and (list? dep) (= 2 (length dep))
110                          (or (string? (car dep)) (symbol? (car dep))))
111                     (let ((v (ext-version (car dep))))
112                       (cond ((not v) 
113                              (warning
114                               "installed extension has unknown version - assuming it is outdated" 
115                               (car dep))
116                              (loop rest missing 
117                                    (alist-cons 
118                                     (->string (car dep))
119                                     (->string (cadr dep))
120                                     upgrade)))
121                             ((version>=? (->string (cadr dep)) v)
122                              (loop rest missing
123                                    (alist-cons
124                                     (->string (car dep)) (->string (cadr dep))
125                                     upgrade)))
126                             (else (loop rest missing upgrade)))))
127                    (else
128                     (warning
129                      "invalid dependency syntax in extension meta information" 
130                      dep)
131                     (loop rest missing upgrade))))))))
132
133    (define *eggs+dirs* '())
134    (define *checked* '())
135
136    (define (try name version)
137      (let loop ((defs (if (and *default-location* *default-transport*)
138                           `(((location ,*default-location*)
139                              (transport ,*default-transport*)))
140                           *default-sources*)))
141        (and (pair? defs)
142             (let* ((def (car defs))
143                    (loc (cadr (or (assq 'location def)
144                                   (error "missing location entry" def))))
145                    (trans (cadr (or (assq 'transport def)
146                                     (error "missing transport entry" def)))))
147               (or (condition-case
148                       (retrieve-extension 
149                        name trans loc
150                        version: version
151                        destination: (and *retrieve-only* (current-directory))
152                        tests: *run-tests*
153                        username: *username* 
154                        password: *password*)
155                     ((exn net) 
156                      (print "TCP connect timeout")
157                      #f)
158                     (e () (abort e)))
159                   (loop (cdr defs)))))))
160
161    (define (retrieve eggs)
162      (print "retrieving ...")
163      (for-each
164       (lambda (egg)
165         (cond ((assoc egg *eggs+dirs*) =>
166                (lambda (a)
167                  ;; push to front
168                  (set! *eggs+dirs* (cons a (delete a *eggs+dirs* eq?))) ) )
169               (else
170                (let* ((name (if (pair? egg) (car egg) egg))
171                       (version (and (pair? egg) (cdr egg)))
172                       (dir (try name version)))
173                  (unless dir
174                    (error "extension or version not found"))
175                  (print " " name " located at " dir)
176                  (set! *eggs+dirs* (alist-cons name dir *eggs+dirs*))))) )
177       eggs)
178      (unless *retrieve-only*
179        (for-each
180         (lambda (e+d)
181           (unless (member (car e+d) *checked*)
182             (set! *checked* (cons (car e+d) *checked*))
183             (let ((mfile (make-pathname (cdr e+d) (car e+d) "meta")))
184               (cond ((file-exists? mfile)
185                      (let ((meta (with-input-from-file mfile read)))
186                        (print "checking dependencies for `" (car e+d) "' ...")
187                        (let-values (((missing upgrade) (outdated-dependencies meta)))
188                          (when (pair? missing)
189                            (print " missing: " (string-intersperse missing ", "))
190                            (retrieve missing))
191                          (when (and (pair? upgrade)
192                                     (or *force*
193                                         (yes-or-no? 
194                                          (string-concatenate
195                                           (append
196                                            (list "The following installed extensions are outdated, because `"
197                                                  (car e+d) "' requires later versions:\n")
198                                            (map (lambda (e)
199                                                   (sprintf 
200                                                    "  ~a (~a -> ~a)~%"
201                                                    (car e) 
202                                                    (let ((v (assq 'version (extension-information (car e)))))
203                                                      (if v (cadr v) "???"))
204                                                    (cdr e)))
205                                                 upgrade)
206                                            '("\nDo you want to replace the existing extensions?")))
207                                          "no") ) )
208                            (let ((ueggs (unzip1 upgrade)))
209                              (print " upgrade: " (string-intersperse ueggs ", "))
210                              (for-each
211                               (lambda (e)
212                                 (print "removing previously installed extension `" e "' ...")
213                                 (remove-extension e *sudo*) )
214                               ueggs)
215                              (retrieve ueggs))))))
216                     (else
217                      (warning 
218                       (string-append
219                        "extension `" (car e+d) "' has no .meta file "
220                        "- assuming it has no dependencies")))))))
221         *eggs+dirs*)))
222
223    (define (install eggs)
224      (retrieve eggs)
225      (unless *retrieve-only*
226        (for-each ; we assume the order reflects the dependency tree...
227         (lambda (e+d)
228           (print "installing " (car e+d) " ...")
229           (print "changing current directory to " (cdr e+d))
230           (parameterize ((current-directory (cdr e+d)))
231             (let ((cmd (sprintf
232                         "~a/csi -bnq -e \"(require-library setup-api)\" -e \"(import setup-api)\" ~a ~a ~a ~a ~a ~a"
233                         *program-path*
234                         (if *sudo* "-e \"(sudo-install #t)\"" "")
235                         (if *keep* "-e \"(keep-intermediates #t)\"" "")
236                         (if *no-install* "-e \"(setup-install-flag #f)\"" "")
237                         (if *host-extension* "-e \"(host-extension #t)\"" "")
238                         (if *prefix* 
239                             (sprintf "-e \"(installation-prefix \\\"~a\\\")\"" *prefix*)
240                             "")
241                         (make-pathname (cdr e+d) (car e+d) "setup"))))
242               (system* cmd))
243             (when (and *run-tests*
244                        (file-exists? "tests")
245                        (directory? "tests")
246                        (file-exists? "tests/run.scm") )
247               (current-directory "tests")
248               (let ((cmd (sprintf "~a/csi -s run.scm ~a" *program-path* (car e+d))))
249                 (print cmd)
250                 (system* cmd)))))
251         *eggs+dirs*)))
252
253  (define (cleanup)
254    (unless *keep*
255      (and-let* ((tmpdir (temporary-directory)))
256        (remove-directory tmpdir))))
257
258  (define (usage code)
259    (print #<<EOF
260usage: chicken-install [OPTION | EXTENSION[:VERSION]] ...
261
262  -h   -help                    show this message and exit
263  -v   -version                 show version and exit
264       -force                   don't ask, install even if versions don't match
265  -k   -keep                    keep temporary files
266  -l   -location LOCATION       install from given location instead of default
267  -t   -transport TRANSPORT     use given transport instead of default
268  -s   -sudo                    use sudo(1) for installing or removing files
269  -r   -retrieve                only retrieve egg into current directory, don't install
270  -n   -no-install              do not install, just build (implies `-keep')
271  -p   -prefix PREFIX           change installation prefix to PREFIX
272       -host-extension          when cross-compiling, compile extension for host
273       -test                    run included test-cases, if available
274       -username USER           set username for transports that require this
275       -password PASS           set password for transports that require this
276EOF
277);|
278    (exit code))
279
280  (define *short-options* '(#\h #\k #\l #\t #\s #\p #\r #\n #\v))
281
282  (define (main args)
283    (let ((defaults (load-defaults)))
284      (let loop ((args args) (eggs '()))
285        (cond ((null? args)
286               (when (null? eggs)
287                 (let ((setups (glob "*.setup")))
288                   (cond ((pair? setups)
289                          (set! *eggs+dirs*
290                            (append
291                             (map (lambda (s) (cons (pathname-file s) ".")) setups)
292                             *eggs+dirs*)))
293                         (else
294                          (print "no setup-scripts to process")
295                          (exit 1))) ) )
296               (unless defaults
297                 (unless *default-transport* 
298                   (error "no default transport defined - please use `-transport' option"))
299                 (unless *default-location* 
300                   (error "no default location defined - please use `-location' option")))
301               (install (reverse eggs)))
302              (else
303               (let ((arg (car args)))
304                 (cond ((or (string=? arg "-help") 
305                            (string=? arg "-h")
306                            (string=? arg "--help"))
307                        (usage 0))
308                       ((string=? arg "-force")
309                        (set! *force* #t)
310                        (loop (cdr args) eggs))
311                       ((or (string=? arg "-k") (string=? arg "-keep"))
312                        (set! *keep* #t)
313                        (loop (cdr args) eggs))
314                       ((or (string=? arg "-s") (string=? arg "-sudo"))
315                        (set! *sudo* #t)
316                        (loop (cdr args) eggs))
317                       ((or (string=? arg "-r") (string=? arg "-retrieve"))
318                        (set! *retrieve-only* #t)
319                        (loop (cdr args) eggs))
320                       ((or (string=? arg "-l") (string=? arg "-location"))
321                        (unless (pair? (cdr args)) (usage 1))
322                        (set! *default-location* (cadr args))
323                        (loop (cddr args) eggs))
324                       ((or (string=? arg "-t") (string=? arg "-transport"))
325                        (unless (pair? (cdr args)) (usage 1))
326                        (set! *default-transport* (string->symbol (cadr args)))
327                        (loop (cddr args) eggs))
328                       ((or (string=? arg "-p") (string=? arg "-prefix"))
329                        (unless (pair? (cdr args)) (usage 1))
330                        (set! *prefix* (cadr args))
331                        (loop (cddr args) eggs))
332                       ((or (string=? arg "-n") (string=? arg "-no-install"))
333                        (set! *keep* #t)
334                        (set! *no-install* #t)
335                        (loop (cdr args) eggs))
336                       ((or (string=? arg "-v") (string=? arg "-version"))
337                        (print (chicken-version))
338                        (exit 0))
339                       ((string=? "-test" arg)
340                        (set! *run-tests* #t)
341                        (loop (cdr args) eggs))
342                       ((string=? "-host-extension" arg)
343                        (set! *host-extension* #t)
344                        (loop (cdr args) eggs))
345                       ((string=? "-username" arg)
346                        (unless (pair? (cdr args)) (usage 1))
347                        (set! *username* (cadr args))
348                        (loop (cddr args) eggs))
349                       ((string=? "-password" arg)
350                        (unless (pair? (cdr args)) (usage 1))
351                        (set! *password* (cadr args))
352                        (loop (cddr args) eggs))
353                       ((and (positive? (string-length arg))
354                             (char=? #\- (string-ref arg 0)))
355                        (if (> (string-length arg) 2)
356                            (let ((sos (string->list (substring arg 1))))
357                              (if (null? (lset-intersection eq? *short-options* sos))
358                                  (loop (append (map (cut string #\- <>) sos) (cdr args)) eggs)
359                                  (usage 1)))
360                            (usage 1)))
361                       ((equal? "setup" (pathname-extension arg))
362                        (let ((egg (pathname-file arg)))
363                          (set! *eggs+dirs*
364                            (alist-cons
365                             egg
366                             (let ((dir (pathname-directory arg)))
367                               (if dir
368                                   (if (absolute-pathname? dir)
369                                       dir
370                                       (make-pathname (current-directory) dir) )
371                                   (current-directory)))
372                             *eggs+dirs*))
373                          (loop (cdr args) (cons egg eggs))))
374                       ((string-match "([^:]+):(.+)" arg) =>
375                        (lambda (m)
376                          (loop (cdr args) (alist-cons (cadr m) (caddr m) eggs))))
377                       (else (loop (cdr args) (cons arg eggs))))))))))
378
379  (handle-exceptions ex
380      (begin
381        (print-error-message ex (current-error-port))
382        (cleanup)
383        (exit 1))
384    (main (command-line-arguments))
385    (cleanup))
386 
387)
Note: See TracBrowser for help on using the repository browser.