source: project/build/base.scm @ 2904

;;;; base.scm


#+(not csi)
(declare
  (export CC C++ OPTIM LINK LINKFLAGS LINKLIBS CSC AR SUFSHR CSCFLAGS SHAREDFLAGS
          CSCOPTIM RANLIB CSCLIBS SHELLMODE FILEMODE EXEMODE CCFLAGS C++FLAGS
          SCANHEADERS BUILD_VERSION SUFDLSHR CSCLINKFLAGS SUFEXE SUFOBJ SUFLIB HDRSCAN INCLUDEDIRS
          link main-from-objects main cc c++ library object objects link-library scheme-extension
          link-shared-library csc user-object scheme-main scheme-link clean install-file
          install-bin install-man install-shell shared-library install-lib) )


(define BUILD_VERSION +version+)
(define CC "cc")
(define C++ "c++")
(define OPTIM "-g")
(define CSCOPTIM "-O2 -d1")
(define CSC "csc")
(define AR "ar ru")
(define RANLIB "ranlib")
(define SUFSHR (if (eq? (software-version) 'macosx) ".dylib" ".so"))
(define SHAREDFLAGS (if (eq? (software-version) 'macosx) "-dynamiclib" "-shared"))
(define SHELLMODE #o755)
(define FILEMODE #o644)
(define EXEMODE #o755)
(define LINKLIBS "")
(define CSCLIBS "")
(define LINKFLAGS "")
(define C++FLAGS "")
(define CCFLAGS "")
(define CSCFLAGS "")
(define CSCLINKFLAGS "")
(define SCANHEADERS #t)
(define LINK #f)
(define SUFDLSHR "so")
(define SUFEXE "")
(define SUFOBJ "o")
(define SUFLIB "a")
(define HDRSCAN "(^|\n)[ \t]*#[ \t]*include[ \t]*[\"]([^\"]+)[\"]")
(define INCLUDEDIRS '())


(define (link image . objs)
  (actions
   "link"
   image
   (lambda _ 
     (run (,($ LINK CC) -o ,image ,@(normalize objs) ,($ LINKFLAGS) ,($ LINKLIBS))))))

(define (scheme-link image . objs)
  (actions
   "link Scheme"
   image
   (lambda _ 
     (run (,($ CSC) -o ,image ,@(normalize objs) ,($ CSCLINKFLAGS) ,($ CSCLIBS))))))

(define (link-shared-library image . objs)
  (let ((image (suffix ($ SUFSHR) image))
        (objs (normalize objs)) )
    (depends "all" image)
    (depends image objs)
    (clean image)
    (actions 
     "link" image
     (lambda _ (run (,($ LINK CC) ,($ SHAREDFLAGS) -o ,image ,@objs ,($ LINKFLAGS) ,($ LINKLIBS) )))) ) )

(define (scheme-extension ext . srcs)
  (let* ((ext (suffix ($ SUFDLSHR) ext))
         (srcs (normalize srcs))
         (os (map (cut suffix SUFOBJ <>) (normalize srcs))))
    (objects srcs)
    (for-each (lambda (o) (set! (on o 'CSCFLAGS) (conc (on o 'CSCFLAGS ($ CSCFLAGS)) " -s "))) os)
    (depends "all" ext)
    (depends ext os)
    (clean ext)
    (actions 
     "link scheme extension" ext
     ^{,($ CSC) -s -o ,ext ,@os ,($ CSCLINKFLAGS) ,($ CSCLIBS)} ) ) )

(define (link-library lib . objs)
  (let ((lib (suffix SUFLIB lib))
        (objs (normalize objs)) )
    (depends "all" lib)
    (depends lib objs)
    (clean lib)
    (actions 
     "link library" lib
     (lambda _
       (run (,($ AR) ,lib ,@objs))
       (run (,($ RANLIB) ,lib)) ) ) ) )

(define (main-from-objects image . objs)
  (let ((objs (normalize objs)))
    (depends "all" image)
    (clean image objs)
    (depends image objs)
    (apply link image objs) ) )

(define (main image . srcs)
  (objects srcs)
  (let ((os (map (cut suffix SUFOBJ <>) (normalize srcs))))
    (apply main-from-objects image os) ) )

(define (shared-library image . srcs)
  (objects srcs)
  (let ((os (map (cut suffix SUFOBJ <>) (normalize srcs))))
    (apply link-shared-library image os) ) )

(define (scheme-main image . srcs)
  (let ((objs (suffix SUFOBJ srcs)))
    (objects srcs)
    (depends "all" image)
    (clean image objs)
    (depends image objs)
    (apply scheme-link image objs) ) )

(define (library lib . srcs)
  (let ((srcs (normalize srcs)))
    (let ((os (map (cut suffix SUFOBJ <>) srcs)))
      (apply link-library lib os)
      (for-each cc os srcs) ) ) ) 

(define (c-headers obj src)
  (when (->boolean SCANHEADERS)
    (when (file-exists? src)
      (depends obj (scan-headers src *VERBOSE* INCLUDEDIRS HDRSCAN))) ) )

(define (cc obj src)
  (let ((obj (suffix SUFOBJ obj)))
    (depends obj src)
    (clean obj)
    (c-headers obj src)
    (actions 
     "cc" obj
     (lambda _ 
       (run (,($ CC) ,($ CCFLAGS) ,($ OPTIM) -c ,src -o ,obj) ) ) ) ) )

(define (c++ obj src)
  (let ((obj (suffix SUFOBJ obj)))
    (depends obj src)
    (clean obj)
    (c-headers obj src)
    (actions 
     "c++" obj
     (lambda _ 
       (run (,($ C++) ,($ C++FLAGS) ,($ OPTIM) -c ,src -o ,obj) ) ) ) ) )

(define (csc obj src)
  (let ((obj (suffix SUFOBJ obj)))
    (depends obj src)
    (clean obj)
    (actions 
     "csc" obj
     (lambda _ 
       (run (,($ CSC) ,($ CSCFLAGS) ,($ CSCOPTIM) -c ,src -o ,obj) ) ) ) ) )

(define (object t s)
  (let ((ext (suffix s)))
    (cond ((not ext) (user-object t s))
          ((member ext '("cc" "cpp" "c++" "cxx" "C")) (c++ t s))
          ((string=? ext "c") (cc t s))
          ((member ext '("scm" "ss")) (csc t s))
          (else (user-object t s)) ) 
    (depends t s) ) )

(define (objects . srcs)
  (for-each
   (lambda (s)
     (object (suffix SUFOBJ s) s) )
   (normalize srcs)) )

(define clean
  (let ((cleaned '()))
    (lambda targets
      (set! cleaned (lset-union string=? cleaned (normalize targets)))
      (actions 
       "clean"
       "clean"
       (lambda _ (run (rm -f ,@cleaned))) ) ) ) )

(define (user-object t s)
  (quit "unable to infer source type of ~a for target ~a" s t) )

(define (ensuredir dir)
  (unless (file-exists? dir) (run (mkdir -p ,dir))))

(define *installed-bins* '())
(define *installed-mans* '())
(define *installed-scripts* '())
(define *installed-files* '())
(define *installed-libs* '())

(notfile "all" "clean" "install" "install-bin" "install-lib" "install-file" "install-man" "install-shell")

(actions
 "install-bin"
 (lambda _
   (for-each 
    (lambda (i)
      (let ((dir (car i))
            (f (cdr i)) )
        (ensuredir dir)
        (run (install -m ,(->mode ($ EXEMODE)) ,f ,dir)) ) )
    *installed-bins*) ) )   

(actions
 "install-file"
 (lambda _
   (for-each 
    (lambda (i)
      (let ((dir (car i))
            (f (cdr i)) )
        (ensuredir dir)
        (run (install -m ,(->mode ($ FILEMODE)) ,f ,dir)) ) )
    *installed-files*) ) )   

(actions
 "install-lib"
 (lambda _
   (for-each 
    (lambda (i)
      (let ((dir (car i))
            (f (cdr i)) )
        (ensuredir dir)
        (run (install -m ,(->mode ($ FILEMODE)) ,f ,dir))
        (when (eq? 'macosx (software-version)) (run (,RANLIB ,(prefix dir f))) ) ) )
    *installed-libs*) ) )   

(actions
 "install-man"
 (lambda _
   (for-each 
    (lambda (i)
      (let ((dir (car i))
            (f (cdr i)) )
        (let ((dir2 (make-pathname dir (conc "man" (suffix f)))))
          (ensuredir dir2)
          (run (install -m ,(->mode ($ FILEMODE)) ,f ,dir2))) ) )
    *installed-mans*) ) )   

(actions
 "install-shell"
 (lambda _
   (for-each 
    (lambda (i)
      (let ((dir (car i))
            (f (cdr i)) )
        (ensuredir dir)
        (run (install -m ,(->mode ($ SHELLMODE)) ,f ,dir)) ) )
    *installed-scripts*) ) )

(define (install-bin dir . srcs)
  (depends "install-bin" srcs)
  (set! *installed-bins* (lset-union equal? *installed-bins* (map (cut cons dir <>) (normalize srcs)))) )

(define (install-file dir . srcs)
  (depends "install-file" srcs)
  (set! *installed-files* (lset-union equal? *installed-files* (map (cut cons dir <>) (normalize srcs))) ) )

(define (install-lib dir . srcs)
  (depends "install-lib" srcs)
  (set! *installed-libs* (lset-union equal? *installed-libs* (map (cut cons dir <>) (normalize srcs))) ) )

(define (install-man dir . srcs)
  (depends "install-man" srcs)
  (set! *installed-mans* (lset-union equal? *installed-mans* (map (cut cons dir <>) (normalize srcs)))))

(define (install-shell dir . srcs)
  (depends "install-shell" srcs)
  (set! *installed-scripts* (lset-union equal? *installed-scripts* (map (cut cons dir <>) (normalize srcs)))))

(depends "install" "install-bin" "install-lib" "install-file" "install-man" "install-shell")