source: project/chicken/branches/scrutiny/scrutinizer.scm @ 14805

Last change on this file since 14805 was 14805, checked in by felix winkelmann, 10 years ago

fixes

File size: 23.4 KB
Line 
1;;;; scrutinizer.scm - The CHICKEN Scheme compiler (local flow analysis)
2;
3; Copyright (c) 2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(declare (unit scrutinizer))
28
29(private compiler
30  compiler-arguments process-command-line perform-lambda-lifting!
31  default-standard-bindings default-extended-bindings
32  foldable-bindings llist-length
33  installation-home decompose-lambda-list external-to-pointer
34  copy-node! variable-visible? mark-variable intrinsic?
35  unit-name insert-timer-checks used-units external-variables hide-variable
36  debug-info-index debug-info-vector-name profile-info-vector-name
37  foreign-declarations emit-trace-info block-compilation line-number-database-size
38  make-block-variable-literal block-variable-literal? block-variable-literal-name
39  target-heap-size target-stack-size constant-declarations variable-mark
40  default-default-target-heap-size default-default-target-stack-size verbose-mode original-program-size
41  current-program-size line-number-database-2 foreign-lambda-stubs immutable-constants foreign-variables
42  rest-parameters-promoted-to-vector inline-table inline-table-used constant-table constants-used
43  broken-constant-nodes inline-substitutions-enabled loop-lambda-names expand-profile-lambda
44  profile-lambda-list profile-lambda-index emit-profile expand-profile-lambda
45  direct-call-ids foreign-type-table first-analysis expand-debug-lambda expand-debug-assignment expand-debug-call
46  initialize-compiler canonicalize-expression expand-foreign-lambda update-line-number-database! scan-toplevel-assignments
47  perform-cps-conversion analyze-expression simplifications perform-high-level-optimizations perform-pre-optimization!
48  reorganize-recursive-bindings substitution-table simplify-named-call compiler-warning real-name
49  perform-closure-conversion prepare-for-code-generation compiler-source-file create-foreign-stub expand-foreign-lambda*
50  transform-direct-lambdas! expand-foreign-callback-lambda* debug-lambda-list debug-variable-list debugging
51  debugging-chicken bomb check-signature posq stringify symbolify build-lambda-list
52  string->c-identifier c-ify-string words check-and-open-input-file close-checked-input-file fold-inner constant?
53  collapsable-literal? immediate? canonicalize-begin-body extract-mutable-constants string->expr get get-all
54  put! collect! count! get-line get-line-2 find-lambda-container display-analysis-database varnode qnode 
55  build-node-graph build-expression-tree fold-boolean inline-lambda-bindings match-node expression-has-side-effects?
56  simple-lambda-node? compute-database-statistics print-program-statistics output gen gen-list 
57  pprint-expressions-to-file foreign-type-check estimate-foreign-result-size scan-used-variables scan-free-variables
58  topological-sort print-version print-usage initialize-analysis-database
59  expand-foreign-callback-lambda default-optimization-passes default-optimization-passes-when-trying-harder
60  units-used-by-default words-per-flonum rewrite inline-locally
61  parameter-limit eq-inline-operator optimizable-rest-argument-operators
62  membership-test-operators membership-unfold-limit valid-compiler-options valid-compiler-options-with-argument
63  make-random-name final-foreign-type inline-max-size simplified-ops
64  generate-code make-variable-list make-argument-list generate-foreign-stubs foreign-type-declaration
65  foreign-argument-conversion foreign-result-conversion foreign-type-convert-argument foreign-type-convert-result
66  scrutinize load-type-database source-info->line)
67
68
69(include "tweaks")
70
71
72(define (d fstr . args)
73  (when (##sys#fudge 13)
74    (printf "[debug] ~?~%" fstr args)) )
75
76;XXX (define-syntax d (syntax-rules () ((_ . _) (void))))
77
78
79;;; Walk node tree, keeping type and binding information
80;
81; result specifiers:
82;
83;   SPEC = * | (VAL1 ...)
84;   VAL = (or VAL1 ...)
85;       | (struct NAME)
86;       | (procedure (VAL1 ... [#!optional VALOPT1 ...] [#!rest [VAL | values]]) . RESULTS)
87;       | BASIC
88;       | deprecated
89;   BASIC = * | string | symbol | char | number | boolean | list | pair |
90;           procedure | vector | null | eof | undefined | port |
91;           blob | noreturn | pointer | locative | fixnum | float
92;   RESULTS = *
93;           | (VAL1 ...)
94
95; global symbol properties:
96;
97;   ##core#type           ->  <typespec>
98;   ##core#declared-type  ->  <bool>
99
100(define-constant +fragment-max-length+ 5)
101(define-constant +fragment-max-depth+ 3)
102
103(define (scrutinize node db)
104  (define (constant-result lit)
105    (cond ((string? lit) 'string)
106          ((symbol? lit) 'symbol)
107          ((fixnum? lit) 'fixnum)
108          ((flonum? lit) 'float)
109          ((number? lit) 'number)       ; in case...
110          ((boolean? lit) 'boolean)
111          ((list? lit) 'list)
112          ((pair? lit) 'pair)
113          ((eof-object? lit) 'eof)
114          ((vector? lit) 'vector)
115          ((and (not (##sys#immediate? lit)) ##sys#generic-structure? lit)
116           `(struct ,(##sys#slot lit 0)))
117          ((null? lit) 'null)
118          ((char? lit) 'char)
119          (else '*)))
120  (define (global-result id loc)
121    (cond ((##sys#get id '##core#type) =>
122           (lambda (a) 
123             (cond #;((and (get db id 'assigned)
124                         (not (##sys#get id '##core#declared-type)))
125                    (##sys#put! id '##core#type #f)
126                    '*)
127                   ((eq? a 'deprecated)
128                    (report1 
129                     loc
130                     (sprintf "use of deprecated toplevel identifier `~a'" id) )
131                    '*)
132                   (else (list a)))))
133          (else '*)))
134  (define (variable-result id e loc)
135    (cond ((and (get db id 'assigned) 
136                (not (##sys#get id '##core#declared-type)) )
137           '*)
138          ((assq id e) =>
139           (lambda (a)
140             (cond ((eq? 'undefined (cdr a))
141                    (report1 
142                     loc
143                     (sprintf "access to variable `~a' which has an undefined value"
144                              (real-name id db)))
145                    '*)
146                   (else (list (cdr a))))))
147          (else (global-result id loc))))
148  (define (always-true1 t)
149    (cond ((and (pair? t) (eq? 'or (car t)))
150           (every always-true1 (cdr t)))
151          ((memq t '(* boolean undefined noreturn)) #f)
152          (else #t)))
153  (define (always-true t loc x)
154    (let ((f (always-true1 t)))
155      (when f
156        (report 
157         loc "of type boolean" 
158         (sprintf 
159          "a result that is of type `~a' and thus always true"
160          t)
161         "value"
162         (sprintf "in conditional:~%~%~a~%," (pp-fragment x))))
163      f))
164  (define (typename t)
165    (case t
166      ((*) "anything")
167      ((char) "character")
168      (else
169       (cond ((symbol? t) (symbol->string t))
170             ((pair? t)
171              (case (car t)
172                ((procedure) 
173                 (if (or (string? (cadr t)) (symbol? (cadr t)))
174                     (->string (cadr t))
175                     (sprintf "a procedure with ~a returning ~a"
176                              (argument-string (cadr t))
177                              (result-string (cddr t)))))
178                ((or)
179                 (string-intersperse
180                  (map typename (cdr t))
181                  " OR "))
182                ((struct)
183                 (sprintf "a structure of type ~a" (cadr t)))
184                (else (bomb "invalid type: ~a" t))))
185             (else (bomb "invalid type: ~a" t))))))
186  (define (argument-string args)
187    (let ((len (length args))
188          (m (multiples len)))
189      (if (zero? len)
190          "zero arguments"
191          (sprintf 
192           "~a argument~a of type~a ~a"
193           len m m
194           (map typename args)))))
195  (define (result-string results)
196    (if (eq? '* results) 
197        "an unknown number of values"
198        (let ((len (length results))
199              (m (multiples len)))
200          (if (zero? len)
201              "zero values"
202              (sprintf 
203               "~a value~a of type~a ~a"
204               len m m
205               (map typename results))))))
206  (define (simplify t)
207    (let ((t2 (simplify1 t)))
208      (d "simplify: ~a -> ~a" t t2)
209      t2))
210  (define (simplify1 t)
211    (call/cc
212     (lambda (return)
213       (if (pair? t)
214           (case (car t)
215             ((or)
216              (cond ((= 2 (length t)) (simplify (second t)))
217                    ((every procedure-type? (cdr t))
218                     (if (any (cut eq? 'procedure <>) (cdr t))
219                         'procedure
220                         (reduce
221                          (lambda (t pt)
222                            (let* ((name1 (and (named? t) (cadr t)))
223                                   (atypes1 (if name1 (third t) (second t)))
224                                   (rtypes1 (if name1 (cdddr t) (cddr t)))
225                                   (name2 (and (named? pt) (cadr pt)))
226                                   (atypes2 (if name2 (third pt) (second pt)))
227                                   (rtypes2 (if name2 (cdddr pt) (cddr pt))))
228                              (append
229                               '(procedure)
230                               (if (and name1 name2 (eq? name1 name2)) (list name1) '())
231                               (list (merge-argument-types atypes1 atypes2))
232                               (merge-result-types rtypes1 rtypes2))))
233                          #f
234                          (cdr t))))
235                    (else
236                     (let* ((ts (append-map
237                                 (lambda (t)
238                                   (let ((t (simplify t)))
239                                     (cond ((and (pair? t) (eq? 'or (car t)))
240                                            (cdr t))
241                                           ((eq? 'noreturn t) '())
242                                           ((eq? t 'undefined) (return 'undefined))
243                                           (else (list t)))))
244                                 (cdr t)))
245                            (ts2 (let loop ((ts ts) (done '()))
246                                   (cond ((null? ts) (reverse done))
247                                         ((eq? '* (car ts)) (return '*))
248                                         ((any (cut type<=? (car ts) <>) (cdr ts))
249                                          (loop (cdr ts) done))
250                                         ((any (cut type<=? (car ts) <>) done)
251                                          (loop (cdr ts) done))
252                                         (else (loop (cdr ts) (cons (car ts) done)))))))
253                       (cond ((equal? ts2 (cdr t)) t)
254                             (else
255                              (d "  or-simplify: ~a" ts2)
256                              (simplify `(or ,@(if (any (cut eq? <> '*) ts2) '(*) ts2)))))))) )
257             ((procedure)
258              (let* ((name (and (named? t) (cadr t)))
259                     (rtypes (if name (cdddr t) (cddr t))))
260                (append
261                 '(procedure)
262                 (if name (list name) '())
263                 (list (map simplify (if name (third t) (second t))))
264                 (if (eq? '* rtypes)
265                     '*
266                     (map simplify rtypes)))))
267             (else t))
268           t))))
269  (define (named? t)
270    (and (pair? t) 
271         (eq? 'procedure (car t))
272         (not (or (null? (cadr t)) (pair? (cadr t))))))
273  (define (rest-type r)
274    (cond ((null? r) '*)
275          ((eq? 'values (car r)) '*)
276          (else (car r))))
277  (define (merge-argument-types ts1 ts2) 
278    (cond ((null? ts1) 
279           (cond ((null? ts2) '())
280                 ((memq (car ts2) '(#!rest #!optional)) ts2)
281                 (else '(#!rest))))
282          ((eq? '#!rest (car ts1))
283           (cond ((eq? '#!rest (car ts2))
284                  `(#!rest
285                    ,(simplify 
286                      `(or ,(rest-type (cdr ts1))
287                           ,(rest-type (cdr ts2))))))
288                 (else '(#!rest))))             ;XXX giving up
289          ((eq? '#!optional (car ts1))
290           (cond ((eq? '#!optional (car ts2))
291                  `(#!optional 
292                    ,(simplify `(or ,(cadr ts1) ,(cadr ts2)))
293                    ,@(merge-argument-types (cddr ts1) (cddr ts2))))
294                 (else '(#!rest))))     ;XXX
295          (else (cons (simplify `(or ,(car ts1) ,(car ts2)))
296                      (merge-argument-types (cdr ts1) (cdr ts2))))))
297  (define (merge-result-types ts1 ts2)  ;XXX possibly overly conservative
298    (cond ((null? ts1) ts2)
299          ((null? ts2) ts1)
300          ((or (atom? ts1) (atom? ts2)) '*)
301          (else (cons (simplify `(or ,(car ts1) ,(car ts2)))
302                      (merge-result-types (cdr ts1) (cdr ts2))))))
303  (define (match t1 t2)
304    (let ((m (match1 t1 t2)))
305      (d "match ~a <-> ~a -> ~a" t1 t2 m)
306      m))
307  (define (match1 t1 t2)
308    (cond ((eq? t1 t2))
309          ((eq? t1 '*))
310          ((eq? t2 '*))
311          ((eq? t1 'noreturn))
312          ((eq? t2 'noreturn))
313          ((and (eq? t1 'number) (memq t2 '(number fixnum float))))
314          ((and (eq? t2 'number) (memq t1 '(number fixnum float))))
315          ((eq? 'procedure t1) (and (pair? t2) (eq? 'procedure (car t2))))
316          ((eq? 'procedure t2) (and (pair? t1) (eq? 'procedure (car t1))))
317          ((and (pair? t1) (eq? 'or (car t1))) (any (cut match <> t2) (cdr t1)))
318          ((and (pair? t2) (eq? 'or (car t2))) (any (cut match t1 <>) (cdr t2)))
319          ((memq t1 '(pair list)) (memq t2 '(pair list)))
320          ((memq t1 '(null list)) (memq t2 '(null list)))
321          ((and (pair? t1) (pair? t2) (eq? (car t1) (car t2)))
322           (case (car t1)
323             ((procedure)
324              (let ((args1 (if (named? t1) (third t1) (second t1)))
325                    (args2 (if (named? t2) (third t2) (second t2))) 
326                    (results1 (if (named? t1) (cdddr t1) (cddr t1))) 
327                    (results2 (if (named? t2) (cdddr t2) (cddr t2))) )
328                (and (match-args args1 args2)
329                     (match-results results1 results2))))
330             ((struct) (equal? t1 t2))
331             (else #f) ) )
332          (else #f)))
333  (define (match-args args1 args2)
334    (d "match-args: ~s <-> ~s" args1 args2)
335    (define (match-rest rtype args opt) ;XXX currently ignores `opt'
336      (let-values (((head tail) (break (cut eq? '#!rest <>) args)))
337        (and (every (cut match rtype <>) head) ; match required args
338             (match rtype (if (pair? tail) (rest-type (cdr tail)) '*)))))
339    (define (optargs a)
340      (memq a '(#!rest #!optional)))
341    (let loop ((args1 args1) (args2 args2) (opt1 #f) (opt2 #f))
342      (d "  args ~a ~a ~a ~a" args1 args2 opt1 opt2)
343      (cond ((null? args1) 
344             (or opt2
345                 (null? args2)
346                 (optargs (car args2))))
347            ((null? args2) 
348             (or opt1
349                 (optargs (car args1))))
350            ((eq? '#!optional (car args1))
351             (loop (cdr args1) args2 #t opt2))
352            ((eq? '#!optional (car args2))
353             (loop args1 (cdr args2) opt1 #t))
354            ((eq? '#!rest (car args1))
355             (match-rest (rest-type (cdr args1)) args2 opt2))
356            ((eq? '#!rest (car args2))
357             (match-rest (rest-type (cdr args2)) args1 opt1))
358            ((match (car args1) (car args2)) (loop (cdr args1) (cdr args2) opt1 opt2))
359            (else #f))))
360  (define (match-results results1 results2)
361    (cond ((null? results1) (atom? results2))
362          ((eq? '* results1))
363          ((eq? '* results2))
364          ((eq? '* results2))
365          ((eq? '* results2))
366          ((null? results2) #f)
367          ((match (car results1) (car results2)) 
368           (match-results (cdr results1) (cdr results2)))
369          (else #f)))
370  (define (type<=? t1 t2)
371    (or (eq? t1 t2)
372        (memq t2 '(* undefined))
373        (case t2
374          ((list) (memq t1 '(null pair)))
375          ((procedure) (and (pair? t1) (eq? 'procedure (car t1))))
376          ((number) (memq t1 '(fixnum float)))
377          (else
378           (and (pair? t1) (pair? t2)
379                (case (car t1)
380                  ((or) (every (cut type<=? <> t2) (cdr t1)))
381                  ((procedure)
382                   (let ((args1 (if (pair? (cadr t1)) (cadr t1) (caddr t1)))
383                         (args2 (if (pair? (cadr t2)) (cadr t2) (caddr t2)))
384                         (res1 (if (pair? (cadr t1)) (cddr t1) (cdddr t1)))
385                         (res2 (if (pair? (cadr t2)) (cddr t2) (cdddr t2))) )
386                     (let loop1 ((args1 args1)
387                                 (args2 args2)
388                                 (m1 0) 
389                                 (m2 0))
390                       (cond ((null? args1) 
391                              (and (or (null? args2) (> m2 0))
392                                   (let loop2 ((res1 res1) (res2 res2))
393                                     (cond ((eq? '* res2) #t)
394                                           ((null? res2) (null? res1))
395                                           ((eq? '* res1) #f)
396                                           ((type<=? (car res1) (car res2))
397                                            (loop2 (cdr res1) (cdr res2)))
398                                           (else #f)))))
399                             ((null? args2) #f)
400                             ((eq? (car args1) '#!optional)
401                              (loop1 (cdr args1) args2 1 m2))
402                             ((eq? (car args2) '#!optional)
403                              (loop1 args1 (cdr args2) m1 1))
404                             ((eq? (car args1) '#!rest)
405                              (loop1 (cdr args1) args2 2 m2))
406                             ((eq? (car args2) '#!rest)
407                              (loop1 args1 (cdr args2) m1 2))
408                             ((type<=? (car args1) (car args2)) 
409                              (loop1 (cdr args1) (cdr args2) m1 m2))
410                             (else #f)))))))))))
411  (define (check expected given loc what #!optional desc) 
412    (d "check: ~a <-> ~a (~a)" expected given loc)
413    (if (match expected given)
414        given
415        (report loc expected given what desc)))
416  (define (multiples n)
417    (if (= n 1) "" "s"))
418  (define (single what tv loc)
419    (if (eq? '* tv)
420        '*
421        (let ((n (length tv)))
422          (cond ((= 1 n) (car tv))
423                ((zero? n)
424                 (report loc "a single result" "zero results" what)
425                 'undefined)
426                (else
427                 (report loc "a single result" (sprintf "~a result~a" n (multiples n)) what)
428                 (first tv))))))
429  (define (report1 loc desc)
430    (compiler-warning
431     'scrutiny
432     "~a~a" 
433     (location-name loc) desc))
434  (define (report loc expected given what #!optional desc)
435    (report1 
436     loc 
437     (sprintf 
438      "~a~a~a~a"
439      (or desc "")
440      (if desc " " "")
441      (if expected
442          (sprintf "expected ~a~a~a" (or what "") (if what " " "") expected)
443          "")
444      (sprintf ", but where given ~a" given))))
445  (define (location-name loc)
446    (define (lname loc1)
447      (if loc1
448          (sprintf "procedure `~a'" (real-name loc1))
449          "unknown procedure"))
450    (cond ((null? loc) "at toplevel:\n  ")
451          ((null? (cdr loc))
452           (sprintf "in toplevel ~a:\n  " (lname (car loc))))
453          (else
454           (let rec ((loc loc))
455             (if (null? (cdr loc))
456                 (location-name loc)
457                 (sprintf "in local ~a,\n  ~a" (lname (car loc)) (rec (cdr loc))))))))
458  (define add-loc cons)
459  (define (fragment x)
460    (let ((x (build-expression-tree x)))
461      (let walk ((x x) (d 0))
462        (cond ((atom? x) x)
463              ((>= d +fragment-max-depth+) '...)
464              ((list? x)
465               (map (cute walk <> (add1 d)) (take x (min +fragment-max-length+ (length x)))))
466              (else x)))))
467  (define (pp-fragment x)
468    (with-output-to-string
469      (lambda ()
470        (pp (fragment x)))))
471  (define (call-result args e loc x params)
472    (define (pname)
473      (sprintf 
474       "in procedure call to `~s'~a" 
475       (fragment x)
476       (if (and (pair? params) (pair? (cdr params)))
477           (sprintf " (line ~a)" (source-info->line (cadr params)))
478           "")))
479    (d "call-result: ~a (~a)" args loc)
480    (let ((ptype (car args))
481          (nargs (length (cdr args))))
482      (unless (procedure-type? ptype)
483        (check 
484         `(procedure ,(make-list nargs '*) *)
485         ptype
486         loc "a procedure of type" (pname)))
487      (let-values (((atypes values-rest) (procedure-argument-types ptype (length (cdr args)))))
488        (d "  argument-types: ~a (~a)" atypes values-rest)
489        (unless (= (length atypes) nargs)
490          (let ((alen (length atypes)))
491            (report 
492             loc
493             (sprintf "~a argument~a" alen (multiples alen))
494             (sprintf "~a argument~a" nargs (multiples nargs))
495             (pname))))
496        (do ((args (cdr args) (cdr args))
497             (atypes atypes (cdr atypes))
498             (i 1 (add1 i)))
499            ((or (null? args) (null? atypes)))
500          (check (car atypes) (car args) loc (sprintf "argument #~a of type" i) (pname)))
501        (let ((r (procedure-result-types ptype values-rest (cdr args))))
502          (d  "  result-types: ~a" r)
503          r))))
504  (define (procedure-type? t)
505    (or (eq? 'procedure t)
506        (and (pair? t) 
507             (or (eq? 'procedure (car t))
508                 (and (eq? 'or (car t))
509                      (every procedure-type? (cdr t)))))))
510  (define (procedure-argument-types t n)
511    (cond ((or (memq t '(* procedure)) 
512               (not-pair? t) )
513           (values (make-list n '*) #f))
514          ((eq? 'procedure (car t))
515           (let* ((vf #f)
516                  (llist
517                   (let loop ((at (if (or (string? (second t)) (symbol? (second t)))
518                                      (third t)
519                                      (second t)))
520                              (m n)
521                              (opt #f))
522                     (cond ((null? at) '())
523                           ((eq? '#!optional (car at)) 
524                            (loop (cdr at) m #t) )
525                           ((eq? '#!rest (car at))
526                            (set! vf (and (pair? (cdr at)) (eq? 'values (cadr at))))
527                            (make-list m (rest-type (cdr at))))
528                           ((and opt (<= m 0)) '())
529                           (else (cons (car at) (loop (cdr at) (sub1 m) opt)))))))
530             (values llist vf)))
531          (else (bomb "not a procedure type" t))))
532  (define (procedure-result-types t values-rest? args)
533    (cond (values-rest? args)
534          ((or (memq t '(* procedure))
535               (not-pair? t) )
536           '*)
537          ((eq? 'procedure (car t))
538           (call/cc
539            (lambda (return)
540              (let loop ((rt (if (or (string? (second t)) (symbol? (second t)))
541                                 (cdddr t)
542                                 (cddr t))))
543                (cond ((null? rt) '())
544                      ((eq? '* rt) (return '*))
545                      (else (cons (car rt) (loop (cdr rt)))))))))
546          (else (bomb "not a procedure type: ~a" t))))
547  (define (walk n e loc dest)           ; returns result specifier
548    (let ((subs (node-subexpressions n))
549          (params (node-parameters n)) 
550          (class (node-class n)) )
551      (d "walk: ~a ~a (loc: ~a, dest: ~a)" class params loc dest)
552      (let ((results
553             (case class
554               ((quote) (list (constant-result (first params))))
555               ((##core#undefined) '(*))
556               ((##core#proc) '(procedure))
557               ((##core#global-ref) (global-result (first params) loc))
558               ((##core#variable) (variable-result (first params) e loc))
559               ((if) (let ((rt (single "in conditional" (walk (first subs) e loc dest) loc)))
560                       (always-true rt loc n)
561                       (let ((r1 (walk (second subs) e loc dest))
562                             (r2 (walk (third subs) e loc dest)))
563                         (cond ((and (not (eq? r1 '*)) (not (eq? '* r2)))
564                                (when (not (= (length r1) (length r2)))
565                                  (report1 
566                                   loc
567                                   (sprintf
568                                    "branches in conditional expression differ in the number of results:~%~%~a"
569                                    (pp-fragment n))))
570                                (map (lambda (t1 t2) (simplify `(or ,t1 ,t2)))
571                                     r1 r2))
572                               (else '*)))))
573               ((let)
574                (let loop ((vars params) (body subs) (e2 '()))
575                  (if (null? vars)
576                      (walk (car body) (append e2 e) loc dest)
577                      (let ((t (single "in `let' binding" (walk (car body) e loc (car vars)) loc)))
578                        (loop (cdr vars) (cdr body) (alist-cons (car vars) t e2))))))
579               ((##core#lambda lambda)
580                (decompose-lambda-list
581                 (first params)
582                 (lambda (vars argc rest)
583                   (let* ((name (if dest (list dest) '()))
584                          (args (append (make-list argc '*) (if rest '(#!rest) '()))) 
585                          (e2 (append (map (lambda (v) (cons v '*)) 
586                                           (if rest (butlast vars) vars))
587                                      e))
588                          (r (walk (first subs)
589                                   (if rest (alist-cons rest 'list e2) e2)
590                                   (add-loc dest loc)
591                                   #f)))
592                     (list
593                      (append
594                       '(procedure) 
595                       name
596                       (list args)
597                       r))))))
598               ((set! ##core#set!)
599                (let* ((var (first params))
600                       (type (##sys#get var '##core#type))
601                       (rt (single 
602                            (sprintf "in assignment to `~a'" var)
603                            (walk (first subs) e loc var)
604                            loc))
605                       (b (assq var e)) )
606                  (when (and type (not b)
607                             (not (match type rt)))
608                    (report1
609                     loc
610                     (sprintf 
611                      "assignment of value of type `~a' to toplevel variable `~a' does not match declared type `~a'"
612                      rt var type)))
613                  (when (and b (eq? 'undefined (cdr b)))
614                    (set-cdr! b rt))
615                  '(undefined)))
616               ((##core#primitive ##core#inline_ref) '*)
617               ((##core#call)
618                (let ((args (map (lambda (n)
619                                   (single 
620                                    "in procedure call argument"
621                                    (walk n e loc #f) loc))
622                                 subs)))
623                  (call-result args e loc (first subs) params)))
624               ((##core#switch ##core#cond)
625                (bomb "unexpected node class: ~a" class))
626               (else
627                (for-each (lambda (n) (walk n e loc #f)) subs)
628                '*))))
629        (d "  -> ~a" results)
630        results)))
631  (walk (first (node-subexpressions node)) '() '() #f))
632
633(define (load-type-database name #!optional (path (repository-path)))
634  (and-let* ((dbfile (file-exists? (make-pathname path name))))
635    (when verbose-mode
636      (printf "loading type database ~a ...~%" dbfile))
637    (for-each
638     (lambda (e)
639       (let* ((name (car e))
640              (old (##sys#get name '##core#type))
641              (new (cadr e)))
642         (when (and old (not (equal? old new)))
643           (compiler-warning 
644            'scrutiny
645            "type-definition `~a' for toplevel binding `~a' conflicts with previously loaded type `~a'"
646            name new old))
647         (##sys#put! name '##core#type new)))
648     (read-file dbfile))))
649
650(define (source-info->line info)
651  (if (list? info)
652      (cadr info)
653      (and info (->string info))) )
Note: See TracBrowser for help on using the repository browser.