source: project/chicken/branches/scrutiny/scrutinizer.scm @ 14525

Last change on this file since 14525 was 14525, checked in by felix winkelmann, 11 years ago

scrutinizer found first bug in eval.scm\!

File size: 20.3 KB
Line 
1;;;; scrutinizer.scm - The CHICKEN Scheme compiler (local flow analysis)
2;
3; Copyright (c) 2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(declare (unit scrutinizer))
28
29(private compiler
30  compiler-arguments process-command-line perform-lambda-lifting!
31  default-standard-bindings default-extended-bindings
32  foldable-bindings llist-length
33  installation-home decompose-lambda-list external-to-pointer
34  copy-node! variable-visible? mark-variable intrinsic?
35  unit-name insert-timer-checks used-units external-variables hide-variable
36  debug-info-index debug-info-vector-name profile-info-vector-name
37  foreign-declarations emit-trace-info block-compilation line-number-database-size
38  make-block-variable-literal block-variable-literal? block-variable-literal-name
39  target-heap-size target-stack-size constant-declarations variable-mark
40  default-default-target-heap-size default-default-target-stack-size verbose-mode original-program-size
41  current-program-size line-number-database-2 foreign-lambda-stubs immutable-constants foreign-variables
42  rest-parameters-promoted-to-vector inline-table inline-table-used constant-table constants-used
43  broken-constant-nodes inline-substitutions-enabled loop-lambda-names expand-profile-lambda
44  profile-lambda-list profile-lambda-index emit-profile expand-profile-lambda
45  direct-call-ids foreign-type-table first-analysis expand-debug-lambda expand-debug-assignment expand-debug-call
46  initialize-compiler canonicalize-expression expand-foreign-lambda update-line-number-database! scan-toplevel-assignments
47  perform-cps-conversion analyze-expression simplifications perform-high-level-optimizations perform-pre-optimization!
48  reorganize-recursive-bindings substitution-table simplify-named-call compiler-warning real-name
49  perform-closure-conversion prepare-for-code-generation compiler-source-file create-foreign-stub expand-foreign-lambda*
50  transform-direct-lambdas! expand-foreign-callback-lambda* debug-lambda-list debug-variable-list debugging
51  debugging-chicken bomb check-signature posq stringify symbolify build-lambda-list
52  string->c-identifier c-ify-string words check-and-open-input-file close-checked-input-file fold-inner constant?
53  collapsable-literal? immediate? canonicalize-begin-body extract-mutable-constants string->expr get get-all
54  put! collect! count! get-line get-line-2 find-lambda-container display-analysis-database varnode qnode 
55  build-node-graph build-expression-tree fold-boolean inline-lambda-bindings match-node expression-has-side-effects?
56  simple-lambda-node? compute-database-statistics print-program-statistics output gen gen-list 
57  pprint-expressions-to-file foreign-type-check estimate-foreign-result-size scan-used-variables scan-free-variables
58  topological-sort print-version print-usage initialize-analysis-database
59  expand-foreign-callback-lambda default-optimization-passes default-optimization-passes-when-trying-harder
60  units-used-by-default words-per-flonum rewrite inline-locally
61  parameter-limit eq-inline-operator optimizable-rest-argument-operators
62  membership-test-operators membership-unfold-limit valid-compiler-options valid-compiler-options-with-argument
63  make-random-name final-foreign-type inline-max-size simplified-ops
64  generate-code make-variable-list make-argument-list generate-foreign-stubs foreign-type-declaration
65  foreign-argument-conversion foreign-result-conversion foreign-type-convert-argument foreign-type-convert-result
66  scrutinize load-type-database source-info->line)
67
68
69(include "tweaks")
70
71
72(define (d fstr . args)
73  (printf "[debug] ~?~%" fstr args))
74
75;(define-syntax d (syntax-rules () ((_ . _) (void))))
76
77
78;;; Walk node tree, keeping type and binding information
79;
80; result specifiers:
81;
82;   SPEC = * | (VAL1 ...)
83;   VAL = (or VAL1 ...)
84;       | (struct NAME)
85;       | (procedure (VAL1 ... [#!optional VALOPT1 ...] [#!rest [VAL]]) . RESULTS)
86;       | BASIC
87;       | deprecated
88;   BASIC = * | string | symbol | char | number | boolean | list | pair |
89;           procedure | vector | null | eof | undefined | port |
90;           blob | noreturn
91;   RESULTS = *
92;           | (VAL1 ...)
93
94; global symbol properties:
95;
96;   ##core#type           ->  <typespec>
97;   ##core#declared-type  ->  <bool>
98
99(define-constant +fragment-max-length+ 5)
100
101(define (scrutinize node db)
102  (define (constant-result lit)
103    (cond ((string? lit) 'string)
104          ((symbol? lit) 'symbol)
105          ((number? lit) 'number)
106          ((boolean? lit) 'boolean)
107          ((list? lit) 'list)
108          ((pair? lit) 'pair)
109          ((eof-object? lit) 'eof)
110          ((vector? lit) 'vector)
111          ((and (not (##sys#immediate? lit)) ##sys#generic-structure? lit)
112           `(struct ,(##sys#slot lit 0)))
113          ((null? lit) 'null)
114          ((char? lit) 'char)
115          (else '*)))
116  (define (global-result id loc)
117    (cond ((##sys#get id '##core#type) =>
118           (lambda (a) 
119             (cond ((and (get db id 'assigned)
120                         (not (##sys#get id '##core#declared-type)))
121                    (##sys#put! id '##core#type #f)
122                    '*)
123                   ((eq? a 'deprecated)
124                    (report1 
125                     loc
126                     (sprintf "use of deprecated toplevel identifier `~a'" id) )
127                    '*)
128                   (else (list a)))))
129          (else '*)))
130  (define (variable-result id e loc)
131    (cond ((and (get db id 'assigned) 
132                (not (##sys#get id '##core#declared-type)) )
133           '*)
134          ((assq id e) =>
135           (lambda (a)
136             (cond ((eq? 'undefined (cdr a))
137                    (pp (list a loc) (current-error-port))
138                    (report1 
139                     loc
140                     (sprintf "access to variable `~a' which has an undefined value"
141                              (real-name id db)))
142                    '*)
143                   (else (list (cdr a))))))
144          (else (global-result id loc))))
145  (define (always-true1 t)
146    (cond ((and (pair? t) (eq? 'or (car t)))
147           (every always-true1 (cdr t)))
148          ((memq t '(* boolean undefined noreturn)) #f)
149          (else #t)))
150  (define (always-true t loc x)
151    (let ((f (always-true1 t)))
152      (when f
153        (report 
154         loc "of type boolean" 
155         (sprintf 
156          "a result that is of type `~a' and thus always true"
157          t)
158         "value"
159         (sprintf "in conditional `~s'," (fragment x))))
160      f))
161  (define (typename t)
162    (case t
163      ((*) "anything")
164      ((char) "character")
165      (else
166       (cond ((symbol? t) (symbol->string t))
167             ((pair? t)
168              (case (car t)
169                ((procedure) 
170                 (if (or (string? (cadr t)) (symbol? (cadr t)))
171                     (->string (cadr t))
172                     (sprintf "a procedure with ~a returning ~a"
173                              (argument-string (cadr t))
174                              (result-string (cddr t)))))
175                ((or)
176                 (string-intersperse
177                  (map typename (cdr t))
178                  " OR "))
179                ((struct)
180                 (sprintf "a structure of type ~a" (cadr t)))
181                (else (bomb "invalid type: ~a" t))))
182             (else (bomb "invalid type: ~a" t))))))
183  (define (argument-string args)
184    (let ((len (length args))
185          (m (multiples len)))
186      (if (zero? len)
187          "zero arguments"
188          (sprintf 
189           "~a argument~a of type~a ~a"
190           len m m
191           (map typename args)))))
192  (define (result-string results)
193    (if (eq? '* results) 
194        "an unknown number of values"
195        (let ((len (length results))
196              (m (multiples len)))
197          (if (zero? len)
198              "zero values"
199              (sprintf 
200               "~a value~a of type~a ~a"
201               len m m
202               (map typename results))))))
203  (define (simplify t)
204    (let ((t2 (simplify1 t)))
205      (d "simplify: ~a -> ~a" t t2)
206      t2))
207  (define (simplify1 t)
208    (call/cc
209     (lambda (return)
210       (if (pair? t)
211           (case (car t)
212             ((or)
213              (if (= 2 (length t))
214                  (simplify (second t))
215                  (let* ((ts (append-map
216                              (lambda (t)
217                                (let ((t (simplify t)))
218                                  (cond ((and (pair? t) (eq? 'or (car t)))
219                                         (cdr t))
220                                        ((eq? 'noreturn t) '())
221                                        ((eq? t 'undefined) (return 'undefined))
222                                        (else (list t)))))
223                              (cdr t)))
224                         (ts2 (let loop ((ts ts))
225                                (cond ((null? ts) '())
226                                      ((eq? '* (car ts)) (return '*))
227                                      ((any (cut type<=? (car ts) <>) (cdr ts))
228                                       (loop (cdr ts)))
229                                      (else (cons (car ts) (loop (cdr ts))))))))
230                    (cond ((equal? ts2 (cdr t)) t)
231                          (else
232                           (d "  or-simplify: ~a" ts2)
233                           (simplify `(or ,@(if (any (cut eq? <> '*) ts2) '(*) ts2))))))))
234             ((procedure)
235              (let* ((name (and (named? t) (cadr t)))
236                     (rtypes (if name (cdddr t) (cddr t))))
237                `(procedure 
238                  ,@(if name (list name) '())
239                  ,(map simplify (if name (third t) (second t)))
240                  ,@(if (eq? '* rtypes)
241                        '*
242                        (map simplify rtypes)))))
243             (else t))
244           t))))
245  (define (named? t)
246    (and (pair? t) 
247         (eq? 'procedure (car t))
248         (not (or (null? (cadr t)) (pair? (cadr t))))))
249  (define (match t1 t2)
250    (let ((m (match1 t1 t2)))
251      (d "match ~a <-> ~a -> ~a" t1 t2 m)
252      m))
253  (define (match1 t1 t2)
254    (cond ((eq? t1 t2))
255          ((eq? t1 '*))
256          ((eq? t2 '*))
257          ((eq? t1 'noreturn))
258          ((eq? t2 'noreturn))
259          ((eq? 'procedure t1) (and (pair? t2) (eq? 'procedure (car t2))))
260          ((eq? 'procedure t2) (and (pair? t1) (eq? 'procedure (car t1))))
261          ((and (pair? t1) (eq? 'or (car t1))) (any (cut match <> t2) (cdr t1)))
262          ((and (pair? t2) (eq? 'or (car t2))) (any (cut match t1 <>) (cdr t2)))
263          ((memq t1 '(pair list)) (memq t2 '(pair list)))
264          ((memq t1 '(null list)) (memq t2 '(null list)))
265          ((and (pair? t1) (pair? t2) (eq? (car t1) (car t2)))
266           (case (car t1)
267             ((procedure)
268              (let ((args1 (if (named? t1) (third t1) (second t1)))
269                    (args2 (if (named? t2) (third t2) (second t2))) 
270                    (results1 (if (named? t1) (cdddr t1) (cddr t1))) 
271                    (results2 (if (named? t2) (cdddr t2) (cddr t2))) )
272                (and (match-args args1 args2)
273                     (match-results results1 results2))))
274             ((struct) (equal? t1 t2))))))
275  (define (match-args args1 args2)
276    (d "match-args: ~s <-> ~s" args1 args2)
277    (define (match-rest rtype args opt) ;XXX currently ignores `opt'
278      (let-values (((head tail) (break (cut eq? '#!rest <>) args)))
279        (and (every (cut match rtype <>) head) ; match required args
280             (match
281                 rtype
282               (if (and (pair? tail) (pair? (cdr tail)))
283                   (cadr tail)
284                   '*) ) ) ) )
285    (define (optargs a)
286      (memq a '(#!rest #!optional)))
287    (let loop ((args1 args1) (args2 args2) (opt1 #f) (opt2 #f))
288      (d "  args ~a ~a ~a ~a" args1 args2 opt1 opt2)
289      (cond ((null? args1) 
290             (or opt2
291                 (null? args2)
292                 (optargs (car args2))))
293            ((null? args2) 
294             (or opt1
295                 (optargs (car args1))))
296            ((eq? '#!optional (car args1))
297             (loop (cdr args1) args2 #t opt2))
298            ((eq? '#!optional (car args2))
299             (loop args1 (cdr args2) opt1 #t))
300            ((eq? '#!rest (car args1))
301             (match-rest (if (pair? (cdr args1)) (cadr args1) '*) args2 opt2))
302            ((eq? '#!rest (car args2))
303             (match-rest (if (pair? (cdr args2)) (cadr args2) '*) args1 opt1))
304            ((match (car args1) (car args2)) (loop (cdr args1) (cdr args2) opt1 opt2))
305            (else #f))))
306  (define (match-results results1 results2)
307    (cond ((null? results1) (atom? results2))
308          ((atom? results2))
309          ((match (car results1) (car results2)) 
310           (match-results (cdr results1) (cdr results2)))
311          (else #f)))
312  (define (type<=? t1 t2)
313    (or (eq? t1 t2)
314        (memq t2 '(* undefined))
315        (case t2
316          ((list) (memq t1 '(null pair)))
317          ((procedure) (and (pair? t1) (eq? 'procedure (car t1))))
318          (else
319           (and (pair? t1) (pair? t2)
320                (case (car t1)
321                  ((or) (every (cut type<=? <> t2) (cdr t1)))
322                  ((procedure)
323                   (let ((args1 (if (pair? (cadr t1)) (cadr t1) (caddr t1)))
324                         (args2 (if (pair? (cadr t2)) (cadr t2) (caddr t2)))
325                         (res1 (if (pair? (cadr t1)) (cddr t1) (cdddr t1)))
326                         (res2 (if (pair? (cadr t2)) (cddr t2) (cdddr t2))) )
327                     (let loop1 ((args1 args1)
328                                 (args2 args2)
329                                 (m1 0) 
330                                 (m2 0))
331                       (cond ((null? args1) 
332                              (and (or (null? args2) (> m2 0))
333                                   (let loop2 ((res1 res1) (res2 res2))
334                                     (cond ((eq? '* res2) #t)
335                                           ((null? res2) (null? res1))
336                                           ((eq? '* res1) #f)
337                                           ((type<=? (car res1) (car res2))
338                                            (loop2 (cdr res1) (cdr res2)))
339                                           (else #f)))))
340                             ((null? args2) #f)
341                             ((eq? (car args1) '#!optional)
342                              (loop1 (cdr args1) args2 1 m2))
343                             ((eq? (car args2) '#!optional)
344                              (loop1 args1 (cdr args2) m1 1))
345                             ((eq? (car args1) '#!rest)
346                              (loop1 (cdr args1) args2 2 m2))
347                             ((eq? (car args2) '#!rest)
348                              (loop1 args1 (cdr args2) m1 2))
349                             ((type<=? (car args1) (car args2)) 
350                              (loop1 (cdr args1) (cdr args2) m1 m2))
351                             (else #f)))))))))))
352  (define (check expected given loc what #!optional desc) 
353    (d "check: ~a <-> ~a (~a)" expected given loc)
354    (if (match expected given)
355        given
356        (report loc expected given what desc)))
357  (define (multiples n)
358    (if (= n 1) "" "s"))
359  (define (single what tv loc)
360    (if (eq? '* tv)
361        '*
362        (let ((n (length tv)))
363          (cond ((= 1 n) (car tv))
364                ((zero? n)
365                 (report loc "a single result" "zero results" what)
366                 'undefined)
367                (else
368                 (report loc "a single result" (sprintf "~a result~a" n (multiples n)) what)
369                 (first tv))))))
370  (define (report1 loc desc)
371    (compiler-warning
372     'scrutiny
373     "~a~a" 
374     (location-name loc) desc))
375  (define (report loc expected given what #!optional desc)
376    (report1 
377     loc 
378     (sprintf 
379      "~a~a~a~a"
380      (or desc "")
381      (if desc " " "")
382      (if expected
383          (sprintf "expected ~a~a~a" (or what "") (if what " " "") expected)
384          "")
385      (sprintf ", but where given ~a" given))))
386  (define (location-name loc)
387    (define (lname loc1)
388      (if loc1
389          (sprintf "procedure `~a'" (real-name loc1))
390          "unknown procedure"))
391    (cond ((null? loc) "at toplevel:\n  ")
392          ((null? (cdr loc))
393           (sprintf "in toplevel ~a:\n  " (lname (car loc))))
394          (else
395           (let rec ((loc loc))
396             (if (null? (cdr loc))
397                 (location-name loc)
398                 (sprintf "in local ~a,\n  ~a" (lname (car loc)) (rec (cdr loc))))))))
399  (define add-loc cons)
400  (define (fragment x)
401    (let ((x (build-expression-tree x)))
402      (cond ((atom? x) x)
403            ((list? x) 
404             (let ((x1 (if (> (length x) +fragment-max-length+)
405                           (append (take x +fragment-max-length+) '(...))
406                           x)))
407               (map (lambda (x) 
408                      (if (and (list? x) (any pair? x))
409                          '(...)
410                          x))
411                    x1)))
412            (else x))))
413  (define (call-result args e loc x params)
414    (define (pname)
415      (sprintf 
416       "in procedure call to `~s'~a" 
417       (fragment x)
418       (if (and (pair? params) (pair? (cdr params)))
419           (sprintf " (line ~a)" (source-info->line (cadr params)))
420           "")))
421    (d "call-result: ~a (~a)" args loc)
422    (let ((ptype (car args))
423          (nargs (length (cdr args))))
424      (unless (procedure-type? ptype)
425        (check 
426         `(procedure ,(make-list nargs '*) *)
427         ptype
428         loc "a procedure of type" (pname)))
429      (let ((atypes (procedure-argument-types ptype (length (cdr args)))))
430        (d "  argument-types: ~a" atypes)
431        (unless (= (length atypes) nargs)
432          (let ((alen (length atypes)))
433            (report 
434             loc
435             (sprintf "~a argument~a" alen (multiples alen))
436             (sprintf "~a argument~a" nargs (multiples nargs))
437             (pname))))
438        (do ((args (cdr args) (cdr args))
439             (atypes atypes (cdr atypes))
440             (i 1 (add1 i)))
441            ((or (null? args) (null? atypes)))
442          (check (car atypes) (car args) loc (sprintf "argument #~a of type" i) (pname)))
443        (let ((r (procedure-result-types ptype)))
444          (d  "  result-types: ~a" r)
445          r))))
446  (define (procedure-type? t)
447    (or (eq? 'procedure t)
448        (and (pair? t) (eq? 'procedure (car t)))))
449  (define (procedure-argument-types t n)
450    (cond ((or (memq t '(* procedure)) 
451               (not-pair? t) )
452           (make-list n '*))
453          ((eq? 'procedure (car t))
454           (let loop ((at (if (or (string? (second t)) (symbol? (second t)))
455                              (third t)
456                              (second t)))
457                      (m n)
458                      (opt #f))
459             (cond ((null? at) '())
460                   ((eq? '#!optional (car at)) 
461                    (loop (cdr at) m #t) )
462                   ((eq? '#!rest (car at))
463                    (if (pair? (cdr at))
464                        (make-list m (cadr at))
465                        (make-list m '*)))
466                   ((and opt (<= m 0)) '())
467                   (else (cons (car at) (loop (cdr at) (sub1 m) opt))))))
468          (else (bomb "not a procedure type: ~a" t))))
469  (define (procedure-result-types t)
470    (cond ((or (memq t '(* procedure)) 
471               (not-pair? t) )
472           '*)
473          ((eq? 'procedure (car t))
474           (call/cc
475            (lambda (return)
476              (let loop ((rt (if (or (string? (second t)) (symbol? (second t)))
477                                 (cdddr t)
478                                 (cddr t))))
479                (cond ((null? rt) '())
480                      ((eq? '* rt) (return '*))
481                      (else (cons (car rt) (loop (cdr rt)))))))))
482          (else (bomb "not a procedure type: ~a" t))))
483  (define (walk n e loc dest)           ; returns result specifier
484    (let ((subs (node-subexpressions n))
485          (params (node-parameters n)) 
486          (class (node-class n)) )
487      (d "walk: ~a ~a (loc: ~a, dest: ~a)" class params loc dest)
488      (let ((results
489             (case class
490               ((quote) (list (constant-result (first params))))
491               ((##core#undefined) '(*))
492               ((##core#proc) '(procedure))
493               ((##core#global-ref) (global-result (first params) loc))
494               ((##core#variable) (variable-result (first params) e loc))
495               ((if) (let ((rt (single "in conditional" (walk (first subs) e loc dest) loc)))
496                       (always-true rt loc n)
497                       (let ((r1 (walk (second subs) e loc dest))
498                             (r2 (walk (third subs) e loc dest)))
499                         (cond ((and (not (eq? r1 '*)) (not (eq? '* r2)))
500                                (when (not (= (length r1) (length r2)))
501                                  (report1 
502                                   loc
503                                   "branches in conditional expression differ in the number of results"))
504                                (map (lambda (t1 t2) (simplify `(or ,t1 ,t2)))
505                                     r1 r2))
506                               (else '*)))))
507               ((let)
508                (let loop ((vars params) (body subs) (e2 '()))
509                  (if (null? vars)
510                      (walk (car body) (append e2 e) loc dest)
511                      (let ((t (single "in `let' binding" (walk (car body) e loc (car vars)) loc)))
512                        (loop (cdr vars) (cdr body) (alist-cons (car vars) t e2))))))
513               ((##core#lambda lambda)
514                (decompose-lambda-list
515                 (first params)
516                 (lambda (vars argc rest)
517                   `((procedure
518                      ,@(if dest (list dest) '())
519                      ,(append (make-list argc '*) (if rest '(#!rest) '()))
520                      ,@(let* ((e2 (append (map (lambda (v) (cons v '*)) 
521                                                (if rest (butlast vars) vars))
522                                           e))
523                               (r (walk (first subs)
524                                        (if rest (alist-cons rest 'list e2) e2)
525                                        (add-loc dest loc)
526                                        #f)))
527                          (if (eq? r '*)
528                              '(*)
529                              r)))))))
530               ((set!)
531                (let* ((var (first params))
532                       (rt (single 
533                            (sprintf "in assignment to `~a'" var)
534                            (walk (first subs) e loc var)
535                            loc))
536                       (b (assq var e)) )
537                  (when (and b (eq? 'undefined (cdr b)))
538                    (set-cdr! b rt))
539                  '(undefined)))
540               ((##core#primitive ##core#inline_ref) '*)
541               ((##core#call)
542                (let ((args (map (lambda (n)
543                                   (single 
544                                    "in procedure call argument"
545                                    (walk n e loc #f) loc))
546                                 subs)))
547                  (call-result args e loc (first subs) params)))
548               ((##core#switch ##core#cond)
549                (bomb "unexpected node class: ~a" class))
550               (else
551                (for-each (lambda (n) (walk n e loc #f)) subs)
552                '*))))
553        (d "  -> ~a" results)
554        results)))
555  (walk (first (node-subexpressions node)) '() '() #f))
556
557(define (load-type-database name)
558  (and-let* ((rp (repository-path))
559             (dbfile (file-exists? (make-pathname rp name))))
560    (when verbose-mode
561      (printf "loading type database ~a ...~%" dbfile))
562    (for-each
563     (lambda (e)
564       (##sys#put! (car e) '##core#type (cadr e)))
565     (read-file dbfile))))
566
567(define (source-info->line info)
568  (if (list? info)
569      (cadr info)
570      (and info (->string info))) )
Note: See TracBrowser for help on using the repository browser.