source: project/chicken/branches/scrutiny/chicken-install.scm @ 14827

Last change on this file since 14827 was 14827, checked in by felix winkelmann, 10 years ago

merged trunk changes until 14826 into scrutiny branch

File size: 21.5 KB
Line 
1;;;; chicken-install.scm
2;
3; Copyright (c) 2008-2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library setup-download setup-api)
28(require-library srfi-1 posix data-structures utils regex ports extras
29                 srfi-13 files)
30(require-library chicken-syntax)        ; in case an import library reexports chicken syntax
31
32
33(module main ()
34
35  (import scheme chicken srfi-1 posix data-structures utils regex ports extras
36          srfi-13 files)
37  (import setup-download setup-api)
38
39  (import foreign)
40
41  (define +default-repository-files+
42    '("setup-api.so" "setup-api.import.so"
43      "setup-utils.so" "setup-utils.import.so"
44      "setup-download.so" "setup-download.import.so"
45      "chicken.import.so"
46      "lolevel.import.so"
47      "srfi-1.import.so"
48      "srfi-4.import.so"
49      "data-structures.import.so"
50      "ports.import.so"
51      "files.import.so"
52      "posix.import.so"
53      "srfi-13.import.so"
54      "srfi-69.import.so"
55      "extras.import.so"
56      "regex.import.so"
57      "srfi-14.import.so"
58      "tcp.import.so"
59      "foreign.import.so"
60      "scheme.import.so"
61      "srfi-18.import.so"
62      "utils.import.so"
63      "csi.import.so"
64      "irregex.import.so"
65      "compiler.import.so"))
66
67  (define *program-path*
68    (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
69          (make-pathname p "bin") )
70        (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )
71
72  (define *keep* #f)
73  (define *force* #f)
74  (define *prefix* #f)
75  (define *host-extension* #f)
76  (define *run-tests* #f)
77  (define *retrieve-only* #f)
78  (define *no-install* #f)
79  (define *username* #f)
80  (define *password* #f)
81  (define *default-sources* '())
82  (define *default-location* #f)
83  (define *default-transport* 'http)
84  (define *windows-shell* (foreign-value "C_WINDOWS_SHELL" bool))
85
86  (define-constant +module-db+ "modules.db")
87  (define-constant +defaults-file+ "setup.defaults")
88
89  (define (load-defaults)
90    (let ([deff (make-pathname (chicken-home) +defaults-file+)])
91      (cond [(not (file-exists? deff))
92             '() ]
93            [else
94             (set! *default-sources* (read-file deff))
95             (pair? *default-sources*) ] ) ) )
96
97  (define (known-default-sources)
98    (if (and *default-location* *default-transport*)
99        `(((location ,*default-location*)
100           (transport ,*default-transport*)))
101        *default-sources* ) )
102
103  (define (invalidate-default-source! def)
104    (set! *default-sources* (delete def *default-sources* eq?)) )
105
106  (define (deps key meta)
107    (or (and-let* ((d (assq key meta)))
108          (cdr d))
109        '()))
110
111  (define (init-repository dir)
112    (let ((src (repository-path))
113          (copy (if *windows-shell*
114                    "copy"
115                    "cp -r")))
116      (print "copying required files to " dir " ...")
117      (for-each
118       (lambda (f)
119         ($system (sprintf "~a ~a ~a" copy (shellpath (make-pathname src f)) (shellpath dir))))
120       +default-repository-files+)))
121
122  (define (ext-version x)
123    (cond ((or (eq? x 'chicken)
124               (equal? x "chicken")
125               (member (->string x) ##sys#core-library-modules))
126           (chicken-version) )
127          ((extension-information x) =>
128           (lambda (info)
129             (let ((a (assq 'version info)))
130               (if a
131                   (->string (cadr a))
132                   "0.0.0"))))
133          (else #f)))
134
135  (define (outdated-dependencies meta)
136    (let ((ds (append
137               (deps 'depends meta)
138               (deps 'needs meta)
139               (if *run-tests* (deps 'test-depends meta) '()))))
140      (let loop ((deps ds) (missing '()) (upgrade '()))
141        (if (null? deps)
142            (values (reverse missing) (reverse upgrade))
143            (let ((dep (car deps))
144                  (rest (cdr deps)))
145              (cond ((or (symbol? dep) (string? dep))
146                     (loop rest
147                           (if (ext-version dep)
148                               missing
149                               (cons (->string dep) missing))
150                           upgrade))
151                    ((and (list? dep) (= 2 (length dep))
152                          (or (string? (car dep)) (symbol? (car dep))))
153                     (let ((v (ext-version (car dep))))
154                       (cond ((not v)
155                              (loop rest (cons (->string (car dep)) missing) upgrade))
156                             ((not (version>=? v (->string (cadr dep))))
157                              (when (string=? "chicken" (->string (car dep)))
158                                (error
159                                 (string-append
160                                  "Your CHICKEN version is not recent enough to use this extension - version "
161                                  (cadr dep) 
162                                  " or newer is required")))
163                              (loop rest missing
164                                    (alist-cons
165                                     (->string (car dep)) (->string (cadr dep))
166                                     upgrade)))
167                             (else (loop rest missing upgrade)))))
168                    (else
169                     (warning
170                      "invalid dependency syntax in extension meta information"
171                      dep)
172                     (loop rest missing upgrade))))))))
173
174  (define *eggs+dirs+vers* '())
175  (define *checked* '())
176  (define *csi* (shellpath (make-pathname *program-path* "csi")))
177 
178  (define (try-extension name version trans locn)
179    (condition-case
180        (retrieve-extension
181         name trans locn
182         version: version
183         destination: (and *retrieve-only* (current-directory))
184         tests: *run-tests*
185         username: *username*
186         password: *password*)
187      [(exn net)
188       (print "TCP connect timeout")
189       (values #f "") ]
190      [(exn http-fetch)
191       (print "HTTP protocol error")
192       (values #f "") ]
193      [e ()
194       (abort e) ] ) )
195
196  (define (try-default-sources name version)
197    (let trying-sources ([defs (known-default-sources)])
198      (if (null? defs)
199          (values #f "")
200          (let* ([def (car defs)]
201                 [locn (cadr (or (assq 'location def)
202                                 (error "missing location entry" def)))]
203                 [trans (cadr (or (assq 'transport def)
204                                  (error "missing transport entry" def)))])
205            (let-values ([(dir ver) (try-extension name version trans locn)])
206              (if dir
207                  (values dir ver)
208                  (begin
209                    (invalidate-default-source! def)
210                    (trying-sources (cdr defs)) ) ) ) ) ) ) )
211
212  (define (make-replace-extension-question e+d+v upgrade)
213    (string-concatenate
214     (append
215      (list "The following installed extensions are outdated, because `"
216            (car e+d+v)
217            "' requires later versions:\n")
218      (map
219       (lambda (e)
220         (conc
221          "  " (car e)
222          " (" (let ([v (assq 'version (extension-information (car e)))]) (if v (cadr v) "???"))
223               " -> " (cdr e) ")"
224          #\newline) )
225       upgrade)
226      '("\nDo you want to replace the existing extensions?"))) )
227
228  (define (retrieve eggs)
229    (print "retrieving ...")
230    (for-each
231     (lambda (egg)
232       (cond [(assoc egg *eggs+dirs+vers*) =>
233              (lambda (a)
234                ;; push to front
235                (set! *eggs+dirs+vers* (cons a (delete a *eggs+dirs+vers* eq?))) ) ]
236             [else
237              (let ([name (if (pair? egg) (car egg) egg)]
238                    [version (and (pair? egg) (cdr egg))])
239                (let-values ([(dir ver) (try-default-sources name version)])
240                  (unless dir (error "extension or version not found"))
241                  (print " " name " located at " dir)
242                  (set! *eggs+dirs+vers* (alist-cons name (list dir ver) *eggs+dirs+vers*)) ) ) ] ) )
243     eggs)
244    (unless *retrieve-only*
245      (for-each
246       (lambda (e+d+v)
247         (unless (member (car e+d+v) *checked*)
248           (set! *checked* (cons (car e+d+v) *checked*))
249           (let ([mfile (make-pathname (cadr e+d+v) (car e+d+v) "meta")])
250             (cond [(file-exists? mfile)
251                    (let ([meta (with-input-from-file mfile read)])
252                      (print "checking dependencies for `" (car e+d+v) "' ...")
253                      (let-values ([(missing upgrade) (outdated-dependencies meta)])
254                        (when (pair? missing)
255                          (print " missing: " (string-intersperse missing ", "))
256                          (retrieve missing))
257                        (when (and (pair? upgrade)
258                                   (or *force*
259                                       (yes-or-no?
260                                        (make-replace-extension-question e+d+v upgrade)
261                                        "no") ) )
262                          (let ([ueggs (unzip1 upgrade)])
263                            (print " upgrade: " (string-intersperse ueggs ", "))
264                            (for-each
265                             (lambda (e)
266                               (print "removing previously installed extension `" e "' ...")
267                               (remove-extension e) )
268                             ueggs)
269                            (retrieve ueggs) ) ) ) ) ]
270                   [else
271                    (warning
272                     (string-append
273                      "extension `" (car e+d+v) "' has no .meta file "
274                      "- assuming it has no dependencies")) ] ) ) ) )
275       *eggs+dirs+vers*) ) )
276
277  (define (make-install-command e+d+v)
278    (conc
279     *csi*
280     " -bnq -e \"(require-library setup-api)\" -e \"(import setup-api)\""
281     (sprintf " -e \"(extension-name-and-version '(\\\"~a\\\" \\\"~a\\\"))\"" (car e+d+v) (caddr e+d+v))
282     (if (sudo-install) " -e \"(sudo-install #t)\"" "")
283     (if *keep* " -e \"(keep-intermediates #t)\"" "")
284     (if *no-install* " -e \"(setup-install-flag #f)\"" "")
285     (if *host-extension* " -e \"(host-extension #t)\"" "")
286     (if *prefix* (sprintf " -e \"(installation-prefix \\\"~a\\\")\"" *prefix*) "")
287     #\space (shellpath (make-pathname (cadr e+d+v) (car e+d+v) "setup"))) )
288
289  (define (install eggs)
290    (retrieve eggs)
291    (unless *retrieve-only*
292      (for-each ; we assume the order reflects the dependency tree...
293       (lambda (e+d+v)
294         (print "installing " (car e+d+v) #\: (caddr e+d+v) " ...")
295         (print "changing current directory to " (cadr e+d+v))
296         (parameterize ((current-directory (cadr e+d+v)))
297           (let ([cmd (make-install-command e+d+v)])
298             (print "  " cmd)
299             ($system cmd))
300           (when (and *run-tests*
301                      (file-exists? "tests")
302                      (directory? "tests")
303                      (file-exists? "tests/run.scm") )
304             (current-directory "tests")
305             (let ((cmd (sprintf "~a -s run.scm ~a" *csi* (car e+d+v))))
306               (print "  " cmd)
307               ($system cmd)))))
308       *eggs+dirs+vers*)))
309
310  (define (cleanup)
311    (unless *keep*
312      (and-let* ((tmpdir (temporary-directory)))
313        (remove-directory tmpdir))))
314
315  (define (update-db)
316    (let* ((files (glob (make-pathname (repository-path) "*.import.*")))
317           (tmpdir (create-temporary-directory))
318           (dbfile (make-pathname tmpdir +module-db+))
319           (rx (regexp ".*/([^/]+)\\.import\\.(scm|so)")))
320      (print "loading import libraries ...")
321      (fluid-let ((##sys#warnings-enabled #f))
322        (for-each
323         (lambda (f)
324           (let ((m (string-match rx f)))
325             (handle-exceptions ex
326                 (print-error-message 
327                  ex (current-error-port) 
328                  (sprintf "Failed to import from `~a'" f))
329               (eval `(import ,(string->symbol (cadr m)))))))
330         files))
331      (print "generating database")
332      (let ((db
333             (sort
334              (append-map
335               (lambda (m)
336                 (let* ((mod (cdr m))
337                        (mname (##sys#module-name mod)))
338                   (print* " " mname)
339                   (let-values (((_ ve se) (##sys#module-exports mod)))
340                     (append
341                      (map (lambda (se) (list (car se) 'syntax mname)) se)
342                      (map (lambda (ve) (list (car ve) 'value mname)) ve)))))
343               ##sys#module-table)
344              (lambda (e1 e2)
345                (string<? (symbol->string (car e1)) (symbol->string (car e2)))))))
346        (newline)
347        (with-output-to-file dbfile
348          (lambda ()
349            (for-each (lambda (x) (write x) (newline)) db)))
350        (copy-file dbfile (make-pathname (repository-path) +module-db+))
351        (remove-directory tmpdir))))
352
353  (define ($system str)
354    (let ((r (system
355              (if *windows-shell*
356                  (string-append "\"" str "\"")
357                  str))))
358      (unless (zero? r)
359        (error "shell command terminated with nonzero exit code" r str))))
360
361  (define (usage code)
362    (print #<<EOF
363usage: chicken-install [OPTION | EXTENSION[:VERSION]] ...
364
365  -h   -help                    show this message and exit
366  -v   -version                 show version and exit
367       -force                   don't ask, install even if versions don't match
368  -k   -keep                    keep temporary files
369  -l   -location LOCATION       install from given location instead of default
370  -t   -transport TRANSPORT     use given transport instead of default
371  -s   -sudo                    use sudo(1) for installing or removing files
372  -r   -retrieve                only retrieve egg into current directory, don't install
373  -n   -no-install              do not install, just build (implies `-keep')
374  -p   -prefix PREFIX           change installation prefix to PREFIX
375       -host-extension          when cross-compiling, compile extension for host
376       -test                    run included test-cases, if available
377       -username USER           set username for transports that require this
378       -password PASS           set password for transports that require this
379  -i   -init DIRECTORY          initialize empty alternative repository
380  -u   -update-db               update export database
381EOF
382);|
383    (exit code))
384
385  (define *short-options* '(#\h #\k #\l #\t #\s #\p #\r #\n #\v #\i #\u))
386
387  (define (main args)
388    (let ((defaults (load-defaults))
389          (update #f)
390          (rx "([^:]+):(.+)"))
391      (let loop ((args args) (eggs '()))
392        (cond ((null? args)
393               (cond (update (update-db))
394                     (else
395                      (when (null? eggs)
396                        (let ((setups (glob "*.setup")))
397                          (cond ((pair? setups)
398                                 (set! *eggs+dirs+vers*
399                                       (append
400                                        (map
401                                         (lambda (s) (cons (pathname-file s) (list "." "")))
402                                         setups)
403                                        *eggs+dirs+vers*)))
404                                (else
405                                 (print "no setup-scripts to process")
406                                 (exit 1))) ) )
407                      (unless defaults
408                        (unless *default-transport*
409                          (error "no default transport defined - please use `-transport' option"))
410                        (unless *default-location*
411                          (error "no default location defined - please use `-location' option")))
412                      (install (reverse eggs)))))
413              (else
414               (let ((arg (car args)))
415                 (cond ((or (string=? arg "-help")
416                            (string=? arg "-h")
417                            (string=? arg "--help"))
418                        (usage 0))
419                       ((string=? arg "-force")
420                        (set! *force* #t)
421                        (loop (cdr args) eggs))
422                       ((or (string=? arg "-k") (string=? arg "-keep"))
423                        (set! *keep* #t)
424                        (loop (cdr args) eggs))
425                       ((or (string=? arg "-s") (string=? arg "-sudo"))
426                        (sudo-install #t)
427                        (loop (cdr args) eggs))
428                       ((or (string=? arg "-r") (string=? arg "-retrieve"))
429                        (set! *retrieve-only* #t)
430                        (loop (cdr args) eggs))
431                       ((or (string=? arg "-l") (string=? arg "-location"))
432                        (unless (pair? (cdr args)) (usage 1))
433                        (set! *default-location* (cadr args))
434                        (loop (cddr args) eggs))
435                       ((or (string=? arg "-t") (string=? arg "-transport"))
436                        (unless (pair? (cdr args)) (usage 1))
437                        (set! *default-transport* (string->symbol (cadr args)))
438                        (loop (cddr args) eggs))
439                       ((or (string=? arg "-p") (string=? arg "-prefix"))
440                        (unless (pair? (cdr args)) (usage 1))
441                        (set! *prefix* (cadr args))
442                        (loop (cddr args) eggs))
443                       ((or (string=? arg "-n") (string=? arg "-no-install"))
444                        (set! *keep* #t)
445                        (set! *no-install* #t)
446                        (loop (cdr args) eggs))
447                       ((or (string=? arg "-v") (string=? arg "-version"))
448                        (print (chicken-version))
449                        (exit 0))
450                       ((or (string=? arg "-u") (string=? arg "-update-db"))
451                        (set! update #t)
452                        (loop (cdr args) eggs))
453                       ((or (string=? arg "-i") (string=? arg "-init"))
454                        (unless (pair? (cdr args)) (usage 1))
455                        (init-repository (cadr args))
456                        (exit 0))
457                       ((string=? "-test" arg)
458                        (set! *run-tests* #t)
459                        (loop (cdr args) eggs))
460                       ((string=? "-host-extension" arg)
461                        (set! *host-extension* #t)
462                        (loop (cdr args) eggs))
463                       ((string=? "-username" arg)
464                        (unless (pair? (cdr args)) (usage 1))
465                        (set! *username* (cadr args))
466                        (loop (cddr args) eggs))
467                       ((string=? "-password" arg)
468                        (unless (pair? (cdr args)) (usage 1))
469                        (set! *password* (cadr args))
470                        (loop (cddr args) eggs))
471                       ((and (positive? (string-length arg))
472                             (char=? #\- (string-ref arg 0)))
473                        (if (> (string-length arg) 2)
474                            (let ((sos (string->list (substring arg 1))))
475                              (if (null? (lset-intersection eq? *short-options* sos))
476                                  (loop (append (map (cut string #\- <>) sos) (cdr args)) eggs)
477                                  (usage 1)))
478                            (usage 1)))
479                       ((equal? "setup" (pathname-extension arg))
480                        (let ((egg (pathname-file arg)))
481                          (set! *eggs+dirs+vers*
482                            (alist-cons
483                             egg
484                             (list
485                              (let ((dir (pathname-directory arg)))
486                                (if dir
487                                    (if (absolute-pathname? dir)
488                                        dir
489                                        (make-pathname (current-directory) dir) )
490                                    (current-directory)))
491                              "")
492                             *eggs+dirs+vers*))
493                          (loop (cdr args) (cons egg eggs))))
494                       ((string-match rx arg) =>
495                        (lambda (m)
496                          (loop (cdr args) (alist-cons (cadr m) (caddr m) eggs))))
497                       (else (loop (cdr args) (cons arg eggs))))))))))
498
499  (register-feature! 'chicken-install)
500  (define ##compiler#compiler-macro-environment '()) ; only to make `compiler' import work
501
502  (handle-exceptions ex
503      (begin
504        (print-error-message ex (current-error-port))
505        (cleanup)
506        (exit 1))
507    (main (command-line-arguments))
508    (cleanup))
509
510) ;module main
Note: See TracBrowser for help on using the repository browser.