source: project/chicken/branches/scrutiny/chicken-install.scm @ 13965

Last change on this file since 13965 was 13965, checked in by felix winkelmann, 10 years ago

merged trunk rev. 13953

File size: 21.3 KB
Line 
1;;;; chicken-install.scm
2;
3; Copyright (c) 2008-2009, The Chicken Team
4; All rights reserved.
5;
6; Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following
7; conditions are met:
8;
9;   Redistributions of source code must retain the above copyright notice, this list of conditions and the following
10;     disclaimer.
11;   Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following
12;     disclaimer in the documentation and/or other materials provided with the distribution.
13;   Neither the name of the author nor the names of its contributors may be used to endorse or promote
14;     products derived from this software without specific prior written permission.
15;
16; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
17; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
18; AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR
19; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
20; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
21; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
22; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
23; OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
24; POSSIBILITY OF SUCH DAMAGE.
25
26
27(require-library setup-download setup-api)
28(require-library srfi-1 posix data-structures utils regex ports extras
29                 srfi-13 files)
30
31
32(module main ()
33
34  (import scheme chicken srfi-1 posix data-structures utils regex ports extras
35          srfi-13 files)
36  (import setup-download setup-api)
37
38  (import foreign)
39
40  (define +default-repository-files+
41    '("setup-api.so" "setup-api.import.so"
42      "setup-utils.so" "setup-utils.import.so"
43      "setup-download.so" "setup-download.import.so"
44      "chicken.import.so"
45      "lolevel.import.so"
46      "srfi-1.import.so"
47      "srfi-4.import.so"
48      "data-structures.import.so"
49      "ports.import.so"
50      "files.import.so"
51      "posix.import.so"
52      "srfi-13.import.so"
53      "srfi-69.import.so"
54      "extras.import.so"
55      "regex.import.so"
56      "srfi-14.import.so"
57      "tcp.import.so"
58      "foreign.import.so"
59      "scheme.import.so"
60      "srfi-18.import.so"
61      "utils.import.so"
62      "csi.import.so"
63      "irregex.import.so"
64      "compiler.import.so"))
65
66  (define *program-path*
67    (or (and-let* ((p (getenv "CHICKEN_PREFIX")))
68          (make-pathname p "bin") )
69        (foreign-value "C_INSTALL_BIN_HOME" c-string) ) )
70
71  (define *keep* #f)
72  (define *force* #f)
73  (define *prefix* #f)
74  (define *host-extension* #f)
75  (define *run-tests* #f)
76  (define *retrieve-only* #f)
77  (define *no-install* #f)
78  (define *username* #f)
79  (define *password* #f)
80  (define *default-sources* '())
81  (define *default-location* #f)
82  (define *default-transport* 'http)
83  (define *windows-shell* (foreign-value "C_WINDOWS_SHELL" bool))
84
85  (define-constant +module-db+ "modules.db")
86  (define-constant +defaults-file+ "setup.defaults")
87
88  (define (load-defaults)
89    (let ([deff (make-pathname (chicken-home) +defaults-file+)])
90      (cond [(not (file-exists? deff))
91             '() ]
92            [else
93             (set! *default-sources* (read-file deff))
94             (pair? *default-sources*) ] ) ) )
95
96  (define (known-default-sources)
97    (if (and *default-location* *default-transport*)
98        `(((location ,*default-location*)
99           (transport ,*default-transport*)))
100        *default-sources* ) )
101
102  (define (invalidate-default-source! def)
103    (set! *default-sources* (delete def *default-sources* eq?)) )
104
105  (define (deps key meta)
106    (or (and-let* ((d (assq key meta)))
107          (cdr d))
108        '()))
109
110  (define (init-repository dir)
111    (let ((src (repository-path))
112          (copy (if *windows-shell*
113                    "copy"
114                    "cp -r")))
115      (print "copying required files to " dir " ...")
116      (for-each
117       (lambda (f)
118         ($system (sprintf "~a ~a ~a" copy (shellpath (make-pathname src f)) (shellpath dir))))
119       +default-repository-files+)))
120
121  (define (ext-version x)
122    (cond ((or (eq? x 'chicken)
123               (equal? x "chicken")
124               (member (->string x) ##sys#core-library-modules))
125           (chicken-version) )
126          ((extension-information x) =>
127           (lambda (info)
128             (let ((a (assq 'version info)))
129               (if a
130                   (->string (cadr a))
131                   "1.0.0"))))
132          (else #f)))
133
134  (define (outdated-dependencies meta)
135    (let ((ds (append
136               (deps 'depends meta)
137               (deps 'needs meta)
138               (if *run-tests* (deps 'test-depends meta) '()))))
139      (let loop ((deps ds) (missing '()) (upgrade '()))
140        (if (null? deps)
141            (values (reverse missing) (reverse upgrade))
142            (let ((dep (car deps))
143                  (rest (cdr deps)))
144              (cond ((or (symbol? dep) (string? dep))
145                     (loop rest
146                           (if (ext-version dep)
147                               missing
148                               (cons (->string dep) missing))
149                           upgrade))
150                    ((and (list? dep) (= 2 (length dep))
151                          (or (string? (car dep)) (symbol? (car dep))))
152                     (let ((v (ext-version (car dep))))
153                       (cond ((not v)
154                              (warning
155                               "installed extension has unknown version - assuming it is outdated"
156                               (car dep))
157                              (loop rest missing
158                                    (alist-cons
159                                     (->string (car dep))
160                                     (->string (cadr dep))
161                                     upgrade)))
162                             ((version>=? (->string (cadr dep)) v)
163                              (loop rest missing
164                                    (alist-cons
165                                     (->string (car dep)) (->string (cadr dep))
166                                     upgrade)))
167                             (else (loop rest missing upgrade)))))
168                    (else
169                     (warning
170                      "invalid dependency syntax in extension meta information"
171                      dep)
172                     (loop rest missing upgrade))))))))
173
174  (define *eggs+dirs+vers* '())
175  (define *checked* '())
176  (define *csi* (shellpath (make-pathname *program-path* "csi")))
177 
178  (define (try-extension name version trans locn)
179    (condition-case
180        (retrieve-extension
181         name trans locn
182         version: version
183         destination: (and *retrieve-only* (current-directory))
184         tests: *run-tests*
185         username: *username*
186         password: *password*)
187      [(exn net)
188       (print "TCP connect timeout")
189       (values #f "") ]
190      [(exn http-fetch)
191       (print "HTTP protocol error")
192       (values #f "") ]
193      [e ()
194       (abort e) ] ) )
195
196  (define (try-default-sources name version)
197    (let trying-sources ([defs (known-default-sources)])
198      (if (null? defs)
199          (values #f "")
200          (let* ([def (car defs)]
201                 [locn (cadr (or (assq 'location def)
202                                 (error "missing location entry" def)))]
203                 [trans (cadr (or (assq 'transport def)
204                                  (error "missing transport entry" def)))])
205            (let-values ([(dir ver) (try-extension name version trans locn)])
206              (if dir
207                  (values dir ver)
208                  (begin
209                    (invalidate-default-source! def)
210                    (trying-sources (cdr defs)) ) ) ) ) ) ) )
211
212  (define (make-replace-extension-question e+d+v upgrade)
213    (string-concatenate
214     (append
215      (list "The following installed extensions are outdated, because `"
216            (car e+d+v)
217            "' requires later versions:\n")
218      (map
219       (lambda (e)
220         (conc
221          "  " (car e)
222          " (" (let ([v (assq 'version (extension-information (car e)))]) (if v (cadr v) "???"))
223               " -> " (cdr e) ")"
224          #\newline) )
225       upgrade)
226      '("\nDo you want to replace the existing extensions?"))) )
227
228  (define (retrieve eggs)
229    (print "retrieving ...")
230    (for-each
231     (lambda (egg)
232       (cond [(assoc egg *eggs+dirs+vers*) =>
233              (lambda (a)
234                ;; push to front
235                (set! *eggs+dirs+vers* (cons a (delete a *eggs+dirs+vers* eq?))) ) ]
236             [else
237              (let ([name (if (pair? egg) (car egg) egg)]
238                    [version (and (pair? egg) (cdr egg))])
239                (let-values ([(dir ver) (try-default-sources name version)])
240                  (unless dir (error "extension or version not found"))
241                  (print " " name " located at " dir)
242                  (set! *eggs+dirs+vers* (alist-cons name (list dir ver) *eggs+dirs+vers*)) ) ) ] ) )
243     eggs)
244    (unless *retrieve-only*
245      (for-each
246       (lambda (e+d+v)
247         (unless (member (car e+d+v) *checked*)
248           (set! *checked* (cons (car e+d+v) *checked*))
249           (let ([mfile (make-pathname (cadr e+d+v) (car e+d+v) "meta")])
250             (cond [(file-exists? mfile)
251                    (let ([meta (with-input-from-file mfile read)])
252                      (print "checking dependencies for `" (car e+d+v) "' ...")
253                      (let-values ([(missing upgrade) (outdated-dependencies meta)])
254                        (when (pair? missing)
255                          (print " missing: " (string-intersperse missing ", "))
256                          (retrieve missing))
257                        (when (and (pair? upgrade)
258                                   (or *force*
259                                       (yes-or-no?
260                                        (make-replace-extension-question e+d+v upgrade)
261                                        "no") ) )
262                          (let ([ueggs (unzip1 upgrade)])
263                            (print " upgrade: " (string-intersperse ueggs ", "))
264                            (for-each
265                             (lambda (e)
266                               (print "removing previously installed extension `" e "' ...")
267                               (remove-extension e) )
268                             ueggs)
269                            (retrieve ueggs) ) ) ) ) ]
270                   [else
271                    (warning
272                     (string-append
273                      "extension `" (car e+d+v) "' has no .meta file "
274                      "- assuming it has no dependencies")) ] ) ) ) )
275       *eggs+dirs+vers*) ) )
276
277  (define (make-install-command e+d+v)
278    (conc
279     *csi*
280     " -bnq -e \"(require-library setup-api)\" -e \"(import setup-api)\""
281     (sprintf " -e \"(extension-name-and-version '(\\\"~a\\\" \\\"~a\\\"))\"" (car e+d+v) (caddr e+d+v))
282     (if (sudo-install) " -e \"(sudo-install #t)\"" "")
283     (if *keep* " -e \"(keep-intermediates #t)\"" "")
284     (if *no-install* " -e \"(setup-install-flag #f)\"" "")
285     (if *host-extension* " -e \"(host-extension #t)\"" "")
286     (if *prefix* (sprintf " -e \"(installation-prefix \\\"~a\\\")\"" *prefix*) "")
287     #\space (shellpath (make-pathname (cadr e+d+v) (car e+d+v) "setup"))) )
288
289  (define (install eggs)
290    (retrieve eggs)
291    (unless *retrieve-only*
292      (for-each ; we assume the order reflects the dependency tree...
293       (lambda (e+d+v)
294         (print "installing " (car e+d+v) #\: (caddr e+d+v) " ...")
295         (print "changing current directory to " (cadr e+d+v))
296         (parameterize ((current-directory (cadr e+d+v)))
297           (let ([cmd (make-install-command e+d+v)])
298             (print "  " cmd)
299             ($system cmd))
300           (when (and *run-tests*
301                      (file-exists? "tests")
302                      (directory? "tests")
303                      (file-exists? "tests/run.scm") )
304             (current-directory "tests")
305             (let ((cmd (sprintf "~a -s run.scm ~a" *csi* (car e+d+v))))
306               (print "  " cmd)
307               ($system cmd)))))
308       *eggs+dirs+vers*)))
309
310  (define (cleanup)
311    (unless *keep*
312      (and-let* ((tmpdir (temporary-directory)))
313        (remove-directory tmpdir))))
314
315  (define (update-db)
316    (let* ((files (glob (make-pathname (repository-path) "*.import.*")))
317           (tmpdir (create-temporary-directory))
318           (dbfile (make-pathname tmpdir +module-db+))
319           (rx (regexp ".*/([^/]+)\\.import\\.(scm|so)")))
320      (fluid-let ((##sys#warnings-enabled #f))
321        (for-each
322         (lambda (f)
323           (let ((m (string-match rx f)))
324             (eval `(import ,(string->symbol (cadr m))))))
325         files))
326      (print "generating database")
327      (let ((db
328             (sort
329              (append-map
330               (lambda (m)
331                 (let* ((mod (cdr m))
332                        (mname (##sys#module-name mod)))
333                   (print* " " mname)
334                   (let-values (((_ ve se) (##sys#module-exports mod)))
335                     (append
336                      (map (lambda (se) (list (car se) 'syntax mname)) se)
337                      (map (lambda (ve) (list (car ve) 'value mname)) ve)))))
338               ##sys#module-table)
339              (lambda (e1 e2)
340                (string<? (symbol->string (car e1)) (symbol->string (car e2)))))))
341        (newline)
342        (with-output-to-file dbfile
343          (lambda ()
344            (for-each (lambda (x) (write x) (newline)) db)))
345        (copy-file dbfile (make-pathname (repository-path) +module-db+))
346        (remove-directory tmpdir))))
347
348  (define ($system str)
349    (let ((r (system
350              (if *windows-shell*
351                  (string-append "\"" str "\"")
352                  str))))
353      (unless (zero? r)
354        (error "shell command terminated with nonzero exit code" r str))))
355
356  (define (usage code)
357    (print #<<EOF
358usage: chicken-install [OPTION | EXTENSION[:VERSION]] ...
359
360  -h   -help                    show this message and exit
361  -v   -version                 show version and exit
362       -force                   don't ask, install even if versions don't match
363  -k   -keep                    keep temporary files
364  -l   -location LOCATION       install from given location instead of default
365  -t   -transport TRANSPORT     use given transport instead of default
366  -s   -sudo                    use sudo(1) for installing or removing files
367  -r   -retrieve                only retrieve egg into current directory, don't install
368  -n   -no-install              do not install, just build (implies `-keep')
369  -p   -prefix PREFIX           change installation prefix to PREFIX
370       -host-extension          when cross-compiling, compile extension for host
371       -test                    run included test-cases, if available
372       -username USER           set username for transports that require this
373       -password PASS           set password for transports that require this
374  -i   -init DIRECTORY          initialize empty alternative repository
375  -u   -update-db               update export database
376EOF
377);|
378    (exit code))
379
380  (define *short-options* '(#\h #\k #\l #\t #\s #\p #\r #\n #\v #\i #\u))
381
382  (define (main args)
383    (let ((defaults (load-defaults))
384          (update #f)
385          (rx "([^:]+):(.+)"))
386      (let loop ((args args) (eggs '()))
387        (cond ((null? args)
388               (cond (update (update-db))
389                     (else
390                      (when (null? eggs)
391                        (let ((setups (glob "*.setup")))
392                          (cond ((pair? setups)
393                                 (set! *eggs+dirs+vers*
394                                       (append
395                                        (map
396                                         (lambda (s) (cons (pathname-file s) (list "." "")))
397                                         setups)
398                                        *eggs+dirs+vers*)))
399                                (else
400                                 (print "no setup-scripts to process")
401                                 (exit 1))) ) )
402                      (unless defaults
403                        (unless *default-transport*
404                          (error "no default transport defined - please use `-transport' option"))
405                        (unless *default-location*
406                          (error "no default location defined - please use `-location' option")))
407                      (install (reverse eggs)))))
408              (else
409               (let ((arg (car args)))
410                 (cond ((or (string=? arg "-help")
411                            (string=? arg "-h")
412                            (string=? arg "--help"))
413                        (usage 0))
414                       ((string=? arg "-force")
415                        (set! *force* #t)
416                        (loop (cdr args) eggs))
417                       ((or (string=? arg "-k") (string=? arg "-keep"))
418                        (set! *keep* #t)
419                        (loop (cdr args) eggs))
420                       ((or (string=? arg "-s") (string=? arg "-sudo"))
421                        (sudo-install #t)
422                        (loop (cdr args) eggs))
423                       ((or (string=? arg "-r") (string=? arg "-retrieve"))
424                        (set! *retrieve-only* #t)
425                        (loop (cdr args) eggs))
426                       ((or (string=? arg "-l") (string=? arg "-location"))
427                        (unless (pair? (cdr args)) (usage 1))
428                        (set! *default-location* (cadr args))
429                        (loop (cddr args) eggs))
430                       ((or (string=? arg "-t") (string=? arg "-transport"))
431                        (unless (pair? (cdr args)) (usage 1))
432                        (set! *default-transport* (string->symbol (cadr args)))
433                        (loop (cddr args) eggs))
434                       ((or (string=? arg "-p") (string=? arg "-prefix"))
435                        (unless (pair? (cdr args)) (usage 1))
436                        (set! *prefix* (cadr args))
437                        (loop (cddr args) eggs))
438                       ((or (string=? arg "-n") (string=? arg "-no-install"))
439                        (set! *keep* #t)
440                        (set! *no-install* #t)
441                        (loop (cdr args) eggs))
442                       ((or (string=? arg "-v") (string=? arg "-version"))
443                        (print (chicken-version))
444                        (exit 0))
445                       ((or (string=? arg "-u") (string=? arg "-update-db"))
446                        (set! update #t)
447                        (loop (cdr args) eggs))
448                       ((or (string=? arg "-i") (string=? arg "-init"))
449                        (unless (pair? (cdr args)) (usage 1))
450                        (init-repository (cadr args))
451                        (exit 0))
452                       ((string=? "-test" arg)
453                        (set! *run-tests* #t)
454                        (loop (cdr args) eggs))
455                       ((string=? "-host-extension" arg)
456                        (set! *host-extension* #t)
457                        (loop (cdr args) eggs))
458                       ((string=? "-username" arg)
459                        (unless (pair? (cdr args)) (usage 1))
460                        (set! *username* (cadr args))
461                        (loop (cddr args) eggs))
462                       ((string=? "-password" arg)
463                        (unless (pair? (cdr args)) (usage 1))
464                        (set! *password* (cadr args))
465                        (loop (cddr args) eggs))
466                       ((and (positive? (string-length arg))
467                             (char=? #\- (string-ref arg 0)))
468                        (if (> (string-length arg) 2)
469                            (let ((sos (string->list (substring arg 1))))
470                              (if (null? (lset-intersection eq? *short-options* sos))
471                                  (loop (append (map (cut string #\- <>) sos) (cdr args)) eggs)
472                                  (usage 1)))
473                            (usage 1)))
474                       ((equal? "setup" (pathname-extension arg))
475                        (let ((egg (pathname-file arg)))
476                          (set! *eggs+dirs+vers*
477                            (alist-cons
478                             egg
479                             (list
480                              (let ((dir (pathname-directory arg)))
481                                (if dir
482                                    (if (absolute-pathname? dir)
483                                        dir
484                                        (make-pathname (current-directory) dir) )
485                                    (current-directory)))
486                              "")
487                             *eggs+dirs+vers*))
488                          (loop (cdr args) (cons egg eggs))))
489                       ((string-match rx arg) =>
490                        (lambda (m)
491                          (loop (cdr args) (alist-cons (cadr m) (caddr m) eggs))))
492                       (else (loop (cdr args) (cons arg eggs))))))))))
493
494  (register-feature! 'chicken-install)
495  (define ##compiler#compiler-macro-environment '()) ; only to make `compiler' import work
496
497  (handle-exceptions ex
498      (begin
499        (print-error-message ex (current-error-port))
500        (cleanup)
501        (exit 1))
502    (main (command-line-arguments))
503    (cleanup))
504
505) ;module main
Note: See TracBrowser for help on using the repository browser.