source: project/chicken/branches/scrutiny/setup-api.scm @ 14827

Last change on this file since 14827 was 14827, checked in by felix winkelmann, 10 years ago

merged trunk changes until 14826 into scrutiny branch

File size: 24.9 KB
Line 
1;;;; setup-api.scm - build + installation API for eggs
2;
3; Copyright (c) 2008-2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library srfi-1 regex utils posix srfi-13 extras ports data-structures files)
28
29; This code is partially quite messy and the API is not overly consistent,
30; mainly because it has grown "organically" while the old chicken-setup program
31; evolved. The code was extracted and put into this module, without much
32; cleaning up. Nevertheless, it should work.
33
34(module setup-api
35
36    (move-file 
37     (run execute)
38     compile
39     make make/proc
40     host-extension
41     install-extension install-program install-script
42     setup-verbose-flag
43     setup-install-flag installation-prefix chicken-prefix 
44     find-library find-header 
45     program-path remove-file* 
46     patch yes-or-no? abort-setup
47     setup-root-directory create-directory/parents
48     test-compile try-compile copy-file run-verbose
49     required-chicken-version required-extension-version cross-chicken
50     sudo-install keep-intermediates
51     version>=?
52     extension-name-and-version
53     extension-name
54     extension-version
55     create-temporary-directory
56     remove-directory
57     remove-extension
58     read-info
59     shellpath)
60 
61  (import scheme chicken foreign
62          regex utils posix ports extras data-structures
63          srfi-1 srfi-13 files)
64
65;;; Constants, variables and parameters
66
67(define-constant setup-file-extension "setup-info")
68
69(define *installed-executables* 
70  `(("chicken" . ,(foreign-value "C_CHICKEN_PROGRAM" c-string))
71    ("csc" . ,(foreign-value "C_CSC_PROGRAM" c-string))
72    ("csi" . ,(foreign-value "C_CSI_PROGRAM" c-string))
73    ("chicken-bug" . ,(foreign-value "C_CHICKEN_BUG_PROGRAM" c-string))))
74
75(define *cc* (foreign-value "C_TARGET_CC" c-string))
76(define *cxx* (foreign-value "C_TARGET_CXX" c-string))
77(define *target-cflags* (foreign-value "C_TARGET_CFLAGS" c-string))
78(define *target-libs* (foreign-value "C_TARGET_MORE_LIBS" c-string))
79(define *target-lib-home* (foreign-value "C_TARGET_LIB_HOME" c-string))
80(define *sudo* #f)
81(define *windows-shell* (foreign-value "C_WINDOWS_SHELL" bool))
82
83(define *windows*
84  (and (eq? (software-type) 'windows) 
85       (build-platform) ) )
86
87(register-feature! 'chicken-setup)
88
89(define host-extension (make-parameter #f))
90
91(define *chicken-bin-path*
92  (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
93        (make-pathname p "bin") )
94      (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )
95
96(define *doc-path*
97  (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
98        (make-pathname p "share/chicken/doc") )
99      (make-pathname
100       (foreign-value "C_INSTALL_SHARE_HOME" c-string) 
101       "doc")))
102
103(define chicken-prefix
104  (or (getenv "CHICKEN_PREFIX")
105      (let ((m (string-match "(.*)/bin/?" *chicken-bin-path*)))
106        (if m
107            (cadr m)
108            "/usr/local") ) ) )
109
110(define (shellpath str)
111  (qs (normalize-pathname str)))
112
113(define (cross-chicken) (##sys#fudge 39))
114
115(define *csc-options* '())
116(define *base-directory* (current-directory))
117
118(define setup-root-directory      (make-parameter *base-directory*))
119(define setup-verbose-flag        (make-parameter #f))
120(define setup-install-flag        (make-parameter #t))
121(define program-path              (make-parameter *chicken-bin-path*))
122(define keep-intermediates (make-parameter #f))
123
124; Setup shell commands
125
126(define *copy-command*)
127(define *remove-command*)
128(define *move-command*)
129(define *chmod-command*)
130(define *ranlib-command*)
131
132(define (windows-user-install-setup)
133  (set! *copy-command*        'copy)
134  (set! *remove-command*      "del /Q /S")
135  (set! *move-command*        'move)
136  (set! *chmod-command*       "chmod")
137  (set! *ranlib-command*      "ranlib") )
138
139(define (unix-user-install-setup)
140  (set! *copy-command*        "cp -r")
141  (set! *remove-command*      "rm -fr")
142  (set! *move-command*        'mv)
143  (set! *chmod-command*       "chmod")
144  (set! *ranlib-command*      "ranlib") )
145
146(define (windows-sudo-install-setup)
147  (set! *sudo* #f)
148  (print "Warning: cannot install as superuser with Windows") )
149
150(define (unix-sudo-install-setup)
151  (set! *copy-command*        "sudo cp -r")
152  (set! *remove-command*      "sudo rm -fr")
153  (set! *move-command*        "sudo mv")
154  (set! *chmod-command*       "sudo chmod")
155  (set! *ranlib-command*      "sudo ranlib") )
156
157(define (user-install-setup)
158  (set! *sudo* #f)
159  (if *windows-shell*
160      (windows-user-install-setup)
161      (unix-user-install-setup) ) )
162
163(define (sudo-install-setup)
164  (set! *sudo* #t)
165  (if *windows-shell*
166      (windows-sudo-install-setup)
167      (unix-sudo-install-setup) ) )
168
169(define (sudo-install . args)
170  (cond ((null? args)   *sudo*)
171        ((car args)     (sudo-install-setup))
172        (else           (user-install-setup)) ) )
173
174; User setup by default
175(user-install-setup)
176
177
178(define create-directory/parents
179  (let ()
180    (define create-directory-0
181      (let ([create-directory create-directory])
182        (lambda (dir)
183          (let loop ([dir dir])
184            (when (and dir (not (directory? dir)))
185              (loop (pathname-directory dir))
186              (create-directory dir))) ) ) )
187    (define (verb dir)
188      (when (setup-verbose-flag) (printf "  creating directory `~a'~%~!" dir)) )
189    (if *windows-shell*
190        (lambda (dir)
191          (verb dir)
192          (create-directory-0 dir) ) 
193        (lambda (dir)
194          (verb dir)
195          ($system (sprintf "mkdir -p ~a" (shellpath dir) ) ) ) ) ) )
196
197(define abort-setup (make-parameter exit))
198
199(define (yes-or-no? str #!key default (abort (abort-setup)))
200  (let loop ()
201    (printf "~%~A (yes/no/abort) " str)
202    (when default (printf "[~A] " default))
203    (flush-output)
204    (let ((ln (read-line)))
205      (cond ((eof-object? ln) (set! ln "abort"))
206            ((and default (string=? "" ln)) (set! ln default)) )
207      (cond ((string-ci=? "yes" ln) #t)
208            ((string-ci=? "no" ln) #f)
209            ((string-ci=? "abort" ln) (abort))
210            (else
211             (printf "~%Please enter \"yes\", \"no\" or \"abort\".~%")
212             (loop) ) ) ) ) )
213 
214(define (patch which rx subst)
215  (when (setup-verbose-flag) (printf "patching ~A ...~%" which))
216  (if (list? which)
217      (with-output-to-file (cadr which)
218       (lambda ()
219         (with-input-from-file (car which)
220           (lambda ()
221             (let loop ()
222               (let ((ln (read-line)))
223                 (unless (eof-object? ln)
224                   (write-line (string-substitute rx subst ln #t)) 
225                   (loop) ) ) ) ) ) ) )
226      (let ((tmp (create-temporary-file)))
227        (patch (list tmp tmp) rx subst)
228        ($system 
229         (sprintf "~A ~A ~A" *move-command* (shellpath tmp)
230                  (shellpath which))))))
231
232(define run-verbose (make-parameter #t))
233
234(define (fixpath prg)
235  (cond ((string=? prg "csc")
236         (string-intersperse 
237          (cons* (shellpath
238                  (make-pathname 
239                   *chicken-bin-path*
240                   (cdr (assoc prg *installed-executables*))))
241                 "-feature" "compiling-extension"
242                 (if (keep-intermediates) "-k" "")
243                 (if (host-extension) "-host" "")
244                 *csc-options*) 
245          " ") )
246        ((assoc prg *installed-executables*) =>
247         (lambda (a) (shellpath (make-pathname *chicken-bin-path* (cdr a)))))
248        (else prg) ) )
249
250(define (fixmaketarget file)
251  (if (and (equal? "so" (pathname-extension file))
252           (not (string=? "so" ##sys#load-dynamic-extension)) )
253      (pathname-replace-extension file ##sys#load-dynamic-extension)
254      file) )
255
256(define (execute explist)
257  (define (smooth lst)
258    (let ((slst (map ->string lst)))
259      (string-intersperse (cons (fixpath (car slst)) (cdr slst)) " ") ) )
260  (for-each
261   (lambda (cmd)
262     (when (run-verbose) (printf "  ~A~%~!" cmd))
263     ($system cmd))
264   (map smooth explist) ) )
265
266(define-syntax run
267  (syntax-rules ()
268    ((_ exp ...)
269     (execute (list `exp ...)))))
270
271(define-syntax compile
272  (syntax-rules ()
273    ((_ exp ...)
274     (run (csc exp ...)))))
275
276
277;;; "make" functionality
278
279(define (make:find-matching-line str spec)
280  (let ((match? (lambda (s) (string=? s str))))
281    (let loop ((lines spec))
282      (cond
283       ((null? lines) #f)
284       (else (let* ((line (car lines))
285                    (names (if (string? (car line))
286                               (list (car line))
287                               (car line))))
288               (if (any match? names)
289                   line
290                   (loop (cdr lines)))))))))
291
292(define (make:form-error s p) (error (sprintf "~a: ~s" s p)))
293(define (make:line-error s p n) (error (sprintf "~a: ~s for line: ~a" s p n)))
294
295(define (make:check-spec spec)
296  (and (or (list? spec) (make:form-error "specification is not a list" spec))
297       (or (pair? spec) (make:form-error "specification is an empty list" spec))
298       (every
299        (lambda (line)
300          (and (or (and (list? line) (<= 2 (length line) 3))
301                   (make:form-error "list is not a list with 2 or 3 parts" line))
302               (or (or (string? (car line))
303                       (and (list? (car line))
304                            (every string? (car line))))
305                   (make:form-error "line does not start with a string or list of strings" line))
306               (let ((name (car line)))
307                 (or (list? (cadr line))
308                     (make:line-error "second part of line is not a list" (cadr line) name)
309                     (every (lambda (dep)
310                               (or (string? dep)
311                                   (make:form-error "dependency item is not a string" dep)))
312                             (cadr line)))
313                 (or (null? (cddr line))
314                     (procedure? (caddr line))
315                     (make:line-error "command part of line is not a thunk" (caddr line) name)))))
316        spec)))
317
318(define (make:check-argv argv)
319  (or (string? argv)
320      (every string? argv)
321      (error "argument is not a string or string list" argv)))
322
323(define (make:make/proc/helper spec argv)
324  (when (vector? argv) (set! argv (vector->list argv)))
325  (make:check-spec spec)
326  (make:check-argv argv)
327  (letrec ((made '())
328           (exn? (condition-predicate 'exn))
329           (exn-message (condition-property-accessor 'exn 'message))
330           (make-file
331            (lambda (s indent)
332              (let* ((line (make:find-matching-line s spec))
333                     (s2 (fixmaketarget s)) 
334                     (date (and (file-exists? s2)
335                                (file-modification-time s2))))
336                (when (setup-verbose-flag)
337                  (printf "make: ~achecking ~a~%" indent s2))
338                (if line
339                    (let ((deps (cadr line)))
340                      (for-each (let ((new-indent (string-append " " indent)))
341                                  (lambda (d) (make-file d new-indent)))
342                                deps)
343                      (let ((reason
344                             (or (not date)
345                                 (any (lambda (dep)
346                                          (let ((dep2 (fixmaketarget dep)))
347                                            (unless (file-exists? dep2)
348                                              (error (sprintf "dependancy ~a was not made~%" dep2)))
349                                            (and (> (file-modification-time dep2) date)
350                                                 dep2)) )
351                                        deps))))
352                        (when reason
353                          (let ((l (cddr line)))
354                            (unless (null? l)
355                              (set! made (cons s made))
356                              (when (setup-verbose-flag)
357                                (printf "make: ~amaking ~a~a~%"
358                                        indent
359                                        s2
360                                        (cond
361                                         ((not date)
362                                          (string-append " because " s2 " does not exist"))
363                                         ((string? reason)
364                                          (string-append " because " reason " changed"))
365                                         (else
366                                          (string-append (sprintf " just because (reason: ~a date: ~a)" 
367                                                                  reason date)))) ) )
368                              (handle-exceptions exn
369                                  (begin
370                                    (printf "make: Failed to make ~a: ~a~%"
371                                            (car line)
372                                            (if (exn? exn)
373                                                (exn-message exn)
374                                                exn))
375                                    (signal exn) )
376                                ((car l))))))))
377                    (unless date
378                      (error (sprintf "don't know how to make ~a" s2))))))))
379    (cond
380     ((string? argv) (make-file argv ""))
381     ((null? argv) (make-file (caar spec) ""))
382     (else (for-each (lambda (f) (make-file f "")) argv)))
383    (when (setup-verbose-flag)
384      (for-each (lambda (item)
385                  (printf "make: made ~a~%" item))
386        (reverse made)))) )
387
388(define make/proc
389  (case-lambda
390   ((spec) (make:make/proc/helper spec '()))
391   ((spec argv)
392    (make:make/proc/helper
393     spec
394     (if (vector? argv)
395         (vector->list argv)
396         argv) ) ) ) )
397
398(define-syntax make
399  ;;XXX use er-macro-transformer
400  (lambda (form r c)
401    (##sys#check-syntax 'make form '(_ _ . #(_ 0 1)))
402    (let ((spec (cadr form))
403          (%list (r 'list))
404          (%lambda (r 'lambda)))
405      (let ((form-error (lambda (s . p) (apply error s spec p))))
406        (and (or (list? spec) (form-error "illegal specification (not a sequence)"))
407             (or (pair? spec) (form-error "empty specification"))
408             (every
409              (lambda (line)
410                (and (or (and (list? line) (>= (length line) 2))
411                         (form-error "clause does not have at least 2 parts" line))
412                     (let ((name (car line)))
413                       (or (list? (cadr line))
414                           (make:line-error "second part of clause is not a sequence" (cadr line) name)))))
415              spec))
416        `(,(r 'make/proc)
417          (list ,@(map (lambda (line)
418                         `(,%list ,(car line)
419                                  (,%list ,@(cadr line))
420                                  ,@(let ((l (cddr line)))
421                                      (if (null? l)
422                                          '()
423                                          `((,%lambda () ,@l))))))
424                       spec))
425          ,@(if (null? (cddr form))
426                '('())
427                (cddr form)))))))
428
429
430;;; Processing setup scripts
431
432(define (make-setup-info-pathname fn #!optional (rpath (repository-path)))
433  (make-pathname rpath fn setup-file-extension) )
434
435(define installation-prefix
436  (make-parameter (or (getenv "CHICKEN_INSTALL_PREFIX") #f)))
437
438(define (write-info id files info)
439  (let ((info `((files ,@files) 
440                ,@info)) )
441    (when (setup-verbose-flag) (printf "writing info ~A -> ~S ...~%" id info))
442    (let* ((sid (->string id))
443           (setup-file (make-setup-info-pathname sid (repo-path #t))))
444      (cond (*sudo*
445             (let ((tmp (create-temporary-file)))
446               (with-output-to-file tmp (cut pp info))
447               (run (,*move-command* ,(shellpath tmp) ,(shellpath setup-file)))))
448            (else (with-output-to-file setup-file (cut pp info))))
449      (unless *windows-shell* (run (,*chmod-command* a+r ,(shellpath setup-file)))))))
450
451(define (copy-file from to #!optional (err #t) (prefix (installation-prefix)))
452  ;;XXX the prefix handling is completely bogus
453  (let ((from (if (pair? from) (car from) from))
454        (to (let ((to-path (if (pair? from) (make-pathname to (cadr from)) to)))
455              (if (and prefix (not (string-prefix? prefix to-path)))
456                  (make-pathname prefix to-path) 
457                  to-path))))
458    (ensure-directory to)
459    (cond ((or (glob? from) (file-exists? from))
460           (begin
461             (run (,*copy-command* ,(shellpath from) ,(shellpath to))) 
462             to))
463          (err (error "file does not exist" from))
464          (else (warning "file does not exist" from)))))
465
466(define (move-file from to)
467  (let ((from  (if (pair? from) (car from) from))
468        (to    (if (pair? from) (make-pathname to (cadr from)) to)))
469    (ensure-directory to)
470    (run (,*move-command* ,(shellpath from) ,(shellpath to)) ) ) )
471
472(define (remove-file* dir)
473  (run (,*remove-command* ,(shellpath dir)) ) )
474
475(define (make-dest-pathname path file)
476  (if (list? file)
477      (make-dest-pathname path (cadr file))
478      (if (absolute-pathname? file)
479          file
480          (make-pathname path file) ) ) )
481
482(define (check-filelist flist)
483  (map (lambda (f)
484         (cond ((string? f) f)
485               ((and (list? f) (every string? f)) f)
486               ((and (pair? f) (list (car f) (cdr f))))
487               (else (error "invalid file-specification" f)) ) )
488       flist) )
489
490(define (translate-extension f #!optional default)
491  (pathname-replace-extension f
492   (let ((ext (pathname-extension f)))
493     (cond ((not ext) default)
494           ((equal? "so" ext) ##sys#load-dynamic-extension)
495           ((equal? "a" ext) (if *windows-shell* "lib" "a"))
496           (else ext)))))
497
498
499;;; Installation
500
501(define (install-extension id files #!optional (info '()))
502  (when (setup-install-flag)
503    (let* ((files (check-filelist (if (list? files) files (list files))))
504           (rpath (repo-path))
505           (rpathd (repo-path #t))
506           (dests (map (lambda (f)
507                         (let ((from (if (pair? f) (car f) f))
508                               (to (make-dest-pathname rpathd f)) )
509                           (when (and (not *windows*) 
510                                      (equal? "so" (pathname-extension to)))
511                             (run (,*remove-command* ,(shellpath to)) ))
512                           (copy-file from to)
513                           (unless *windows-shell*
514                             (run (,*chmod-command* a+r ,(shellpath to))))
515                           (and-let* ((static (assq 'static info)))
516                             (when (and (eq? (software-version) 'macosx)
517                                        (equal? (cadr static) from) 
518                                        (equal? (pathname-extension to) "a"))
519                               (run (,*ranlib-command* ,(shellpath to)) ) ))
520                           (make-dest-pathname rpath f)))
521                       files) ) 
522           (pre (installation-prefix))
523           (docpath (if pre
524                        (ensure-directory (make-pathname pre "share/chicken/doc"))
525                        *doc-path*)))
526      (and-let* ((docs (assq 'documentation info)))
527        (print "\n* Installing documentation files in " docpath ":")
528        (for-each
529         (lambda (f)
530           (copy-file f (make-pathname docpath f) #f) )
531         (cdr docs))
532        (newline))
533      (and-let* ((exs (assq 'examples info)))
534        (print "\n* Installing example files in " docpath ":")
535        (for-each
536         (lambda (f)
537           (let ((destf (make-pathname docpath f)))
538             (copy-file f destf #f)
539             (unless *windows-shell*
540               (run (,*chmod-command* a+rx ,destf)) ) ))
541         (cdr exs))
542        (newline))
543      (write-info id dests info) ) ) )
544
545(define (install-program id files #!optional (info '()))
546  (define (exify f)
547    (translate-extension
548     f
549     (if *windows-shell* "exe" #f) ) )
550  (when (setup-install-flag)
551    (let* ((files (check-filelist (if (list? files) files (list files))))
552           (ppath ((lambda (pre)
553                     (if pre 
554                         (ensure-directory (make-pathname pre "bin"))
555                         (program-path)))
556                   (installation-prefix)))
557           (files (if *windows*
558                      (map (lambda (f)
559                             (if (list? f) 
560                                 (list (exify (car f)) (exify (cadr f)))
561                                 (exify f) ) )
562                           files)
563                      files) ) 
564           (dests (map (lambda (f)
565                         (let ((from (if (pair? f) (car f) f))
566                               (to (make-dest-pathname ppath f)) )
567                           (copy-file from to) 
568                           (unless *windows-shell*
569                                   (run (,*chmod-command* a+r ,(shellpath to))))
570                           to) )
571                       files) ) )
572      (write-info id dests info) ) ) )
573
574(define (install-script id files #!optional (info '()))
575  (when (setup-install-flag)
576    (let* ((files (check-filelist (if (list? files) files (list files))))
577           (ppath ((lambda (pre) 
578                     (if pre
579                         (ensure-directory (make-pathname pre "bin"))
580                         (program-path)))
581                   (installation-prefix)))
582           (pfiles (map (lambda (f)
583                          (let ((from (if (pair? f) (car f) f))
584                                (to (make-dest-pathname ppath f)) )
585                            (copy-file from to) 
586                            (unless *windows-shell*
587                                    (run (,*chmod-command* a+r ,(shellpath to))))
588                            to) )
589                        files) ) )
590      (unless *windows-shell*
591        (run (,*chmod-command* a+rx ,(string-intersperse pfiles " "))) )
592      (write-info id pfiles info) ) ) )
593
594
595;;; More helper stuff
596
597(define (repo-path #!optional ddir?)
598  (let ((p (if (and ddir? (installation-prefix))
599               (make-pathname 
600                (installation-prefix) 
601                (sprintf "lib/chicken/~a" (##sys#fudge 42)))
602               (repository-path))) )
603    (ensure-directory p)
604    p) )
605
606(define (ensure-directory path)
607  (and-let* ((dir (pathname-directory path)))
608    (if (file-exists? dir)
609        (unless (directory? dir)
610          (error "cannot create directory: a file with the same name already exists") )
611        (begin
612          (create-directory/parents dir)
613          (unless *windows-shell*
614                  (run (,*chmod-command* a+x ,(shellpath dir)))))))
615  path)
616
617(define (try-compile code #!key c++ (cc (if c++ *cxx* *cc*)) (cflags "") (ldflags "") 
618                     (verb (setup-verbose-flag)) (compile-only #f))
619  (let* ((fname (create-temporary-file "c"))
620         (oname (pathname-replace-extension fname "o"))
621         (r (begin
622              (with-output-to-file fname (cut display code))
623              (system 
624               (let ((cmd (conc
625                           cc " "
626                           (if compile-only "-c" "") " "
627                           cflags " " *target-cflags* " "
628                           fname " "
629                           (if compile-only
630                               "" 
631                               (conc "-L" *target-lib-home* " " ldflags " " *target-libs*) )
632                           " >/dev/null "
633                           (if verb "" "2>&1") ) ) )
634                 (when verb (print cmd " ..."))
635                 cmd) ) ) ) )
636    (when verb (print (if (zero? r) "succeeded." "failed.")))
637    ($system (sprintf "~A ~A" *remove-command* (shellpath fname)))
638    (zero? r) ) )
639
640(define (required-chicken-version v)
641  (when (version>=? v (chicken-version) ) 
642    (error (sprintf "CHICKEN version ~a or higher is required" v)) ) )
643
644(define (upgrade-message ext msg)
645  (error
646   (sprintf
647    "the required extension `~s' ~a - please run~%~%  chicken-install ~a~%~%and repeat the current installation operation."
648    ext msg ext) ) )
649
650(define (required-extension-version . args)
651  (let loop ((args args))
652    (cond ((null? args) #f)
653          ((and (list? args) (>= (length args) 2))
654           (let* ((ext (car args))
655                  (version (cadr args))
656                  (more (cddr args))
657                  (info (extension-information ext)))
658             (if info
659                 (let ((ver (and (assq 'version info) (cadr (assq 'version info)))))
660                   (cond ((not ver) (upgrade-message ext "has no associated version information"))
661                         ((and (version>=? version ver) (not (string=? (->string version) (->string ver))))
662                          (upgrade-message 
663                           ext
664                           (sprintf "is older than ~a, which is what this extension requires"
665                                    version) ) )
666                         (else (loop more)) ) ) 
667                 (upgrade-message ext "is not installed") ) ) )
668          (else
669           (error 'required-extension-information "bad argument format" args)) ) ) )
670
671(define test-compile try-compile)
672
673(define (find-library name proc)
674  (test-compile 
675   (sprintf "#ifdef __cplusplus~%extern \"C\"~%#endif~%char ~a();~%int main() { ~a(); return 0; }~%" proc proc)
676   ldflags: (conc "-l" name) ) )
677
678(define (find-header name)
679  (test-compile
680   (sprintf "#include <~a>\nint main() { return 0; }\n" name)
681   compile-only: #t) )
682
683(define (version>=? v1 v2)
684  (define (version->list v)
685    (map (lambda (x) (or (string->number x) x))
686         (string-split-fields "[-\\._]" (->string v) #:infix)))
687  (let loop ((p1 (version->list v1))
688             (p2 (version->list v2)))
689    (cond ((null? p1) (null? p2))
690          ((null? p2))
691          ((number? (car p1))
692           (and (number? (car p2))
693                (or (> (car p1) (car p2))
694                    (and (= (car p1) (car p2))
695                         (loop (cdr p1) (cdr p2))))))
696          ((number? (car p2)))
697          ((string>? (car p1) (car p2)))
698          (else
699           (and (string=? (car p1) (car p2))
700                (loop (cdr p1) (cdr p2)))))))
701
702(define extension-name-and-version
703  (make-parameter '("" "")
704    (lambda (x)
705      (cond [(or (not x) (null? x))
706             '("" "") ]
707            [(and (list? x) (= 2 (length x)))
708             (let ([nam (car x)]
709                   [ver (cadr x)]
710                   [ensure-string (lambda (x) (if (or (not x) (null? x)) "" (->string x)))])
711               (list (ensure-string nam) (ensure-string ver)) ) ]
712            [else
713             (warning "invalid extension-name-and-version" x)
714             (extension-name-and-version) ] ) ) ) )
715
716(define (extension-name)
717  (car (extension-name-and-version)) )
718
719(define (extension-version #!optional defver)
720  (let ([ver (cadr (extension-name-and-version))])
721    (if (string-null? ver)
722        (and defver (->string defver))
723        ver ) ) )
724
725(define (read-info egg)
726  (with-input-from-file
727      (make-pathname (repository-path) egg ".setup-info")
728    read))
729
730(define (create-temporary-directory)
731  (let ((dir (or (getenv "TMPDIR") (getenv "TEMP") (getenv "TMP") "/tmp")))
732    (let loop ()
733      (let* ((n (##sys#fudge 16))       ; current milliseconds
734             (pn (make-pathname dir (string-append "chicken-install-" (number->string n 16)) "tmp")))
735        (cond ((file-exists? pn) (loop))
736              (else (create-directory pn) pn))))))
737
738(define (remove-directory dir #!optional (strict #t))
739  (cond ((not (file-exists? dir))
740         (if strict
741             (error 'remove-directory "cannot remove - directory not found" dir)
742             #f))
743        (*sudo*
744         ($system (sprintf "sudo rm -fr ~a" (shellpath dir))))
745        (else
746         (let walk ((dir dir))
747           (let ((files (directory dir #t)))
748             (for-each
749              (lambda (f)
750                (unless (or (string=? "." f) (string=? ".." f))
751                  (let ((p (make-pathname dir f)))
752                    (if (directory? p)
753                        (walk p) 
754                        (delete-file p)))))
755              files)
756             (delete-directory dir)))) ))
757
758(define (remove-extension egg)
759  (and-let* ((files (assq 'files (read-info egg))))
760    (for-each remove-file* (cdr files)))
761  (remove-file* (make-pathname (repository-path) egg "setup-info")))
762
763(define ($system str)
764  (let ((r (system
765            (if *windows-shell*
766                (string-append "\"" str "\"")   ; double quotes, yes - thanks to Matthew Flatt
767                str))))
768    (unless (zero? r)
769      (error "shell command failed with nonzero exit status" r str))))
770
771)
Note: See TracBrowser for help on using the repository browser.