source: project/chicken/trunk/batch-driver.scm @ 12595

Last change on this file since 12595 was 12595, checked in by felix winkelmann, 12 years ago
  • removed custom declarations
  • added "-update-db" option to chicken-install
  • chicken: "-quiet" is useless and DEPRECATED
  • added support for db file in repository (not used yet)
  • compiler warns if first form in module body is not an `import' form
File size: 24.2 KB
Line 
1;;;; batch-driver.scm - Driver procedure for the compiler
2;
3; Copyright (c) 2000-2007, Felix L. Winkelmann
4; Copyright (c) 2008, The Chicken Team
5; All rights reserved.
6;
7; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
8; conditions are met:
9;
10;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
11;     disclaimer.
12;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
13;     disclaimer in the documentation and/or other materials provided with the distribution.
14;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
15;     products derived from this software without specific prior written permission.
16;
17; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
18; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
19; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
20; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
21; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
22; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
23; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
24; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
25; POSSIBILITY OF SUCH DAMAGE.
26
27
28(declare
29  (unit driver)
30  (disable-warning var))
31
32
33(private
34 compiler
35  compiler-arguments process-command-line dump-nodes dump-undefined-globals
36  default-standard-bindings default-extended-bindings side-effecting-standard-bindings
37  non-foldable-standard-bindings foldable-standard-bindings non-foldable-extended-bindings foldable-extended-bindings
38  standard-bindings-that-never-return-false side-effect-free-standard-bindings-that-never-return-false
39  compiler-cleanup-hook disabled-warnings local-definitions inline-output-file
40  file-io-only undefine-shadowed-macros profiled-procedures
41  unit-name insert-timer-checks used-units inline-max-size inline-locally
42  debugging perform-lambda-lifting! disable-stack-overflow-checking
43  foreign-declarations emit-trace-info block-compilation line-number-database-size
44  target-heap-size target-stack-size target-heap-growth target-heap-shrinkage
45  default-default-target-heap-size default-default-target-stack-size verbose-mode original-program-size
46  target-initial-heap-size postponed-initforms
47  current-program-size line-number-database-2 foreign-lambda-stubs immutable-constants foreign-variables
48  rest-parameters-promoted-to-vector inline-table inline-table-used constant-table constants-used
49  broken-constant-nodes inline-substitutions-enabled
50  emit-profile profile-lambda-list profile-lambda-index profile-info-vector-name
51  direct-call-ids foreign-type-table first-analysis emit-closure-info
52  initialize-compiler canonicalize-expression expand-foreign-lambda update-line-number-database scan-toplevel-assignments
53  perform-cps-conversion analyze-expression simplifications perform-high-level-optimizations perform-pre-optimization!
54  reorganize-recursive-bindings substitution-table simplify-named-call emit-unsafe-marker
55  perform-closure-conversion prepare-for-code-generation compiler-source-file create-foreign-stub expand-foreign-lambda*
56  transform-direct-lambdas! source-filename standalone-executable
57  debugging-chicken bomb check-signature posq stringify symbolify build-lambda-list
58  string->c-identifier c-ify-string words check-and-open-input-file close-checked-input-file fold-inner constant?
59  collapsable-literal? immediate? canonicalize-begin-body extract-mutable-constants string->expr get get-all
60  put! collect! count! get-line get-line-2 find-lambda-container display-analysis-database varnode qnode 
61  build-node-graph build-expression-tree fold-boolean inline-lambda-bindings match-node expression-has-side-effects?
62  simple-lambda-node? compute-database-statistics print-program-statistics output gen gen-list external-protos-first
63  pprint-expressions-to-file foreign-type-check estimate-foreign-result-size scan-used-variables scan-free-variables
64  topological-sort print-version print-usage initialize-analysis-database dump-exported-globals
65  default-declarations units-used-by-default words-per-flonum default-debugging-declarations
66  default-profiling-declarations default-optimization-passes
67  file-requirements import-libraries inline-globally
68  foreign-string-result-reserve parameter-limit eq-inline-operator optimizable-rest-argument-operators
69  membership-test-operators membership-unfold-limit valid-compiler-options valid-compiler-options-with-argument
70  chop-separator chop-extension display-real-name-table display-line-number-database explicit-use-flag
71  generate-code make-variable-list make-argument-list generate-foreign-stubs foreign-type-declaration
72  do-lambda-lifting compiler-warning emit-global-inline-file load-inline-file
73  foreign-argument-conversion foreign-result-conversion)
74
75
76(include "tweaks")
77
78(define-constant default-profile-name "PROFILE")
79(define-constant funny-message-timeout 60000)
80
81(define user-options-pass (make-parameter #f))
82(define user-read-pass (make-parameter #f))
83(define user-preprocessor-pass (make-parameter #f))
84(define user-pass (make-parameter #f))
85(define user-pass-2 (make-parameter #f))
86(define user-post-analysis-pass (make-parameter #f))
87
88
89;;; Compile a complete source file:
90
91(define (compile-source-file filename . options)
92  (define (option-arg p)
93    (if (null? (cdr p))
94        (quit "missing argument to `-~A' option" (car p))
95        (let ([arg (cadr p)])
96          (if (symbol? arg)
97              (quit "invalid argument to `~A' option" arg)
98              arg) ) ) )
99  (initialize-compiler)
100  (set! explicit-use-flag (memq 'explicit-use options))
101  (let ([initforms `((##core#declare
102                      ,@(append
103                         default-declarations
104                         (if explicit-use-flag
105                             '()
106                             `((uses ,@units-used-by-default)) ) ) ) ) ]
107        [verbose (memq 'verbose options)]
108        [outfile (cond [(memq 'output-file options) 
109                        => (lambda (node)
110                             (let ([oname (option-arg node)])
111                               (if (symbol? oname)
112                                   (symbol->string oname)
113                                   oname) ) ) ]
114                       [(memq 'to-stdout options) #f]
115                       [else (make-pathname #f (if filename (pathname-file filename) "out") "c")] ) ]
116        [ipath (map chop-separator (string-split (or (getenv "CHICKEN_INCLUDE_PATH") "") ";"))]
117        [opasses default-optimization-passes]
118        [time0 #f]
119        [time-breakdown #f]
120        [forms '()]
121        [cleanup-forms '(((##sys#implicit-exit-handler)))]
122        [profile (or (memq 'profile options) (memq 'accumulate-profile options) (memq 'profile-name options))]
123        [profile-name (or (and-let* ((pn (memq 'profile-name options))) (cadr pn)) default-profile-name)]
124        [hsize (memq 'heap-size options)]
125        [hisize (memq 'heap-initial-size options)]
126        [hgrowth (memq 'heap-growth options)]
127        [hshrink (memq 'heap-shrinkage options)]
128        [kwstyle (memq 'keyword-style options)]
129        [uses-units '()]
130        [uunit (memq 'unit options)]
131        [a-only (memq 'analyze-only options)]
132        [dynamic (memq 'dynamic options)]
133        [dumpnodes #f]
134        [start-time #f]
135        (upap #f)
136        [ssize (or (memq 'nursery options) (memq 'stack-size options))] )
137
138    (define (cputime) (##sys#fudge 6))
139
140    (define (dribble fstr . args)
141      (when verbose (printf "~?~%~!" fstr args)))
142
143    (define (print-header mode dbgmode)
144      (dribble "pass: ~a" mode)
145      (and (memq dbgmode debugging-chicken)
146           (begin
147             (printf "[~a]~%" mode)
148             #t) ) )
149
150    (define (print-node mode dbgmode n)
151      (when (print-header mode dbgmode)
152        (if dumpnodes
153            (dump-nodes n)
154            (pretty-print (build-expression-tree n)) ) ) )
155
156    (define (print-db mode dbgmode db pass)
157      (when (print-header mode dbgmode)
158        (printf "(iteration ~s)~%" pass)
159        (display-analysis-database db) ) )
160
161    (define (print-expr mode dbgmode xs)
162      (when (print-header mode dbgmode)
163        (for-each pretty-print xs) ) )
164
165    (define (infohook class data val)
166      (let ([data2 ((or ##sys#default-read-info-hook (lambda (a b c) b)) class data val)])
167        (when (and (eq? 'list-info class) (symbol? (car data2)))
168          (##sys#hash-table-set!
169           ##sys#line-number-database
170           (car data2)
171           (alist-cons data2 val
172                       (or (##sys#hash-table-ref ##sys#line-number-database (car data2))
173                           '() ) ) ) )
174        data2) )
175
176    (define (arg-val str)
177      (let* ((len (string-length str))
178             (len1 (- len 1)) )
179        (or (if (< len 2)
180                (string->number str)
181                (case (string-ref str len1)
182                  ((#\m #\M) (* (string->number (substring str 0 len1)) (* 1024 1024)))
183                  ((#\k #\K) (* (string->number (substring str 0 len1)) 1024))
184                  (else (string->number str)) ) )
185            (quit "invalid numeric argument ~S" str) ) ) )
186
187    (define (collect-options opt)
188      (let loop ([opts options])
189        (cond [(memq opt opts) => (lambda (p) (cons (option-arg p) (loop (cddr p))))]
190              [else '()] ) ) )
191
192    (define (begin-time)
193      (when time-breakdown (set! time0 (cputime))) )
194
195    (define (end-time pass)
196      (when time-breakdown
197        (printf "milliseconds needed for ~a: \t~s~%" pass (- (cputime) time0)) ) )
198
199    (define (read-form in)
200      (##sys#read in infohook) )
201
202    (define (analyze pass node . args)
203      (let-optionals args ((no 0) (contf #t))
204        (let ((db (analyze-expression node)))
205          (when upap
206            (upap pass db node
207                  (cut get db <> <>)
208                  (cut put! db <> <> <>)
209                  no contf) )
210          db) ) )
211
212    (when uunit
213      (set! unit-name (string->c-identifier (stringify (option-arg uunit)))) )
214    (when (or unit-name dynamic)
215      (set! standalone-executable #f))
216    (set! debugging-chicken 
217      (append-map
218       (lambda (do)
219         (map (lambda (c) (string->symbol (string c)))
220              (string->list do) ) )
221       (collect-options 'debug) ) )
222    (set! dumpnodes (memq '|D| debugging-chicken))
223    (set! import-libraries
224      (map (lambda (il)
225             (cons (string->symbol il) 
226                   (string-append il ".import.scm")))
227           (collect-options 'emit-import-library)))
228    (when (memq 'lambda-lift options) (set! do-lambda-lifting #t))
229    (when (memq 't debugging-chicken) (##sys#start-timer))
230    (when (memq 'b debugging-chicken) (set! time-breakdown #t))
231    (when (memq 'emit-exports options)
232      (warning "deprecated compiler option: emit-exports") )
233    (when (memq 'raw options)
234      (set! explicit-use-flag #t)
235      (set! cleanup-forms '())
236      (set! initforms '()) )
237    (when (memq 'no-lambda-info options)
238      (set! emit-closure-info #f) )
239    (when (memq 'local options)
240      (set! local-definitions #t))
241    (when (memq 'inline-global options)
242      (set! inline-locally #t)
243      (set! inline-globally #t))
244    (set! disabled-warnings (map string->symbol (collect-options 'disable-warning)))
245    (when (memq 'no-warnings options) 
246      (dribble "Warnings are disabled")
247      (set! ##sys#warnings-enabled #f) )
248    (when (memq 'optimize-leaf-routines options) (set! optimize-leaf-routines #t))
249    (when (memq 'unsafe options) 
250      (set! unsafe #t) )
251    (when (and dynamic (memq 'unsafe-libraries options))
252      (set! emit-unsafe-marker #t) )
253    (when (memq 'disable-interrupts options) (set! insert-timer-checks #f))
254    (when (memq 'fixnum-arithmetic options) (set! number-type 'fixnum))
255    (when (memq 'block options) (set! block-compilation #t))
256    (when (memq 'emit-external-prototypes-first options)
257      (set! external-protos-first #t))
258    (when (memq 'inline options) (set! inline-locally #t))
259    (and-let* ((ifile (memq 'emit-inline-file options)))
260      (set! inline-locally #t)          ; otherwise this option makes no sense
261      (set! local-definitions #t)
262      (set! inline-output-file (option-arg ifile)))
263    (and-let* ([inlimit (memq 'inline-limit options)])
264      (set! inline-max-size 
265        (let ([arg (option-arg inlimit)])
266          (or (string->number arg)
267              (quit "invalid argument to `-inline-limit' option: `~A'" arg) ) ) ) )
268    (when (memq 'case-insensitive options) 
269      (dribble "Identifiers and symbols are case insensitive")
270      (register-feature! 'case-insensitive)
271      (case-sensitive #f) )
272    (when (memq 'compress-literals options)
273      (compiler-warning 'usage "`the -compress-literals' option is obsolete") )
274    (when kwstyle
275      (let ([val (option-arg kwstyle)])
276        (cond [(string=? "prefix" val) (keyword-style #:prefix)]
277              [(string=? "none" val) (keyword-style #:none)]
278              [(string=? "suffix" val) (keyword-style #:suffix)]
279              [else (quit "invalid argument to `-keyword-style' option")] ) ) )
280    (set! verbose-mode verbose)
281    (set! ##sys#read-error-with-line-number #t)
282    (set! ##sys#include-pathnames
283      (append (map chop-separator (collect-options 'include-path))
284              ##sys#include-pathnames
285              ipath) )
286    (when (and outfile filename (string=? outfile filename))
287      (quit "source- and output-filename are the same") )
288    (set! uses-units
289      (map string->symbol 
290           (append-map
291            (cut string-split <> ",")
292            (collect-options 'uses))))
293    (when (memq 'keep-shadowed-macros options)
294      (set! undefine-shadowed-macros #f) )
295
296    ;; Handle feature options:
297    (for-each
298     register-feature!
299     (append-map (cut string-split <> ",") (collect-options 'feature)))
300
301    ;; Load extensions:
302    (set! ##sys#features (cons #:compiler-extension ##sys#features))
303    (let ([extends (collect-options 'extend)])
304      (dribble "Loading compiler extensions...")
305      (when verbose (load-verbose #t))
306      (for-each
307       (lambda (f) (load (##sys#resolve-include-filename f #f #t))) 
308       extends) )
309    (set! ##sys#features (delete #:compiler-extension ##sys#features eq?))
310
311    (set! ##sys#features (cons '#:compiling ##sys#features))
312    (set! upap (user-post-analysis-pass))
313
314    ;; Insert postponed initforms:
315    (set! initforms (append initforms postponed-initforms))
316
317    ;; Handle `-extension' options:
318    (when (memq 'extension options)
319      (set! initforms 
320        (append
321         initforms
322         `((define-extension 
323             ,(string->symbol
324               (cond (outfile (pathname-file outfile))
325                     (filename (pathname-file filename))
326                     (else (quit "no filename available for `-extension' option")) ) ) ) ) ) ) )
327
328    ;; Append required extensions to initforms:
329    (let ()
330      (define (ids opt)
331        (lset-difference 
332         eq?
333         (map string->symbol
334              (append-map
335               (cut string-split <> ",")
336               (collect-options opt)))
337         uses-units))
338      (set! initforms
339        (append
340         initforms 
341         (map (lambda (r) `(##core#require-extension (,r) #t)) 
342              (ids 'require-extension))))
343
344    (when (memq 'compile-syntax options)
345      (set! ##sys#enable-runtime-macros #t) )
346    (set! target-heap-size
347      (if hsize
348          (arg-val (option-arg hsize))
349          (and-let* ([hsize default-default-target-heap-size]
350                     [(not (zero? hsize))] )
351            hsize) ) )
352    (set! target-initial-heap-size (and hisize (arg-val (option-arg hisize))))
353    (set! target-heap-growth (and hgrowth (arg-val (option-arg hgrowth))))
354    (set! target-heap-shrinkage (and hshrink (arg-val (option-arg hshrink))))
355    (set! target-stack-size
356      (if ssize
357          (arg-val (option-arg ssize))
358          (and-let* ([ssize default-default-target-stack-size]
359                     [(not (zero? ssize))] )
360            ssize) ) )
361    (set! emit-trace-info (not (memq 'no-trace options)))
362    (set! disable-stack-overflow-checking (memq 'disable-stack-overflow-checks options))
363    (when (memq 'm debugging-chicken) (set-gc-report! #t))
364    (unless (memq 'no-usual-integrations options)
365      (set! standard-bindings default-standard-bindings)
366      (set! extended-bindings default-extended-bindings) )
367    (dribble "debugging info: ~A"
368             (if emit-trace-info
369                 "calltrace"
370                 "none") )
371    (when profile
372      (let ([acc (eq? 'accumulate-profile (car profile))])
373        (set! emit-profile #t)
374        (set! initforms
375          (append
376           initforms
377           default-profiling-declarations
378           (if acc
379               '((set! ##sys#profile-append-mode #t))
380               '() ) ) )
381        (dribble "Generating ~aprofile" (if acc "accumulated " "")) ) )
382
383    (and-let* ((dbfile (file-exists? (make-pathname (repository-path) "db"))))
384      (dribble "loading database ~a" dbfile)
385      (for-each
386       (lambda (e)
387         (##sys#put! 
388          (car e) '##core#db
389          (append (or (##sys#get (car e) '##core#db) '()) (cdr e))) )
390       (read-file dbfile)))
391
392    (cond ((memq 'version options)
393           (print-version #t)
394           (newline) )
395          ((or (memq 'help options) (memq '-help options) (memq 'h options) (memq '-h options))
396           (print-usage))
397          ((memq 'release options)
398           (display (chicken-version)) 
399           (newline) )
400          ((not filename)
401           (print-version #t)
402           (display "\nEnter \"chicken -help\" for information on how to use it.\n") )
403          (else
404
405           ;; Display header:
406           (dribble "compiling `~a' ..." filename)
407           (set! source-filename filename)
408           (debugging 'r "options" options)
409           (debugging 'r "debugging options" debugging-chicken)
410           (debugging 'r "target heap size" target-heap-size)
411           (debugging 'r "target stack size" target-stack-size)
412           (set! start-time (cputime))
413
414           ;; Read toplevel expressions:
415           (set! ##sys#line-number-database (make-vector line-number-database-size '()))
416           (let ([prelude (collect-options 'prelude)]
417                 [postlude (collect-options 'postlude)] 
418                 [files (append
419                         (collect-options 'prologue)
420                         (list filename)
421                         (collect-options 'epilogue) ) ]  )
422
423             (let ([proc (user-read-pass)])
424               (cond [proc
425                      (dribble "User read pass...")
426                      (set! forms (proc prelude files postlude)) ]
427                     [else
428                      (do ([files files (cdr files)])
429                          ((null? files)
430                           (set! forms
431                             (append (map string->expr prelude)
432                                     (reverse forms)
433                                     (map string->expr postlude) ) ) )
434                        (let* ((f (car files))
435                               (in (check-and-open-input-file f)) )
436                          (fluid-let ((##sys#current-source-filename f))
437                            (let ((x1 (read-form in)) )
438                              (do ((x x1 (read-form in)))
439                                  ((eof-object? x) 
440                                   (close-checked-input-file in f) )
441                                (set! forms (cons x forms)) ) ) ) ) ) ] ) ) )
442
443           ;; Start compilation passes:
444           (let ([proc (user-preprocessor-pass)])
445             (when proc
446               (dribble "User preprocessing pass...")
447               (set! forms (map proc forms))))
448
449           (print-expr "source" '|1| forms)
450           (begin-time)
451           (unless (null? uses-units)
452             (set! ##sys#explicit-library-modules (append ##sys#explicit-library-modules uses-units))
453             (set! forms (cons `(declare (uses ,@uses-units)) forms)) )
454           (let* ([exps0 (map canonicalize-expression (append initforms forms))]
455                  [pvec (gensym)]
456                  [plen (length profile-lambda-list)]
457                  [exps (append
458                         (map (lambda (ic) `(set! ,(cdr ic) ',(car ic))) immutable-constants)
459                         (map (lambda (n) `(##core#callunit ,n)) used-units)
460                         (if emit-profile
461                             `((set! ,profile-info-vector-name 
462                                 (##sys#register-profile-info
463                                  ',plen
464                                  ',(if unit-name #f profile-name))))
465                             '() )
466                         (map (lambda (pl)
467                                `(##sys#set-profile-info-vector!
468                                  ,profile-info-vector-name
469                                  ',(car pl)
470                                  ',(cdr pl) ) )
471                              profile-lambda-list)
472                         exps0
473                         (if (and (not unit-name) (not dynamic))
474                             cleanup-forms
475                             '() )
476                         '((##core#undefined))) ] )
477
478             (when (debugging '|N| "real name table:")
479               (display-real-name-table) )
480             (when (debugging 'n "line number database:")
481               (display-line-number-database) )
482
483             (when (and block-compilation unit-name)
484               (compiler-warning 
485                'usage
486                "compilation of library unit `~a' in block-mode - globals may not be accessible outside this unit"
487                unit-name) )
488
489             (when (and unit-name dynamic)
490               (compiler-warning 'usage "library unit `~a' compiled in dynamic mode" unit-name) )
491
492             (when (and unsafe (feature? 'compiling-extension))
493               (compiler-warning 
494                'style
495                "compiling extensions in unsafe mode is bad practice and should be avoided as it may be surprising to an unsuspecting user") )
496
497             (set! ##sys#line-number-database line-number-database-2)
498             (set! line-number-database-2 #f)
499
500             (end-time "canonicalization")
501             (print-expr "canonicalized" '|2| exps)
502
503             (when (memq 'check-syntax options) (exit))
504
505             (let ([proc (user-pass)])
506               (when proc
507                 (dribble "User pass...")
508                 (begin-time)
509                 (set! exps (map proc exps))
510                 (end-time "user pass") ) )
511
512             (let ((req (concatenate (vector->list file-requirements))))
513               (when (debugging 'M "; requirements:")
514                 (pp req))
515               (when inline-globally
516                 (for-each
517                  (lambda (id)
518                    (and-let* ((ifile (##sys#resolve-include-filename 
519                                       (make-pathname #f (symbol->string id) "inline")
520                                       #f #t))
521                               ((file-exists? ifile)))
522                      (dribble "Loading inline file ~a ..." ifile)
523                      (load-inline-file ifile)))
524                  (concatenate (map cdr req)))))
525
526             (let* ([node0 (make-node
527                            'lambda '(())
528                            (list (build-node-graph
529                                   (canonicalize-begin-body exps) ) ) ) ] 
530                    [proc (user-pass-2)] )
531               (when proc
532                 (dribble "Secondary user pass...")
533                 (begin-time)
534                 (set! first-analysis #f)
535                 (let ([db (analyze 'user node0)])
536                   (print-db "analysis (u)" '|0| db 0)
537                   (end-time "pre-analysis (u)")
538                   (begin-time)
539                   (proc node0)
540                   (end-time "secondary user pass")
541                   (print-node "secondary user pass" '|U| node0) )
542                 (set! first-analysis #t) )
543
544               (when do-lambda-lifting
545                 (begin-time)
546                 (set! first-analysis #f)
547                 (let ([db (analyze 'lift node0)])
548                   (print-db "analysis" '|0| db 0)
549                   (end-time "pre-analysis")
550                   (begin-time)
551                   (perform-lambda-lifting! node0 db)
552                   (end-time "lambda lifting")
553                   (print-node "lambda lifted" '|L| node0) )
554                 (set! first-analysis #t) )
555
556               (set! ##sys#line-number-database #f)
557               (set! constant-table #f)
558               (set! inline-table #f)
559               (unless unsafe
560                 (scan-toplevel-assignments (first (node-subexpressions node0))) )
561
562               (begin-time)
563               (let ([node1 (perform-cps-conversion node0)])
564                 (end-time "cps conversion")
565                 (print-node "cps" '|3| node1)
566
567                 ;; Optimization loop:
568                 (let loop ([i 1] [node2 node1] [progress #t])
569
570                   (begin-time)
571                   (let ([db (analyze 'opt node2 i progress)])
572                     (when first-analysis
573                       (when (memq 'u debugging-chicken)
574                         (dump-undefined-globals db)) )
575                     (set! first-analysis #f)
576                     (end-time "analysis")
577                     (print-db "analysis" '|4| db i)
578
579                     (when (memq 's debugging-chicken) (print-program-statistics db))
580
581                     (cond [progress
582                            (debugging 'p "optimization pass" i)
583
584                            (begin-time)
585                            (receive (node2 progress-flag)
586                                (perform-high-level-optimizations node2 db)
587                              (end-time "optimization")
588                              (print-node "optimized-iteration" '|5| node2)
589
590                              (cond [progress-flag (loop (add1 i) node2 #t)]
591                                    [(not inline-substitutions-enabled)
592                                     (debugging 'p "rewritings enabled...")
593                                     (set! inline-substitutions-enabled #t)
594                                     (loop (add1 i) node2 #t) ]
595                                    [optimize-leaf-routines
596                                     (begin-time)
597                                     (let ([db (analyze 'leaf node2)])
598                                       (end-time "analysis")
599                                       (begin-time)
600                                       (let ([progress (transform-direct-lambdas! node2 db)])
601                                         (end-time "leaf routine optimization")
602                                         (loop (add1 i) node2 progress) ) ) ]
603                                    [else (loop (add1 i) node2 #f)] ) ) ]
604                           
605                           [else
606                            (print-node "optimized" '|7| node2)
607
608                            (when inline-output-file
609                              (let ((f inline-output-file))
610                                (dribble "Generating global inline file `~a' ..." f)
611                                (emit-global-inline-file f db) ) )
612
613                            (begin-time)
614                            (let ([node3 (perform-closure-conversion node2 db)])
615                              (end-time "closure conversion")
616                              (print-db "final-analysis" '|8| db i)
617                              (when (and ##sys#warnings-enabled (> (- (cputime) start-time) funny-message-timeout))
618                                (display "(don't worry - still compiling...)\n") )
619                              (when a-only (exit 0))
620                              (print-node "closure-converted" '|9| node3)
621
622                              (begin-time)
623                              (receive (node literals lliterals lambdas)
624                                  (prepare-for-code-generation node3 db)
625                                (end-time "preparation")
626
627                                (begin-time)
628                                (let ((out (if outfile (open-output-file outfile) (current-output-port))) )
629                                  (dribble "generating `~A' ..." outfile)
630                                  (generate-code literals lliterals lambdas out filename dynamic db)
631                                  (when outfile (close-output-port out)))
632                                (end-time "code generation")
633                                (when (memq 't debugging-chicken) (##sys#display-times (##sys#stop-timer)))
634                                (compiler-cleanup-hook)
635                                (dribble "compilation finished.") ) ) ] ) ) ) ) ) ) ) ) ) ) )
Note: See TracBrowser for help on using the repository browser.